matita/matita/lib/turing/multi_universal/unistep_aux.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||
   8     \   /  This file is distributed under the terms of the
   9      \ /   GNU General Public License Version 2
  10       V_____________________________________________________________*)
  11
  12 include "turing/multi_universal/moves_2.ma".
  13 include "turing/multi_universal/match.ma".
  14 include "turing/multi_universal/copy.ma".
  15 include "turing/multi_universal/alphabet.ma".
  16 include "turing/multi_universal/tuples.ma".
  17
  18
  19 definition obj ≝ (0:DeqNat).
  20 definition cfg ≝ (1:DeqNat).
  21 definition prg ≝ (2:DeqNat).
  22
  23 definition obj_to_cfg ≝
  24   (ifTM ?? (inject_TM ? (test_null ?) 2 obj)
  25     (copy_char_N obj cfg FSUnialpha 2)
  26     (inject_TM ? (write FSUnialpha null) 2 cfg)
  27      tc_true) ·
  28   inject_TM ? (move_to_end FSUnialpha L) 2 cfg ·
  29   mmove cfg FSUnialpha 2 R.
  30
  31 definition R_obj_to_cfg ≝ λt1,t2:Vector (tape FSUnialpha) 3.
  32   ∀c,ls.
  33   nth cfg ? t1 (niltape ?) = midtape ? ls c [ ] →
  34   (∀lso,x,rso.nth obj ? t1 (niltape ?) = midtape FSUnialpha lso x rso →
  35    t2 = change_vec ?? t1
  36          (mk_tape ? [ ] (option_hd ? (reverse ? (x::ls))) (tail ? (reverse ? (x::ls)))) cfg) ∧
  37   (current ? (nth obj ? t1 (niltape ?)) = None ? →
  38    t2 = change_vec ?? t1
  39          (mk_tape ? [ ] (option_hd FSUnialpha (reverse ? (null::ls)))
  40            (tail ? (reverse ? (null::ls)))) cfg).
  41
  42 axiom accRealize_to_Realize :
  43   ∀sig,n.∀M:mTM sig n.∀Rtrue,Rfalse,acc.
  44   M ⊨ [ acc: Rtrue, Rfalse ] →  M ⊨ Rtrue ∪ Rfalse.
  45
  46 lemma eq_mk_tape_rightof :
  47  ∀alpha,a,al.mk_tape alpha (a::al) (None ?) [ ] = rightof ? a al.
  48 #alpha #a #al %
  49 qed.
  50
  51 lemma tape_move_mk_tape_R :
  52   ∀sig,ls,c,rs.
  53   (c = None ? → ls = [ ] ∨ rs = [ ]) →
  54   tape_move ? (mk_tape sig ls c rs) R =
  55   mk_tape ? (option_cons ? c ls) (option_hd ? rs) (tail ? rs).
  56 #sig * [ * [ * | #c * ] | #l0 #ls0 * [ *
  57 [| #r0 #rs0 #H @False_ind cases (H (refl ??)) #H1 destruct (H1) ] | #c * ] ]
  58 normalize //
  59 qed.
  60
  61 lemma None_or_Some: ∀A.∀a. a =None A ∨ ∃b. a = Some ? b.
  62 #A * /2/ #a %2 %{a} %
  63 qed.
  64
  65 lemma not_None_to_Some: ∀A.∀a. a ≠ None A → ∃b. a = Some ? b.
  66 #A * /2/ * #H @False_ind @H %
  67 qed.
  68
  69 lemma sem_obj_to_cfg : obj_to_cfg ⊨  R_obj_to_cfg.
  70 @(sem_seq_app FSUnialpha 2 ?????
  71   (sem_if ??????????
  72    (sem_test_null_multi ?? obj ?)
  73    (sem_copy_char_N …)
  74    (sem_inject ???? cfg ? (sem_write FSUnialpha null)))
  75   (sem_seq ?????? (sem_inject ???? cfg ? (sem_move_to_end_l ?))
  76     (sem_move_multi ? 2 cfg R ?))) //
  77 #ta #tout *
  78 #tb * #Hif * #tc * #HM2 #HM3 #c #ls #Hcfg
  79 (* Hif *)
  80 cases Hif -Hif
  81 [ * #t1 * * #Hcurta #Ht1 destruct (Ht1)
  82   lapply (not_None_to_Some … Hcurta) * #curta #Hcurtaeq
  83   whd in ⊢ (%→?); #Htb % [2: #Hcur @False_ind /2/]
  84   #lso #xo #rso #Hobjta cases HM2 whd in ⊢ (%→?); * #_
  85   #HM2 #Heq >Htb in HM2; >nth_change_vec [2: @leb_true_to_le %]
  86   >Hcfg >Hcurtaeq #HM2 lapply (HM2 … (refl ??)) -HM2
  87   whd in match (left ??); whd in match (right ??);
  88   >reverse_cons #Htc >HM3 @(eq_vec … (niltape ?)) #i #lei2
  89   cases (le_to_or_lt_eq … (le_S_S_to_le …lei2))
  90   [#lei1 cases (le_to_or_lt_eq … (le_S_S_to_le …lei1))
  91     [#lei0 lapply(le_n_O_to_eq … (le_S_S_to_le …lei0)) #eqi <eqi
  92      >nth_change_vec_neq [2:@eqb_false_to_not_eq %]
  93      <(Heq 0) [2:@eqb_false_to_not_eq %] >Htb
  94      >nth_change_vec_neq [2:@eqb_false_to_not_eq %]
  95      >nth_change_vec_neq [%|2:@eqb_false_to_not_eq %]
  96     |#Hi >Hi >nth_change_vec // >nth_change_vec // >Htc
  97      >Hobjta in Hcurtaeq; whd in ⊢ (??%?→?); #Htmp destruct(Htmp)
  98      >tape_move_mk_tape_R [2: #_ %1 %] %
  99     ]
 100   |#Hi >Hi >nth_change_vec_neq [2:@eqb_false_to_not_eq %]
 101    >nth_change_vec_neq [2:@eqb_false_to_not_eq %]
 102    <(Heq 2) [2:@eqb_false_to_not_eq %] >Htb
 103    >nth_change_vec_neq [%|2:@eqb_false_to_not_eq %]
 104   ]
 105 | * #t1 * * #Hcurta #Ht1 destruct (Ht1)
 106   * whd in ⊢ (%→?); #Htb lapply (Htb … Hcfg) -Htb #Htb
 107   #Htbeq %
 108     [#lso #xo #rso #Hmid @False_ind >Hmid in Hcurta;
 109      whd in ⊢ (??%?→?); #Htmp destruct (Htmp)]
 110   #_ cases HM2 whd in ⊢ (%→?); * #_
 111   #HM2 #Heq >Htb in HM2; #HM2 lapply (HM2 … (refl ??)) -HM2
 112   #Htc >HM3 @(eq_vec … (niltape ?)) #i #lei2
 113   cases (le_to_or_lt_eq … (le_S_S_to_le …lei2))
 114   [#lei1 cases (le_to_or_lt_eq … (le_S_S_to_le …lei1))
 115     [#lei0 lapply(le_n_O_to_eq … (le_S_S_to_le …lei0)) #eqi <eqi
 116      >nth_change_vec_neq [2:@eqb_false_to_not_eq %]
 117      >nth_change_vec_neq [2:@eqb_false_to_not_eq %]
 118      <(Heq 0) [2:@eqb_false_to_not_eq %] >Htb
 119      <(Htbeq 0) [2:@eqb_false_to_not_eq %] %
 120     |#Hi >Hi >nth_change_vec // >nth_change_vec // >Htc
 121      >tape_move_mk_tape_R [2: #_ %1 %] >reverse_cons %
 122     ]
 123   |#Hi >Hi >nth_change_vec_neq [2:@eqb_false_to_not_eq %]
 124    >nth_change_vec_neq [2:@eqb_false_to_not_eq %]
 125    <(Heq 2) [2:@eqb_false_to_not_eq %]
 126    <(Htbeq 2) [%|@eqb_false_to_not_eq %]
 127   ]
 128 ]
 129 qed.
 130
 131 (* another semantics for obj_to_cfg *)
 132 definition low_char' ≝ λc.
 133   match c with
 134   [ None ⇒ null
 135   | Some b ⇒ if (is_bit b) then b else null
 136   ].
 137
 138 lemma low_char_option : ∀s.
 139   low_char' (option_map FinBool FSUnialpha bit s) = low_char s.
 140 * //
 141 qed.
 142
 143 definition R_obj_to_cfg1 ≝ λt1,t2:Vector (tape FSUnialpha) 3.
 144   ∀c,ls.
 145   nth cfg ? t1 (niltape ?) = midtape ? ls c [ ] →
 146   let x ≝ current ? (nth obj ? t1 (niltape ?)) in
 147   (∀b. x= Some ? b → is_bit b = true) →
 148   t2 = change_vec ?? t1
 149          (mk_tape ? [ ] (option_hd FSUnialpha (reverse ? (low_char' x::ls)))
 150            (tail ? (reverse ? (low_char' x::ls)))) cfg.
 151
 152 lemma sem_obj_to_cfg1: obj_to_cfg ⊨ R_obj_to_cfg1.
 153 @(Realize_to_Realize … sem_obj_to_cfg) #t1 #t2 #Hsem
 154 #c #ls #Hcfg lapply(Hsem c ls Hcfg) * #HSome #HNone #Hb
 155 cases (None_or_Some ? (current ? (nth obj ? t1 (niltape ?))))
 156   [#Hcur >Hcur @HNone @Hcur
 157   |* #b #Hb1 >Hb1
 158    cut (low_char' (Some ? b) = b)  [whd in ⊢ (??%?); >(Hb b Hb1) %] #Hlow >Hlow
 159    lapply(current_to_midtape … Hb1) * #lsobj * #rsobj #Hmid
 160    @(HSome … Hmid)
 161   ]
 162 qed.
 163
 164 (* test_null_char *)
 165 definition test_null_char ≝ test_char FSUnialpha (λc.c == null).
 166
 167 definition R_test_null_char_true ≝ λt1,t2.
 168   current FSUnialpha t1 = Some ? null ∧ t1 = t2.
 169
 170 definition R_test_null_char_false ≝ λt1,t2.
 171   current FSUnialpha t1 ≠ Some ? null ∧ t1 = t2.
 172
 173 lemma sem_test_null_char :
 174   test_null_char ⊨ [ tc_true : R_test_null_char_true, R_test_null_char_false].
 175 #t1 cases (sem_test_char FSUnialpha (λc.c == null) t1) #k * #outc * * #Hloop #Htrue
 176 #Hfalse %{k} %{outc} % [ %
 177 [ @Hloop
 178 | #Houtc cases (Htrue ?) [| @Houtc] * #c * #Hcurt1 #Hcnull lapply (\P Hcnull)
 179   -Hcnull #H destruct (H) #Houtc1 %
 180   [ @Hcurt1 | <Houtc1 % ] ]
 181 | #Houtc cases (Hfalse ?) [| @Houtc] #Hc #Houtc %
 182   [ % #Hcurt1 >Hcurt1 in Hc; #Hc lapply (Hc ? (refl ??))
 183     >(?:((null:FSUnialpha) == null) = true) [|@(\b (refl ??)) ]
 184     #H destruct (H)
 185   | <Houtc % ] ]
 186 qed.
 187
 188 definition cfg_to_obj ≝
 189   mmove cfg FSUnialpha 2 L ·
 190   (ifTM ?? (inject_TM ? test_null_char 2 cfg)
 191     (nop ? 2)
 192     (copy_char_N cfg obj FSUnialpha 2)
 193     tc_true).
 194 (* ·
 195   inject_TM ? (move_to_end FSUnialpha L) 2 cfg ·
 196   mmove cfg FSUnialpha 2 R. *)
 197
 198 definition R_cfg_to_obj ≝ λt1,t2:Vector (tape FSUnialpha) 3.
 199   ∀c,ls.
 200   nth cfg ? t1 (niltape ?) = mk_tape FSUnialpha (c::ls) (None ?) [ ] →
 201   (c = null → t2 = change_vec ?? t1 (midtape ? ls c [ ]) cfg) ∧
 202   (c ≠ null →
 203    t2 = change_vec ??
 204           (change_vec ?? t1
 205              (midtape ? (left ? (nth obj ? t1 (niltape ?))) c (right ? (nth obj ? t1 (niltape ?)))) obj)
 206           (midtape ? ls c [ ]) cfg).
 207
 208 lemma tape_move_mk_tape_L :
 209   ∀sig,ls,c,rs.
 210   (c = None ? → ls = [ ] ∨ rs = [ ]) →
 211   tape_move ? (mk_tape sig ls c rs) L =
 212   mk_tape ? (tail ? ls) (option_hd ? ls) (option_cons ? c rs).
 213 #sig * [ * [ * | #c * ] | #l0 #ls0 * [ *
 214 [| #r0 #rs0 #H @False_ind cases (H (refl ??)) #H1 destruct (H1) ] | #c * ] ]
 215 normalize //
 216 qed.
 217
 218 lemma sem_cfg_to_obj : cfg_to_obj ⊨  R_cfg_to_obj.
 219 @(sem_seq_app FSUnialpha 2 ????? (sem_move_multi ? 2 cfg L ?)
 220   (sem_if ??????????
 221    (acc_sem_inject ?????? cfg ? sem_test_null_char)
 222    (sem_nop …)
 223    (sem_copy_char_N …)))
 224 // [@sym_not_eq //]
 225 #ta #tb *
 226 #tc * whd in ⊢ (%→?); #Htc *
 227 [ * #te * * * #Hcurtc #Hte1 #Hte2 whd in ⊢ (%→?); #Htb destruct (Htb)
 228   #c #ls #Hta %
 229   [ #Hc >Hta in Htc; >eq_mk_tape_rightof whd in match (tape_move ???); #Htc
 230     cut (te = tc)
 231     [ lapply (eq_vec_change_vec ??????? (sym_eq … Hte1) Hte2) >change_vec_same // ]
 232       -Hte1 -Hte2 #Hte //
 233     | #Hc >Hta in Htc; >eq_mk_tape_rightof whd in match (tape_move ???); #Htc
 234       >Htc in Hcurtc; >nth_change_vec // normalize in ⊢ (%→?);
 235       #H destruct (H) @False_ind cases Hc /2/ ]
 236 | * #te * * * #Hcurtc #Hte1 #Hte2
 237   whd in ⊢ (%→?); #Htb
 238   #c #ls #Hta % #Hc
 239   [ >Htc in Hcurtc; >Hta >nth_change_vec //
 240     normalize in ⊢ (%→?); * #H @False_ind /2/
 241   | cut (te = tc)
 242     [ lapply (eq_vec_change_vec ??????? (sym_eq … Hte1) Hte2)
 243       >change_vec_same // ] -Hte1 -Hte2 #Hte destruct (Hte)
 244     >Hta in Htc; whd in match (tape_move ???); #Htc
 245     >Htc in Htb; >nth_change_vec //
 246     >nth_change_vec_neq [2:@eqb_false_to_not_eq //] >Hta
 247     #Htb @Htb
 248   ]
 249 qed.
 250
 251 definition char_to_move ≝ λc.match c with
 252   [ bit b ⇒ if b then R else L
 253   | _ ⇒ N].
 254
 255 definition char_to_bit_option ≝ λc.match c with
 256   [ bit b ⇒ Some ? (bit b)
 257   | _ ⇒ None ?].
 258
 259 definition R_cfg_to_obj1 ≝ λt1,t2:Vector (tape FSUnialpha) 3.
 260   ∀c,ls.
 261   nth cfg ? t1 (niltape ?) = mk_tape FSUnialpha (c::ls) (None ?) [ ] →
 262   c ≠ bar →
 263   let new_obj ≝
 264       tape_write ? (nth obj ? t1 (niltape ?)) (char_to_bit_option c) in
 265     t2 = change_vec ??
 266           (change_vec ?? t1
 267             (tape_write ? (nth obj ? t1 (niltape ?)) (char_to_bit_option c)) obj)
 268           (midtape ? ls c [ ]) cfg.
 269
 270 lemma sem_cfg_to_obj1: cfg_to_obj ⊨  R_cfg_to_obj1.
 271 @(Realize_to_Realize … sem_cfg_to_obj) #t1 #t2 #H #c #ls #Hcfg #Hbar
 272 cases (H c ls Hcfg) cases (true_or_false (c==null)) #Hc
 273   [#Ht2 #_ >(Ht2 (\P Hc)) -Ht2 @(eq_vec … (niltape ?))
 274    #i #lei2 cases (le_to_or_lt_eq … (le_S_S_to_le …lei2))
 275     [#lei1 cases (le_to_or_lt_eq … (le_S_S_to_le …lei1))
 276       [#lei0 lapply(le_n_O_to_eq … (le_S_S_to_le …lei0)) #eqi <eqi
 277        >nth_change_vec_neq [2:@eqb_false_to_not_eq %]
 278        >nth_change_vec_neq in ⊢ (???%); [2:@eqb_false_to_not_eq %]
 279        >nth_change_vec // >(\P Hc) %
 280       |#Hi >Hi >nth_change_vec //
 281       ]
 282     |#Hi >Hi >nth_change_vec_neq [2:@eqb_false_to_not_eq %]
 283      >nth_change_vec_neq [2:@eqb_false_to_not_eq %]
 284      >nth_change_vec_neq [2:@eqb_false_to_not_eq %] %
 285     ]
 286   |#_ #Ht2 >(Ht2 (\Pf Hc)) -Ht2 @(eq_vec … (niltape ?))
 287    #i #lei2 cases (le_to_or_lt_eq … (le_S_S_to_le …lei2))
 288     [#lei1 cases (le_to_or_lt_eq … (le_S_S_to_le …lei1))
 289       [#lei0 lapply(le_n_O_to_eq … (le_S_S_to_le …lei0)) #eqi <eqi
 290        >nth_change_vec_neq [2:@eqb_false_to_not_eq %]
 291        >nth_change_vec_neq in ⊢ (???%); [2:@eqb_false_to_not_eq %]
 292        >nth_change_vec // >nth_change_vec //
 293        lapply (\bf Hbar) lapply Hc elim c //
 294         [whd in ⊢ (??%?→?); #H destruct (H)
 295         |#_ whd in ⊢ (??%?→?); #H destruct (H)
 296         ]
 297       |#Hi >Hi >nth_change_vec //
 298       ]
 299     |#Hi >Hi >nth_change_vec_neq [2:@eqb_false_to_not_eq %]
 300      >nth_change_vec_neq [2:@eqb_false_to_not_eq %]
 301      >nth_change_vec_neq [2:@eqb_false_to_not_eq %] %
 302     ]
 303   ]
 304 qed.
 305
 306
 307 (* macchina che muove il nastro obj a destra o sinistra a seconda del valore
 308    del current di prg, che codifica la direzione in cui ci muoviamo *)
 309
 310 definition tape_move_obj : mTM FSUnialpha 2 ≝
 311   ifTM ??
 312    (inject_TM ? (test_char ? (λc:FSUnialpha.c == bit false)) 2 prg)
 313    (mmove obj FSUnialpha 2 L)
 314    (ifTM ??
 315     (inject_TM ? (test_char ? (λc:FSUnialpha.c == bit true)) 2 prg)
 316     (mmove obj FSUnialpha 2 R)
 317     (nop ??)
 318     tc_true)
 319    tc_true.
 320
 321 definition R_tape_move_obj' ≝ λt1,t2:Vector (tape FSUnialpha) 3.
 322   (current ? (nth prg ? t1 (niltape ?)) = Some ? (bit false) →
 323    t2 = change_vec ?? t1 (tape_move ? (nth obj ? t1 (niltape ?)) L) obj) ∧
 324   (current ? (nth prg ? t1 (niltape ?)) = Some ? (bit true) →
 325    t2 = change_vec ?? t1 (tape_move ? (nth obj ? t1 (niltape ?)) R) obj) ∧
 326   (current ? (nth prg ? t1 (niltape ?)) ≠ Some ? (bit false) →
 327    current ? (nth prg ? t1 (niltape ?)) ≠ Some ? (bit true) →
 328    t2 = t1).
 329
 330 lemma sem_tape_move_obj' : tape_move_obj ⊨ R_tape_move_obj'.
 331 #ta cases (sem_if ??????????
 332   (acc_sem_inject ?????? prg ? (sem_test_char ? (λc:FSUnialpha.c == bit false)))
 333   (sem_move_multi ? 2 obj L ?)
 334   (sem_if ??????????
 335    (acc_sem_inject ?????? prg ? (sem_test_char ? (λc:FSUnialpha.c == bit true)))
 336    (sem_move_multi ? 2 obj R ?)
 337    (sem_nop …)) ta) //
 338 #i * #outc * #Hloop #HR %{i} %{outc} % [@Hloop] -i
 339 cases HR -HR
 340 [ * #tb * * * * #c * #Hcurta_prg #Hc lapply (\P Hc) -Hc #Hc #Htb1 #Htb2
 341   whd in ⊢ (%→%); #Houtc >Houtc -Houtc % [ %
 342   [ >Hcurta_prg #H destruct (H) >(?:tb = ta)
 343     [| lapply (eq_vec_change_vec ??????? Htb1 Htb2)
 344        >change_vec_same // ] %
 345   | >Hcurta_prg #H destruct (H) destruct (Hc) ]
 346   | >Hcurta_prg >Hc * #H @False_ind /2/ ]
 347 | * #tb * * * #Hnotfalse #Htb1 #Htb2 cut (tb = ta)
 348   [ lapply (eq_vec_change_vec ??????? Htb1 Htb2)
 349      >change_vec_same // ] -Htb1 -Htb2 #Htb destruct (Htb) *
 350   [ * #tc * * * * #c * #Hcurta_prg #Hc lapply (\P Hc) -Hc #Hc #Htc1 #Htc2
 351     whd in ⊢ (%→%); #Houtc >Houtc -Houtc % [ %
 352     [ >Hcurta_prg #H destruct (H) destruct (Hc)
 353     | >Hcurta_prg #H destruct (H) >(?:tc = ta)
 354       [| lapply (eq_vec_change_vec ??????? Htc1 Htc2)
 355         >change_vec_same // ] % ]
 356     | >Hcurta_prg >Hc #_ * #H @False_ind /2/ ]
 357   | * #tc * * * #Hnottrue #Htc1 #Htc2 cut (tc = ta)
 358     [ lapply (eq_vec_change_vec ??????? Htc1 Htc2)
 359       >change_vec_same // ] -Htc1 -Htc2
 360     #Htc destruct (Htc) whd in ⊢ (%→?); #Houtc % [ %
 361     [ #Hcurta_prg lapply (\Pf (Hnotfalse ? Hcurta_prg)) * #H @False_ind /2/
 362     | #Hcurta_prg lapply (\Pf (Hnottrue ? Hcurta_prg)) * #H @False_ind /2/ ]
 363     | #_ #_ @Houtc ]
 364   ]
 365 ]
 366 qed.
 367
 368 definition R_tape_move_obj ≝ λt1,t2:Vector (tape FSUnialpha) 3.
 369   ∀c. current ? (nth prg ? t1 (niltape ?)) = Some ? c →
 370   t2 = change_vec ?? t1 (tape_move ? (nth obj ? t1 (niltape ?)) (char_to_move c)) obj.
 371
 372 lemma sem_tape_move_obj : tape_move_obj ⊨ R_tape_move_obj.
 373 @(Realize_to_Realize … sem_tape_move_obj')
 374 #ta #tb * * #Htb1 #Htb2 #Htb3 * [ *
 375 [ @Htb2 | @Htb1 ]
 376 | #Hcurta_prg change with (nth obj ? ta (niltape ?)) in match (tape_move ???);
 377   >change_vec_same @Htb3 >Hcurta_prg % #H destruct (H)
 378 | #Hcurta_prg change with (nth obj ? ta (niltape ?)) in match (tape_move ???);
 379   >change_vec_same @Htb3 >Hcurta_prg % #H destruct (H)
 380 ]
 381 qed.
 382
 383 (************** list of tape ******************)
 384 definition list_of_tape ≝ λsig.λt:tape sig.
 385   reverse ? (left ? t)@option_cons ? (current ? t) (right ? t).
 386
 387 lemma list_of_midtape: ∀sig,ls,c,rs.
 388   list_of_tape sig (midtape ? ls c rs) = reverse ? ls@c::rs.
 389 // qed-.
 390
 391 lemma list_of_rightof: ∀sig,ls,c.
 392   list_of_tape sig (rightof ? c ls) = reverse ? (c::ls).
 393 #sig #ls #c <(append_nil ? (reverse ? (c::ls)))
 394 // qed-.
 395
 396 lemma list_of_tape_move: ∀sig,t,m.
 397   list_of_tape sig t = list_of_tape sig (tape_move ? t m).
 398 #sig #t * // cases t //
 399  [(* rightof, move L *) #a #l >list_of_midtape
 400   >append_cons <reverse_single <reverse_append %
 401  |(* midtape, move L *) * //
 402   #a #ls #c #rs >list_of_midtape >list_of_midtape
 403   >reverse_cons >associative_append %
 404  |(* midtape, move R *) #ls #c *
 405    [>list_of_midtape >list_of_rightof >reverse_cons %
 406    |#a #rs >list_of_midtape >list_of_midtape >reverse_cons
 407     >associative_append %
 408    ]
 409  ]
 410 qed.
 411
 412 lemma list_of_tape_write: ∀sig,cond,t,c.
 413 (∀b. c = Some ? b → cond b =true) →
 414 (∀x. mem ? x (list_of_tape ? t) → cond x =true ) →
 415 ∀x. mem ? x (list_of_tape sig (tape_write ? t c)) → cond x =true.
 416 #sig #cond #t #c #Hc #Htape #x lapply Hc cases c
 417   [(* c is None *) #_ whd in match (tape_write ???); @Htape
 418   |#b #Hb lapply (Hb … (refl ??)) -Hb #Hb
 419    whd in match (tape_write ???); >list_of_midtape
 420    #Hx cases(mem_append ???? Hx) -Hx
 421     [#Hx @Htape @mem_append_l1 @Hx
 422     |* [//]
 423      #Hx @Htape @mem_append_l2 cases (current sig t)
 424       [@Hx | #c1 %2 @Hx]
 425     ]
 426   ]
 427 qed.
 428
 429 lemma current_in_list: ∀sig,t,b.
 430   current sig t = Some ? b → mem ? b (list_of_tape sig t).
 431 #sig #t #b cases t
 432   [whd in ⊢ (??%?→?); #Htmp destruct
 433   |#l #b whd in ⊢ (??%?→?); #Htmp destruct
 434   |#l #b whd in ⊢ (??%?→?); #Htmp destruct
 435   |#ls #c #rs whd in ⊢ (??%?→?); #Htmp destruct
 436    >list_of_midtape @mem_append_l2 % %
 437   ]
 438 qed.
 439
 440 definition restart_tape ≝ λi,n.
 441   mmove i FSUnialpha n L ·
 442   inject_TM ? (move_to_end FSUnialpha L) n i ·
 443   mmove i FSUnialpha n R.
 444
 445 definition R_restart_tape ≝ λi,n.λint,outt:Vector (tape FSUnialpha) (S n).
 446    ∀t.t = nth i ? int (niltape ?) →
 447    outt = change_vec ?? int
 448     (mk_tape ? [ ] (option_hd ? (list_of_tape ? t)) (tail ? (list_of_tape ? t))) i.
 449
 450 lemma sem_restart_tape : ∀i,n.i < S n → restart_tape i n ⊨ R_restart_tape i n.
 451 #i #n #Hleq
 452 @(sem_seq_app ??????? (sem_move_multi ? n i L ?)
 453   (sem_seq ?????? (sem_inject ???? i ? (sem_move_to_end_l ?))
 454    (sem_move_multi ? n i R ?))) [1,2,3:@le_S_S_to_le //]
 455 #ta #tb * #tc * whd in ⊢ (%→?); #Htc
 456 * #td * * * #Htd1 #Htd2 #Htd3
 457 whd in ⊢ (%→?); #Htb *
 458 [ #Hta_i <Hta_i in Htc; whd in ⊢ (???(????%?)→?); #Htc
 459   cut (td = tc)
 460   [ <(change_vec_same … tc … i … (niltape ?))
 461     @(eq_vec_change_vec … (niltape ?))
 462     [ @Htd1 >Htc >nth_change_vec //
 463     | @Htd3 ] ]
 464   (* >Htc in Htd1; >nth_change_vec // *) -Htd1 -Htd2 -Htd3
 465   #Htd >Htd in Htb; >Htc >change_vec_change_vec >nth_change_vec //
 466   #Htb >Htb %
 467 | #r0 #rs0 #Hta_i <Hta_i in Htc; whd in ⊢ (???(????%?)→?); #Htc
 468   cut (td = tc)
 469   [ <(change_vec_same … tc … i … (niltape ?))
 470     @(eq_vec_change_vec … (niltape ?))
 471     [ @Htd1 >Htc >nth_change_vec //
 472     | @Htd3 ] ]
 473   (* >Htc in Htd1; >nth_change_vec // *) -Htd1 -Htd2 -Htd3
 474   #Htd >Htd in Htb; >Htc >change_vec_change_vec >nth_change_vec //
 475   #Htb >Htb %
 476 | #l0 #ls0 #Hta_i <Hta_i in Htc; whd in ⊢ (???(????%?)→?); #Htc
 477   cut (td = change_vec ?? tc (mk_tape ? [ ] (None ?) (reverse ? ls0@[l0])) i)
 478   [ <(change_vec_same … tc … i … (niltape ?))
 479     @(eq_vec_change_vec … (niltape ?))
 480     [ @Htd2 >Htc >nth_change_vec //
 481     | #j #Hij >nth_change_vec_neq // @Htd3 // ]]
 482   #Htd >Htd in Htb; >Htc >change_vec_change_vec >change_vec_change_vec
 483   >nth_change_vec // #Htb >Htb <(reverse_reverse ? ls0) in ⊢ (???%);
 484   cases (reverse ? ls0)
 485   [ %
 486   | #l1 #ls1 >reverse_cons
 487      >(?: list_of_tape ? (rightof ? l0 (reverse ? ls1@[l1])) =
 488           l1::ls1@[l0])
 489      [|change with (reverse ??@?) in ⊢ (??%?);
 490        whd in match (left ??); >reverse_cons >reverse_append
 491        whd in ⊢ (??%?); @eq_f >reverse_reverse normalize >append_nil % ] % ]
 492 | *
 493   [ #c #rs #Hta_i <Hta_i in Htc; whd in ⊢ (???(????%?)→?); #Htc
 494     cut (td = tc)
 495     [ <(change_vec_same … tc … i … (niltape ?))
 496     @(eq_vec_change_vec … (niltape ?))
 497     [ @Htd1 >Htc >nth_change_vec //
 498     | @Htd3 ] ]
 499     (* >Htc in Htd1; >nth_change_vec // *) -Htd1 -Htd2 -Htd3
 500     #Htd >Htd in Htb; >Htc >change_vec_change_vec >nth_change_vec //
 501     #Htb >Htb %
 502   | #l0 #ls0 #c #rs #Hta_i <Hta_i in Htc; whd in ⊢ (???(????%?)→?); #Htc
 503     cut (td = change_vec ?? tc (mk_tape ? [ ] (None ?) (reverse ? ls0@l0::c::rs)) i)
 504     [ @(eq_vec_change_vec … (niltape ?))
 505       [ @Htd2 >Htc >nth_change_vec //
 506       | @Htd3 ] ]
 507     #Htd >Htd in Htb; >Htc >change_vec_change_vec >change_vec_change_vec
 508     >nth_change_vec // #Htb >Htb <(reverse_reverse ? ls0) in ⊢ (???%);
 509     cases (reverse ? ls0)
 510     [ %
 511     | #l1 #ls1 >reverse_cons
 512       >(?: list_of_tape ? (midtape ? (l0::reverse ? ls1@[l1]) c rs) =
 513             l1::ls1@l0::c::rs)
 514       [|change with (reverse ??@?) in ⊢ (??%?);
 515         whd in match (left ??); >reverse_cons >reverse_append
 516         whd in ⊢ (??%?); @eq_f >reverse_reverse normalize
 517         >associative_append % ] % ]
 518   ]
 519 ]
 520 qed.