matita/matita/lib/turing/mono.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||
   8     \   /  This file is distributed under the terms of the
   9      \ /   GNU General Public License Version 2
  10       V_____________________________________________________________*)
  11
  12 include "basics/vectors.ma".
  13 (* include "basics/relations.ma". *)
  14
  15 (******************************** tape ****************************************)
  16
  17 (* A tape is essentially a triple 〈left,current,right〉 where however the current
  18 symbol could be missing. This may happen for three different reasons: both tapes
  19 are empty; we are on the left extremity of a non-empty tape (left overflow), or
  20 we are on the right extremity of a non-empty tape (right overflow). *)
  21
  22 inductive tape (sig:FinSet) : Type[0] ≝
  23 | niltape : tape sig
  24 | leftof  : sig → list sig → tape sig
  25 | rightof : sig → list sig → tape sig
  26 | midtape : list sig → sig → list sig → tape sig.
  27
  28 definition left ≝
  29  λsig.λt:tape sig.match t with
  30  [ niltape ⇒ [] | leftof _ _ ⇒ [] | rightof s l ⇒ s::l | midtape l _ _ ⇒ l ].
  31
  32 definition right ≝
  33  λsig.λt:tape sig.match t with
  34  [ niltape ⇒ [] | leftof s r ⇒ s::r | rightof _ _ ⇒ []| midtape _ _ r ⇒ r ].
  35
  36 definition current ≝
  37  λsig.λt:tape sig.match t with
  38  [ midtape _ c _ ⇒ Some ? c | _ ⇒ None ? ].
  39
  40 definition mk_tape :
  41   ∀sig:FinSet.list sig → option sig → list sig → tape sig ≝
  42   λsig,lt,c,rt.match c with
  43   [ Some c' ⇒ midtape sig lt c' rt
  44   | None ⇒ match lt with
  45     [ nil ⇒ match rt with
  46       [ nil ⇒ niltape ?
  47       | cons r0 rs0 ⇒ leftof ? r0 rs0 ]
  48     | cons l0 ls0 ⇒ rightof ? l0 ls0 ] ].
  49
  50 inductive move : Type[0] ≝
  51   | L : move | R : move | N : move.
  52
  53 (********************************** machine ***********************************)
  54
  55 record TM (sig:FinSet): Type[1] ≝
  56 { states : FinSet;
  57   trans : states × (option sig) → states × (option (sig × move));
  58   start: states;
  59   halt : states → bool
  60 }.
  61
  62 definition tape_move_left ≝ λsig:FinSet.λlt:list sig.λc:sig.λrt:list sig.
  63   match lt with
  64   [ nil ⇒ leftof sig c rt
  65   | cons c0 lt0 ⇒ midtape sig lt0 c0 (c::rt) ].
  66
  67 definition tape_move_right ≝ λsig:FinSet.λlt:list sig.λc:sig.λrt:list sig.
  68   match rt with
  69   [ nil ⇒ rightof sig c lt
  70   | cons c0 rt0 ⇒ midtape sig (c::lt) c0 rt0 ].
  71
  72 definition tape_move ≝ λsig.λt: tape sig.λm:option (sig × move).
  73   match m with
  74   [ None ⇒ t
  75   | Some m' ⇒
  76     let 〈s,m1〉 ≝ m' in
  77     match m1 with
  78       [ R ⇒ tape_move_right ? (left ? t) s (right ? t)
  79       | L ⇒ tape_move_left ? (left ? t) s (right ? t)
  80       | N ⇒ midtape ? (left ? t) s (right ? t)
  81       ] ].
  82
  83 record config (sig,states:FinSet): Type[0] ≝
  84 { cstate : states;
  85   ctape: tape sig
  86 }.
  87
  88 definition step ≝ λsig.λM:TM sig.λc:config sig (states sig M).
  89   let current_char ≝ current ? (ctape ?? c) in
  90   let 〈news,mv〉 ≝ trans sig M 〈cstate ?? c,current_char〉 in
  91   mk_config ?? news (tape_move sig (ctape ?? c) mv).
  92
  93 (******************************** loop ****************************************)
  94 let rec loop (A:Type[0]) n (f:A→A) p a on n ≝
  95   match n with
  96   [ O ⇒ None ?
  97   | S m ⇒ if p a then (Some ? a) else loop A m f p (f a)
  98   ].
  99
 100 lemma loop_S_true :
 101   ∀A,n,f,p,a. p a = true →
 102     loop A (S n) f p a = Some ? a.
 103 #A #n #f #p #a #pa normalize >pa //
 104 qed.
 105
 106 lemma loop_S_false :
 107   ∀A,n,f,p,a.  p a = false →
 108     loop A (S n) f p a = loop A n f p (f a).
 109 normalize #A #n #f #p #a #Hpa >Hpa %
 110 qed.
 111
 112 lemma loop_incr : ∀A,f,p,k1,k2,a1,a2.
 113   loop A k1 f p a1 = Some ? a2 →
 114     loop A (k2+k1) f p a1 = Some ? a2.
 115 #A #f #p #k1 #k2 #a1 #a2 generalize in match a1; elim k1
 116 [normalize #a0 #Hfalse destruct
 117 |#k1' #IH #a0 <plus_n_Sm whd in ⊢ (??%? → ??%?);
 118  cases (true_or_false (p a0)) #Hpa0 >Hpa0 whd in ⊢ (??%? → ??%?); // @IH
 119 ]
 120 qed.
 121
 122 lemma loop_merge : ∀A,f,p,q.(∀b. p b = false → q b = false) →
 123  ∀k1,k2,a1,a2,a3,a4.
 124    loop A k1 f p a1 = Some ? a2 →
 125      f a2 = a3 → q a2 = false →
 126        loop A k2 f q a3 = Some ? a4 →
 127          loop A (k1+k2) f q a1 = Some ? a4.
 128 #Sig #f #p #q #Hpq #k1 elim k1
 129   [normalize #k2 #a1 #a2 #a3 #a4 #H destruct
 130   |#k1' #Hind #k2 #a1 #a2 #a3 #a4 normalize in ⊢ (%→?);
 131    cases (true_or_false (p a1)) #pa1 >pa1 normalize in ⊢ (%→?);
 132    [#eqa1a2 destruct #eqa2a3 #Hqa2 #H
 133     whd in ⊢ (??(??%???)?); >plus_n_Sm @loop_incr
 134     whd in ⊢ (??%?); >Hqa2 >eqa2a3 @H
 135    |normalize >(Hpq … pa1) normalize #H1 #H2 #H3 @(Hind … H2) //
 136    ]
 137  ]
 138 qed.
 139
 140 lemma loop_split : ∀A,f,p,q.(∀b. q b = true → p b = true) →
 141  ∀k,a1,a2.
 142    loop A k f q a1 = Some ? a2 →
 143    ∃k1,a3.
 144     loop A k1 f p a1 = Some ? a3 ∧
 145       loop A (S(k-k1)) f q a3 = Some ? a2.
 146 #A #f #p #q #Hpq #k elim k
 147   [#a1 #a2 normalize #Heq destruct
 148   |#i #Hind #a1 #a2 normalize
 149    cases (true_or_false (q a1)) #Hqa1 >Hqa1 normalize
 150     [ #Ha1a2 destruct
 151      @(ex_intro … 1) @(ex_intro … a2) %
 152        [normalize >(Hpq …Hqa1) // |>Hqa1 //]
 153     |#Hloop cases (true_or_false (p a1)) #Hpa1
 154        [@(ex_intro … 1) @(ex_intro … a1) %
 155          [normalize >Hpa1 // |>Hqa1 <Hloop normalize //]
 156        |cases (Hind …Hloop) #k2 * #a3 * #Hloop1 #Hloop2
 157         @(ex_intro … (S k2)) @(ex_intro … a3) %
 158          [normalize >Hpa1 normalize // | @Hloop2 ]
 159        ]
 160     ]
 161   ]
 162 qed.
 163
 164 lemma loop_eq : ∀sig,f,q,i,j,a,x,y.
 165   loop sig i f q a = Some ? x → loop sig j f q a = Some ? y → x = y.
 166 #sig #f #q #i #j @(nat_elim2 … i j)
 167 [ #n #a #x #y normalize #Hfalse destruct (Hfalse)
 168 | #n #a #x #y #H1 normalize #Hfalse destruct (Hfalse)
 169 | #n1 #n2 #IH #a #x #y normalize cases (q a) normalize
 170   [ #H1 #H2 destruct %
 171   | /2/ ]
 172 ]
 173 qed.
 174
 175 (************************** Realizability *************************************)
 176 definition loopM ≝ λsig,M,i,cin.
 177   loop ? i (step sig M) (λc.halt sig M (cstate ?? c)) cin.
 178
 179 definition initc ≝ λsig.λM:TM sig.λt.
 180   mk_config sig (states sig M) (start sig M) t.
 181
 182 definition Realize ≝ λsig.λM:TM sig.λR:relation (tape sig).
 183 ∀t.∃i.∃outc.
 184   loopM sig M i (initc sig M t) = Some ? outc ∧ R t (ctape ?? outc).
 185
 186 definition WRealize ≝ λsig.λM:TM sig.λR:relation (tape sig).
 187 ∀t,i,outc.
 188   loopM sig M i (initc sig M t) = Some ? outc → R t (ctape ?? outc).
 189
 190 definition Terminate ≝ λsig.λM:TM sig.λt. ∃i,outc.
 191   loopM sig M i (initc sig M t) = Some ? outc.
 192
 193 notation "M \vDash R" non associative with precedence 45 for @{ 'models $M $R}.
 194 interpretation "realizability" 'models M R = (Realize ? M R).
 195
 196 notation "M \VDash R" non associative with precedence 45 for @{ 'wmodels $M $R}.
 197 interpretation "weak realizability" 'wmodels M R = (WRealize ? M R).
 198
 199 interpretation "termination" 'fintersects M t = (Terminate ? M t).
 200
 201 lemma WRealize_to_Realize : ∀sig.∀M: TM sig.∀R.
 202   (∀t.M ↓ t) → M ⊫ R → M ⊨ R.
 203 #sig #M #R #HT #HW #t cases (HT … t) #i * #outc #Hloop
 204 @(ex_intro … i) @(ex_intro … outc) % // @(HW … i) //
 205 qed.
 206
 207 theorem Realize_to_WRealize : ∀sig.∀M:TM sig.∀R.
 208   M ⊨ R → M ⊫ R.
 209 #sig #M #R #H1 #inc #i #outc #Hloop
 210 cases (H1 inc) #k * #outc1 * #Hloop1 #HR >(loop_eq … Hloop Hloop1) //
 211 qed.
 212
 213 definition accRealize ≝ λsig.λM:TM sig.λacc:states sig M.λRtrue,Rfalse.
 214 ∀t.∃i.∃outc.
 215   loopM sig M i (initc sig M t) = Some ? outc ∧
 216     (cstate ?? outc = acc → Rtrue t (ctape ?? outc)) ∧
 217     (cstate ?? outc ≠ acc → Rfalse t (ctape ?? outc)).
 218
 219 (******************************** NOP Machine *********************************)
 220
 221 (* NO OPERATION
 222    t1 = t2 *)
 223
 224 definition nop_states ≝ initN 1.
 225 definition start_nop : initN 1 ≝ mk_Sig ?? 0 (le_n … 1).
 226
 227 definition nop ≝
 228   λalpha:FinSet.mk_TM alpha nop_states
 229   (λp.let 〈q,a〉 ≝ p in 〈q,None ?〉)
 230   start_nop (λ_.true).
 231
 232 definition R_nop ≝ λalpha.λt1,t2:tape alpha.t2 = t1.
 233
 234 lemma sem_nop :
 235   ∀alpha.nop alpha ⊨ R_nop alpha.
 236 #alpha #intape @(ex_intro ?? 1)
 237 @(ex_intro … (mk_config ?? start_nop intape)) % %
 238 qed.
 239
 240 (************************** Sequential Composition ****************************)
 241
 242 definition seq_trans ≝ λsig. λM1,M2 : TM sig.
 243 λp. let 〈s,a〉 ≝ p in
 244   match s with
 245   [ inl s1 ⇒
 246       if halt sig M1 s1 then 〈inr … (start sig M2), None ?〉
 247       else let 〈news1,m〉 ≝ trans sig M1 〈s1,a〉 in 〈inl … news1,m〉
 248   | inr s2 ⇒ let 〈news2,m〉 ≝ trans sig M2 〈s2,a〉 in 〈inr … news2,m〉
 249   ].
 250
 251 definition seq ≝ λsig. λM1,M2 : TM sig.
 252   mk_TM sig
 253     (FinSum (states sig M1) (states sig M2))
 254     (seq_trans sig M1 M2)
 255     (inl … (start sig M1))
 256     (λs.match s with
 257       [ inl _ ⇒ false | inr s2 ⇒ halt sig M2 s2]).
 258
 259 notation "a · b" non associative with precedence 65 for @{ 'middot $a $b}.
 260 interpretation "sequential composition" 'middot a b = (seq ? a b).
 261
 262 definition Rcomp ≝ λA.λR1,R2:relation A.λa1,a2.
 263   ∃am.R1 a1 am ∧ R2 am a2.
 264
 265 interpretation "relation composition" 'compose R1 R2 = (Rcomp ? R1 R2).
 266
 267 definition lift_confL ≝
 268   λsig,S1,S2,c.match c with
 269   [ mk_config s t ⇒ mk_config sig (FinSum S1 S2) (inl … s) t ].
 270
 271 definition lift_confR ≝
 272   λsig,S1,S2,c.match c with
 273   [ mk_config s t ⇒ mk_config sig (FinSum S1 S2) (inr … s) t ].
 274
 275 definition halt_liftL ≝
 276   λS1,S2,halt.λs:FinSum S1 S2.
 277   match s with
 278   [ inl s1 ⇒ halt s1
 279   | inr _ ⇒ true ]. (* should be vacuous in all cases we use halt_liftL *)
 280
 281 definition halt_liftR ≝
 282   λS1,S2,halt.λs:FinSum S1 S2.
 283   match s with
 284   [ inl _ ⇒ false
 285   | inr s2 ⇒ halt s2 ].
 286
 287 lemma p_halt_liftL : ∀sig,S1,S2,halt,c.
 288   halt (cstate sig S1 c) =
 289      halt_liftL S1 S2 halt (cstate … (lift_confL … c)).
 290 #sig #S1 #S2 #halt #c cases c #s #t %
 291 qed.
 292
 293 lemma trans_liftL : ∀sig,M1,M2,s,a,news,move.
 294   halt ? M1 s = false →
 295   trans sig M1 〈s,a〉 = 〈news,move〉 →
 296   trans sig (seq sig M1 M2) 〈inl … s,a〉 = 〈inl … news,move〉.
 297 #sig (*#M1*) * #Q1 #T1 #init1 #halt1 #M2 #s #a #news #move
 298 #Hhalt #Htrans whd in ⊢ (??%?); >Hhalt >Htrans %
 299 qed.
 300
 301 lemma trans_liftR : ∀sig,M1,M2,s,a,news,move.
 302   halt ? M2 s = false →
 303   trans sig M2 〈s,a〉 = 〈news,move〉 →
 304   trans sig (seq sig M1 M2) 〈inr … s,a〉 = 〈inr … news,move〉.
 305 #sig #M1 * #Q2 #T2 #init2 #halt2 #s #a #news #move
 306 #Hhalt #Htrans whd in ⊢ (??%?); >Hhalt >Htrans %
 307 qed.
 308
 309 lemma config_eq :
 310   ∀sig,M,c1,c2.
 311   cstate sig M c1 = cstate sig M c2 →
 312   ctape sig M c1 = ctape sig M c2 →  c1 = c2.
 313 #sig #M1 * #s1 #t1 * #s2 #t2 //
 314 qed.
 315
 316 lemma step_lift_confR : ∀sig,M1,M2,c0.
 317  halt ? M2 (cstate ?? c0) = false →
 318  step sig (seq sig M1 M2) (lift_confR sig (states ? M1) (states ? M2) c0) =
 319  lift_confR sig (states ? M1) (states ? M2) (step sig M2 c0).
 320 #sig #M1 (* * #Q1 #T1 #init1 #halt1 *) #M2 * #s #t
 321   lapply (refl ? (trans ?? 〈s,current sig t〉))
 322   cases (trans ?? 〈s,current sig t〉) in ⊢ (???% → %);
 323   #s0 #m0 cases t
 324   [ #Heq #Hhalt
 325   | 2,3: #s1 #l1 #Heq #Hhalt
 326   |#ls #s1 #rs #Heq #Hhalt ]
 327   whd in ⊢ (???(????%)); >Heq whd in ⊢ (???%);
 328   whd in ⊢ (??(???%)?); whd in ⊢ (??%?); >(trans_liftR … Heq) //
 329 qed.
 330
 331 lemma step_lift_confL : ∀sig,M1,M2,c0.
 332  halt ? M1 (cstate ?? c0) = false →
 333  step sig (seq sig M1 M2) (lift_confL sig (states ? M1) (states ? M2) c0) =
 334  lift_confL sig ?? (step sig M1 c0).
 335 #sig #M1 (* * #Q1 #T1 #init1 #halt1 *) #M2 * #s #t
 336   lapply (refl ? (trans ?? 〈s,current sig t〉))
 337   cases (trans ?? 〈s,current sig t〉) in ⊢ (???% → %);
 338   #s0 #m0 cases t
 339   [ #Heq #Hhalt
 340   | 2,3: #s1 #l1 #Heq #Hhalt
 341   |#ls #s1 #rs #Heq #Hhalt ]
 342   whd in ⊢ (???(????%)); >Heq whd in ⊢ (???%);
 343   whd in ⊢ (??(???%)?); whd in ⊢ (??%?); >(trans_liftL … Heq) //
 344 qed.
 345
 346 lemma loop_lift : ∀A,B,k,lift,f,g,h,hlift,c1,c2.
 347   (∀x.hlift (lift x) = h x) →
 348   (∀x.h x = false → lift (f x) = g (lift x)) →
 349   loop A k f h c1 = Some ? c2 →
 350   loop B k g hlift (lift c1) = Some ? (lift … c2).
 351 #A #B #k #lift #f #g #h #hlift #c1 #c2 #Hfg #Hhlift
 352 generalize in match c1; elim k
 353 [#c0 normalize in ⊢ (??%? → ?); #Hfalse destruct (Hfalse)
 354 |#k0 #IH #c0 whd in ⊢ (??%? → ??%?);
 355  cases (true_or_false (h c0)) #Hc0 >Hfg >Hc0 normalize
 356  [ #Heq destruct (Heq) % | <Hhlift // @IH ]
 357 qed.
 358
 359 lemma loop_Some :
 360   ∀A,k,f,p,a,b.loop A k f p a = Some ? b → p b = true.
 361 #A #k #f #p elim k
 362   [#a #b normalize #Hfalse destruct
 363   |#k0 #IH #a #b whd in ⊢ (??%? → ?); cases (true_or_false (p a)) #Hpa
 364     [ >Hpa normalize #H1 destruct // | >Hpa normalize @IH ]
 365   ]
 366 qed.
 367
 368 lemma trans_liftL_true : ∀sig,M1,M2,s,a.
 369   halt ? M1 s = true →
 370   trans sig (seq sig M1 M2) 〈inl … s,a〉 = 〈inr … (start ? M2),None ?〉.
 371 #sig #M1 #M2 #s #a #Hhalt whd in ⊢ (??%?); >Hhalt %
 372 qed.
 373
 374 lemma eq_ctape_lift_conf_L : ∀sig,S1,S2,outc.
 375   ctape sig (FinSum S1 S2) (lift_confL … outc) = ctape … outc.
 376 #sig #S1 #S2 #outc cases outc #s #t %
 377 qed.
 378
 379 lemma eq_ctape_lift_conf_R : ∀sig,S1,S2,outc.
 380   ctape sig (FinSum S1 S2) (lift_confR … outc) = ctape … outc.
 381 #sig #S1 #S2 #outc cases outc #s #t %
 382 qed.
 383
 384 theorem sem_seq: ∀sig.∀M1,M2:TM sig.∀R1,R2.
 385   M1 ⊨ R1 → M2 ⊨ R2 → M1 · M2 ⊨ R1 ∘ R2.
 386 #sig #M1 #M2 #R1 #R2 #HR1 #HR2 #t
 387 cases (HR1 t) #k1 * #outc1 * #Hloop1 #HM1
 388 cases (HR2 (ctape sig (states ? M1) outc1)) #k2 * #outc2 * #Hloop2 #HM2
 389 @(ex_intro … (k1+k2)) @(ex_intro … (lift_confR … outc2))
 390 %
 391 [@(loop_merge ???????????
 392    (loop_lift ??? (lift_confL sig (states sig M1) (states sig M2))
 393    (step sig M1) (step sig (seq sig M1 M2))
 394    (λc.halt sig M1 (cstate … c))
 395    (λc.halt_liftL ?? (halt sig M1) (cstate … c)) … Hloop1))
 396   [ * *
 397    [ #sl #tl whd in ⊢ (??%? → ?); #Hl %
 398    | #sr #tr whd in ⊢ (??%? → ?); #Hr destruct (Hr) ]
 399   || #c0 #Hhalt <step_lift_confL //
 400   | #x <p_halt_liftL %
 401   |6:cases outc1 #s1 #t1 %
 402   |7:@(loop_lift … (initc ?? (ctape … outc1)) … Hloop2)
 403     [ * #s2 #t2 %
 404     | #c0 #Hhalt <step_lift_confR // ]
 405   |whd in ⊢ (??(???%)?);whd in ⊢ (??%?);
 406    generalize in match Hloop1; cases outc1 #sc1 #tc1 #Hloop10
 407    >(trans_liftL_true sig M1 M2 ??)
 408     [ whd in ⊢ (??%?); whd in ⊢ (???%);
 409       @config_eq whd in ⊢ (???%); //
 410     | @(loop_Some ?????? Hloop10) ]
 411  ]
 412 | @(ex_intro … (ctape ? (FinSum (states ? M1) (states ? M2)) (lift_confL … outc1)))
 413   % // >eq_ctape_lift_conf_L >eq_ctape_lift_conf_R //
 414 ]
 415 qed.
 416