matita/matita/lib/turing/universal/marks.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||
   8     \   /  This file is distributed under the terms of the
   9      \ /   GNU General Public License Version 2
  10       V_____________________________________________________________*)
  11
  12
  13 (* COMPARE BIT
  14
  15 *)
  16
  17 include "turing/if_machine.ma".
  18 include "turing/basic_machines.ma".
  19 include "turing/universal/alphabet.ma".
  20
  21 (* ADVANCE TO MARK (right)
  22
  23    sposta la testina a destra fino a raggiungere il primo carattere marcato
  24
  25 *)
  26
  27 (* 0, a ≠ mark _ ⇒ 0, R
  28 0, a = mark _ ⇒ 1, N *)
  29
  30 definition atm_states ≝ initN 3.
  31
  32 definition atm0 : atm_states ≝ mk_Sig ?? 0 (leb_true_to_le 1 3 (refl …)).
  33 definition atm1 : atm_states ≝ mk_Sig ?? 1 (leb_true_to_le 2 3 (refl …)).
  34 definition atm2 : atm_states ≝ mk_Sig ?? 2 (leb_true_to_le 3 3 (refl …)).
  35
  36 definition atmr_step ≝
  37   λalpha:FinSet.λtest:alpha→bool.
  38   mk_TM alpha atm_states
  39   (λp.let 〈q,a〉 ≝ p in
  40    match a with
  41    [ None ⇒ 〈atm1, None ?〉
  42    | Some a' ⇒
  43      match test a' with
  44      [ true ⇒ 〈atm1,None ?〉
  45      | false ⇒ 〈atm2,Some ? 〈a',R〉〉 ]])
  46   atm0 (λx.notb (x == atm0)).
  47
  48 definition Ratmr_step_true ≝
  49   λalpha,test,t1,t2.
  50    ∃ls,a,rs.
  51    t1 = midtape alpha ls a rs ∧ test a = false ∧
  52    t2 = mk_tape alpha (a::ls) (option_hd ? rs) (tail ? rs).
  53
  54 definition Ratmr_step_false ≝
  55   λalpha,test,t1,t2.
  56     t1 = t2 ∧
  57     (current alpha t1 = None ? ∨
  58      (∃a.current ? t1 = Some ? a ∧ test a = true)).
  59
  60 lemma atmr_q0_q1 :
  61   ∀alpha,test,ls,a0,rs. test a0 = true →
  62   step alpha (atmr_step alpha test)
  63     (mk_config ?? atm0 (midtape … ls a0 rs)) =
  64   mk_config alpha (states ? (atmr_step alpha test)) atm1
  65     (midtape … ls a0 rs).
  66 #alpha #test #ls #a0 #ts #Htest whd in ⊢ (??%?);
  67 whd in match (trans … 〈?,?〉); >Htest %
  68 qed.
  69
  70 lemma atmr_q0_q2 :
  71   ∀alpha,test,ls,a0,rs. test a0 = false →
  72   step alpha (atmr_step alpha test)
  73     (mk_config ?? atm0 (midtape … ls a0 rs)) =
  74   mk_config alpha (states ? (atmr_step alpha test)) atm2
  75     (mk_tape … (a0::ls) (option_hd ? rs) (tail ? rs)).
  76 #alpha #test #ls #a0 #ts #Htest whd in ⊢ (??%?);
  77 whd in match (trans … 〈?,?〉); >Htest cases ts //
  78 qed.
  79
  80 lemma sem_atmr_step :
  81   ∀alpha,test.
  82   accRealize alpha (atmr_step alpha test)
  83     atm2 (Ratmr_step_true alpha test) (Ratmr_step_false alpha test).
  84 #alpha #test *
  85 [ @(ex_intro ?? 2)
  86   @(ex_intro ?? (mk_config ?? atm1 (niltape ?))) %
  87   [ % // whd in ⊢ ((??%%)→?); #Hfalse destruct | #_ % // % % ]
  88 | #a #al @(ex_intro ?? 2) @(ex_intro ?? (mk_config ?? atm1 (leftof ? a al)))
  89   % [ % // whd in ⊢ ((??%%)→?); #Hfalse destruct | #_ % // % % ]
  90 | #a #al @(ex_intro ?? 2) @(ex_intro ?? (mk_config ?? atm1 (rightof ? a al)))
  91   % [ % // whd in ⊢ ((??%%)→?); #Hfalse destruct | #_ % // % % ]
  92 | #ls #c #rs @(ex_intro ?? 2)
  93   cases (true_or_false (test c)) #Htest
  94   [ @(ex_intro ?? (mk_config ?? atm1 ?))
  95     [| %
  96       [ %
  97         [ whd in ⊢ (??%?); >atmr_q0_q1 //
  98         | whd in ⊢ ((??%%)→?); #Hfalse destruct ]
  99       | #_ % // %2 @(ex_intro ?? c) % // ]
 100     ]
 101   | @(ex_intro ?? (mk_config ?? atm2 (mk_tape ? (c::ls) (option_hd ? rs) (tail ? rs))))
 102     %
 103     [ %
 104       [ whd in ⊢ (??%?); >atmr_q0_q2 //
 105       | #_ @(ex_intro ?? ls) @(ex_intro ?? c) @(ex_intro ?? rs)
 106         % // % //
 107       ]
 108     | #Hfalse @False_ind @(absurd ?? Hfalse) %
 109     ]
 110   ]
 111 ]
 112 qed.
 113
 114 definition R_adv_to_mark_r ≝ λalpha,test,t1,t2.
 115   ∀ls,c,rs.
 116   (t1 = midtape alpha ls c rs  →
 117   ((test c = true ∧ t2 = t1) ∨
 118    (test c = false ∧
 119     ∀rs1,b,rs2. rs = rs1@b::rs2 →
 120      test b = true → (∀x.memb ? x rs1 = true → test x = false) →
 121      t2 = midtape ? (reverse ? rs1@c::ls) b rs2))).
 122
 123 definition adv_to_mark_r ≝
 124   λalpha,test.whileTM alpha (atmr_step alpha test) atm2.
 125
 126 lemma wsem_adv_to_mark_r :
 127   ∀alpha,test.
 128   WRealize alpha (adv_to_mark_r alpha test) (R_adv_to_mark_r alpha test).
 129 #alpha #test #t #i #outc #Hloop
 130 lapply (sem_while … (sem_atmr_step alpha test) t i outc Hloop) [%]
 131 -Hloop * #t1 * #Hstar @(star_ind_l ??????? Hstar)
 132 [ #tapea * #Htapea *
 133   [ #H1 #ls #c #rs #H2 >H2 in H1; whd in ⊢ (??%? → ?);
 134     #Hfalse destruct (Hfalse)
 135   | * #a * #Ha #Htest #ls #c #rs #H2 %
 136     >H2 in Ha; whd in ⊢ (??%? → ?); #Heq destruct (Heq) % //
 137     <Htapea //
 138   ]
 139 | #tapea #tapeb #tapec #Hleft #Hright #IH #HRfalse
 140   lapply (IH HRfalse) -IH #IH
 141   #ls #c #rs #Htapea %2
 142   cases Hleft #ls0 * #a0 * #rs0 * * #Htapea' #Htest #Htapeb
 143
 144   >Htapea' in Htapea; #Htapea destruct (Htapea) % // *
 145   [ #b #rs2 #Hrs >Hrs in Htapeb; #Htapeb #Htestb #_
 146     cases (IH … Htapeb)
 147     [ * #_ #Houtc >Houtc >Htapeb %
 148     | * #Hfalse >Hfalse in Htestb; #Htestb destruct (Htestb) ]
 149   | #r1 #rs1 #b #rs2 #Hrs >Hrs in Htapeb; #Htapeb #Htestb #Hmemb
 150     cases (IH … Htapeb)
 151     [ * #Hfalse >(Hmemb …) in Hfalse;
 152       [ #Hft destruct (Hft)
 153       | @memb_hd ]
 154     | * #Htestr1 #H1 >reverse_cons >associative_append
 155       @H1 // #x #Hx @Hmemb @memb_cons //
 156     ]
 157   ]
 158 qed.
 159
 160 lemma terminate_adv_to_mark_r :
 161   ∀alpha,test.
 162   ∀t.Terminate alpha (adv_to_mark_r alpha test) t.
 163 #alpha #test #t
 164 @(terminate_while … (sem_atmr_step alpha test))
 165   [ %
 166   | cases t
 167     [ % #t1 * #ls0 * #c0 * #rs0 * * #Hfalse destruct (Hfalse)
 168     |2,3: #a0 #al0 % #t1 * #ls0 * #c0 * #rs0 * * #Hfalse destruct (Hfalse)
 169     | #ls #c #rs generalize in match c; -c generalize in match ls; -ls
 170       elim rs
 171       [#ls #c % #t1 * #ls0 * #c0 * #rs0 * *
 172        #H1 destruct (H1) #Hc0 #Ht1 normalize in Ht1;
 173        % #t2 * #ls1 * #c1 * #rs1 * * >Ht1
 174        normalize in ⊢ (%→?); #Hfalse destruct (Hfalse)
 175       | #r0 #rs0 #IH #ls #c % #t1 * #ls0 * #c0 * #rs0 * *
 176         #H1 destruct (H1) #Hc0 #Ht1 normalize in Ht1;
 177         >Ht1 @IH
 178       ]
 179     ]
 180   ]
 181 qed.
 182
 183 lemma sem_adv_to_mark_r :
 184   ∀alpha,test.
 185   Realize alpha (adv_to_mark_r alpha test) (R_adv_to_mark_r alpha test).
 186 /2/
 187 qed.
 188
 189 (* MARK machine
 190
 191    marks the current character
 192  *)
 193
 194 definition mark_states ≝ initN 2.
 195
 196 definition ms0 : mark_states ≝ mk_Sig ?? 0 (leb_true_to_le 1 2 (refl …)).
 197 definition ms1 : mark_states ≝ mk_Sig ?? 1 (leb_true_to_le 2 2 (refl …)).
 198
 199 definition mark ≝
 200   λalpha:FinSet.mk_TM (FinProd … alpha FinBool) mark_states
 201   (λp.let 〈q,a〉 ≝ p in
 202     match a with
 203     [ None ⇒ 〈ms1,None ?〉
 204     | Some a' ⇒ match (pi1 … q) with
 205       [ O ⇒ let 〈a'',b〉 ≝ a' in 〈ms1,Some ? 〈〈a'',true〉,N〉〉
 206       | S q ⇒ 〈ms1,None ?〉 ] ])
 207   ms0 (λq.q == ms1).
 208
 209 definition R_mark ≝ λalpha,t1,t2.
 210   ∀ls,c,b,rs.
 211   t1 = midtape (FinProd … alpha FinBool) ls 〈c,b〉 rs →
 212   t2 = midtape ? ls 〈c,true〉 rs.
 213
 214 lemma sem_mark :
 215   ∀alpha.Realize ? (mark alpha) (R_mark alpha).
 216 #alpha #intape @(ex_intro ?? 2) cases intape
 217 [ @ex_intro
 218   [| % [ % | #ls #c #b #rs #Hfalse destruct ] ]
 219 |#a #al @ex_intro
 220   [| % [ % | #ls #c #b #rs #Hfalse destruct ] ]
 221 |#a #al @ex_intro
 222   [| % [ % | #ls #c #b #rs #Hfalse destruct ] ]
 223 | #ls * #c #b #rs
 224   @ex_intro [| % [ % | #ls0 #c0 #b0 #rs0 #H1 destruct (H1) % ] ] ]
 225 qed.
 226
 227
 228 (* MOVE RIGHT AND MARK machine
 229
 230    marks the first character on the right
 231
 232    (could be rewritten using (mark; move_right))
 233  *)
 234
 235 definition mrm_states ≝ initN 3.
 236
 237 definition mrm0 : mrm_states ≝ mk_Sig ?? 0 (leb_true_to_le 1 3 (refl …)).
 238 definition mrm1 : mrm_states ≝ mk_Sig ?? 1 (leb_true_to_le 2 3 (refl …)).
 239 definition mrm2 : mrm_states ≝ mk_Sig ?? 2 (leb_true_to_le 3 3 (refl …)).
 240
 241 definition move_right_and_mark ≝
 242   λalpha:FinSet.mk_TM (FinProd … alpha FinBool) mrm_states
 243   (λp.let 〈q,a〉 ≝ p in
 244     match a with
 245     [ None ⇒ 〈mrm2,None ?〉
 246     | Some a' ⇒ match pi1 … q with
 247       [ O ⇒ 〈mrm1,Some ? 〈a',R〉〉
 248       | S q ⇒ match q with
 249         [ O ⇒ let 〈a'',b〉 ≝ a' in
 250               〈mrm2,Some ? 〈〈a'',true〉,N〉〉
 251         | S _ ⇒ 〈mrm2,None ?〉 ] ] ])
 252   mrm0 (λq.q == mrm2).
 253
 254 definition R_move_right_and_mark ≝ λalpha,t1,t2.
 255   ∀ls,c,d,b,rs.
 256   t1 = midtape (FinProd … alpha FinBool) ls c (〈d,b〉::rs) →
 257   t2 = midtape ? (c::ls) 〈d,true〉 rs.
 258
 259 lemma sem_move_right_and_mark :
 260   ∀alpha.Realize ? (move_right_and_mark alpha) (R_move_right_and_mark alpha).
 261 #alpha #intape @(ex_intro ?? 3) cases intape
 262 [ @ex_intro
 263   [| % [ % | #ls #c #d #b #rs #Hfalse destruct ] ]
 264 |#a #al @ex_intro
 265   [| % [ % | #ls #c #d #b #rs #Hfalse destruct ] ]
 266 |#a #al @ex_intro
 267   [| % [ % | #ls #c #d #b #rs #Hfalse destruct ] ]
 268 | #ls #c *
 269   [ @ex_intro [| % [ % | #ls0 #c0 #d0 #b0 #rs0 #Hfalse destruct ] ]
 270   | * #d #b #rs @ex_intro
 271     [| % [ % | #ls0 #c0 #d0 #b0 #rs0 #H1 destruct (H1) % ] ] ] ]
 272 qed.
 273
 274 (* CLEAR MARK machine
 275
 276    clears the mark in the current character
 277  *)
 278
 279 definition clear_mark_states ≝ initN 3.
 280
 281 definition clear0 : clear_mark_states ≝ mk_Sig ?? 0 (leb_true_to_le 1 3 (refl …)).
 282 definition clear1 : clear_mark_states ≝ mk_Sig ?? 1 (leb_true_to_le 2 3 (refl …)).
 283 definition claer2 : clear_mark_states ≝ mk_Sig ?? 2 (leb_true_to_le 3 3 (refl …)).
 284
 285 definition clear_mark ≝
 286   λalpha:FinSet.mk_TM (FinProd … alpha FinBool) clear_mark_states
 287   (λp.let 〈q,a〉 ≝ p in
 288     match a with
 289     [ None ⇒ 〈clear1,None ?〉
 290     | Some a' ⇒ match pi1 … q with
 291       [ O ⇒ let 〈a'',b〉 ≝ a' in 〈clear1,Some ? 〈〈a'',false〉,N〉〉
 292       | S q ⇒ 〈clear1,None ?〉 ] ])
 293   clear0 (λq.q == clear1).
 294
 295 definition R_clear_mark ≝ λalpha,t1,t2.
 296   ∀ls,c,b,rs.
 297   t1 = midtape (FinProd … alpha FinBool) ls 〈c,b〉 rs →
 298   t2 = midtape ? ls 〈c,false〉 rs.
 299
 300 lemma sem_clear_mark :
 301   ∀alpha.Realize ? (clear_mark alpha) (R_clear_mark alpha).
 302 #alpha #intape @(ex_intro ?? 2) cases intape
 303 [ @ex_intro
 304   [| % [ % | #ls #c #b #rs #Hfalse destruct ] ]
 305 |#a #al @ex_intro
 306   [| % [ % | #ls #c #b #rs #Hfalse destruct ] ]
 307 |#a #al @ex_intro
 308   [| % [ % | #ls #c #b #rs #Hfalse destruct ] ]
 309 | #ls * #c #b #rs
 310   @ex_intro [| % [ % | #ls0 #c0 #b0 #rs0 #H1 destruct (H1) % ] ] ]
 311 qed.
 312
 313 (* ADVANCE MARK RIGHT machine
 314
 315    clears mark on current char,
 316    moves right, and marks new current char
 317
 318 *)
 319
 320 definition adv_mark_r ≝
 321   λalpha:FinSet.
 322     seq ? (clear_mark alpha)
 323       (seq ? (move_r ?) (mark alpha)).
 324
 325 definition R_adv_mark_r ≝ λalpha,t1,t2.
 326   ∀ls,c,d,b,rs.
 327   t1 = midtape (FinProd … alpha FinBool) ls 〈c,true〉 (〈d,b〉::rs) →
 328   t2 = midtape ? (〈c,false〉::ls) 〈d,true〉 rs.
 329
 330 lemma sem_adv_mark_r :
 331   ∀alpha.Realize ? (adv_mark_r alpha) (R_adv_mark_r alpha).
 332 #alpha #intape
 333 cases (sem_seq ????? (sem_clear_mark …)
 334          (sem_seq ????? (sem_move_r ?) (sem_mark alpha)) intape)
 335 #k * #outc * #Hloop whd in ⊢ (%→?);
 336 * #ta * whd in ⊢ (%→?); #Hs1 * #tb * whd in ⊢ (%→%→?); #Hs2 #Hs3
 337 @(ex_intro ?? k) @(ex_intro ?? outc) %
 338 [ @Hloop
 339 | -Hloop #ls #c #d #b #rs #Hintape @(Hs3 … b)
 340   @(Hs2 ls 〈c,false〉 (〈d,b〉::rs))
 341   @(Hs1 … Hintape)
 342 ]
 343 qed.
 344
 345 (* ADVANCE TO MARK (left)
 346
 347 axiomatized
 348
 349 *)
 350
 351 definition R_adv_to_mark_l ≝ λalpha,test,t1,t2.
 352   ∀ls,c,rs.
 353   (t1 = midtape alpha ls c rs  →
 354   ((test c = true ∧ t2 = t1) ∨
 355    (test c = false ∧
 356     ∀ls1,b,ls2. ls = ls1@b::ls2 →
 357      test b = true → (∀x.memb ? x ls1 = true → test x = false) →
 358      t2 = midtape ? ls2 b (reverse ? ls1@c::rs)))).
 359
 360 axiom adv_to_mark_l : ∀alpha:FinSet.(alpha → bool) → TM alpha.
 361 (* definition adv_to_mark_l ≝
 362   λalpha,test.whileTM alpha (atml_step alpha test) 2. *)
 363
 364 axiom wsem_adv_to_mark_l :
 365   ∀alpha,test.
 366   WRealize alpha (adv_to_mark_l alpha test) (R_adv_to_mark_l alpha test).
 367 (*
 368 #alpha #test #t #i #outc #Hloop
 369 lapply (sem_while … (sem_atmr_step alpha test) t i outc Hloop) [%]
 370 -Hloop * #t1 * #Hstar @(star_ind_l ??????? Hstar)
 371 [ #tapea * #Htapea *
 372   [ #H1 #ls #c #rs #H2 >H2 in H1; whd in ⊢ (??%? → ?);
 373     #Hfalse destruct (Hfalse)
 374   | * #a * #Ha #Htest #ls #c #rs #H2 %
 375     >H2 in Ha; whd in ⊢ (??%? → ?); #Heq destruct (Heq) % //
 376     <Htapea //
 377   ]
 378 | #tapea #tapeb #tapec #Hleft #Hright #IH #HRfalse
 379   lapply (IH HRfalse) -IH #IH
 380   #ls #c #rs #Htapea %2
 381   cases Hleft #ls0 * #a0 * #rs0 * * #Htapea' #Htest #Htapeb
 382
 383   >Htapea' in Htapea; #Htapea destruct (Htapea) % // *
 384   [ #b #rs2 #Hrs >Hrs in Htapeb; #Htapeb #Htestb #_
 385     cases (IH … Htapeb)
 386     [ * #_ #Houtc >Houtc >Htapeb %
 387     | * #Hfalse >Hfalse in Htestb; #Htestb destruct (Htestb) ]
 388   | #r1 #rs1 #b #rs2 #Hrs >Hrs in Htapeb; #Htapeb #Htestb #Hmemb
 389     cases (IH … Htapeb)
 390     [ * #Hfalse >(Hmemb …) in Hfalse;
 391       [ #Hft destruct (Hft)
 392       | @memb_hd ]
 393     | * #Htestr1 #H1 >reverse_cons >associative_append
 394       @H1 // #x #Hx @Hmemb @memb_cons //
 395     ]
 396   ]
 397 qed.
 398 *)
 399
 400 axiom terminate_adv_to_mark_l :
 401   ∀alpha,test.
 402   ∀t.Terminate alpha (adv_to_mark_l alpha test) t.
 403 (*
 404 #alpha #test #t
 405 @(terminate_while … (sem_atmr_step alpha test))
 406   [ %
 407   | cases t
 408     [ % #t1 * #ls0 * #c0 * #rs0 * * #Hfalse destruct (Hfalse)
 409     |2,3: #a0 #al0 % #t1 * #ls0 * #c0 * #rs0 * * #Hfalse destruct (Hfalse)
 410     | #ls #c #rs generalize in match c; -c generalize in match ls; -ls
 411       elim rs
 412       [#ls #c % #t1 * #ls0 * #c0 * #rs0 * *
 413        #H1 destruct (H1) #Hc0 #Ht1 normalize in Ht1;
 414        % #t2 * #ls1 * #c1 * #rs1 * * >Ht1
 415        normalize in ⊢ (%→?); #Hfalse destruct (Hfalse)
 416       | #r0 #rs0 #IH #ls #c % #t1 * #ls0 * #c0 * #rs0 * *
 417         #H1 destruct (H1) #Hc0 #Ht1 normalize in Ht1;
 418         >Ht1 @IH
 419       ]
 420     ]
 421   ]
 422 qed.
 423 *)
 424
 425 lemma sem_adv_to_mark_l :
 426   ∀alpha,test.
 427   Realize alpha (adv_to_mark_l alpha test) (R_adv_to_mark_l alpha test).
 428 /2/
 429 qed.
 430
 431 (*
 432    ADVANCE BOTH MARKS machine
 433
 434    l1 does not contain marks ⇒
 435
 436
 437    input:
 438    l0 x* a l1 x0* a0 l2
 439               ^
 440
 441    output:
 442    l0 x a* l1 x0 a0* l2
 443         ^
 444 *)
 445
 446 definition is_marked ≝
 447   λalpha.λp:FinProd … alpha FinBool.
 448   let 〈x,b〉 ≝ p in b.
 449
 450 definition adv_both_marks ≝
 451   λalpha.seq ? (adv_mark_r alpha)
 452     (seq ? (move_l ?)
 453      (seq ? (adv_to_mark_l (FinProd alpha FinBool) (is_marked alpha))
 454        (adv_mark_r alpha))).
 455
 456 definition R_adv_both_marks ≝
 457   λalpha,t1,t2.
 458     ∀l0,x,a,l1,x0,a0,l2. (∀c.memb ? c l1 = true → is_marked ? c = false) →
 459     t1 = midtape (FinProd … alpha FinBool)
 460         (l1@〈a,false〉::〈x,true〉::l0) 〈x0,true〉 (〈a0,false〉::l2) →
 461     t2 = midtape ? (〈x,false〉::l0) 〈a,true〉 (reverse ? l1@〈x0,false〉::〈a0,true〉::l2).
 462
 463 lemma sem_adv_both_marks :
 464   ∀alpha.Realize ? (adv_both_marks alpha) (R_adv_both_marks alpha).
 465 #alpha #intape
 466 cases (sem_seq ????? (sem_adv_mark_r …)
 467         (sem_seq ????? (sem_move_l …)
 468           (sem_seq ????? (sem_adv_to_mark_l ? (is_marked ?))
 469             (sem_adv_mark_r alpha))) intape)
 470 #k * #outc * #Hloop whd in ⊢ (%→?);
 471 * #ta * whd in ⊢ (%→?); #Hs1 * #tb * whd in ⊢ (%→?); #Hs2
 472 * #tc * whd in ⊢ (%→%→?); #Hs3 #Hs4
 473 @(ex_intro ?? k) @(ex_intro ?? outc) %
 474 [ @Hloop
 475 | -Hloop #l0 #x #a #l1 #x0 #a0 #l2 #Hl1 #Hintape
 476   @(Hs4 … false) -Hs4
 477   lapply (Hs1 … Hintape) #Hta
 478   lapply (Hs2 … Hta) #Htb
 479   cases (Hs3 … Htb)
 480   [ * #Hfalse normalize in Hfalse; destruct (Hfalse)
 481   | * #_ -Hs3 #Hs3
 482     lapply (Hs3 (l1@[〈a,false〉]) 〈x,true〉 l0 ???)
 483     [ #x1 #Hx1 cases (memb_append … Hx1)
 484       [ @Hl1
 485       | #Hx1' >(memb_single … Hx1') % ]
 486     | %
 487     | >associative_append %
 488     | >reverse_append #Htc @Htc ]
 489   ]
 490 qed.
 491
 492 (*
 493    MATCH AND ADVANCE(f)
 494
 495    input:
 496    l0 x* a l1 x0* a0 l2
 497               ^
 498
 499    output:
 500    l0 x a* l1 x0 a0* l2   (f(x0) == true)
 501         ^
 502    l0 x* a l1 x0* a0 l2   (f(x0) == false)
 503               ^
 504 *)
 505
 506 definition match_and_adv ≝
 507   λalpha,f.ifTM ? (test_char ? f)
 508      (adv_both_marks alpha) (clear_mark ?) tc_true.
 509
 510 definition R_match_and_adv ≝
 511   λalpha,f,t1,t2.
 512     ∀l0,x,a,l1,x0,a0,l2. (∀c.memb ? c l1 = true → is_marked ? c = false) →
 513     t1 = midtape (FinProd … alpha FinBool)
 514         (l1@〈a,false〉::〈x,true〉::l0) 〈x0,true〉 (〈a0,false〉::l2) →
 515     (f 〈x0,true〉 = true ∧ t2 = midtape ? (〈x,false〉::l0) 〈a,true〉 (reverse ? l1@〈x0,false〉::〈a0,true〉::l2))
 516     ∨ (f 〈x0,true〉 = false ∧
 517     t2 = midtape ? (l1@〈a,false〉::〈x,true〉::l0) 〈x0,false〉 (〈a0,false〉::l2)).
 518
 519 lemma sem_match_and_adv :
 520   ∀alpha,f.Realize ? (match_and_adv alpha f) (R_match_and_adv alpha f).
 521 #alpha #f #intape
 522 cases (sem_if ? (test_char ? f) … tc_true (sem_test_char ? f) (sem_adv_both_marks alpha) (sem_clear_mark ?) intape)
 523 #k * #outc * #Hloop #Hif @(ex_intro ?? k) @(ex_intro ?? outc)
 524 % [ @Hloop ] -Hloop
 525 cases Hif
 526 [ * #ta * whd in ⊢ (%→%→?); #Hta #Houtc
 527   #l0 #x #a #l1 #x0 #a0 #l2 #Hl1 #Hintape
 528   >Hintape in Hta; #Hta cases (Hta … (refl ??)) -Hta #Hf #Hta % %
 529   [ @Hf | @Houtc [ @Hl1 | @Hta ] ]
 530 | * #ta * whd in ⊢ (%→%→?); #Hta #Houtc
 531   #l0 #x #a #l1 #x0 #a0 #l2 #Hl1 #Hintape
 532   >Hintape in Hta; #Hta cases (Hta … (refl ??)) -Hta #Hf #Hta %2 %
 533   [ @Hf | >(Houtc … Hta) % ]
 534 ]
 535 qed.
 536
 537 (*
 538  if x = c
 539       then move_right; ----
 540            adv_to_mark_r;
 541            if current (* x0 *) = 0
 542               then advance_mark ----
 543                    adv_to_mark_l;
 544                    advance_mark
 545               else STOP
 546       else M
 547 *)
 548
 549 definition comp_step_subcase ≝
 550   λalpha,c,elseM.ifTM ? (test_char ? (λx.x == c))
 551     (seq ? (move_r …)
 552       (seq ? (adv_to_mark_r ? (is_marked alpha))
 553       (match_and_adv ? (λx.x == c))))
 554     elseM tc_true.
 555
 556 definition R_comp_step_subcase ≝
 557   λalpha,c,RelseM,t1,t2.
 558     ∀l0,x,rs.t1 = midtape (FinProd … alpha FinBool) l0 〈x,true〉 rs →
 559     (〈x,true〉 = c ∧
 560      ∀a,l1,x0,a0,l2. (∀c.memb ? c l1 = true → is_marked ? c = false) →
 561      rs = 〈a,false〉::l1@〈x0,true〉::〈a0,false〉::l2 →
 562      ((x = x0 ∧
 563       t2 = midtape ? (〈x,false〉::l0) 〈a,true〉 (l1@〈x0,false〉::〈a0,true〉::l2)) ∨
 564       (x ≠ x0 ∧
 565       t2 = midtape (FinProd … alpha FinBool)
 566         (reverse ? l1@〈a,false〉::〈x,true〉::l0) 〈x0,false〉 (〈a0,false〉::l2)))) ∨
 567     (〈x,true〉 ≠ c ∧ RelseM t1 t2).
 568
 569 lemma sem_comp_step_subcase :
 570   ∀alpha,c,elseM,RelseM.
 571   Realize ? elseM RelseM →
 572   Realize ? (comp_step_subcase alpha c elseM)
 573     (R_comp_step_subcase alpha c RelseM).
 574 #alpha #c #elseM #RelseM #Helse #intape
 575 cases (sem_if ? (test_char ? (λx.x == c)) … tc_true
 576         (sem_test_char ? (λx.x == c))
 577         (sem_seq ????? (sem_move_r …)
 578           (sem_seq ????? (sem_adv_to_mark_r ? (is_marked alpha))
 579              (sem_match_and_adv ? (λx.x == c)))) Helse intape)
 580 #k * #outc * #Hloop #HR @(ex_intro ?? k) @(ex_intro ?? outc)
 581 % [ @Hloop ] -Hloop cases HR -HR
 582 [ * #ta * whd in ⊢ (%→?); #Hta * #tb * whd in ⊢ (%→?); #Htb
 583   * #tc * whd in ⊢ (%→?); #Htc whd in ⊢ (%→?); #Houtc
 584   #l0 #x #rs #Hintape cases (true_or_false (〈x,true〉==c)) #Hc
 585   [ % % [ @(\P Hc) ]
 586     #a #l1 #x0 #a0 #l2 #Hl1 #Hrs >Hrs in Hintape; #Hintape
 587     >Hintape in Hta; #Hta cases (Hta ? (refl ??)) -Hta
 588     #Hx #Hta lapply (Htb … Hta) -Htb #Htb
 589     cases (Htc … Htb) [ * #Hfalse normalize in Hfalse; destruct (Hfalse) ]
 590     -Htc * #_ #Htc lapply (Htc l1 〈x0,true〉 (〈a0,false〉::l2) (refl ??) (refl ??) Hl1)
 591     -Htc #Htc cases (Houtc ???????? Htc) -Houtc
 592     [ * #Hx0 #Houtc %
 593       % [ <(\P Hx0) in Hx; #Hx lapply (\P Hx) #Hx' destruct (Hx') %
 594         | >Houtc >reverse_reverse % ]
 595     | * #Hx0 #Houtc %2
 596       % [ <(\P Hx) in Hx0; #Hx0 lapply (\Pf Hx0) @not_to_not #Hx' >Hx' %
 597         | >Houtc % ]
 598     | #x #membx @Hl1 <(reverse_reverse …l1) @memb_reverse @membx ]
 599   | %2 % [ @(\Pf Hc) ]
 600     >Hintape in Hta; #Hta cases (Hta ? (refl ??)) -Hta #Hx #Hta
 601     >Hx in Hc;#Hc destruct (Hc) ]
 602 | * #ta * whd in ⊢ (%→?); #Hta #Helse #ls #c0 #rs #Hintape %2
 603   >Hintape in Hta; #Hta cases (Hta ? (refl ??)) -Hta #Hc #Hta %
 604   [ @(\Pf Hc) | <Hta @Helse ]
 605 ]
 606 qed.
 607
 608 (*
 609 - se marcato, itero
 610 - se non è marcato
 611   + se è un bit, ho fallito il confronto della tupla corrente
 612   + se è un separatore, la tupla fa match
 613
 614
 615 ifTM ? (test_char ? is_marked)
 616   (single_finalTM … (comp_step_subcase unialpha 〈bit false,true〉
 617     (comp_step_subcase unialpha 〈bit true,true〉
 618       (clear_mark …))))
 619   (nop ?)
 620 *)
 621
 622 definition comp_step ≝
 623   ifTM ? (test_char ? (is_marked ?))
 624   (single_finalTM … (comp_step_subcase FSUnialpha 〈bit false,true〉
 625     (comp_step_subcase FSUnialpha 〈bit true,true〉
 626       (comp_step_subcase FSUnialpha 〈null,true〉
 627         (clear_mark …)))))
 628   (nop ?)
 629   tc_true.
 630
 631 definition R_comp_step_true ≝
 632   λt1,t2.
 633     ∀l0,c,rs.t1 = midtape (FinProd … FSUnialpha FinBool) l0 c rs →
 634     ∃c'. c = 〈c',true〉 ∧
 635     ((bit_or_null c' = true ∧
 636      ∀a,l1,c0,a0,l2.
 637       rs = 〈a,false〉::l1@〈c0,true〉::〈a0,false〉::l2 →
 638       (∀c.memb ? c l1 = true → is_marked ? c = false) →
 639       (c0 = c' ∧
 640        t2 = midtape ? (〈c',false〉::l0) 〈a,true〉 (l1@〈c0,false〉::〈a0,true〉::l2)) ∨
 641       (c0 ≠ c' ∧
 642        t2 = midtape (FinProd … FSUnialpha FinBool)
 643         (reverse ? l1@〈a,false〉::〈c',true〉::l0) 〈c0,false〉 (〈a0,false〉::l2))) ∨
 644      (bit_or_null c' = false ∧ t2 = midtape ? l0 〈c',false〉 rs)).
 645
 646 definition R_comp_step_false ≝
 647   λt1,t2.
 648    ∀ls,c,rs.t1 = midtape (FinProd … FSUnialpha FinBool) ls c rs →
 649    is_marked ? c = false ∧ t2 = t1.
 650
 651 lemma sem_comp_step :
 652   accRealize ? comp_step (inr … (inl … (inr … start_nop)))
 653     R_comp_step_true R_comp_step_false.
 654 #intape
 655 cases (acc_sem_if … (sem_test_char ? (is_marked ?))
 656         (sem_comp_step_subcase FSUnialpha 〈bit false,true〉 ??
 657           (sem_comp_step_subcase FSUnialpha 〈bit true,true〉 ??
 658             (sem_comp_step_subcase FSUnialpha 〈null,true〉 ??
 659               (sem_clear_mark …))))
 660         (sem_nop …) intape)
 661 #k * #outc * * #Hloop #H1 #H2
 662 @(ex_intro ?? k) @(ex_intro ?? outc) %
 663 [ % [@Hloop ] ] -Hloop
 664 [ #Hstate lapply (H1 Hstate) -H1 -Hstate -H2 *
 665   #ta * whd in ⊢ (%→?); #Hleft #Hright #ls #c #rs #Hintape
 666   >Hintape in Hleft; #Hleft cases (Hleft ? (refl ??)) -Hleft
 667   cases c in Hintape; #c' #b #Hintape whd in ⊢ (??%?→?);
 668   #Hb >Hb #Hta @(ex_intro ?? c') % //
 669   cases (Hright … Hta)
 670   [ * #Hc' #H1 % % [destruct (Hc') % ]
 671     #a #l1 #c0 #a0 #l2 #Hrs >Hrs in Hintape; #Hintape #Hl1
 672     cases (H1 … Hl1 Hrs)
 673     [ * #Htmp >Htmp -Htmp #Houtc % % // @Houtc
 674     | * #Hneq #Houtc %2 %
 675       [ @sym_not_eq //
 676       | @Houtc ]
 677     ]
 678   | * #Hc #Helse1 cases (Helse1 … Hta)
 679     [ * #Hc' #H1 % % [destruct (Hc') % ]
 680       #a #l1 #c0 #a0 #l2 #Hrs >Hrs in Hintape; #Hintape #Hl1
 681       cases (H1 … Hl1 Hrs)
 682       [ * #Htmp >Htmp -Htmp #Houtc % % // @Houtc
 683       | * #Hneq #Houtc %2 %
 684         [ @sym_not_eq //
 685         | @Houtc ]
 686       ]
 687     | * #Hc' #Helse2 cases (Helse2 … Hta)
 688       [ * #Hc'' #H1 % % [destruct (Hc'') % ]
 689         #a #l1 #c0 #a0 #l2 #Hrs >Hrs in Hintape; #Hintape #Hl1
 690         cases (H1 … Hl1 Hrs)
 691         [ * #Htmp >Htmp -Htmp #Houtc % % // @Houtc
 692         | * #Hneq #Houtc %2 %
 693           [ @sym_not_eq //
 694           | @Houtc ]
 695         ]
 696       | * #Hc'' whd in ⊢ (%→?); #Helse3 %2 %
 697         [ generalize in match Hc''; generalize in match Hc'; generalize in match Hc;
 698           cases c'
 699           [ * [ #_ #Hfalse @False_ind @(absurd ?? Hfalse) %
 700               | #Hfalse @False_ind @(absurd ?? Hfalse) % ]
 701           | #_ #_ #Hfalse @False_ind @(absurd ?? Hfalse) %
 702           |*: #_ #_ #_ % ]
 703         | @(Helse3 … Hta)
 704         ]
 705       ]
 706     ]
 707   ]
 708 | #Hstate lapply (H2 Hstate) -H1 -Hstate -H2 *
 709   #ta * whd in ⊢ (%→%→?); #Hleft #Hright #ls #c #rs #Hintape
 710   >Hintape in Hleft; #Hleft
 711   cases (Hleft ? (refl ??)) -Hleft
 712   #Hc #Hta % // >Hright //
 713 ]
 714 qed.
 715
 716 definition compare ≝
 717   whileTM ? comp_step (inr … (inl … (inr … start_nop))).
 718
 719 (*
 720 definition R_compare :=
 721   λt1,t2.
 722   (t
 723
 724   ∀ls,c,b,rs.t1 = midtape ? ls 〈c,b〉 rs →
 725   (b = true → rs = ....) →
 726   (b = false ∧ ....) ∨
 727   (b = true ∧
 728
 729    rs = cs@l1@〈c0,true〉::cs0@l2
 730    (
 731
 732
 733   ls 〈c,b〉 cs l1 〈c0,b0〉 cs0 l2
 734
 735
 736 ACCETTAZIONE:
 737   ls (hd (Ls@〈grid,false〉))* (tail (Ls@〈grid,false〉)) l1 (hd (Ls@〈comma,false〉))* (tail (Ls@〈comma,false〉)) l2
 738      ^^^^^^^^^^^^^^^^^^^^^^^
 739
 740   ls Ls 〈grid,false〉 l1 Ls 〈comma,true〉 l2
 741         ^^^^^^^^^^^^
 742
 743 RIFIUTO: c ≠ d
 744
 745   ls (hd (Ls@〈c,false〉))* (tail (Ls@〈c,false〉)) l1 (hd (Ls@〈d,false〉))* (tail (Ls@〈d,false〉)) l2
 746      ^^^^^^^^^^^^^^^^^^^^^^^
 747
 748
 749   ls Ls 〈c,true〉 l1 Ls 〈d,false〉 l2
 750                        ^^^^^^^^
 751
 752   ).
 753
 754   |bs| = |b0s| →
 755   (∃la,d.〈b,true〉::bs = la@[〈grid,d〉] ∧ ∀x.memb ? x la → is_bit (\fst x) = true) →
 756   (∃lb,d0.〈b0,true〉::b0s = lb@[〈comma,d0〉] ∧ ∀x.memb ? x lb → is_bit (\fst x) = true) →
 757   t1 = midtape ? l0 〈b,true〉 (bs@l1@〈b0,true〉::b0s@l2 →
 758
 759   mk_tape left (option current) right
 760
 761   (b = grid ∧ b0 = comma ∧ bs = [] ∧ b0s = [] ∧
 762    t2 = midtape ? l0 〈grid,false〉 (l1@〈comma,true〉::l2)) ∨
 763   (b = bit x ∧ b = c ∧ bs = b0s
 764   *)
 765 definition R_compare :=
 766   λt1,t2.
 767   ∀ls,c,rs.t1 = midtape (FinProd … FSUnialpha FinBool) ls c rs →
 768   (∀c'.bit_or_null c' = false → c = 〈c',true〉 → t2 = midtape ? ls 〈c',false〉 rs) ∧
 769   (∀c'. c = 〈c',false〉 → t2 = t1) ∧
 770   ∀b,b0,bs,b0s,l1,l2.
 771   |bs| = |b0s| →
 772   (∀c.memb (FinProd … FSUnialpha FinBool) c bs = true → bit_or_null (\fst c) = true) →
 773   (∀c.memb (FinProd … FSUnialpha FinBool) c b0s = true → bit_or_null (\fst c) = true) →
 774   (∀c.memb ? c bs = true → is_marked ? c = false) →
 775   (∀c.memb ? c b0s = true → is_marked ? c = false) →
 776   (∀c.memb ? c l1 = true → is_marked ? c = false) →
 777   c = 〈b,true〉 → bit_or_null b = true →
 778   rs = bs@〈grid,false〉::l1@〈b0,true〉::b0s@〈comma,false〉::l2 →
 779   (〈b,true〉::bs = 〈b0,true〉::b0s ∧
 780    t2 = midtape ? (reverse ? bs@〈b,false〉::ls)
 781           〈grid,false〉 (l1@〈b0,false〉::b0s@〈comma,true〉::l2)) ∨
 782   (∃la,c',d',lb,lc.c' ≠ d' ∧
 783     〈b,false〉::bs = la@〈c',false〉::lb ∧
 784     〈b0,false〉::b0s = la@〈d',false〉::lc ∧
 785     t2 = midtape (FinProd … FSUnialpha FinBool) (reverse ? la@
 786                     reverse ? l1@
 787                     〈grid,false〉::
 788                     reverse ? lb@
 789                     〈c',true〉::
 790                     reverse ? la@ls)
 791                     〈d',false〉 (lc@〈comma,false〉::l2)).
 792
 793 lemma wsem_compare : WRealize ? compare R_compare.
 794 #t #i #outc #Hloop
 795 lapply (sem_while ?????? sem_comp_step t i outc Hloop) [%]
 796 -Hloop * #t1 * #Hstar @(star_ind_l ??????? Hstar)
 797 [ #tapea whd in ⊢ (%→?); #Rfalse #ls #c #rs #Htapea %
 798   [ %
 799     [ #c' #Hc' #Hc lapply (Rfalse … Htapea) -Rfalse * >Hc
 800       whd in ⊢ (??%?→?); #Hfalse destruct (Hfalse)
 801     | #c' #Hc lapply (Rfalse … Htapea) -Rfalse * #_
 802       #Htrue @Htrue ]
 803   | #b #b0 #bs #b0s #l1 #l2 #Hlen #Hbs1 #Hb0s1 #Hbs2 #Hb0s2 #Hl1 #Hc
 804     cases (Rfalse … Htapea) -Rfalse >Hc whd in ⊢ (??%?→?);#Hfalse destruct (Hfalse)
 805   ]
 806 | #tapea #tapeb #tapec #Hleft #Hright #IH #Htapec lapply (IH Htapec) -Htapec -IH #IH
 807   whd in Hleft; #ls #c #rs #Htapea cases (Hleft … Htapea) -Hleft
 808   #c' * #Hc >Hc cases (true_or_false (bit_or_null c')) #Hc'
 809   [2: *
 810     [ * >Hc' #H @False_ind destruct (H)
 811     | * #_ #Htapeb cases (IH … Htapeb) * #_ #H #_ %
 812       [%
 813         [#c1 #Hc1 #Heqc destruct (Heqc) <Htapeb @(H c1) %
 814         |#c1 #Hfalse destruct (Hfalse)
 815         ]
 816       |#b #b0 #bs #b0s #l1 #l2 #_ #_ #_ #_ #_ #_
 817        #Heq destruct (Heq) >Hc' #Hfalse @False_ind destruct (Hfalse)
 818       ]
 819     ]
 820  |#Hleft %
 821     [ %
 822       [ #c'' #Hc'' #Heq destruct (Heq) >Hc'' in Hc'; #H destruct (H)
 823       | #c0 #Hfalse destruct (Hfalse)
 824       ]
 825     |#b #b0 #bs #b0s #l1 #l2 #Hlen #Hbs1 #Hb0s1 #Hbs2 #Hb0s2 #Hl1
 826      #Heq destruct (Heq) #_ #Hrs cases Hleft -Hleft
 827       [2: * >Hc' #Hfalse @False_ind destruct ] * #_
 828        @(list_cases2 … Hlen)
 829        [ #Hbs #Hb0s generalize in match Hrs; >Hbs in ⊢ (%→?); >Hb0s in ⊢ (%→?);
 830        -Hrs #Hrs normalize in Hrs; #Hleft cases (Hleft ????? Hrs ?) -Hleft
 831          [ * #Heqb #Htapeb cases (IH … Htapeb) -IH * #IH #_ #_
 832           % %
 833             [ >Heqb >Hbs >Hb0s %
 834             | >Hbs >Hb0s @IH %
 835             ]
 836          |* #Hneqb #Htapeb %2
 837           @(ex_intro … [ ]) @(ex_intro … b)
 838           @(ex_intro … b0) @(ex_intro … [ ])
 839           @(ex_intro … [ ]) %
 840             [ % [ % [@sym_not_eq //| >Hbs %] | >Hb0s %]
 841             | cases (IH … Htapeb) -IH * #_ #IH #_ >(IH ? (refl ??))
 842               @Htapeb
 843             ]
 844          | @Hl1 ]
 845       | * #b' #bitb' * #b0' #bitb0' #bs' #b0s' #Hbs #Hb0s
 846         generalize in match Hrs; >Hbs in ⊢ (%→?); >Hb0s in ⊢ (%→?);
 847         cut (bit_or_null b' = true ∧ bit_or_null b0' = true ∧
 848              bitb' = false ∧ bitb0' = false)
 849         [ % [ % [ % [ >Hbs in Hbs1; #Hbs1 @(Hbs1 〈b',bitb'〉) @memb_hd
 850             | >Hb0s in Hb0s1; #Hb0s1 @(Hb0s1 〈b0',bitb0'〉) @memb_hd ]
 851             | >Hbs in Hbs2; #Hbs2 @(Hbs2 〈b',bitb'〉) @memb_hd ]
 852             | >Hb0s in Hb0s2; #Hb0s2 @(Hb0s2 〈b0',bitb0'〉) @memb_hd ]
 853         | * * * #Ha #Hb #Hc #Hd >Hc >Hd
 854           #Hrs #Hleft
 855           cases (Hleft b' (bs'@〈grid,false〉::l1) b0 b0'
 856                          (b0s'@〈comma,false〉::l2) ??) -Hleft
 857           [ 3: >Hrs normalize @eq_f >associative_append %
 858           | * #Hb0 #Htapeb cases (IH …Htapeb) -IH * #_ #_ #IH
 859             cases (IH b' b0' bs' b0s' (l1@[〈b0,false〉]) l2 ??????? Ha ?) -IH
 860             [ * #Heq #Houtc % %
 861               [ >Hb0 @eq_f >Hbs in Heq; >Hb0s in ⊢ (%→?); #Heq
 862                 destruct (Heq) >Hb0s >Hc >Hd %
 863               | >Houtc >Hbs >Hb0s >Hc >Hd >reverse_cons >associative_append
 864                 >associative_append %
 865               ]
 866             | * #la * #c' * #d' * #lb * #lc * * * #H1 #H2 #H3 #H4 %2
 867               @(ex_intro … (〈b,false〉::la)) @(ex_intro … c') @(ex_intro … d')
 868               @(ex_intro … lb) @(ex_intro … lc)
 869               % [ % [ % // >Hbs >Hc >H2 % | >Hb0s >Hd >H3 >Hb0 % ]
 870                 | >H4 >Hbs >Hb0s >Hc >Hd >Hb0 >reverse_append
 871                   >reverse_cons >reverse_cons
 872                   >associative_append >associative_append
 873                   >associative_append >associative_append %
 874                 ]
 875             | generalize in match Hlen; >Hbs >Hb0s
 876               normalize #Hlen destruct (Hlen) @e0
 877             | #c0 #Hc0 @Hbs1 >Hbs @memb_cons //
 878             | #c0 #Hc0 @Hb0s1 >Hb0s @memb_cons //
 879             | #c0 #Hc0 @Hbs2 >Hbs @memb_cons //
 880             | #c0 #Hc0 @Hb0s2 >Hb0s @memb_cons //
 881             | #c0 #Hc0 cases (memb_append … Hc0)
 882               [ @Hl1 | #Hc0' >(memb_single … Hc0') % ]
 883             | %
 884             | >associative_append >associative_append % ]
 885          | * #Hneq #Htapeb %2
 886             @(ex_intro … []) @(ex_intro … b) @(ex_intro … b0)
 887             @(ex_intro … bs) @(ex_intro … b0s) %
 888            [ % // % // @sym_not_eq //
 889            | >Hbs >Hb0s >Hc >Hd >reverse_cons >associative_append
 890              >reverse_append in Htapeb; >reverse_cons
 891              >associative_append >associative_append
 892              #Htapeb <Htapeb
 893              cases (IH … Htapeb) -Htapeb -IH * #_ #IH #_ @(IH ? (refl ??))
 894            ]
 895          | #c1 #Hc1 cases (memb_append … Hc1) #Hyp
 896            [ @Hbs2 >Hbs @memb_cons @Hyp
 897            | cases (orb_true_l … Hyp)
 898              [ #Hyp2 >(\P Hyp2) %
 899              | @Hl1
 900              ]
 901            ]
 902          ]
 903 ]]]]]
 904 qed.
 905
 906 axiom sem_compare : Realize ? compare R_compare.