matita/matita/lib/turing/multi_universal/match.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "turing/simple_machines.ma".
  16 include "turing/multi_universal/compare.ma".
  17 include "turing/multi_universal/par_test.ma".
  18 include "turing/multi_universal/moves_2.ma".
  19
  20 lemma eq_vec_change_vec : ∀sig,n.∀v1,v2:Vector sig n.∀i,t,d.
  21   nth i ? v2 d = t →
  22   (∀j.i ≠ j → nth j ? v1 d = nth j ? v2 d) →
  23   v2 = change_vec ?? v1 t i.
  24 #sig #n #v1 #v2 #i #t #d #H1 #H2 @(eq_vec … d)
  25 #i0 #Hlt cases (decidable_eq_nat i0 i) #Hii0
  26 [ >Hii0 >nth_change_vec //
  27 | >nth_change_vec_neq [|@sym_not_eq //] @sym_eq @H2 @sym_not_eq // ]
  28 qed.
  29
  30 lemma right_mk_tape :
  31   ∀sig,ls,c,rs.(c = None ? → ls = [ ] ∨ rs = [ ]) → right ? (mk_tape sig ls c rs) = rs.
  32 #sig #ls #c #rs cases c // cases ls
  33 [ cases rs //
  34 | #l0 #ls0 #H normalize cases (H (refl ??)) #H1 [ destruct (H1) | >H1 % ] ]
  35 qed.
  36
  37 lemma left_mk_tape : ∀sig,ls,c,rs.left ? (mk_tape sig ls c rs) = ls.
  38 #sig #ls #c #rs cases c // cases ls // cases rs //
  39 qed.
  40
  41 lemma current_mk_tape : ∀sig,ls,c,rs.current ? (mk_tape sig ls c rs) = c.
  42 #sig #ls #c #rs cases c // cases ls // cases rs //
  43 qed.
  44
  45 lemma length_tail : ∀A,l.0 < |l| → |tail A l| < |l|.
  46 #A * normalize //
  47 qed.
  48
  49 (*
  50 [ ]   → [ ], l2, 1
  51 a::al →
  52       [ ]   → [ ], l1, 2
  53       b::bl → match rec(al,bl)
  54             x, y, 1 → b::x, y, 1
  55             x, y, 2 → a::x, y, 2
  56 *)
  57
  58 lemma lists_length_split :
  59  ∀A.∀l1,l2:list A.(∃la,lb.(|la| = |l1| ∧ l2 = la@lb) ∨ (|la| = |l2| ∧ l1 = la@lb)).
  60 #A #l1 elim l1
  61 [ #l2 %{[ ]} %{l2} % % %
  62 | #hd1 #tl1 #IH *
  63   [ %{[ ]} %{(hd1::tl1)} %2 % %
  64   | #hd2 #tl2 cases (IH tl2) #x * #y *
  65     [ * #IH1 #IH2 %{(hd2::x)} %{y} % normalize % //
  66     | * #IH1 #IH2 %{(hd1::x)} %{y} %2 normalize % // ]
  67   ]
  68 ]
  69 qed.
  70
  71 definition option_cons ≝ λsig.λc:option sig.λl.
  72   match c with [ None ⇒ l | Some c0 ⇒ c0::l ].
  73
  74 lemma opt_cons_tail_expand : ∀A,l.l = option_cons A (option_hd ? l) (tail ? l).
  75 #A * //
  76 qed.
  77
  78 definition match_test ≝ λsrc,dst.λsig:DeqSet.λn.λv:Vector ? n.
  79   match (nth src (option sig) v (None ?)) with
  80   [ None ⇒  false
  81   | Some x ⇒  notb (nth dst (DeqOption sig) v (None ?) == None ?) ].
  82
  83 definition rewind ≝ λsrc,dst,sig,n.
  84   parmove src dst sig n L · mmove src sig n R · mmove dst sig n R.
  85
  86 definition R_rewind_strong ≝ λsrc,dst,sig,n.λint,outt: Vector (tape sig) (S n).
  87   (∀x,x0,xs,rs.
  88     nth src ? int (niltape ?) = midtape sig (xs@[x0]) x rs →
  89     ∀ls0,y,y0,target,rs0.|xs| = |target| →
  90     nth dst ? int (niltape ?) = midtape sig (target@y0::ls0) y rs0 →
  91     outt = change_vec ??
  92            (change_vec ?? int (midtape sig [] x0 (reverse ? xs@x::rs)) src)
  93            (midtape sig ls0 y0 (reverse ? target@y::rs0)) dst) ∧
  94   (∀x,x0,xs,rs.
  95     nth dst ? int (niltape ?) = midtape sig (xs@[x0]) x rs →
  96     ∀ls0,y,y0,target,rs0.|xs| = |target| →
  97     nth src ? int (niltape ?) = midtape sig (target@y0::ls0) y rs0 →
  98     outt = change_vec ??
  99            (change_vec ?? int (midtape sig [] x0 (reverse ? xs@x::rs)) dst)
 100            (midtape sig ls0 y0 (reverse ? target@y::rs0)) src) ∧
 101   (∀x,rs.nth src ? int (niltape ?) = midtape sig [] x rs →
 102    ∀ls0,y,rs0.nth dst ? int (niltape ?) = midtape sig ls0 y rs0 →
 103    outt = int) ∧
 104   (∀x,rs.nth dst ? int (niltape ?) = midtape sig [] x rs →
 105    ∀ls0,y,rs0.nth src ? int (niltape ?) = midtape sig ls0 y rs0 →
 106    outt = int).
 107
 108 definition R_rewind ≝ λsrc,dst,sig,n.λint,outt: Vector (tape sig) (S n).
 109   (∀x,x0,xs,rs.
 110     nth src ? int (niltape ?) = midtape sig (xs@[x0]) x rs →
 111     ∀ls0,y,y0,target,rs0.|xs| = |target| →
 112     nth dst ? int (niltape ?) = midtape sig (target@y0::ls0) y rs0 →
 113     outt = change_vec ??
 114            (change_vec ?? int (midtape sig [] x0 (reverse ? xs@x::rs)) src)
 115            (midtape sig ls0 y0 (reverse ? target@y::rs0)) dst) ∧
 116   (∀x,rs.nth src ? int (niltape ?) = midtape sig [] x rs →
 117    ∀ls0,y,rs0.nth dst ? int (niltape ?) = midtape sig ls0 y rs0 →
 118    outt = int).
 119
 120 (*
 121 theorem accRealize_to_Realize :
 122   ∀sig,n.∀M:mTM sig n.∀Rtrue,Rfalse,acc.
 123   M ⊨ [ acc: Rtrue, Rfalse ] →  M ⊨ Rtrue ∪ Rfalse.
 124 #sig #n #M #Rtrue #Rfalse #acc #HR #t
 125 cases (HR t) #k * #outc * * #Hloop
 126 #Htrue #Hfalse %{k} %{outc} % //
 127 cases (true_or_false (cstate sig (states sig n M) n outc == acc)) #Hcase
 128 [ % @Htrue @(\P Hcase) | %2 @Hfalse @(\Pf Hcase) ]
 129 qed.
 130 *)
 131
 132 lemma sem_rewind_strong : ∀src,dst,sig,n.
 133   src ≠ dst → src < S n → dst < S n →
 134   rewind src dst sig n ⊨ R_rewind_strong src dst sig n.
 135 #src #dst #sig #n #Hneq #Hsrc #Hdst
 136 @(sem_seq_app sig n ????? (sem_parmoveL src dst sig n Hneq Hsrc Hdst) ?)
 137 [| @(sem_seq_app sig n ????? (sem_move_multi … R ?) (sem_move_multi … R ?)) //
 138  @le_S_S_to_le // ]
 139 #ta #tb * #tc * * * #Htc1 #Htc2 #_ * #td * whd in ⊢ (%→%→?); #Htd #Htb % [ % [ %
 140 [ #x #x0 #xs #rs #Hmidta_src #ls0 #y #y0 #target #rs0 #Hlen #Hmidta_dst
 141   >(Htc1 ??? Hmidta_src ls0 y (target@[y0]) rs0 ??) in Htd;
 142   [|>Hmidta_dst //
 143   |>length_append >length_append >Hlen % ]
 144   >change_vec_commute [|@sym_not_eq //]
 145   >change_vec_change_vec
 146   >nth_change_vec_neq [|@sym_not_eq //]
 147   >nth_change_vec // >reverse_append >reverse_single
 148   >reverse_append >reverse_single normalize in match (tape_move ???);
 149   >rev_append_def >append_nil #Htd >Htd in Htb;
 150   >change_vec_change_vec >nth_change_vec //
 151   cases ls0 [|#l1 #ls1] normalize in match (tape_move ???); //
 152 | #x #x0 #xs #rs #Hmidta_dst #ls0 #y #y0 #target #rs0 #Hlen #Hmidta_src
 153   >(Htc2 ??? Hmidta_dst ls0 y (target@[y0]) rs0 ??) in Htd;
 154   [|>Hmidta_src //
 155   |>length_append >length_append >Hlen % ]
 156   >change_vec_change_vec
 157   >change_vec_commute [|@sym_not_eq //]
 158   >nth_change_vec //
 159   >reverse_append >reverse_single
 160   >reverse_append >reverse_single
 161   cases ls0 [|#l1 #ls1] normalize in match (tape_move ???);
 162   #Htd >Htd in Htb; >change_vec_change_vec >nth_change_vec //
 163   >rev_append_def >change_vec_commute // normalize in match (tape_move ???); // ]
 164 | #x #rs #Hmidta_src #ls0 #y #rs0 #Hmidta_dst
 165   lapply (Htc1 … Hmidta_src … (refl ??) Hmidta_dst) -Htc1 #Htc >Htc in Htd;
 166   >change_vec_commute [|@sym_not_eq //] >change_vec_change_vec
 167   >nth_change_vec_neq [|@sym_not_eq //]
 168   >nth_change_vec // lapply (refl ? ls0) cases ls0 in ⊢ (???%→%);
 169   [ #Hls0 #Htd >Htd in Htb;
 170     >nth_change_vec // >change_vec_change_vec
 171     whd in match (tape_move ???);whd in match (tape_move ???); <Hmidta_src
 172     <Hls0 <Hmidta_dst >change_vec_same >change_vec_same //
 173   | #l1 #ls1 #Hls0 #Htd >Htd in Htb;
 174     >nth_change_vec // >change_vec_change_vec
 175     whd in match (tape_move ???);whd in match (tape_move ???); <Hmidta_src
 176     <Hls0 <Hmidta_dst >change_vec_same >change_vec_same //
 177   ] ]
 178 | #x #rs #Hmidta_dst #ls0 #y #rs0 #Hmidta_src
 179   lapply (Htc2 … Hmidta_dst … (refl ??) Hmidta_src) -Htc2 #Htc >Htc in Htd;
 180   >change_vec_change_vec >change_vec_commute [|@sym_not_eq //]
 181   >nth_change_vec // lapply (refl ? ls0) cases ls0 in ⊢ (???%→%);
 182   [ #Hls0 destruct (Hls0) #Htd >Htd in Htb;
 183     >nth_change_vec // >change_vec_change_vec
 184     whd in match (tape_move ???);whd in match (tape_move ???);
 185     <Hmidta_src <Hmidta_dst >change_vec_same >change_vec_same //
 186   | #l1 #ls1 #Hls0 destruct (Hls0) #Htd >Htd in Htb;
 187     >nth_change_vec // >change_vec_change_vec
 188     whd in match (tape_move ???); whd in match (tape_move ???); <Hmidta_src
 189     <Hmidta_dst >change_vec_same >change_vec_same //
 190   ]
 191 ]
 192 qed.
 193
 194 lemma sem_rewind : ∀src,dst,sig,n.
 195   src ≠ dst → src < S n → dst < S n →
 196   rewind src dst sig n ⊨ R_rewind src dst sig n.
 197 #src #dst #sig #n #Hneq #Hsrc #Hdst @(Realize_to_Realize … (sem_rewind_strong …)) //
 198 #ta #tb * * * #H1 #H2 #H3 #H4 % /2 by /
 199 qed.
 200
 201 definition match_step ≝ λsrc,dst,sig,n.
 202   compare src dst sig n ·
 203      (ifTM ?? (partest sig n (match_test src dst sig ?))
 204       (single_finalTM ??
 205         (rewind src dst sig n · (inject_TM ? (move_r ?) n dst)))
 206       (nop …)
 207       partest1).
 208
 209 (* we assume the src is a midtape
 210    we stop
 211    if the dst is out of bounds (outt = int)
 212    or dst.right is shorter than src.right (outt.current → None)
 213    or src.right is a prefix of dst.right (out = just right of the common prefix) *)
 214 definition R_match_step_false ≝
 215   λsrc,dst,sig,n.λint,outt: Vector (tape sig) (S n).
 216   ∀ls,x,xs.
 217   nth src ? int (niltape ?) = midtape sig ls x xs →
 218   ((current sig (nth dst (tape sig) int (niltape sig)) = None ?) ∧ outt = int) ∨
 219     (∃ls0,rs0,xs0. nth dst ? int (niltape ?) = midtape sig ls0 x rs0 ∧
 220       xs = rs0@xs0 ∧
 221       outt = change_vec ??
 222              (change_vec ?? int (mk_tape sig (reverse ? rs0@x::ls) (option_hd ? xs0) (tail ? xs0)) src)
 223              (mk_tape ? (reverse ? rs0@x::ls0) (None ?) [ ]) dst) ∨
 224     (∃ls0,rs0.
 225      nth dst ? int (niltape ?) = midtape sig ls0 x (xs@rs0) ∧
 226      (* ∀rsj,c.
 227      rs0 = c::rsj → *)
 228      outt = change_vec ??
 229             (change_vec ?? int (mk_tape sig (reverse ? xs@x::ls) (None ?) [ ]) src)
 230             (mk_tape sig (reverse ? xs@x::ls0) (option_hd ? rs0) (tail ? rs0)) dst).
 231
 232 (*
 233    we assume the src is a midtape [ ] s rs
 234    if we iterate
 235    then dst.current = Some ? s1
 236    and  if s ≠ s1 then outt = int.dst.move_right()
 237    and  if s = s1
 238         then int.src.right and int.dst.right have a common prefix
 239         and  the heads of their suffixes are different
 240         and  outt = int.dst.move_right().
 241
 242  *)
 243 definition R_match_step_true ≝
 244   λsrc,dst,sig,n.λint,outt: Vector (tape sig) (S n).
 245   ∀s,rs.nth src ? int (niltape ?) = midtape ? [ ] s rs →
 246   outt = change_vec ?? int
 247          (tape_move_mono … (nth dst ? int (niltape ?)) (〈None ?,R〉)) dst ∧
 248   (∃s0.current sig (nth dst (tape sig) int (niltape sig)) = Some ? s0 ∧
 249    (s0 = s →
 250    ∃xs,ci,rs',ls0,cj,rs0.
 251    rs = xs@ci::rs' ∧
 252    nth dst ? int (niltape ?) = midtape sig ls0 s (xs@cj::rs0) ∧
 253    ci ≠ cj)).
 254
 255 lemma sem_match_step :
 256   ∀src,dst,sig,n.src ≠ dst → src < S n → dst < S n →
 257   match_step src dst sig n ⊨
 258     [ inr ?? (inr ?? (inl … (inr ?? start_nop))) :
 259       R_match_step_true src dst sig n,
 260       R_match_step_false src dst sig n ].
 261 #src #dst #sig #n #Hneq #Hsrc #Hdst
 262 @(acc_sem_seq_app sig n … (sem_compare src dst sig n Hneq Hsrc Hdst)
 263     (acc_sem_if ? n … (sem_partest sig n (match_test src dst sig ?))
 264       (sem_seq …
 265         (sem_rewind ???? Hneq Hsrc Hdst)
 266         (sem_inject … dst (le_S_S_to_le … Hdst) (sem_move_r ? )))
 267       (sem_nop …)))
 268 [ #ta #tb #tc * lapply (refl ? (current ? (nth src ? ta (niltape ?))))
 269   cases (current ? (nth src ? ta (niltape ?))) in ⊢ (???%→%);
 270   [ #Hcurta_src #Hcomp #_ * #td * >Hcomp [| % %2 %]
 271     whd in ⊢ (%→?); * whd in ⊢ (??%?→?);
 272     >nth_current_chars >Hcurta_src normalize in ⊢ (%→?); #H destruct (H)
 273   | #s #Hs lapply (refl ? (current ? (nth dst ? ta (niltape ?))))
 274     cases (current ? (nth dst ? ta (niltape ?))) in ⊢ (???%→%);
 275     [ #Hcurta_dst #Hcomp #_ * #td * >Hcomp [| %2 %]
 276       whd in ⊢ (%→?); * whd in ⊢ (??%?→?);
 277       >nth_current_chars >nth_current_chars >Hs >Hcurta_dst
 278       normalize in ⊢ (%→?); #H destruct (H)
 279     | #s0 #Hs0
 280       cases (current_to_midtape … Hs) #ls * #rs #Hmidta_src >Hmidta_src
 281       cases (current_to_midtape … Hs0) #ls0 * #rs0 #Hmidta_dst >Hmidta_dst
 282       cases (true_or_false (s == s0)) #Hss0
 283       [ lapply (\P Hss0) -Hss0 #Hss0 destruct (Hss0)
 284         #_ #Hcomp cases (Hcomp ????? (refl ??) (refl ??)) -Hcomp [ *
 285         [ * #rs' * #_ #Hcurtc_dst * #td * whd in ⊢ (%→?); * whd in ⊢ (??%?→?);
 286           >nth_current_chars >nth_current_chars >Hcurtc_dst
 287           cases (current ? (nth src …))
 288           [normalize in ⊢ (%→?); #H destruct (H)
 289           | #x >nth_change_vec // cases (reverse ? rs0)
 290             [ normalize in ⊢ (%→?); #H destruct (H)
 291             | #r1 #rs1 normalize in ⊢ (%→?); #H destruct (H) ] ]
 292         | * #rs0' * #_ #Hcurtc_src * #td * whd in ⊢ (%→?); * whd in ⊢ (??%?→?);
 293           >(?:nth src ? (current_chars ?? tc) (None ?) = None ?)
 294           [|>nth_current_chars >Hcurtc_src >nth_change_vec_neq
 295             [>nth_change_vec [cases (append ???) // | @Hsrc]
 296             |@(not_to_not … Hneq) //
 297             ]]
 298           normalize in ⊢ (%→?); #H destruct (H) ]
 299         | * #xs * #ci * #cj * #rs'' * #rs0' * * * #Hcicj #Hrs #Hrs0
 300           #Htc * #td * * #Hmatch #Htd destruct (Htd) * #te * *
 301           >Htc >change_vec_commute // >nth_change_vec //
 302           >change_vec_commute [|@sym_not_eq //] >nth_change_vec // #Hte #_ #Htb
 303           #s' #rs' >Hmidta_src #H destruct (H)
 304           lapply (Hte … (refl ??) … (refl ??) (refl ??)) -Hte
 305           >change_vec_commute // >change_vec_change_vec
 306           >change_vec_commute [|@sym_not_eq //] >change_vec_change_vec #Hte
 307           >Hte in Htb; * * #_ >nth_change_vec // #Htb1
 308           lapply (Htb1 … (refl ??)) -Htb1 #Htb1 #Htb2 %
 309           [ @(eq_vec … (niltape ?)) #i #Hi
 310             cases (true_or_false ((dst : DeqNat) == i)) #Hdsti
 311             [ <(\P Hdsti) >Htb1 >nth_change_vec // >Hmidta_dst
 312               >Hrs0 >reverse_reverse cases xs [|#r1 #rs1] %
 313             | <Htb2 [|@(\Pf Hdsti)] >nth_change_vec_neq [| @(\Pf Hdsti)]
 314               >Hrs0 >reverse_reverse >nth_change_vec_neq in ⊢ (???%);
 315               <Hrs <Hmidta_src [|@(\Pf Hdsti)] >change_vec_same % ]
 316           | >Hmidta_dst %{s'} % [%] #_
 317             >Hrs0 %{xs} %{ci} %{rs''} %{ls0} %{cj} %{rs0'} % // % //
 318           ]
 319         ]
 320       | lapply (\Pf Hss0) -Hss0 #Hss0 #Htc cut (tc = ta)
 321         [@Htc % % @(not_to_not ??? Hss0) #H destruct (H) %]
 322         -Htc #Htc destruct (Htc) #_ * #td * whd in ⊢ (%→?); * #_
 323         #Htd destruct (Htd) * #te * * #_ #Hte * * #_ #Htb1 #Htb2
 324         #s1 #rs1 >Hmidta_src #H destruct (H)
 325         lapply (Hte … Hmidta_src … Hmidta_dst) -Hte #Hte destruct (Hte) %
 326         [ @(eq_vec … (niltape ?)) #i #Hi
 327           cases (true_or_false ((dst : DeqNat) == i)) #Hdsti
 328           [ <(\P Hdsti) >(Htb1 … Hmidta_dst) >nth_change_vec // >Hmidta_dst
 329             cases rs0 [|#r2 #rs2] %
 330           | <Htb2 [|@(\Pf Hdsti)] >nth_change_vec_neq [| @(\Pf Hdsti)] % ]
 331         | >Hs0 %{s0} % // #H destruct (H) @False_ind cases (Hss0) /2/ ]
 332       ]
 333     ]
 334   ]
 335 | #ta #tb #tc * #Hcomp1 #Hcomp2 * #td * * #Htest #Htd destruct (Htd)
 336   whd in ⊢ (%→?); #Htb destruct (Htb) #ls #x #xs #Hta_src
 337   lapply (refl ? (current ? (nth dst ? ta (niltape ?))))
 338   cases (current ? (nth dst ? ta (niltape ?))) in ⊢ (???%→?);
 339   [ #Hcurta_dst % % % // @Hcomp1 %2 //
 340   | #x0 #Hcurta_dst cases (current_to_midtape … Hcurta_dst) -Hcurta_dst
 341     #ls0 * #rs0 #Hta_dst cases (true_or_false (x == x0)) #Hxx0
 342     [ lapply (\P Hxx0) -Hxx0 #Hxx0 destruct (Hxx0)
 343     | >(?:tc=ta) in Htest;
 344       [|@Hcomp1 % % >Hta_src >Hta_dst @(not_to_not ??? (\Pf Hxx0)) normalize
 345         #Hxx0' destruct (Hxx0') % ]
 346       whd in ⊢ (??%?→?);
 347       >nth_current_chars >Hta_src >nth_current_chars >Hta_dst
 348       whd in ⊢ (??%?→?); #Hfalse destruct (Hfalse) ] -Hcomp1
 349       cases (Hcomp2 … Hta_src Hta_dst) [ *
 350       [ * #rs' * #Hxs #Hcurtc % %2 %{ls0} %{rs0} %{rs'} %
 351         [ % // | >Hcurtc % ]
 352       | * #rs0' * #Hxs #Htc %2 >Htc %{ls0} %{rs0'} % // ]
 353       | * #xs0 * #ci * #cj * #rs' * #rs0' * * *
 354         #Hci #Hxs #Hrs0 #Htc @False_ind
 355         whd in Htest:(??%?);
 356         >(?:nth src ? (current_chars ?? tc) (None ?) = Some ? ci) in Htest;
 357         [|>nth_current_chars >Htc >nth_change_vec_neq [|@(not_to_not … Hneq) //]
 358           >nth_change_vec //]
 359         >(?:nth dst ? (current_chars ?? tc) (None ?) = Some ? cj)
 360         [|>nth_current_chars >Htc >nth_change_vec //]
 361         normalize #H destruct (H) ] ] ]
 362 qed.
 363
 364 definition match_m ≝ λsrc,dst,sig,n.
 365   whileTM … (match_step src dst sig n)
 366     (inr ?? (inr ?? (inl … (inr ?? start_nop)))).
 367
 368 definition R_match_m ≝
 369   λsrc,dst,sig,n.λint,outt: Vector (tape sig) (S n).
 370   ∀x,rs.
 371   nth src ? int (niltape ?) = midtape sig [ ] x rs →
 372   (current sig (nth dst (tape sig) int (niltape sig)) = None ? →
 373    right ? (nth dst (tape sig) int (niltape sig)) = [ ] → outt = int) ∧
 374   (∀ls0,x0,rs0.
 375    nth dst ? int (niltape ?) = midtape sig ls0 x0 rs0 →
 376    (∃l,l1.x0::rs0 = l@x::rs@l1 ∧
 377     outt = change_vec ??
 378            (change_vec ?? int
 379              (mk_tape sig (reverse ? rs@[x]) (None ?) [ ]) src)
 380            (mk_tape sig ((reverse ? (l@x::rs))@ls0) (option_hd ? l1) (tail ? l1)) dst) ∨
 381     ∀l,l1.x0::rs0 ≠ l@x::rs@l1).
 382
 383 lemma not_sub_list_merge :
 384   ∀T.∀a,b:list T. (∀l1.a ≠ b@l1) → (∀t,l,l1.a ≠ t::l@b@l1) → ∀l,l1.a ≠ l@b@l1.
 385 #T #a #b #H1 #H2 #l elim l normalize //
 386 qed.
 387
 388 lemma not_sub_list_merge_2 :
 389   ∀T:DeqSet.∀a,b:list T.∀t. (∀l1.t::a ≠ b@l1) → (∀l,l1.a ≠ l@b@l1) → ∀l,l1.t::a ≠ l@b@l1.
 390 #T #a #b #t #H1 #H2 #l elim l //
 391 #t0 #l1 #IH #l2 cases (true_or_false (t == t0)) #Htt0
 392 [ >(\P Htt0) % normalize #H destruct (H) cases (H2 l1 l2) /2/
 393 | normalize % #H destruct (H) cases (\Pf Htt0) /2/ ]
 394 qed.
 395
 396
 397 lemma wsem_match_m : ∀src,dst,sig,n.
 398 src ≠ dst → src < S n → dst < S n →
 399   match_m src dst sig n ⊫ R_match_m src dst sig n.
 400 #src #dst #sig #n #Hneq #Hsrc #Hdst #ta #k #outc #Hloop
 401 lapply (sem_while … (sem_match_step src dst sig n Hneq Hsrc Hdst) … Hloop) //
 402 -Hloop * #tb * #Hstar @(star_ind_l ??????? Hstar) -Hstar
 403 [ #Hfalse #x #xs #Hmid_src
 404   cases (Hfalse … Hmid_src) -Hfalse
 405   [(* current dest = None *) *
 406     [ * #Hcur_dst #Houtc %
 407       [#_ >Houtc //
 408       | #ls0 #x0 #rs0 #Hmid_dst >Hmid_dst in Hcur_dst;
 409         normalize in ⊢ (%→?); #H destruct (H)
 410       ]
 411     | * #ls0 * #rs0 * #xs0 * * #Htc_dst #Hrs0 #HNone %
 412       [ >Htc_dst normalize in ⊢ (%→?); #H destruct (H)
 413       | #ls1 #x1 #rs1 >Htc_dst #H destruct (H)
 414         >Hrs0 >HNone cases xs0
 415         [ % %{[ ]} %{[ ]} % [ >append_nil >append_nil %]
 416           @eq_f3 //
 417           [ >reverse_append %
 418           | >reverse_append >reverse_cons >reverse_append
 419             >associative_append >associative_append % ]
 420         | #x2 #xs2 %2 #l #l1 % #Habs lapply (eq_f ?? (length ?) ?? Habs)
 421           >length_append whd in ⊢ (??%(??%)→?); >length_append
 422           >length_append normalize >commutative_plus whd in ⊢ (???%→?);
 423           #H destruct (H) lapply e0 >(plus_n_O (|rs1|)) in ⊢ (??%?→?);
 424           >associative_plus >associative_plus
 425           #e1 lapply (injective_plus_r ??? e1) whd in ⊢ (???%→?);
 426           #e2 destruct (e2)
 427         ]
 428       ]
 429     ]
 430   |* #ls0 * #rs0 * #Hmid_dst #Houtc %
 431     [ >Hmid_dst normalize in ⊢ (%→?); #H destruct (H)
 432     |#ls1 #x1 #rs1 >Hmid_dst #H destruct (H)
 433      %1 %{[ ]} %{rs0} % [%]
 434      >reverse_cons >associative_append >Houtc %
 435     ]
 436   ]
 437 |-ta #ta #tc #Htrue #Hstar #IH #Hout lapply (IH Hout) -IH -Hout #IH whd
 438  #x #xs #Hmidta_src
 439  lapply (refl ? (current ? (nth dst ? ta (niltape ?))))
 440  cases (current ? (nth dst ? ta (niltape ?))) in ⊢ (???%→?);
 441   [#Hcurta_dst %
 442     [#Hcurta_dst #Hrightta_dst whd in Htrue; >Hmidta_src in Htrue; #Htrue
 443      cases (Htrue ?? (refl ??)) -Htrue #Htc
 444      cut (tc = ta)
 445      [ >Htc whd in match (tape_move_mono ???); whd in match (tape_write ???);
 446        <(change_vec_same … ta dst (niltape ?)) in ⊢ (???%);
 447        lapply Hrightta_dst lapply Hcurta_dst -Hrightta_dst -Hcurta_dst
 448        cases (nth dst ? ta (niltape ?))
 449        [ #_ #_ %
 450        | #r0 #rs0 #_ normalize in ⊢ (%→?); #H destruct (H)
 451        | #l0 #ls0 #_ #_ %
 452        | #ls #x0 #rs normalize in ⊢ (%→?); #H destruct (H) ] ]
 453      -Htc #Htc destruct (Htc) #_
 454      cases (IH … Hmidta_src) #Houtc #_ @Houtc //
 455     |#ls0 #x0 #rs0 #Hmidta_dst >Hmidta_dst in Hcurta_dst;
 456      normalize in ⊢ (%→?); #H destruct (H)
 457     ]
 458   | #c #Hcurta_dst % [ >Hcurta_dst #H destruct (H) ]
 459     #ls0 #x0 #rs0 #Hmidta_dst >Hmidta_dst in Hcurta_dst; normalize in ⊢ (%→?);
 460     #H destruct (H) whd in Htrue; >Hmidta_src in Htrue; #Htrue
 461     cases (Htrue ?? (refl …)) -Htrue >Hmidta_dst #Htc
 462     cases (true_or_false (x==c)) #eqx
 463     [ lapply (\P eqx) -eqx #eqx destruct (eqx) * #s0 * whd in ⊢ (??%?→?); #Hs0
 464       destruct (Hs0) #Htrue cases (Htrue (refl ??)) -Htrue
 465       #xs0 * #ci * #rs' * #ls1 * #cj * #rs1 * * #Hxs #H destruct (H) #Hcicj
 466       >Htc in IH; whd in ⊢ (%→?); >nth_change_vec_neq [|@sym_not_eq //]
 467       #IH cases (IH … Hmidta_src) -IH #_ >nth_change_vec //
 468       cut (∃x1,xs1.xs0@cj::rs1 = x1::xs1)
 469       [ cases xs0 [ %{cj} %{rs1} % | #x1 #xs1 %{x1} %{(xs1@cj::rs1)} % ] ] * #x1 * #xs1
 470       #Hxs1 >Hxs1 #IH cases (IH … (refl ??)) -IH
 471       [ * #l * #l1 * #Hxs1'
 472         >change_vec_commute // >change_vec_change_vec
 473         #Houtc % %{(s0::l)} %{l1} %
 474         [ normalize <Hxs1' %
 475         | >reverse_cons >associative_append >change_vec_commute // @Houtc ]
 476       | #H %2 #l #l1 >(?:l@s0::xs@l1 = l@(s0::xs)@l1) [|%]
 477         @not_sub_list_merge
 478         [ #l2 >Hxs <Hxs1 % normalize #H1 lapply (cons_injective_r ????? H1)
 479           >associative_append #H2 lapply (append_l2_injective ????? (refl ??) H2)
 480           #H3 lapply (cons_injective_l ????? H3) #H3 >H3 in Hcicj; * /2/
 481         |#t #l2 #l3 % normalize #H1 lapply (cons_injective_r ????? H1)
 482          -H1 #H1 cases (H l2 l3) #H2 @H2 @H1
 483         ]
 484       ]
 485     | #_ cases (IH x xs ?) -IH
 486       [| >Htc >nth_change_vec_neq [|@sym_not_eq //] @Hmidta_src ]
 487       >Htc >nth_change_vec // cases rs0
 488       [ #_ #_ %2 #l #l1 cases l
 489        [ normalize cases xs
 490          [ cases l1
 491            [ normalize % #H destruct (H) cases (\Pf eqx) /2/
 492            | #tmp1 #l2 normalize % #H destruct (H) ]
 493          | #tmp1 #l2 normalize % #H destruct (H) ]
 494        | #tmp1 #l2 normalize % #H destruct (H)cases l2 in e0;
 495          [ normalize #H1 destruct (H1)
 496          | #tmp2 #l3 normalize #H1 destruct (H1) ] ]
 497       | #r1 #rs1 #_ #IH cases (IH … (refl ??)) -IH
 498         [ * #l * #l1 * #Hll1 #Houtc % %{(c::l)} %{l1} % [ >Hll1 % ]
 499           >Houtc >change_vec_commute // >change_vec_change_vec
 500           >change_vec_commute [|@sym_not_eq //]
 501           >reverse_cons >associative_append %
 502         | #Hll1 %2 @(not_sub_list_merge_2 ?? (x::xs)) normalize [|@Hll1]
 503          #l1 % #H destruct (H) cases (\Pf eqx) /2/
 504         ]
 505       ]
 506     ]
 507   ]
 508 ]
 509 qed.
 510
 511 definition R_match_step_true_naive ≝
 512   λsrc,dst,sig,n.λint,outt: Vector (tape sig) (S n).
 513   |left ? (nth src ? outt (niltape ?))| +
 514   |option_cons ? (current ? (nth dst ? outt (niltape ?))) (right ? (nth dst ? outt (niltape ?)))| <
 515   |left ? (nth src ? int (niltape ?))| +
 516   |option_cons ? (current ? (nth dst ? int (niltape ?))) (right ? (nth dst ? int (niltape ?)))|.
 517
 518 lemma sem_match_step_termination :
 519   ∀src,dst,sig,n.src ≠ dst → src < S n → dst < S n →
 520   match_step src dst sig n ⊨
 521     [ inr ?? (inr ?? (inl … (inr ?? start_nop))) :
 522       R_match_step_true_naive src dst sig n,
 523       R_match_step_false src dst sig n ].
 524 #src #dst #sig #n #Hneq #Hsrc #Hdst
 525 @(acc_sem_seq_app sig n … (sem_compare src dst sig n Hneq Hsrc Hdst)
 526     (acc_sem_if ? n … (sem_partest sig n (match_test src dst sig ?))
 527       (sem_seq …
 528         (sem_rewind_strong ???? Hneq Hsrc Hdst)
 529         (sem_inject … dst (le_S_S_to_le … Hdst) (sem_move_r ? )))
 530       (sem_nop …)))
 531 [ #ta #tb #tc * lapply (refl ? (current ? (nth src ? ta (niltape ?))))
 532   cases (current ? (nth src ? ta (niltape ?))) in ⊢ (???%→%);
 533   [ #Hcurta_src #Hcomp #_ * #td * >Hcomp [| % %2 %]
 534     whd in ⊢ (%→?); * whd in ⊢ (??%?→?);
 535     >nth_current_chars >Hcurta_src normalize in ⊢ (%→?); #H destruct (H)
 536   | #s #Hs lapply (refl ? (current ? (nth dst ? ta (niltape ?))))
 537     cases (current ? (nth dst ? ta (niltape ?))) in ⊢ (???%→%);
 538     [ #Hcurta_dst #Hcomp #_ * #td * >Hcomp [| %2 %]
 539       whd in ⊢ (%→?); * whd in ⊢ (??%?→?);
 540       >nth_current_chars >nth_current_chars >Hs >Hcurta_dst
 541       normalize in ⊢ (%→?); #H destruct (H)
 542     | #s0 #Hs0
 543       cases (current_to_midtape … Hs) #ls * #rs #Hmidta_src >Hmidta_src
 544       cases (current_to_midtape … Hs0) #ls0 * #rs0 #Hmidta_dst >Hmidta_dst
 545       cases (true_or_false (s == s0)) #Hss0
 546       [ lapply (\P Hss0) -Hss0 #Hss0 destruct (Hss0)
 547         #_ #Hcomp cases (Hcomp ????? (refl ??) (refl ??)) -Hcomp [ *
 548         [ * #rs' * #_ #Hcurtc_dst * #td * whd in ⊢ (%→?); * whd in ⊢ (??%?→?);
 549           >nth_current_chars >nth_current_chars >Hcurtc_dst
 550           cases (current ? (nth src …))
 551           [normalize in ⊢ (%→?); #H destruct (H)
 552           | #x >nth_change_vec [|@Hdst] cases (reverse ? rs0)
 553             [ normalize in ⊢ (%→?); #H destruct (H)
 554             | #r1 #rs1 normalize in ⊢ (%→?); #H destruct (H) ] ]
 555         | * #rs0' * #_ #Hcurtc_src * #td * whd in ⊢ (%→?); * whd in ⊢ (??%?→?);
 556           >(?:nth src ? (current_chars ?? tc) (None ?) = None ?)
 557           [|>nth_current_chars >Hcurtc_src >nth_change_vec_neq
 558             [>nth_change_vec [cases (append ???) // | @Hsrc]
 559             |@(not_to_not … Hneq) //
 560             ]]
 561           normalize in ⊢ (%→?); #H destruct (H) ]
 562         | * #xs * #ci * #cj * #rs'' * #rs0' * * * #Hcicj #Hrs #Hrs0
 563           #Htc * #td * * #Hmatch #Htd destruct (Htd) * #te * * *
 564           >Htc >change_vec_commute [|//] >nth_change_vec [|//]
 565           >change_vec_commute [|@sym_not_eq //] >nth_change_vec [|//]
 566           cases (lists_length_split ? ls ls0) #lsa * #lsb * * #Hlen #Hlsalsb
 567           destruct (Hlsalsb)  *
 568           [ #Hte #_ #_ <(reverse_reverse … ls) in Hte; <(reverse_reverse … lsa)
 569             cut (|reverse ? lsa| = |reverse ? ls|) [ // ] #Hlen'
 570             @(list_cases2 … Hlen')
 571             [ #H1 #H2 >H1 >H2 -H1 -H2 normalize in match (reverse ? [ ]); #Hte #_
 572               lapply (Hte … (refl ??) … (refl ??) (refl ??)) -Hte
 573               >change_vec_commute [|//] >change_vec_change_vec
 574               >change_vec_commute [|@sym_not_eq //] >change_vec_change_vec #Hte
 575               >Hte * * #_ >nth_change_vec [|//] >reverse_reverse
 576               #H lapply (H … (refl ??)) -H #Htb1 #Htb2
 577               cut (tb = change_vec ?? (change_vec (tape sig) (S n) ta (midtape sig [ ] s0 (xs@ci::rs'')) src) (mk_tape sig (s0::lsb) (option_hd sig (xs@cj::rs0')) (tail sig (xs@cj::rs0'))) dst)
 578               [ @(eq_vec_change_vec … (niltape ?))
 579                 [@Htb1| #j #Hj <Htb2 // >(nth_change_vec_neq ??????? Hj) % ] ]
 580               -Htb1 -Htb2 #Htb >Htb whd >nth_change_vec [|//]
 581               >nth_change_vec_neq [|@sym_not_eq //] >nth_change_vec [|//]
 582               >right_mk_tape [|cases xs [|#x0 #xs0] normalize in ⊢ (??%?→?); #H destruct (H)]
 583               normalize in match (left ??);
 584               >Hmidta_src >Hmidta_dst >current_mk_tape <opt_cons_tail_expand
 585               whd in match (option_cons ???); >Hrs0
 586               normalize in ⊢ (?(?%)%); //
 587             | #hda #hdb #tla #tlb #H1 #H2 >H1 >H2
 588               >reverse_cons >reverse_cons #Hte
 589               lapply (Hte ci hdb (reverse ? xs@s0::reverse ? tlb) rs'' ?
 590                        lsb cj hda (reverse ? xs@s0::reverse ? tla) rs0' ??)
 591               [ /2 by cons_injective_l, nil/
 592               | >length_append >length_append @eq_f @(eq_f ?? S)
 593                 >H1 in Hlen'; >H2 whd in ⊢ (??%%→?); #Hlen'
 594                 >length_reverse >length_reverse destruct (Hlen') //
 595               | /2 by refl, trans_eq/ ] -Hte
 596               #Hte #_ * * #_ >Hte >nth_change_vec [|//] #Htb1 #Htb2
 597               cut (tb = change_vec ?? (change_vec (tape sig) (S n) ta
 598                         (mk_tape sig (hda::lsb) (option_hd ? (reverse sig (reverse sig xs@s0::reverse sig tla)@cj::rs0')) (tail ? (reverse sig (reverse sig xs@s0::reverse sig tla)@cj::rs0'))) dst)
 599                         (midtape ? [ ] hdb (reverse sig (reverse sig xs@s0::reverse sig tlb)@ci::rs'')) src)
 600               [ >change_vec_commute [|@sym_not_eq //] @(eq_vec_change_vec … (niltape ?))
 601                 [ @Htb1 %
 602                 | #j #Hj <Htb2 // >change_vec_commute // >change_vec_change_vec
 603                   >change_vec_commute [|@sym_not_eq //] >change_vec_change_vec
 604                   >nth_change_vec_neq in ⊢ (???%); // ] ]
 605               -Htb1 -Htb2 #Htb >Htb whd
 606               >nth_change_vec [|//] >nth_change_vec_neq [|//] >nth_change_vec [|//]
 607               >right_mk_tape
 608               [| cases (reverse sig (reverse sig xs@s0::reverse sig tla))
 609                  [|#x0 #xs0] normalize in ⊢ (??%?→?); #H destruct (H) ]
 610               >Hmidta_src >Hmidta_dst
 611               whd in match (left ??); whd in match (left ??); whd in match (right ??);
 612               >current_mk_tape <opt_cons_tail_expand whd in match (option_cons ???);
 613               >Hrs0 >length_append whd in ⊢ (??(??%)); >length_append >length_reverse
 614               >length_append >commutative_plus in match (|reverse ??| + ?);
 615               whd in match (|?::?|); >length_reverse >length_reverse
 616               <(length_reverse ? ls) <Hlen' >H1 normalize // ]
 617          | #_ #Hte #_ <(reverse_reverse … ls0) in Hte; <(reverse_reverse … lsa)
 618             cut (|reverse ? lsa| = |reverse ? ls0|) [ // ] #Hlen'
 619             @(list_cases2 … Hlen')
 620             [ #H1 #H2 >H1 >H2 normalize in match (reverse ? [ ]); #Hte
 621               lapply (Hte … (refl ??) … (refl ??) (refl ??)) -Hte
 622               >change_vec_change_vec >change_vec_commute [|@sym_not_eq //]
 623               >change_vec_change_vec #Hte #_
 624               >Hte * * #_ >nth_change_vec [|//] >reverse_reverse
 625               #H lapply (H … (refl ??)) -H #Htb1 #Htb2
 626               cut (tb = change_vec ?? (change_vec (tape sig) (S n) ta (mk_tape ? [s0] (option_hd ? (xs@cj::rs0')) (tail ? (xs@cj::rs0'))) dst)
 627                            (midtape ? lsb s0 (xs@ci::rs'')) src)
 628               [ >change_vec_commute [|@sym_not_eq //] @(eq_vec_change_vec … (niltape ?))
 629                 [ @Htb1
 630                 | #j #Hj <Htb2 // >nth_change_vec_neq in ⊢ (???%); // ] ]
 631               -Htb1 -Htb2 #Htb >Htb whd >nth_change_vec [|//]
 632               >nth_change_vec_neq [|//] >nth_change_vec [|//]
 633               >right_mk_tape
 634               [| cases xs [|#x0 #xs0] normalize in ⊢ (??%?→?); #H destruct (H) ]
 635               normalize in match (left ??);
 636               >Hmidta_src >Hmidta_dst >current_mk_tape <opt_cons_tail_expand >Hrs0
 637               >length_append normalize >length_append >length_append
 638               <(reverse_reverse ? lsa) >H1 normalize //
 639             | #hda #hdb #tla #tlb #H1 #H2 >H1 >H2
 640               >reverse_cons >reverse_cons #Hte
 641               lapply (Hte cj hdb (reverse ? xs@s0::reverse ? tlb) rs0' ?
 642                        lsb ci hda (reverse ? xs@s0::reverse ? tla) rs'' ??)
 643               [ /2 by cons_injective_l, nil/
 644               | >length_append >length_append @eq_f @(eq_f ?? S)
 645                 >H1 in Hlen'; >H2 whd in ⊢ (??%%→?); #Hlen'
 646                 >length_reverse >length_reverse destruct (Hlen') //
 647               | /2 by refl, trans_eq/ ] -Hte
 648               #Hte #_ * * #_ >Hte >nth_change_vec_neq [|//] >nth_change_vec [|//] #Htb1 #Htb2
 649               cut (tb = change_vec ?? (change_vec (tape sig) (S n) ta
 650                         (mk_tape sig [hdb] (option_hd ? (reverse sig (reverse sig xs@s0::reverse sig tlb)@cj::rs0')) (tail ? (reverse sig (reverse sig xs@s0::reverse sig tlb)@cj::rs0'))) dst)
 651                         (midtape ? lsb hda (reverse sig (reverse sig xs@s0::reverse sig tla)@ci::rs'')) src)
 652               [ >change_vec_commute [|@sym_not_eq //] @(eq_vec_change_vec … (niltape ?))
 653                 [ @Htb1 %
 654                 | #j #Hj <Htb2 [|//] >change_vec_change_vec
 655                   >change_vec_commute [|@sym_not_eq //]
 656                   >change_vec_change_vec >nth_change_vec_neq in ⊢ (???%); // ] ]
 657               -Htb1 -Htb2 #Htb >Htb whd
 658               >nth_change_vec [|//] >nth_change_vec_neq [|//] >nth_change_vec [|//]
 659               >right_mk_tape
 660               [| cases (reverse sig (reverse sig xs@s0::reverse sig tlb))
 661                  [|#x0 #xs0] normalize in ⊢ (??%?→?); #H destruct (H) ]
 662               >Hmidta_src >Hmidta_dst
 663               whd in match (left ??); whd in match (left ??); whd in match (right ??);
 664               >current_mk_tape <opt_cons_tail_expand
 665               whd in match (option_cons ???);
 666               >Hrs0 >length_append whd in ⊢ (??(??%)); >length_append >length_reverse
 667               >length_append >commutative_plus in match (|reverse ??| + ?);
 668               whd in match (|?::?|); >length_reverse >length_reverse
 669               <(length_reverse ? lsa) >Hlen' >H2 >length_append
 670               normalize //
 671             ]
 672           ]
 673         ]
 674       | lapply (\Pf Hss0) -Hss0 #Hss0 #Htc cut (tc = ta)
 675         [@Htc % % @(not_to_not ??? Hss0) #H destruct (H) %]
 676         -Htc #Htc destruct (Htc) #_ * #td * whd in ⊢ (%→?); * #_
 677         #Htd destruct (Htd) * #te * * * * >Hmidta_src >Hmidta_dst
 678         cases (lists_length_split ? ls ls0) #lsa * #lsb * * #Hlen #Hlsalsb
 679         destruct (Hlsalsb)
 680         [ <(reverse_reverse … ls) <(reverse_reverse … lsa)
 681           cut (|reverse ? lsa| = |reverse ? ls|) [ // ] #Hlen'
 682           @(list_cases2 … Hlen')
 683           [ #H1 #H2 >H1 >H2 -H1 -H2 #_ #_ normalize in match (reverse ? [ ]); #Hte #_
 684             lapply (Hte … (refl ??) … (refl ??)) -Hte #Hte destruct (Hte) * * #_
 685             >Hmidta_dst #Htb1 lapply (Htb1 … (refl ??)) -Htb1 #Htb1 #Htb2
 686             cut (tb = change_vec ?? ta (mk_tape ? (s0::lsa@lsb) (option_hd ? rs0) (tail ? rs0)) dst)
 687             [@(eq_vec_change_vec … (niltape ?)) [@Htb1|@Htb2] ]
 688             -Htb1 -Htb2 #Htb >Htb whd >nth_change_vec [|//]
 689             >nth_change_vec_neq [|@sym_not_eq //] >Hmidta_src >Hmidta_dst
 690             >right_mk_tape
 691             [| cases rs0 [ #_ %2 % | #x0 #xs0 normalize in ⊢ (??%?→?); #H destruct (H)] ]
 692             normalize in match (left ??); normalize in match (right ??);
 693             >Hmidta_src >Hmidta_dst >current_mk_tape <opt_cons_tail_expand
 694             normalize //
 695           | #hda #hdb #tla #tlb #H1 #H2 >H1 >H2
 696             >reverse_cons >reverse_cons >associative_append #Hte
 697             lapply (Hte ???? (refl ??) ? s0 ? (reverse ? tla) ?? (refl ??))
 698             [ >length_reverse >length_reverse cut (|hda::tla| = |hdb::tlb|) //
 699               normalize #H destruct (H) // ] #Hte #_ #_ #_
 700             * * #_ >Hte >nth_change_vec [|//] #Htb1 #Htb2
 701             cut (tb = change_vec ?? (change_vec (tape sig) (S n) ta
 702                       (mk_tape sig (hda::lsb) (option_hd ? (reverse sig (reverse sig tla)@s0::rs0)) (tail ? (reverse sig (reverse sig tla)@s0::rs0))) dst)
 703                       (midtape ? [ ] hdb (reverse sig (reverse sig tlb)@s::rs)) src)
 704             [ >change_vec_commute [|@sym_not_eq //] @(eq_vec_change_vec … (niltape ?))
 705               [ @Htb1 //
 706               | #j #Hj <Htb2 // >nth_change_vec_neq in ⊢ (???%); // ]]
 707             -Htb1 -Htb2 #Htb >Htb whd
 708             >nth_change_vec [|//] >nth_change_vec_neq [|//] >nth_change_vec [|//]
 709             >right_mk_tape
 710             [| cases (reverse sig (reverse sig tla))
 711                [|#x0 #xs0] normalize in ⊢ (??%?→?); #H destruct (H) ]
 712             >Hmidta_src >Hmidta_dst
 713             whd in match (left ??); whd in match (left ??); whd in match (right ??);
 714             >current_mk_tape <opt_cons_tail_expand >length_append
 715             >length_reverse >length_reverse <(length_reverse ? ls) <Hlen'
 716             >H1 normalize // ]
 717        | #_ <(reverse_reverse … ls0) <(reverse_reverse … lsa)
 718          cut (|reverse ? lsa| = |reverse ? ls0|) [ // ] #Hlen'
 719          @(list_cases2 … Hlen')
 720          [ #H1 #H2 >H1 >H2 normalize in match (reverse ? [ ]); #_ #_ #Hte
 721            lapply (Hte … (refl ??) … (refl ??)) -Hte #Hte destruct (Hte)
 722            * * #_ >Hmidta_dst #Htb1 lapply (Htb1 … (refl ??)) -Htb1 #Htb1 #Htb2
 723            cut (tb = change_vec (tape sig) (S n) ta (mk_tape ? (s0::ls0) (option_hd ? rs0) (tail ? rs0)) dst)
 724            [ @(eq_vec_change_vec … (niltape ?)) // @Htb2 ]
 725            -Htb1 -Htb2 #Htb >Htb whd >nth_change_vec [|//]
 726            >nth_change_vec_neq [|@sym_not_eq //] >Hmidta_src >Hmidta_dst
 727            >current_mk_tape >right_mk_tape
 728            [| cases rs0 [ #_ %2 % | #x0 #xs0 normalize in ⊢ (??%?→?); #H destruct (H) ]]
 729            normalize in ⊢ (??%); <opt_cons_tail_expand
 730            normalize //
 731          | #hda #hdb #tla #tlb #H1 #H2 >H1 >H2
 732            >reverse_cons >reverse_cons #Hte #_ #_
 733            lapply (Hte s0 hdb (reverse ? tlb) rs0 ?
 734                     lsb s hda (reverse ? tla) rs ??)
 735            [ /2 by cons_injective_l, nil/
 736            | >length_reverse >length_reverse cut (|hda::tla| = |hdb::tlb|) //
 737              normalize #H destruct (H) //
 738            | /2 by refl, trans_eq/ ] -Hte
 739            #Hte * * #_ >Hte >nth_change_vec_neq [|//] >nth_change_vec [|//] #Htb1 #Htb2
 740            cut (tb = change_vec ?? (change_vec (tape sig) (S n) ta
 741                      (mk_tape sig [hdb] (option_hd ? (reverse sig (reverse sig tlb)@s0::rs0)) (tail ? (reverse sig (reverse sig tlb)@s0::rs0))) dst)
 742                      (midtape ? lsb hda (reverse sig (reverse sig tla)@s::rs)) src)
 743            [ >change_vec_commute [|@sym_not_eq //] @(eq_vec_change_vec … (niltape ?))
 744              [ @Htb1 %
 745              | #j #Hj <Htb2 // >change_vec_commute [|@sym_not_eq //]
 746                >nth_change_vec_neq in ⊢ (???%); // ]]
 747            -Htb1 -Htb2 #Htb >Htb whd
 748            >nth_change_vec [|//] >nth_change_vec_neq [|//] >nth_change_vec [|//]
 749            >right_mk_tape
 750            [| cases (reverse ? (reverse ? tlb)) [|#x0 #xs0] normalize in ⊢ (??%?→?); #H destruct (H) ]
 751            >Hmidta_src >Hmidta_dst
 752            whd in match (left ??); whd in match (left ??); whd in match (right ??);
 753            >current_mk_tape <opt_cons_tail_expand >length_append
 754            normalize in ⊢ (??%); >length_append >reverse_reverse
 755            <(length_reverse ? lsa) >Hlen' >H2 normalize //
 756          ]
 757        ]
 758      ]
 759    ]
 760  ]
 761 | #ta #tb #tc * #Hcomp1 #Hcomp2 * #td * * #Htest #Htd destruct (Htd)
 762   whd in ⊢ (%→?); #Htb destruct (Htb) #ls #x #xs #Hta_src
 763   lapply (refl ? (current ? (nth dst ? ta (niltape ?))))
 764   cases (current ? (nth dst ? ta (niltape ?))) in ⊢ (???%→?);
 765   [ #Hcurta_dst % % % // @Hcomp1 %2 //
 766   | #x0 #Hcurta_dst cases (current_to_midtape … Hcurta_dst) -Hcurta_dst
 767     #ls0 * #rs0 #Hta_dst cases (true_or_false (x == x0)) #Hxx0
 768     [ lapply (\P Hxx0) -Hxx0 #Hxx0 destruct (Hxx0)
 769     | >(?:tc=ta) in Htest;
 770       [|@Hcomp1 % % >Hta_src >Hta_dst @(not_to_not ??? (\Pf Hxx0)) normalize
 771         #Hxx0' destruct (Hxx0') % ]
 772       whd in ⊢ (??%?→?);
 773       >nth_current_chars >Hta_src >nth_current_chars >Hta_dst
 774       whd in ⊢ (??%?→?); #Hfalse destruct (Hfalse) ] -Hcomp1
 775       cases (Hcomp2 … Hta_src Hta_dst) [ *
 776       [ * #rs' * #Hxs #Hcurtc % %2 %{ls0} %{rs0} %{rs'} %
 777         [ % // | >Hcurtc % ]
 778       | * #rs0' * #Hxs #Htc %2 >Htc %{ls0} %{rs0'} % // ]
 779       | * #xs0 * #ci * #cj * #rs' * #rs0' * * *
 780         #Hci #Hxs #Hrs0 #Htc @False_ind
 781         whd in Htest:(??%?);
 782         >(?:nth src ? (current_chars ?? tc) (None ?) = Some ? ci) in Htest;
 783         [|>nth_current_chars >Htc >nth_change_vec_neq [|@(not_to_not … Hneq) //]
 784           >nth_change_vec //]
 785         >(?:nth dst ? (current_chars ?? tc) (None ?) = Some ? cj)
 786         [|>nth_current_chars >Htc >nth_change_vec //]
 787         normalize #H destruct (H) ] ] ]
 788 qed.
 789
 790 (* lemma WF_to_WF_f : ∀A,B,R,f,b. WF A R (f b) → WF B (λx,y.R (f x) (f y)) b. *)
 791 let rec WF_to_WF_f A B R f b (Hwf: WF A R (f b)) on Hwf: WF B (λx,y.R (f x) (f y)) b ≝
 792   match Hwf return (λa0,r.f b = a0 → WF B (λx,y:B. R (f x) (f y)) b) with
 793   [ wf a Hwfa ⇒ λHeq.? ] (refl ??).
 794 % #b1 #HRb @WF_to_WF_f @Hwfa <Heq @HRb
 795 qed.
 796
 797 lemma lt_WF : ∀n.WF ? lt n.
 798 #n @(nat_elim1 n) -n #n #IH % @IH
 799 qed.
 800
 801 lemma terminate_match_m :
 802   ∀src,dst,sig,n,t.
 803   src ≠ dst → src < S n → dst < S n →
 804   match_m src dst sig n ↓ t.
 805 #src #dst #sig #n #ta #Hneq #Hsrc #Hdst
 806 @(terminate_while … (sem_match_step_termination src dst sig n Hneq Hsrc Hdst)) //
 807 letin f ≝ (λt0:Vector (tape sig) (S n).|left ? (nth src (tape ?) t0 (niltape ?))|
 808     +|option_cons ? (current ? (nth dst (tape ?) t0 (niltape ?)))
 809       (right ? (nth dst (tape ?) t0 (niltape ?)))|)
 810 change with (λx,y.f x < f y) in ⊢ (??%?); @WF_to_WF_f @lt_WF
 811 qed.
 812
 813 lemma sem_match_m : ∀src,dst,sig,n.
 814 src ≠ dst → src < S n → dst < S n →
 815   match_m src dst sig n \vDash R_match_m src dst sig n.
 816 #src #dst #sig #n #Hneq #Hsrc #Hdst @WRealize_to_Realize [/2/| @wsem_match_m // ]
 817 qed.