matita/matita/lib/turing/multi_universal/match.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "turing/multi_universal/moves.ma".
  16 include "turing/if_multi.ma".
  17 include "turing/inject.ma".
  18 include "turing/basic_machines.ma".
  19
  20 definition compare_states ≝ initN 3.
  21
  22 definition comp0 : compare_states ≝ mk_Sig ?? 0 (leb_true_to_le 1 3 (refl …)).
  23 definition comp1 : compare_states ≝ mk_Sig ?? 1 (leb_true_to_le 2 3 (refl …)).
  24 definition comp2 : compare_states ≝ mk_Sig ?? 2 (leb_true_to_le 3 3 (refl …)).
  25
  26 (*
  27
  28 0) (x,x) → (x,x)(R,R) → 1
  29    (x,y≠x) → None 2
  30 1) (_,_) → None 1
  31 2) (_,_) → None 2
  32
  33 *)
  34
  35 definition trans_compare_step ≝
  36  λi,j.λsig:FinSet.λn.λis_endc.
  37  λp:compare_states × (Vector (option sig) (S n)).
  38  let 〈q,a〉 ≝ p in
  39  match pi1 … q with
  40  [ O ⇒ match nth i ? a (None ?) with
  41    [ None ⇒ 〈comp2,null_action ? n〉
  42    | Some ai ⇒ match nth j ? a (None ?) with
  43      [ None ⇒ 〈comp2,null_action ? n〉
  44      | Some aj ⇒ if notb (is_endc ai) ∧ ai == aj
  45          then 〈comp1,change_vec ? (S n)
  46                       (change_vec ? (S n) (null_action ? n) (Some ? 〈ai,R〉) i)
  47                         (Some ? 〈aj,R〉) j〉
  48          else 〈comp2,null_action ? n〉 ]
  49    ]
  50  | S q ⇒ match q with
  51    [ O ⇒ (* 1 *) 〈comp1,null_action ? n〉
  52    | S _ ⇒ (* 2 *) 〈comp2,null_action ? n〉 ] ].
  53
  54 definition compare_step ≝
  55   λi,j,sig,n,is_endc.
  56   mk_mTM sig n compare_states (trans_compare_step i j sig n is_endc)
  57     comp0 (λq.q == comp1 ∨ q == comp2).
  58
  59 definition R_comp_step_true ≝
  60   λi,j,sig,n,is_endc.λint,outt: Vector (tape sig) (S n).
  61   ∃x.
  62    is_endc x = false ∧
  63    current ? (nth i ? int (niltape ?)) = Some ? x ∧
  64    current ? (nth j ? int (niltape ?)) = Some ? x ∧
  65    outt = change_vec ??
  66             (change_vec ?? int
  67               (tape_move ? (nth i ? int (niltape ?)) (Some ? 〈x,R〉)) i)
  68             (tape_move ? (nth j ? int (niltape ?)) (Some ? 〈x,R〉)) j.
  69
  70 definition R_comp_step_false ≝
  71   λi,j:nat.λsig,n,is_endc.λint,outt: Vector (tape sig) (S n).
  72    ((∃x.current ? (nth i ? int (niltape ?)) = Some ? x ∧ is_endc x = true) ∨
  73    current ? (nth i ? int (niltape ?)) ≠ current ? (nth j ? int (niltape ?)) ∨
  74    current ? (nth i ? int (niltape ?)) = None ? ∨
  75    current ? (nth j ? int (niltape ?)) = None ?) ∧ outt = int.
  76
  77 lemma comp_q0_q2_null :
  78   ∀i,j,sig,n,is_endc,v.i < S n → j < S n →
  79   (nth i ? (current_chars ?? v) (None ?) = None ? ∨
  80    nth j ? (current_chars ?? v) (None ?) = None ?) →
  81   step sig n (compare_step i j sig n is_endc) (mk_mconfig ??? comp0 v)
  82   = mk_mconfig ??? comp2 v.
  83 #i #j #sig #n #is_endc #v #Hi #Hj
  84 whd in ⊢ (? → ??%?); >(eq_pair_fst_snd … (trans ????)) whd in ⊢ (?→??%?);
  85 * #Hcurrent
  86 [ @eq_f2
  87   [ whd in ⊢ (??(???%)?); >Hcurrent %
  88   | whd in ⊢ (??(???????(???%))?); >Hcurrent @tape_move_null_action ]
  89 | @eq_f2
  90   [ whd in ⊢ (??(???%)?); >Hcurrent cases (nth i ?? (None sig)) //
  91   | whd in ⊢ (??(???????(???%))?); >Hcurrent
  92     cases (nth i ?? (None sig)) [|#x] @tape_move_null_action ] ]
  93 qed.
  94
  95 lemma comp_q0_q2_neq :
  96   ∀i,j,sig,n,is_endc,v.i < S n → j < S n →
  97   ((∃x.nth i ? (current_chars ?? v) (None ?) = Some ? x ∧ is_endc x = true) ∨
  98     nth i ? (current_chars ?? v) (None ?) ≠ nth j ? (current_chars ?? v) (None ?)) →
  99   step sig n (compare_step i j sig n is_endc) (mk_mconfig ??? comp0 v)
 100   = mk_mconfig ??? comp2 v.
 101 #i #j #sig #n #is_endc #v #Hi #Hj lapply (refl ? (nth i ?(current_chars ?? v)(None ?)))
 102 cases (nth i ?? (None ?)) in ⊢ (???%→?);
 103 [ #Hnth #_ @comp_q0_q2_null // % //
 104 | #ai #Hai lapply (refl ? (nth j ?(current_chars ?? v)(None ?)))
 105   cases (nth j ?? (None ?)) in ⊢ (???%→?);
 106   [ #Hnth #_ @comp_q0_q2_null // %2 //
 107   | #aj #Haj *
 108     [ * #c * >Hai #Heq #Hendc whd in ⊢ (??%?);
 109       >(eq_pair_fst_snd … (trans ????)) whd in ⊢ (??%?); @eq_f2
 110       [ whd in match (trans ????); >Hai >Haj destruct (Heq)
 111         whd in ⊢ (??(???%)?); >Hendc //
 112       | whd in match (trans ????); >Hai >Haj destruct (Heq)
 113         whd in ⊢ (??(???????(???%))?); >Hendc @tape_move_null_action
 114       ]
 115     | #Hneq
 116       whd in ⊢ (??%?); >(eq_pair_fst_snd … (trans ????)) whd in ⊢ (??%?); @eq_f2
 117       [ whd in match (trans ????); >Hai >Haj
 118         whd in ⊢ (??(???%)?); cut ((¬is_endc ai∧ai==aj)=false)
 119         [>(\bf ?) /2 by not_to_not/ cases (is_endc ai) // |#Hcut >Hcut //]
 120         | whd in match (trans ????); >Hai >Haj
 121           whd in ⊢ (??(???????(???%))?); cut ((¬is_endc ai∧ai==aj)=false)
 122           [>(\bf ?) /2 by not_to_not/ cases (is_endc ai) //
 123           |#Hcut >Hcut @tape_move_null_action
 124           ]
 125         ]
 126       ]
 127     ]
 128 ]
 129 qed.
 130
 131 lemma comp_q0_q1 :
 132   ∀i,j,sig,n,is_endc,v,a.i ≠ j → i < S n → j < S n →
 133   nth i ? (current_chars ?? v) (None ?) = Some ? a → is_endc a = false →
 134   nth j ? (current_chars ?? v) (None ?) = Some ? a →
 135   step sig n (compare_step i j sig n is_endc) (mk_mconfig ??? comp0 v) =
 136     mk_mconfig ??? comp1
 137      (change_vec ? (S n)
 138        (change_vec ?? v
 139          (tape_move ? (nth i ? v (niltape ?)) (Some ? 〈a,R〉)) i)
 140        (tape_move ? (nth j ? v (niltape ?)) (Some ? 〈a,R〉)) j).
 141 #i #j #sig #n #is_endc #v #a #Heq #Hi #Hj #Ha1 #Hnotendc #Ha2
 142 whd in ⊢ (??%?); >(eq_pair_fst_snd … (trans ????)) whd in ⊢ (??%?); @eq_f2
 143 [ whd in match (trans ????);
 144   >Ha1 >Ha2 whd in ⊢ (??(???%)?); >Hnotendc >(\b ?) //
 145 | whd in match (trans ????);
 146   >Ha1 >Ha2 whd in ⊢ (??(???????(???%))?); >Hnotendc >(\b ?) //
 147   change with (change_vec ?????) in ⊢ (??(???????%)?);
 148   <(change_vec_same … v j (niltape ?)) in ⊢ (??%?);
 149   <(change_vec_same … v i (niltape ?)) in ⊢ (??%?);
 150   >pmap_change >pmap_change >tape_move_null_action
 151   @eq_f2 // @eq_f2 // >nth_change_vec_neq //
 152 ]
 153 qed.
 154
 155 lemma sem_comp_step :
 156   ∀i,j,sig,n,is_endc.i ≠ j → i < S n → j < S n →
 157   compare_step i j sig n is_endc ⊨
 158     [ comp1: R_comp_step_true i j sig n is_endc,
 159              R_comp_step_false i j sig n is_endc ].
 160 #i #j #sig #n #is_endc #Hneq #Hi #Hj #int
 161 lapply (refl ? (current ? (nth i ? int (niltape ?))))
 162 cases (current ? (nth i ? int (niltape ?))) in ⊢ (???%→?);
 163 [ #Hcuri %{2} %
 164   [| % [ %
 165     [ whd in ⊢ (??%?); >comp_q0_q2_null /2/ % <Hcuri in ⊢ (???%);
 166       @sym_eq @nth_vec_map
 167     | normalize in ⊢ (%→?); #H destruct (H) ]
 168   | #_ % // % %2 // ] ]
 169 | #a #Ha lapply (refl ? (current ? (nth j ? int (niltape ?))))
 170   cases (current ? (nth j ? int (niltape ?))) in ⊢ (???%→?);
 171   [ #Hcurj %{2} %
 172     [| % [ %
 173        [ whd in ⊢ (??%?); >comp_q0_q2_null /2/ %2 <Hcurj in ⊢ (???%);
 174          @sym_eq @nth_vec_map
 175        | normalize in ⊢ (%→?); #H destruct (H) ]
 176        | #_ % // >Ha >Hcurj % % %2 % #H destruct (H) ] ]
 177   | #b #Hb %{2}
 178    cases (true_or_false (is_endc a)) #Haendc
 179     [ %
 180       [| % [ %
 181         [whd in ⊢  (??%?);  >comp_q0_q2_neq //
 182          % %{a} % // <Ha @sym_eq @nth_vec_map
 183         | normalize in ⊢ (%→?); #H destruct (H) ]
 184       | #_ % // % % % >Ha %{a} % // ]
 185       ]
 186     |cases (true_or_false (a == b)) #Hab
 187       [ %
 188         [| % [ %
 189           [whd in ⊢  (??%?);  >(comp_q0_q1 … a Hneq Hi Hj) //
 190             [>(\P Hab) <Hb @sym_eq @nth_vec_map
 191             |<Ha @sym_eq @nth_vec_map ]
 192           | #_ whd >(\P Hab) %{b} % // % // <(\P Hab) % // ]
 193           | * #H @False_ind @H %
 194         ] ]
 195       | %
 196         [| % [ %
 197           [whd in ⊢  (??%?);  >comp_q0_q2_neq //
 198            <(nth_vec_map ?? (current …) i ? int (niltape ?))
 199            <(nth_vec_map ?? (current …) j ? int (niltape ?)) %2 >Ha >Hb
 200            @(not_to_not ??? (\Pf Hab)) #H destruct (H) %
 201           | normalize in ⊢ (%→?); #H destruct (H) ]
 202         | #_ % // % % %2 >Ha >Hb @(not_to_not ??? (\Pf Hab)) #H destruct (H) % ] ]
 203       ]
 204     ]
 205   ]
 206 ]
 207 qed.
 208
 209 definition compare ≝ λi,j,sig,n,is_endc.
 210   whileTM … (compare_step i j sig n is_endc) comp1.
 211
 212 definition R_compare ≝
 213   λi,j,sig,n,is_endc.λint,outt: Vector (tape sig) (S n).
 214   ((∃x.current ? (nth i ? int (niltape ?)) = Some ? x ∧ is_endc x = true) ∨
 215    (current ? (nth i ? int (niltape ?)) ≠ current ? (nth j ? int (niltape ?)) ∨
 216     current ? (nth i ? int (niltape ?)) = None ? ∨
 217     current ? (nth j ? int (niltape ?)) = None ?) → outt = int) ∧
 218   (∀ls,x,xs,ci,rs,ls0,cj,rs0.
 219     nth i ? int (niltape ?) = midtape sig ls x (xs@ci::rs) →
 220     nth j ? int (niltape ?) = midtape sig ls0 x (xs@cj::rs0) →
 221     (∀c0. memb ? c0 (x::xs) = true → is_endc c0 = false) →
 222     (is_endc ci = true ∨ ci ≠ cj) →
 223     outt = change_vec ??
 224            (change_vec ?? int (midtape sig (reverse ? xs@x::ls) ci rs) i)
 225            (midtape sig (reverse ? xs@x::ls0) cj rs0) j).
 226
 227 lemma wsem_compare : ∀i,j,sig,n,is_endc.i ≠ j → i < S n → j < S n →
 228   compare i j sig n is_endc ⊫ R_compare i j sig n is_endc.
 229 #i #j #sig #n #is_endc #Hneq #Hi #Hj #ta #k #outc #Hloop
 230 lapply (sem_while … (sem_comp_step i j sig n is_endc Hneq Hi Hj) … Hloop) //
 231 -Hloop * #tb * #Hstar @(star_ind_l ??????? Hstar) -Hstar
 232 [ #tc whd in ⊢ (%→?); * * [ * [ *
 233   [* #curi * #Hcuri #Hendi #Houtc %
 234     [ #_ @Houtc
 235     | #ls #x #xs #ci #rs #ls0 #cj #rs0 #Hnthi #Hnthj #Hnotendc
 236       @False_ind
 237       >Hnthi in Hcuri; normalize in ⊢ (%→?); #H destruct (H)
 238       >(Hnotendc ? (memb_hd … )) in Hendi; #H destruct (H)
 239     ]
 240   |#Hcicj #Houtc %
 241     [ #_ @Houtc
 242     | #ls #x #xs #ci #rs #ls0 #cj #rs0 #Hnthi #Hnthj
 243       >Hnthi in Hcicj; >Hnthj normalize in ⊢ (%→?); * #H @False_ind @H %
 244     ]]
 245   | #Hci #Houtc %
 246     [ #_ @Houtc
 247     | #ls #x #xs #ci #rs #ls0 #cj #rs0 #Hnthi >Hnthi in Hci;
 248       normalize in ⊢ (%→?); #H destruct (H) ] ]
 249   | #Hcj #Houtc %
 250     [ #_ @Houtc
 251     | #ls #x #xs #ci #rs #ls0 #cj #rs0 #_ #Hnthj >Hnthj in Hcj;
 252       normalize in ⊢ (%→?); #H destruct (H) ] ]
 253   | #tc #td #te * #x * * * #Hendcx #Hci #Hcj #Hd #Hstar #IH #He lapply (IH He) -IH *
 254     #IH1 #IH2 %
 255     [ >Hci >Hcj * [* #x0 * #H destruct (H) >Hendcx #H destruct (H)
 256     |* [* #H @False_ind [cases H -H #H @H % | destruct (H)] | #H destruct (H)]]
 257     | #ls #c0 #xs #ci #rs #ls0 #cj #rs0 cases xs
 258       [ #Hnthi #Hnthj #Hnotendc #Hcicj >IH1
 259         [ >Hd @eq_f3 //
 260           [ @eq_f3 // >(?:c0=x) [ >Hnthi % ]
 261             >Hnthi in Hci;normalize #H destruct (H) %
 262           | >(?:c0=x) [ >Hnthj % ]
 263             >Hnthi in Hci;normalize #H destruct (H) % ]
 264         | >Hd >nth_change_vec // >nth_change_vec_neq [|@sym_not_eq //]
 265           >nth_change_vec // >Hnthi >Hnthj normalize
 266           cases Hcicj #Hcase
 267           [%1 %{ci} % // | %2 %1 %1 @(not_to_not ??? Hcase) #H destruct (H) % ]
 268         ]
 269       | #x0 #xs0 #Hnthi #Hnthj #Hnotendc #Hcicj
 270         >(IH2 (c0::ls) x0 xs0 ci rs (c0::ls0) cj rs0 … Hcicj)
 271         [ >Hd >change_vec_commute in ⊢ (??%?); //
 272           >change_vec_change_vec >change_vec_commute in ⊢ (??%?); //
 273           @sym_not_eq //
 274         | #c1 #Hc1 @Hnotendc @memb_cons @Hc1
 275         | >Hd >nth_change_vec // >Hnthj normalize
 276           >Hnthi in Hci;normalize #H destruct (H) %
 277         | >Hd >nth_change_vec_neq [|@sym_not_eq //] >Hnthi
 278           >nth_change_vec // normalize
 279           >Hnthi in Hci;normalize #H destruct (H) %
 280         ]
 281 ]]]
 282 qed.
 283
 284 lemma terminate_compare :  ∀i,j,sig,n,is_endc,t.
 285   i ≠ j → i < S n → j < S n →
 286   compare i j sig n is_endc ↓ t.
 287 #i #j #sig #n #is_endc #t #Hneq #Hi #Hj
 288 @(terminate_while … (sem_comp_step …)) //
 289 <(change_vec_same … t i (niltape ?))
 290 cases (nth i (tape sig) t (niltape ?))
 291 [ % #t1 * #x * * * #_ >nth_change_vec // normalize in ⊢ (%→?); #Hx destruct
 292 |2,3: #a0 #al0 % #t1 * #x * * * #_ >nth_change_vec // normalize in ⊢ (%→?); #Hx destruct
 293 | #ls #c #rs lapply c -c lapply ls -ls lapply t -t elim rs
 294   [#t #ls #c % #t1 * #x * * * #Hendcx >nth_change_vec // normalize in ⊢ (%→?);
 295    #H1 destruct (H1) #Hxsep >change_vec_change_vec #Ht1 %
 296    #t2 * #x0 * * * #Hendcx0 >Ht1 >nth_change_vec_neq [|@sym_not_eq //]
 297    >nth_change_vec // normalize in ⊢ (%→?); #H destruct (H)
 298   |#r0 #rs0 #IH #t #ls #c % #t1 * #x * * >nth_change_vec //
 299    normalize in ⊢ (%→?); #H destruct (H) #Hcur
 300    >change_vec_change_vec >change_vec_commute // #Ht1 >Ht1 @IH
 301   ]
 302 ]
 303 qed.
 304
 305 lemma sem_compare : ∀i,j,sig,n,is_endc.
 306   i ≠ j → i < S n → j < S n →
 307   compare i j sig n is_endc ⊨ R_compare i j sig n is_endc.
 308 #i #j #sig #n #is_endc #Hneq #Hi #Hj @WRealize_to_Realize /2/
 309 qed.
 310
 311 (*
 312    |conf1   $
 313    |confin 0/1 confout move
 314
 315   match machine step ≝
 316     compare;
 317     if (cur(src) != $)
 318       then
 319         parmoveL;
 320         moveR(dst);
 321       else nop
 322  *)
 323
 324 definition match_step ≝ λsrc,dst,sig,n,is_startc,is_endc.
 325   compare src dst sig n is_endc ·
 326     (ifTM ?? (inject_TM ? (test_char ? (λa.is_endc a == false)) n src)
 327       (single_finalTM ??
 328         (parmove src dst sig n L is_startc · (inject_TM ? (move_r ?) n dst)))
 329       (nop …)
 330       tc_true).
 331
 332 definition Rtc_multi_true ≝
 333   λalpha,test,n,i.λt1,t2:Vector ? (S n).
 334    (∃c. current alpha (nth i ? t1 (niltape ?)) = Some ? c ∧ test c = true) ∧ t2 = t1.
 335
 336 definition Rtc_multi_false ≝
 337   λalpha,test,n,i.λt1,t2:Vector ? (S n).
 338     (∀c. current alpha (nth i ? t1 (niltape ?)) = Some ? c → test c = false) ∧ t2 = t1.
 339
 340 definition R_match_step_false ≝
 341   λsrc,dst,sig,n,is_endc.λint,outt: Vector (tape sig) (S n).
 342    (((∃x.current ? (nth src ? int (niltape ?)) = Some ? x ∧ is_endc x = true) ∨
 343      current sig (nth src (tape sig) int (niltape sig)) = None ? ∨
 344      current sig (nth dst (tape sig) int (niltape sig)) = None ? ) ∧ outt = int) ∨
 345    (∃ls,ls0,rs,rs0,x,xs.
 346     nth src ? int (niltape ?) = midtape sig ls x (xs@rs) ∧ is_endc x = false ∧
 347     nth dst ? int (niltape ?) = midtape sig ls0 x (xs@rs0) ∧
 348     ∀rsi,rsj,end,c.
 349     rs = end::rsi → rs0 = c::rsj →
 350     (∀c0. memb ? c0 (x::xs) = true → is_endc c0 = false) ∧ is_endc end = true ∧
 351     nth dst ? int (niltape ?) = midtape sig ls0 x (xs@c::rsj) ∧
 352     outt = change_vec ??
 353            (change_vec ?? int (midtape sig (reverse ? xs@x::ls) end rsi) src)
 354            (midtape sig (reverse ? xs@x::ls0) c rsj) dst).
 355
 356 definition R_match_step_true ≝
 357   λsrc,dst,sig,n,is_startc,is_endc.λint,outt: Vector (tape sig) (S n).
 358   ∀s.current sig (nth src (tape sig) int (niltape sig)) = Some ? s →
 359   is_startc s = true →
 360   (∀c.c ∈ right ? (nth src (tape sig) int (niltape sig)) = true → is_startc c = false) →
 361   (∀s1.current sig (nth dst (tape sig) int (niltape sig)) = Some ? s1 → s ≠ s1 →
 362    outt = change_vec ?? int
 363           (tape_move … (nth dst ? int (niltape ?)) (Some ? 〈s1,R〉)) dst ∧ is_endc s = false) ∧
 364   (∀ls,x,xs,ci,rs,ls0,cj,rs0.
 365     nth src ? int (niltape ?) = midtape sig ls x (xs@ci::rs) →
 366     nth dst ? int (niltape ?) = midtape sig ls0 x (xs@cj::rs0) → ci ≠ cj →
 367     (∀c0. memb ? c0 (x::xs) = true → is_endc c0 = false) →
 368     outt = change_vec ?? int
 369            (tape_move … (nth dst ? int (niltape ?)) (Some ? 〈x,R〉)) dst ∧ is_endc ci = false).
 370
 371 lemma sem_test_char_multi :
 372   ∀alpha,test,n,i.i ≤ n →
 373   inject_TM ? (test_char ? test) n i ⊨
 374   [ tc_true : Rtc_multi_true alpha test n i, Rtc_multi_false alpha test n i ].
 375 #alpha #test #n #i #Hin #int
 376 cases (acc_sem_inject … Hin (sem_test_char alpha test) int)
 377 #k * #outc * * #Hloop #Htrue #Hfalse %{k} %{outc} % [ %
 378 [ @Hloop
 379 | #Hqtrue lapply (Htrue Hqtrue) * * * #c *
 380   #Hcur #Htestc #Hnth_i #Hnth_j %
 381   [ %{c} % //
 382   | @(eq_vec … (niltape ?)) #i0 #Hi0
 383     cases (decidable_eq_nat i0 i) #Hi0i
 384     [ >Hi0i @Hnth_i
 385     | @sym_eq @Hnth_j @sym_not_eq // ] ] ]
 386 | #Hqfalse lapply (Hfalse Hqfalse) * * #Htestc #Hnth_i #Hnth_j %
 387   [ @Htestc
 388   | @(eq_vec … (niltape ?)) #i0 #Hi0
 389     cases (decidable_eq_nat i0 i) #Hi0i
 390     [ >Hi0i @Hnth_i
 391     | @sym_eq @Hnth_j @sym_not_eq // ] ] ]
 392 qed.
 393
 394 axiom comp_list: ∀S:DeqSet. ∀l1,l2:list S.∀is_endc. ∃l,tl1,tl2.
 395   l1 = l@tl1 ∧ l2 = l@tl2 ∧ (∀c.c ∈ l = true → is_endc c = false) ∧
 396   ∀a,tla. tl1 = a::tla → is_endc a = true ∨ (∀b,tlb.tl2 = b::tlb → a≠b).
 397
 398 axiom daemon : ∀X:Prop.X.
 399
 400 lemma sem_match_step :
 401   ∀src,dst,sig,n,is_startc,is_endc.src ≠ dst → src < S n → dst < S n →
 402   match_step src dst sig n is_startc is_endc ⊨
 403     [ inr ?? (inr ?? (inl … (inr ?? start_nop))) :
 404       R_match_step_true src dst sig n is_startc is_endc,
 405       R_match_step_false src dst sig n is_endc ].
 406 #src #dst #sig #n #is_startc #is_endc #Hneq #Hsrc #Hdst
 407 @(acc_sem_seq_app sig n … (sem_compare src dst sig n is_endc Hneq Hsrc Hdst)
 408     (acc_sem_if ? n … (sem_test_char_multi sig (λa.is_endc a == false) n src (le_S_S_to_le … Hsrc))
 409       (sem_seq …
 410         (sem_parmoveL ???? is_startc Hneq Hsrc Hdst)
 411         (sem_inject … dst (le_S_S_to_le … Hdst) (sem_move_r ? )))
 412       (sem_nop …)))
 413 [#ta #tb #tc * #Hcomp1 #Hcomp2 * #td * * * #c * #Hcurtc #Hcend #Htd >Htd -Htd
 414  #Htb #s #Hcurta_src #Hstart #Hnotstart %
 415  [ #s1 #Hcurta_dst #Hneqss1
 416    lapply Htb lapply Hcurtc -Htb -Hcurtc >(?:tc=ta)
 417    [|@Hcomp1 %2 % % >Hcurta_src >Hcurta_dst @(not_to_not … Hneqss1) #H destruct (H) % ]
 418    #Hcurtc * #te * * #_ #Hte >Hte // whd in ⊢ (%→?); * * #_ #Htbdst #Htbelse %
 419    [ @(eq_vec … (niltape ?)) #i #Hi cases (decidable_eq_nat i dst) #Hidst
 420      [ >Hidst >nth_change_vec // cases (current_to_midtape … Hcurta_dst)
 421        #ls * #rs #Hta_mid >(Htbdst … Hta_mid) >Hta_mid cases rs //
 422      | >nth_change_vec_neq [|@sym_not_eq //] @sym_eq @Htbelse @sym_not_eq // ]
 423    | >Hcurtc in Hcurta_src; #H destruct (H) cases (is_endc s) in Hcend;
 424      normalize #H destruct (H) // ]
 425  |#ls #x #xs #ci #rs #ls0 #cj #rs0 #Htasrc_mid #Htadst_mid #Hcicj #Hnotendc
 426   lapply (Hcomp2 … Htasrc_mid Htadst_mid Hnotendc (or_intror ?? Hcicj))
 427   -Hcomp2 #Hcomp2
 428   cases Htb #td * * #Htd #_ >Htasrc_mid in Hcurta_src; normalize in ⊢ (%→?);
 429   #H destruct (H)
 430   >(Htd ls ci (reverse ? xs) rs s ??? ls0 cj (reverse ? xs) s rs0 (refl ??)) //
 431   [| >Hcomp2 >nth_change_vec //
 432    | #c0 #Hc0 @(Hnotstart c0) >Htasrc_mid
 433      cases (orb_true_l … Hc0) -Hc0 #Hc0
 434     [@memb_append_l2 >(\P Hc0) @memb_hd
 435     |@memb_append_l1 <(reverse_reverse …xs) @memb_reverse //
 436     ]
 437    | >Hcomp2 >nth_change_vec_neq [|@sym_not_eq // ] @nth_change_vec // ]
 438   * * #_ #Htbdst #Htbelse %
 439   [ @(eq_vec … (niltape ?)) #i #Hi cases (decidable_eq_nat i dst) #Hidst
 440      [ >Hidst >nth_change_vec // >Htadst_mid >(Htbdst ls0 s (xs@cj::rs0))
 441        [ cases xs //
 442        | >nth_change_vec // ]
 443      | >nth_change_vec_neq [|@sym_not_eq //]
 444        <Htbelse [|@sym_not_eq // ]
 445        >nth_change_vec_neq [|@sym_not_eq //]
 446         (* STOP. *)
 447        cases (decidable_eq_nat i src) #Hisrc
 448        [ >Hisrc >nth_change_vec // >Htasrc_mid //
 449        | >nth_change_vec_neq [|@sym_not_eq //]
 450          <(Htbelse i) [|@sym_not_eq // ]
 451          >Hcomp2 >nth_change_vec_neq [|@sym_not_eq // ]
 452          >nth_change_vec_neq [|@sym_not_eq // ] //
 453        ]
 454      ]
 455   | >Hcomp2 in Hcurtc; >nth_change_vec_neq [|@sym_not_eq //]
 456      >nth_change_vec // whd in ⊢ (??%?→?);
 457      #H destruct (H) cases (is_endc c) in Hcend;
 458      normalize #H destruct (H) // ]
 459   ]
 460 |#intape #outtape #ta * #Hcomp1 #Hcomp2 * #tb * * #Hc #Htb
 461  whd in ⊢ (%→?); #Hout >Hout >Htb whd
 462  lapply (current_to_midtape sig (nth src ? intape (niltape ?)))
 463  cases (current … (nth src ? intape (niltape ?))) in Hcomp1;
 464   [#Hcomp1 #_ %1 % [%1 %2 // | @Hcomp1 %2 %1 %2 %]
 465   |#c_src lapply (current_to_midtape sig (nth dst ? intape (niltape ?)))
 466    cases (current … (nth dst ? intape (niltape ?)))
 467     [#_ #Hcomp1 #_ %1 % [%2 % | @Hcomp1 %2 % % % #H destruct (H)]
 468     |#c_dst cases (true_or_false (c_src == c_dst)) #Hceq
 469       [#Hmid_dst cases (Hmid_dst c_dst (refl …)) -Hmid_dst
 470        #ls_dst * #rs_dst #Hmid_dst #Hcomp1
 471        #Hmid_src cases (Hmid_src c_src (refl …)) -Hmid_src
 472        #ls_src * #rs_src #Hmid_src
 473        cases (true_or_false (is_endc c_src)) #Hc_src
 474        [ % % [ % % %{c_src} % // | @Hcomp1 % %{c_src} % // ]
 475        | %2 cases (comp_list … rs_src rs_dst is_endc) #xs * #rsi * #rsj * * *
 476          #Hrs_src #Hrs_dst #Hnotendc #Hneq
 477          %{ls_src} %{ls_dst} %{rsi} %{rsj} %{c_src} %{xs} %
 478            [% [% // <Hrs_src //|<Hrs_dst >(\P Hceq) // ]]
 479          #rsi0 #rsj0 #end #c #Hend #Hc_dst
 480          >Hrs_src in Hmid_src; >Hend #Hmid_src
 481          >Hrs_dst in Hmid_dst; >Hc_dst <(\P Hceq) #Hmid_dst
 482          cut (is_endc end = true ∨ end ≠ c)
 483          [cases (Hneq … Hend) /2/ -Hneq #Hneq %2 @(Hneq … Hc_dst) ] #Hneq
 484          lapply (Hcomp2 … Hmid_src Hmid_dst ? Hneq)
 485           [#c0 #Hc0 cases (orb_true_l … Hc0) -Hc0 #Hc0
 486             [ >(\P Hc0) //
 487             | @Hnotendc // ]
 488           ]
 489          -Hcomp2 #Hcomp2 <Hcomp2
 490          % // % [
 491            >Hcomp2 in Hc; >nth_change_vec_neq [|@sym_not_eq //]
 492             >nth_change_vec // #H lapply (H ? (refl …))
 493             cases (is_endc end) [|normalize #H destruct (H) ]
 494             #_ % // #c0 #Hc0 cases (orb_true_l … Hc0) -Hc0 #Hc0
 495               [ >(\P Hc0) // | @Hnotendc // ]
 496          |@Hmid_dst]
 497          ]
 498       |#_ #Hcomp1 #Hsrc cases (Hsrc ? (refl ??)) -Hsrc #ls * #rs #Hsrc
 499        %1 %
 500         [% % %{c_src} % // lapply (Hc c_src) -Hc >Hcomp1
 501          [| %2 % % @(not_to_not ??? (\Pf Hceq)) #H destruct (H) // ]
 502          cases (is_endc c_src) //
 503          >Hsrc #Hc lapply (Hc (refl ??)) normalize #H destruct (H)
 504         |@Hcomp1 %2 %1 %1 @(not_to_not ??? (\Pf Hceq)) #H destruct (H) //
 505         ]
 506       ]
 507     ]
 508   ]
 509 qed.
 510
 511 definition match_m ≝ λsrc,dst,sig,n,is_startc,is_endc.
 512   whileTM … (match_step src dst sig n is_startc is_endc)
 513     (inr ?? (inr ?? (inl … (inr ?? start_nop)))).
 514
 515 definition R_match_m ≝
 516   λi,j,sig,n,is_startc,is_endc.λint,outt: Vector (tape sig) (S n).
 517   (((∃x.current ? (nth i ? int (niltape ?)) = Some ? x ∧ is_endc x = true) ∨
 518     current ? (nth i ? int (niltape ?)) = None ? ∨
 519     current ? (nth j ? int (niltape ?)) = None ?) → outt = int) ∧
 520   (∀ls,x,xs,ci,rs,ls0,x0,rs0.
 521     (∀x. is_startc x ≠ is_endc x) →
 522     is_startc x = true → is_endc ci = true →
 523     (∀z. memb ? z (x::xs) = true → is_endc x = false) →
 524     nth i ? int (niltape ?) = midtape sig ls x (xs@ci::rs) →
 525     nth j ? int (niltape ?) = midtape sig ls0 x0 rs0 →
 526     (∃l,l1.x0::rs0 = l@x::xs@l1 →
 527      ∀cj,l2.l1=cj::l2 →
 528      outt = change_vec ??
 529             (change_vec ?? int (midtape sig (reverse ? xs@x::ls) ci rs) i)
 530             (midtape sig ((reverse ? (l@x::xs))@ls0) cj l2) j) ∨
 531     ∀l,l1.x0::rs0 ≠ l@x::xs@l1).
 532
 533 axiom sub_list_dec: ∀A.∀l,ls:list A.
 534   ∃l1,l2. l = l1@ls@l2 ∨ ∀l1,l2. l ≠ l1@ls@l2.
 535
 536 lemma wsem_match_m : ∀src,dst,sig,n,is_startc,is_endc.
 537 src ≠ dst → src < S n → dst < S n →
 538   match_m src dst sig n is_startc is_endc ⊫ R_match_m src dst sig n is_startc is_endc.
 539 #src #dst #sig #n #is_startc #is_endc #Hneq #Hsrc #Hdst #ta #k #outc #Hloop
 540 lapply (sem_while … (sem_match_step src dst sig n is_startc is_endc Hneq Hsrc Hdst) … Hloop) //
 541 -Hloop * #tb * #Hstar @(star_ind_l ??????? Hstar) -Hstar
 542 [ #tc whd in ⊢ (%→%); *
 543   [ * * [ *
 544     [ * #cur_src * #H1 #H2 #Houtc %
 545       [ #_ @Houtc
 546       | #ls #x #xs #ci #rs #ls0 #cj #rs0 #Hdiff #Hstartc #Hendc #Hnotend #Hnthi
 547         @False_ind
 548         >Hnthi in H1; whd in ⊢ (??%?→?); #H destruct (H) cases (Hdiff cur_src)
 549         #Habs @Habs //
 550       ]
 551     | #Hci #Houtc %
 552       [ #_ @Houtc
 553       | #ls #x #xs #ci #rs #ls0 #cj #rs0 #Hdiff #Hstartc #Hendc #Hnotend
 554         #Hnthi >Hnthi in Hci; normalize in ⊢ (%→?); #H destruct (H) ] ]
 555     | #Hcj #Houtc %
 556       [ #_ @Houtc
 557       | #ls #x #xs #ci #rs #ls0 #cj #rs0 #Hdiff #Hstartc #Hendc #_ #_ #Hnthj >Hnthj in Hcj;
 558         normalize in ⊢ (%→?); #H destruct (H) ]
 559     ]
 560   |* #ls * #ls0 * #rs * #rs0 * #x0 * #xs * * * #Hsrc #Hx0 #Hdst #H %
 561     [>Hsrc *
 562       [* [* #x * whd in ⊢ (??%?→?); #Habs destruct (Habs) >Hx0 #Habs destruct (Habs)
 563                 |whd in ⊢ (??%?→?); #Habs destruct (Habs) ]
 564          |>Hdst whd in ⊢ (??%?→?); #Habs destruct (Habs)  ]
 565     |#ls1 #x1 #xs1 #ci #rsi #ls2 #x2 #rs2
 566      #Hdiff #Hstart #Hend #Hnotend
 567      >Hsrc #Hsrc1 destruct (Hsrc1) >Hdst #Hdst1 destruct (Hdst1)
 568      %1 %{[ ]} %{rs0} normalize in ⊢ (%→?); #Heq #cj #l2 #Hl1
 569      cut (xs=xs1)
 570        [@(append_l1_injective_r … rs0 rs0 (refl …)) @(cons_injective_r …Heq)]
 571      #eqxs <eqxs
 572      whd in match (append ? [ ] (x2::xs)); >reverse_cons >associative_append
 573      normalize in match (append ? [x2] ls2);
 574      cases (H rsi l2 ci cj ? Hl1)
 575       [* #_ #_ #H3 @H3
 576       |>eqxs in e0; #e0 @(append_l2_injective … e0) //
 577       ]
 578     ]
 579   ]
 580 |
 581
 582
 583      cases (comp_list ? (x1::xs1@ci::rsi) (x2::rs2) is_endc)
 584      #l * #tl1 * #tl2 * * * #H1 #H2 #H3 #H4
 585