matita/matita/lib/turing/multi_universal/unistep_aux.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||
   8     \   /  This file is distributed under the terms of the
   9      \ /   GNU General Public License Version 2
  10       V_____________________________________________________________*)
  11
  12 include "turing/auxiliary_machines.ma".
  13 include "turing/auxiliary_multi_machines.ma".
  14 include "turing/multi_universal/alphabet.ma".
  15 include "turing/multi_universal/tuples.ma".
  16
  17
  18 definition obj ≝ (0:DeqNat).
  19 definition cfg ≝ (1:DeqNat).
  20 definition prg ≝ (2:DeqNat).
  21
  22 definition obj_to_cfg ≝
  23   (ifTM ?? (inject_TM ? (test_null ?) 2 obj)
  24     (copy_char_N obj cfg FSUnialpha 2)
  25     (inject_TM ? (write FSUnialpha null) 2 cfg)
  26      tc_true) ·
  27   inject_TM ? (move_to_end FSUnialpha L) 2 cfg ·
  28   mmove cfg FSUnialpha 2 R.
  29
  30 definition R_obj_to_cfg ≝ λt1,t2:Vector (tape FSUnialpha) 3.
  31   ∀c,ls.
  32   nth cfg ? t1 (niltape ?) = midtape ? ls c [ ] →
  33   (∀lso,x,rso.nth obj ? t1 (niltape ?) = midtape FSUnialpha lso x rso →
  34    t2 = change_vec ?? t1
  35          (mk_tape ? [ ] (option_hd ? (reverse ? (x::ls))) (tail ? (reverse ? (x::ls)))) cfg) ∧
  36   (current ? (nth obj ? t1 (niltape ?)) = None ? →
  37    t2 = change_vec ?? t1
  38          (mk_tape ? [ ] (option_hd FSUnialpha (reverse ? (null::ls)))
  39            (tail ? (reverse ? (null::ls)))) cfg).
  40
  41 (*
  42 axiom accRealize_to_Realize :
  43   ∀sig,n.∀M:mTM sig n.∀Rtrue,Rfalse,acc.
  44   M ⊨ [ acc: Rtrue, Rfalse ] →  M ⊨ Rtrue ∪ Rfalse.
  45 *)
  46
  47 lemma eq_mk_tape_rightof :
  48  ∀alpha,a,al.mk_tape alpha (a::al) (None ?) [ ] = rightof ? a al.
  49 #alpha #a #al %
  50 qed.
  51
  52 lemma tape_move_mk_tape_R :
  53   ∀sig,ls,c,rs.
  54   (c = None ? → ls = [ ] ∨ rs = [ ]) →
  55   tape_move ? (mk_tape sig ls c rs) R =
  56   mk_tape ? (option_cons ? c ls) (option_hd ? rs) (tail ? rs).
  57 #sig * [ * [ * | #c * ] | #l0 #ls0 * [ *
  58 [| #r0 #rs0 #H @False_ind cases (H (refl ??)) #H1 destruct (H1) ] | #c * ] ]
  59 normalize //
  60 qed.
  61
  62 lemma None_or_Some: ∀A.∀a. a =None A ∨ ∃b. a = Some ? b.
  63 #A * /2/ #a %2 %{a} %
  64 qed.
  65
  66 lemma not_None_to_Some: ∀A.∀a. a ≠ None A → ∃b. a = Some ? b.
  67 #A * /2/ * #H @False_ind @H %
  68 qed.
  69
  70 lemma sem_obj_to_cfg : obj_to_cfg ⊨  R_obj_to_cfg.
  71 @(sem_seq_app FSUnialpha 2 ?????
  72   (sem_if ??????????
  73    (sem_test_null_multi ?? obj ?)
  74    (sem_copy_char_N …)
  75    (sem_inject ???? cfg ? (sem_write FSUnialpha null)))
  76   (sem_seq ?????? (sem_inject ???? cfg ? (sem_move_to_end_l ?))
  77     (sem_move_multi ? 2 cfg R ?))) //
  78 #ta #tout *
  79 #tb * #Hif * #tc * #HM2 #HM3 #c #ls #Hcfg
  80 (* Hif *)
  81 cases Hif -Hif
  82 [ * #t1 * * #Hcurta #Ht1 destruct (Ht1)
  83   lapply (not_None_to_Some … Hcurta) * #curta #Hcurtaeq
  84   whd in ⊢ (%→?); #Htb % [2: #Hcur @False_ind /2/]
  85   #lso #xo #rso #Hobjta cases HM2 whd in ⊢ (%→?); * #_
  86   #HM2 #Heq >Htb in HM2; >nth_change_vec [2: @leb_true_to_le %]
  87   >Hcfg >Hcurtaeq #HM2 lapply (HM2 … (refl ??)) -HM2
  88   whd in match (left ??); whd in match (right ??);
  89   >reverse_cons #Htc >HM3 @(eq_vec … (niltape ?)) #i #lei2
  90   cases (le_to_or_lt_eq … (le_S_S_to_le …lei2))
  91   [#lei1 cases (le_to_or_lt_eq … (le_S_S_to_le …lei1))
  92     [#lei0 lapply(le_n_O_to_eq … (le_S_S_to_le …lei0)) #eqi <eqi
  93      >nth_change_vec_neq [2:@eqb_false_to_not_eq %]
  94      <(Heq 0) [2:@eqb_false_to_not_eq %] >Htb
  95      >nth_change_vec_neq [2:@eqb_false_to_not_eq %]
  96      >nth_change_vec_neq [%|2:@eqb_false_to_not_eq %]
  97     |#Hi >Hi >nth_change_vec // >nth_change_vec // >Htc
  98      >Hobjta in Hcurtaeq; whd in ⊢ (??%?→?); #Htmp destruct(Htmp)
  99      >tape_move_mk_tape_R [2: #_ %1 %] %
 100     ]
 101   |#Hi >Hi >nth_change_vec_neq [2:@eqb_false_to_not_eq %]
 102    >nth_change_vec_neq [2:@eqb_false_to_not_eq %]
 103    <(Heq 2) [2:@eqb_false_to_not_eq %] >Htb
 104    >nth_change_vec_neq [%|2:@eqb_false_to_not_eq %]
 105   ]
 106 | * #t1 * * #Hcurta #Ht1 destruct (Ht1)
 107   * whd in ⊢ (%→?); #Htb lapply (Htb … Hcfg) -Htb #Htb
 108   #Htbeq %
 109     [#lso #xo #rso #Hmid @False_ind >Hmid in Hcurta;
 110      whd in ⊢ (??%?→?); #Htmp destruct (Htmp)]
 111   #_ cases HM2 whd in ⊢ (%→?); * #_
 112   #HM2 #Heq >Htb in HM2; #HM2 lapply (HM2 … (refl ??)) -HM2
 113   #Htc >HM3 @(eq_vec … (niltape ?)) #i #lei2
 114   cases (le_to_or_lt_eq … (le_S_S_to_le …lei2))
 115   [#lei1 cases (le_to_or_lt_eq … (le_S_S_to_le …lei1))
 116     [#lei0 lapply(le_n_O_to_eq … (le_S_S_to_le …lei0)) #eqi <eqi
 117      >nth_change_vec_neq [2:@eqb_false_to_not_eq %]
 118      >nth_change_vec_neq [2:@eqb_false_to_not_eq %]
 119      <(Heq 0) [2:@eqb_false_to_not_eq %] >Htb
 120      <(Htbeq 0) [2:@eqb_false_to_not_eq %] %
 121     |#Hi >Hi >nth_change_vec // >nth_change_vec // >Htc
 122      >tape_move_mk_tape_R [2: #_ %1 %] >reverse_cons %
 123     ]
 124   |#Hi >Hi >nth_change_vec_neq [2:@eqb_false_to_not_eq %]
 125    >nth_change_vec_neq [2:@eqb_false_to_not_eq %]
 126    <(Heq 2) [2:@eqb_false_to_not_eq %]
 127    <(Htbeq 2) [%|@eqb_false_to_not_eq %]
 128   ]
 129 ]
 130 qed.
 131
 132 (* another semantics for obj_to_cfg *)
 133 definition low_char' ≝ λc.
 134   match c with
 135   [ None ⇒ null
 136   | Some b ⇒ if (is_bit b) then b else null
 137   ].
 138
 139 lemma low_char_option : ∀s.
 140   low_char' (option_map FinBool FSUnialpha bit s) = low_char s.
 141 * //
 142 qed.
 143
 144 definition R_obj_to_cfg1 ≝ λt1,t2:Vector (tape FSUnialpha) 3.
 145   ∀c,ls.
 146   nth cfg ? t1 (niltape ?) = midtape ? ls c [ ] →
 147   let x ≝ current ? (nth obj ? t1 (niltape ?)) in
 148   (∀b. x= Some ? b → is_bit b = true) →
 149   t2 = change_vec ?? t1
 150          (mk_tape ? [ ] (option_hd FSUnialpha (reverse ? (low_char' x::ls)))
 151            (tail ? (reverse ? (low_char' x::ls)))) cfg.
 152
 153 lemma sem_obj_to_cfg1: obj_to_cfg ⊨ R_obj_to_cfg1.
 154 @(Realize_to_Realize … sem_obj_to_cfg) #t1 #t2 #Hsem
 155 #c #ls #Hcfg lapply(Hsem c ls Hcfg) * #HSome #HNone #Hb
 156 cases (None_or_Some ? (current ? (nth obj ? t1 (niltape ?))))
 157   [#Hcur >Hcur @HNone @Hcur
 158   |* #b #Hb1 >Hb1
 159    cut (low_char' (Some ? b) = b)  [whd in ⊢ (??%?); >(Hb b Hb1) %] #Hlow >Hlow
 160    lapply(current_to_midtape … Hb1) * #lsobj * #rsobj #Hmid
 161    @(HSome … Hmid)
 162   ]
 163 qed.
 164
 165 (* test_null_char *)
 166 definition test_null_char ≝ test_char FSUnialpha (λc.c == null).
 167
 168 definition R_test_null_char_true ≝ λt1,t2.
 169   current FSUnialpha t1 = Some ? null ∧ t1 = t2.
 170
 171 definition R_test_null_char_false ≝ λt1,t2.
 172   current FSUnialpha t1 ≠ Some ? null ∧ t1 = t2.
 173
 174 lemma sem_test_null_char :
 175   test_null_char ⊨ [ tc_true : R_test_null_char_true, R_test_null_char_false].
 176 #t1 cases (sem_test_char FSUnialpha (λc.c == null) t1) #k * #outc * * #Hloop #Htrue
 177 #Hfalse %{k} %{outc} % [ %
 178 [ @Hloop
 179 | #Houtc cases (Htrue ?) [| @Houtc] * #c * #Hcurt1 #Hcnull lapply (\P Hcnull)
 180   -Hcnull #H destruct (H) #Houtc1 %
 181   [ @Hcurt1 | <Houtc1 % ] ]
 182 | #Houtc cases (Hfalse ?) [| @Houtc] #Hc #Houtc %
 183   [ % #Hcurt1 >Hcurt1 in Hc; #Hc lapply (Hc ? (refl ??))
 184     >(?:((null:FSUnialpha) == null) = true) [|@(\b (refl ??)) ]
 185     #H destruct (H)
 186   | <Houtc % ] ]
 187 qed.
 188
 189 definition cfg_to_obj ≝
 190   mmove cfg FSUnialpha 2 L ·
 191   (ifTM ?? (inject_TM ? test_null_char 2 cfg)
 192     (nop ? 2)
 193     (copy_char_N cfg obj FSUnialpha 2)
 194     tc_true).
 195 (* ·
 196   inject_TM ? (move_to_end FSUnialpha L) 2 cfg ·
 197   mmove cfg FSUnialpha 2 R. *)
 198
 199 definition R_cfg_to_obj ≝ λt1,t2:Vector (tape FSUnialpha) 3.
 200   ∀c,ls.
 201   nth cfg ? t1 (niltape ?) = mk_tape FSUnialpha (c::ls) (None ?) [ ] →
 202   (c = null → t2 = change_vec ?? t1 (midtape ? ls c [ ]) cfg) ∧
 203   (c ≠ null →
 204    t2 = change_vec ??
 205           (change_vec ?? t1
 206              (midtape ? (left ? (nth obj ? t1 (niltape ?))) c (right ? (nth obj ? t1 (niltape ?)))) obj)
 207           (midtape ? ls c [ ]) cfg).
 208
 209 lemma tape_move_mk_tape_L :
 210   ∀sig,ls,c,rs.
 211   (c = None ? → ls = [ ] ∨ rs = [ ]) →
 212   tape_move ? (mk_tape sig ls c rs) L =
 213   mk_tape ? (tail ? ls) (option_hd ? ls) (option_cons ? c rs).
 214 #sig * [ * [ * | #c * ] | #l0 #ls0 * [ *
 215 [| #r0 #rs0 #H @False_ind cases (H (refl ??)) #H1 destruct (H1) ] | #c * ] ]
 216 normalize //
 217 qed.
 218
 219 lemma sem_cfg_to_obj : cfg_to_obj ⊨  R_cfg_to_obj.
 220 @(sem_seq_app FSUnialpha 2 ????? (sem_move_multi ? 2 cfg L ?)
 221   (sem_if ??????????
 222    (acc_sem_inject ?????? cfg ? sem_test_null_char)
 223    (sem_nop …)
 224    (sem_copy_char_N …)))
 225 // [@sym_not_eq //]
 226 #ta #tb *
 227 #tc * whd in ⊢ (%→?); #Htc *
 228 [ * #te * * * #Hcurtc #Hte1 #Hte2 whd in ⊢ (%→?); #Htb destruct (Htb)
 229   #c #ls #Hta %
 230   [ #Hc >Hta in Htc; >eq_mk_tape_rightof whd in match (tape_move ???); #Htc
 231     cut (te = tc)
 232     [ lapply (eq_vec_change_vec ??????? (sym_eq … Hte1) Hte2) >change_vec_same // ]
 233       -Hte1 -Hte2 #Hte //
 234     | #Hc >Hta in Htc; >eq_mk_tape_rightof whd in match (tape_move ???); #Htc
 235       >Htc in Hcurtc; >nth_change_vec // normalize in ⊢ (%→?);
 236       #H destruct (H) @False_ind cases Hc /2/ ]
 237 | * #te * * * #Hcurtc #Hte1 #Hte2
 238   whd in ⊢ (%→?); #Htb
 239   #c #ls #Hta % #Hc
 240   [ >Htc in Hcurtc; >Hta >nth_change_vec //
 241     normalize in ⊢ (%→?); * #H @False_ind /2/
 242   | cut (te = tc)
 243     [ lapply (eq_vec_change_vec ??????? (sym_eq … Hte1) Hte2)
 244       >change_vec_same // ] -Hte1 -Hte2 #Hte destruct (Hte)
 245     >Hta in Htc; whd in match (tape_move ???); #Htc
 246     >Htc in Htb; >nth_change_vec //
 247     >nth_change_vec_neq [2:@eqb_false_to_not_eq //] >Hta
 248     #Htb @Htb
 249   ]
 250 qed.
 251
 252 definition char_to_move ≝ λc.match c with
 253   [ bit b ⇒ if b then R else L
 254   | _ ⇒ N].
 255
 256 definition char_to_bit_option ≝ λc.match c with
 257   [ bit b ⇒ Some ? (bit b)
 258   | _ ⇒ None ?].
 259
 260 definition R_cfg_to_obj1 ≝ λt1,t2:Vector (tape FSUnialpha) 3.
 261   ∀c,ls.
 262   nth cfg ? t1 (niltape ?) = mk_tape FSUnialpha (c::ls) (None ?) [ ] →
 263   c ≠ bar →
 264   let new_obj ≝
 265       tape_write ? (nth obj ? t1 (niltape ?)) (char_to_bit_option c) in
 266     t2 = change_vec ??
 267           (change_vec ?? t1
 268             (tape_write ? (nth obj ? t1 (niltape ?)) (char_to_bit_option c)) obj)
 269           (midtape ? ls c [ ]) cfg.
 270
 271 lemma sem_cfg_to_obj1: cfg_to_obj ⊨  R_cfg_to_obj1.
 272 @(Realize_to_Realize … sem_cfg_to_obj) #t1 #t2 #H #c #ls #Hcfg #Hbar
 273 cases (H c ls Hcfg) cases (true_or_false (c==null)) #Hc
 274   [#Ht2 #_ >(Ht2 (\P Hc)) -Ht2 @(eq_vec … (niltape ?))
 275    #i #lei2 cases (le_to_or_lt_eq … (le_S_S_to_le …lei2))
 276     [#lei1 cases (le_to_or_lt_eq … (le_S_S_to_le …lei1))
 277       [#lei0 lapply(le_n_O_to_eq … (le_S_S_to_le …lei0)) #eqi <eqi
 278        >nth_change_vec_neq [2:@eqb_false_to_not_eq %]
 279        >nth_change_vec_neq in ⊢ (???%); [2:@eqb_false_to_not_eq %]
 280        >nth_change_vec // >(\P Hc) %
 281       |#Hi >Hi >nth_change_vec //
 282       ]
 283     |#Hi >Hi >nth_change_vec_neq [2:@eqb_false_to_not_eq %]
 284      >nth_change_vec_neq [2:@eqb_false_to_not_eq %]
 285      >nth_change_vec_neq [2:@eqb_false_to_not_eq %] %
 286     ]
 287   |#_ #Ht2 >(Ht2 (\Pf Hc)) -Ht2 @(eq_vec … (niltape ?))
 288    #i #lei2 cases (le_to_or_lt_eq … (le_S_S_to_le …lei2))
 289     [#lei1 cases (le_to_or_lt_eq … (le_S_S_to_le …lei1))
 290       [#lei0 lapply(le_n_O_to_eq … (le_S_S_to_le …lei0)) #eqi <eqi
 291        >nth_change_vec_neq [2:@eqb_false_to_not_eq %]
 292        >nth_change_vec_neq in ⊢ (???%); [2:@eqb_false_to_not_eq %]
 293        >nth_change_vec // >nth_change_vec //
 294        lapply (\bf Hbar) lapply Hc elim c //
 295         [whd in ⊢ (??%?→?); #H destruct (H)
 296         |#_ whd in ⊢ (??%?→?); #H destruct (H)
 297         ]
 298       |#Hi >Hi >nth_change_vec //
 299       ]
 300     |#Hi >Hi >nth_change_vec_neq [2:@eqb_false_to_not_eq %]
 301      >nth_change_vec_neq [2:@eqb_false_to_not_eq %]
 302      >nth_change_vec_neq [2:@eqb_false_to_not_eq %] %
 303     ]
 304   ]
 305 qed.
 306
 307
 308 (* macchina che muove il nastro obj a destra o sinistra a seconda del valore
 309    del current di prg, che codifica la direzione in cui ci muoviamo *)
 310
 311 definition tape_move_obj : mTM FSUnialpha 2 ≝
 312   ifTM ??
 313    (inject_TM ? (test_char ? (λc:FSUnialpha.c == bit false)) 2 prg)
 314    (mmove obj FSUnialpha 2 L)
 315    (ifTM ??
 316     (inject_TM ? (test_char ? (λc:FSUnialpha.c == bit true)) 2 prg)
 317     (mmove obj FSUnialpha 2 R)
 318     (nop ??)
 319     tc_true)
 320    tc_true.
 321
 322 definition R_tape_move_obj' ≝ λt1,t2:Vector (tape FSUnialpha) 3.
 323   (current ? (nth prg ? t1 (niltape ?)) = Some ? (bit false) →
 324    t2 = change_vec ?? t1 (tape_move ? (nth obj ? t1 (niltape ?)) L) obj) ∧
 325   (current ? (nth prg ? t1 (niltape ?)) = Some ? (bit true) →
 326    t2 = change_vec ?? t1 (tape_move ? (nth obj ? t1 (niltape ?)) R) obj) ∧
 327   (current ? (nth prg ? t1 (niltape ?)) ≠ Some ? (bit false) →
 328    current ? (nth prg ? t1 (niltape ?)) ≠ Some ? (bit true) →
 329    t2 = t1).
 330
 331 lemma sem_tape_move_obj' : tape_move_obj ⊨ R_tape_move_obj'.
 332 #ta cases (sem_if ??????????
 333   (acc_sem_inject ?????? prg ? (sem_test_char ? (λc:FSUnialpha.c == bit false)))
 334   (sem_move_multi ? 2 obj L ?)
 335   (sem_if ??????????
 336    (acc_sem_inject ?????? prg ? (sem_test_char ? (λc:FSUnialpha.c == bit true)))
 337    (sem_move_multi ? 2 obj R ?)
 338    (sem_nop …)) ta) //
 339 #i * #outc * #Hloop #HR %{i} %{outc} % [@Hloop] -i
 340 cases HR -HR
 341 [ * #tb * * * * #c * #Hcurta_prg #Hc lapply (\P Hc) -Hc #Hc #Htb1 #Htb2
 342   whd in ⊢ (%→%); #Houtc >Houtc -Houtc % [ %
 343   [ >Hcurta_prg #H destruct (H) >(?:tb = ta)
 344     [| lapply (eq_vec_change_vec ??????? Htb1 Htb2)
 345        >change_vec_same // ] %
 346   | >Hcurta_prg #H destruct (H) destruct (Hc) ]
 347   | >Hcurta_prg >Hc * #H @False_ind /2/ ]
 348 | * #tb * * * #Hnotfalse #Htb1 #Htb2 cut (tb = ta)
 349   [ lapply (eq_vec_change_vec ??????? Htb1 Htb2)
 350      >change_vec_same // ] -Htb1 -Htb2 #Htb destruct (Htb) *
 351   [ * #tc * * * * #c * #Hcurta_prg #Hc lapply (\P Hc) -Hc #Hc #Htc1 #Htc2
 352     whd in ⊢ (%→%); #Houtc >Houtc -Houtc % [ %
 353     [ >Hcurta_prg #H destruct (H) destruct (Hc)
 354     | >Hcurta_prg #H destruct (H) >(?:tc = ta)
 355       [| lapply (eq_vec_change_vec ??????? Htc1 Htc2)
 356         >change_vec_same // ] % ]
 357     | >Hcurta_prg >Hc #_ * #H @False_ind /2/ ]
 358   | * #tc * * * #Hnottrue #Htc1 #Htc2 cut (tc = ta)
 359     [ lapply (eq_vec_change_vec ??????? Htc1 Htc2)
 360       >change_vec_same // ] -Htc1 -Htc2
 361     #Htc destruct (Htc) whd in ⊢ (%→?); #Houtc % [ %
 362     [ #Hcurta_prg lapply (\Pf (Hnotfalse ? Hcurta_prg)) * #H @False_ind /2/
 363     | #Hcurta_prg lapply (\Pf (Hnottrue ? Hcurta_prg)) * #H @False_ind /2/ ]
 364     | #_ #_ @Houtc ]
 365   ]
 366 ]
 367 qed.
 368
 369 definition R_tape_move_obj ≝ λt1,t2:Vector (tape FSUnialpha) 3.
 370   ∀c. current ? (nth prg ? t1 (niltape ?)) = Some ? c →
 371   t2 = change_vec ?? t1 (tape_move ? (nth obj ? t1 (niltape ?)) (char_to_move c)) obj.
 372
 373 lemma sem_tape_move_obj : tape_move_obj ⊨ R_tape_move_obj.
 374 @(Realize_to_Realize … sem_tape_move_obj')
 375 #ta #tb * * #Htb1 #Htb2 #Htb3 * [ *
 376 [ @Htb2 | @Htb1 ]
 377 | #Hcurta_prg change with (nth obj ? ta (niltape ?)) in match (tape_move ???);
 378   >change_vec_same @Htb3 >Hcurta_prg % #H destruct (H)
 379 | #Hcurta_prg change with (nth obj ? ta (niltape ?)) in match (tape_move ???);
 380   >change_vec_same @Htb3 >Hcurta_prg % #H destruct (H)
 381 ]
 382 qed.
 383
 384 (************** list of tape ******************)
 385 definition list_of_tape ≝ λsig.λt:tape sig.
 386   reverse ? (left ? t)@option_cons ? (current ? t) (right ? t).
 387
 388 lemma list_of_midtape: ∀sig,ls,c,rs.
 389   list_of_tape sig (midtape ? ls c rs) = reverse ? ls@c::rs.
 390 // qed-.
 391
 392 lemma list_of_rightof: ∀sig,ls,c.
 393   list_of_tape sig (rightof ? c ls) = reverse ? (c::ls).
 394 #sig #ls #c <(append_nil ? (reverse ? (c::ls)))
 395 // qed-.
 396
 397 lemma list_of_tape_move: ∀sig,t,m.
 398   list_of_tape sig t = list_of_tape sig (tape_move ? t m).
 399 #sig #t * // cases t //
 400  [(* rightof, move L *) #a #l >list_of_midtape
 401   >append_cons <reverse_single <reverse_append %
 402  |(* midtape, move L *) * //
 403   #a #ls #c #rs >list_of_midtape >list_of_midtape
 404   >reverse_cons >associative_append %
 405  |(* midtape, move R *) #ls #c *
 406    [>list_of_midtape >list_of_rightof >reverse_cons %
 407    |#a #rs >list_of_midtape >list_of_midtape >reverse_cons
 408     >associative_append %
 409    ]
 410  ]
 411 qed.
 412
 413 lemma list_of_tape_write: ∀sig,cond,t,c.
 414 (∀b. c = Some ? b → cond b =true) →
 415 (∀x. mem ? x (list_of_tape ? t) → cond x =true ) →
 416 ∀x. mem ? x (list_of_tape sig (tape_write ? t c)) → cond x =true.
 417 #sig #cond #t #c #Hc #Htape #x lapply Hc cases c
 418   [(* c is None *) #_ whd in match (tape_write ???); @Htape
 419   |#b #Hb lapply (Hb … (refl ??)) -Hb #Hb
 420    whd in match (tape_write ???); >list_of_midtape
 421    #Hx cases(mem_append ???? Hx) -Hx
 422     [#Hx @Htape @mem_append_l1 @Hx
 423     |* [//]
 424      #Hx @Htape @mem_append_l2 cases (current sig t)
 425       [@Hx | #c1 %2 @Hx]
 426     ]
 427   ]
 428 qed.
 429
 430 lemma current_in_list: ∀sig,t,b.
 431   current sig t = Some ? b → mem ? b (list_of_tape sig t).
 432 #sig #t #b cases t
 433   [whd in ⊢ (??%?→?); #Htmp destruct
 434   |#l #b whd in ⊢ (??%?→?); #Htmp destruct
 435   |#l #b whd in ⊢ (??%?→?); #Htmp destruct
 436   |#ls #c #rs whd in ⊢ (??%?→?); #Htmp destruct
 437    >list_of_midtape @mem_append_l2 % %
 438   ]
 439 qed.
 440
 441 definition restart_tape ≝ λi,n.
 442   mmove i FSUnialpha n L ·
 443   inject_TM ? (move_to_end FSUnialpha L) n i ·
 444   mmove i FSUnialpha n R.
 445
 446 definition R_restart_tape ≝ λi,n.λint,outt:Vector (tape FSUnialpha) (S n).
 447    ∀t.t = nth i ? int (niltape ?) →
 448    outt = change_vec ?? int
 449     (mk_tape ? [ ] (option_hd ? (list_of_tape ? t)) (tail ? (list_of_tape ? t))) i.
 450
 451 lemma sem_restart_tape : ∀i,n.i < S n → restart_tape i n ⊨ R_restart_tape i n.
 452 #i #n #Hleq
 453 @(sem_seq_app ??????? (sem_move_multi ? n i L ?)
 454   (sem_seq ?????? (sem_inject ???? i ? (sem_move_to_end_l ?))
 455    (sem_move_multi ? n i R ?))) [1,2,3:@le_S_S_to_le //]
 456 #ta #tb * #tc * whd in ⊢ (%→?); #Htc
 457 * #td * * * #Htd1 #Htd2 #Htd3
 458 whd in ⊢ (%→?); #Htb *
 459 [ #Hta_i <Hta_i in Htc; whd in ⊢ (???(????%?)→?); #Htc
 460   cut (td = tc)
 461   [ <(change_vec_same … tc … i … (niltape ?))
 462     @(eq_vec_change_vec … (niltape ?))
 463     [ @Htd1 >Htc >nth_change_vec //
 464     | @Htd3 ] ]
 465   (* >Htc in Htd1; >nth_change_vec // *) -Htd1 -Htd2 -Htd3
 466   #Htd >Htd in Htb; >Htc >change_vec_change_vec >nth_change_vec //
 467   #Htb >Htb %
 468 | #r0 #rs0 #Hta_i <Hta_i in Htc; whd in ⊢ (???(????%?)→?); #Htc
 469   cut (td = tc)
 470   [ <(change_vec_same … tc … i … (niltape ?))
 471     @(eq_vec_change_vec … (niltape ?))
 472     [ @Htd1 >Htc >nth_change_vec //
 473     | @Htd3 ] ]
 474   (* >Htc in Htd1; >nth_change_vec // *) -Htd1 -Htd2 -Htd3
 475   #Htd >Htd in Htb; >Htc >change_vec_change_vec >nth_change_vec //
 476   #Htb >Htb %
 477 | #l0 #ls0 #Hta_i <Hta_i in Htc; whd in ⊢ (???(????%?)→?); #Htc
 478   cut (td = change_vec ?? tc (mk_tape ? [ ] (None ?) (reverse ? ls0@[l0])) i)
 479   [ <(change_vec_same … tc … i … (niltape ?))
 480     @(eq_vec_change_vec … (niltape ?))
 481     [ @Htd2 >Htc >nth_change_vec //
 482     | #j #Hij >nth_change_vec_neq // @Htd3 // ]]
 483   #Htd >Htd in Htb; >Htc >change_vec_change_vec >change_vec_change_vec
 484   >nth_change_vec // #Htb >Htb <(reverse_reverse ? ls0) in ⊢ (???%);
 485   cases (reverse ? ls0)
 486   [ %
 487   | #l1 #ls1 >reverse_cons
 488      >(?: list_of_tape ? (rightof ? l0 (reverse ? ls1@[l1])) =
 489           l1::ls1@[l0])
 490      [|change with (reverse ??@?) in ⊢ (??%?);
 491        whd in match (left ??); >reverse_cons >reverse_append
 492        whd in ⊢ (??%?); @eq_f >reverse_reverse normalize >append_nil % ] % ]
 493 | *
 494   [ #c #rs #Hta_i <Hta_i in Htc; whd in ⊢ (???(????%?)→?); #Htc
 495     cut (td = tc)
 496     [ <(change_vec_same … tc … i … (niltape ?))
 497     @(eq_vec_change_vec … (niltape ?))
 498     [ @Htd1 >Htc >nth_change_vec //
 499     | @Htd3 ] ]
 500     (* >Htc in Htd1; >nth_change_vec // *) -Htd1 -Htd2 -Htd3
 501     #Htd >Htd in Htb; >Htc >change_vec_change_vec >nth_change_vec //
 502     #Htb >Htb %
 503   | #l0 #ls0 #c #rs #Hta_i <Hta_i in Htc; whd in ⊢ (???(????%?)→?); #Htc
 504     cut (td = change_vec ?? tc (mk_tape ? [ ] (None ?) (reverse ? ls0@l0::c::rs)) i)
 505     [ @(eq_vec_change_vec … (niltape ?))
 506       [ @Htd2 >Htc >nth_change_vec //
 507       | @Htd3 ] ]
 508     #Htd >Htd in Htb; >Htc >change_vec_change_vec >change_vec_change_vec
 509     >nth_change_vec // #Htb >Htb <(reverse_reverse ? ls0) in ⊢ (???%);
 510     cases (reverse ? ls0)
 511     [ %
 512     | #l1 #ls1 >reverse_cons
 513       >(?: list_of_tape ? (midtape ? (l0::reverse ? ls1@[l1]) c rs) =
 514             l1::ls1@l0::c::rs)
 515       [|change with (reverse ??@?) in ⊢ (??%?);
 516         whd in match (left ??); >reverse_cons >reverse_append
 517         whd in ⊢ (??%?); @eq_f >reverse_reverse normalize
 518         >associative_append % ] % ]
 519   ]
 520 ]
 521 qed.