matita/matita/lib/turing/universal/move_char_c.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||
   8     \   /  This file is distributed under the terms of the
   9      \ /   GNU General Public License Version 2
  10       V_____________________________________________________________*)
  11
  12
  13 (* MOVE_CHAR (variant c) MACHINE
  14
  15 Sposta il carattere binario su cui si trova la testina appena prima del primo # alla sua destra.
  16
  17 Input:
  18 (ls,cs,rs can be empty; # is a parameter)
  19
  20   ls x cs # rs
  21        ^
  22        H
  23
  24 Output:
  25   ls cs x # rs
  26         ^
  27         H
  28
  29 Initial state = 〈0,#〉
  30 Final state = 〈4,#〉
  31
  32 *)
  33
  34 include "turing/while_machine.ma".
  35
  36 definition mcc_states : FinSet → FinSet ≝ λalpha:FinSet.FinProd (initN 5) alpha.
  37
  38 definition mcc0 : initN 5 ≝ mk_Sig ?? 0 (leb_true_to_le 1 5 (refl …)).
  39 definition mcc1 : initN 5 ≝ mk_Sig ?? 1 (leb_true_to_le 2 5 (refl …)).
  40 definition mcc2 : initN 5 ≝ mk_Sig ?? 2 (leb_true_to_le 3 5 (refl …)).
  41 definition mcc3 : initN 5 ≝ mk_Sig ?? 3 (leb_true_to_le 4 5 (refl …)).
  42 definition mcc4 : initN 5 ≝ mk_Sig ?? 4 (leb_true_to_le 5 5 (refl …)).
  43
  44 definition mcc_step ≝
  45  λalpha:FinSet.λsep:alpha.
  46  mk_TM alpha (mcc_states alpha)
  47  (λp.let 〈q,a〉 ≝ p in
  48   let 〈q',b〉 ≝ q in
  49   let q' ≝ pi1 nat (λi.i<5) q' in (* perche' devo passare il predicato ??? *)
  50   match a with
  51   [ None ⇒ 〈〈mcc4,sep〉,None ?〉
  52   | Some a' ⇒
  53   match q' with
  54   [ O ⇒ (* qinit *)
  55     match a' == sep with
  56     [ true ⇒ 〈〈mcc4,sep〉,None ?〉
  57     | false ⇒ 〈〈mcc1,a'〉,Some ? 〈a',L〉〉 ]
  58   | S q' ⇒  match q' with
  59     [ O ⇒ (* q1 *)
  60       〈〈mcc2,a'〉,Some ? 〈b,R〉〉
  61     | S q' ⇒ match q' with
  62       [ O ⇒ (* q2 *)
  63         〈〈mcc3,sep〉,Some ? 〈b,R〉〉
  64       | S q' ⇒ match q' with
  65         [ O ⇒ (* qacc *)
  66           〈〈mcc3,sep〉,None ?〉
  67         | S q' ⇒ (* qfail *)
  68           〈〈mcc4,sep〉,None ?〉 ] ] ] ] ])
  69   〈mcc0,sep〉
  70   (λq.let 〈q',a〉 ≝ q in q' == mcc3 ∨ q' == mcc4).
  71
  72 lemma mcc_q0_q1 :
  73   ∀alpha:FinSet.∀sep,a,ls,a0,rs.
  74   a0 == sep = false →
  75   step alpha (mcc_step alpha sep)
  76     (mk_config ?? 〈mcc0,a〉 (mk_tape … ls (Some ? a0) rs)) =
  77   mk_config alpha (states ? (mcc_step alpha sep)) 〈mcc1,a0〉
  78     (tape_move_left alpha ls a0 rs).
  79 #alpha #sep #a *
  80 [ #a0 #rs #Ha0 whd in ⊢ (??%?);
  81   normalize in match (trans ???); >Ha0 %
  82 | #a1 #ls #a0 #rs #Ha0 whd in ⊢ (??%?);
  83   normalize in match (trans ???); >Ha0 %
  84 ]
  85 qed.
  86
  87 lemma mcc_q1_q2 :
  88   ∀alpha:FinSet.∀sep,a,ls,a0,rs.
  89   step alpha (mcc_step alpha sep)
  90     (mk_config ?? 〈mcc1,a〉 (mk_tape … ls (Some ? a0) rs)) =
  91   mk_config alpha (states ? (mcc_step alpha sep)) 〈mcc2,a0〉
  92     (tape_move_right alpha ls a rs).
  93 #alpha #sep #a #ls #a0 * //
  94 qed.
  95
  96 lemma mcc_q2_q3 :
  97   ∀alpha:FinSet.∀sep,a,ls,a0,rs.
  98   step alpha (mcc_step alpha sep)
  99     (mk_config ?? 〈mcc2,a〉 (mk_tape … ls (Some ? a0) rs)) =
 100   mk_config alpha (states ? (mcc_step alpha sep)) 〈mcc3,sep〉
 101     (tape_move_right alpha ls a rs).
 102 #alpha #sep #a #ls #a0 * //
 103 qed.
 104
 105 definition Rmcc_step_true ≝
 106   λalpha,sep,t1,t2.
 107    ∀a,b,ls,rs.
 108     t1 = midtape alpha (a::ls) b rs →
 109     b ≠ sep ∧
 110     t2 = mk_tape alpha (a::b::ls) (option_hd ? rs) (tail ? rs).
 111
 112 definition Rmcc_step_false ≝
 113   λalpha,sep,t1,t2.
 114     left ? t1 ≠ [] →  current alpha t1 ≠ None alpha →
 115       current alpha t1 = Some alpha sep ∧ t2 = t1.
 116
 117 lemma mcc_trans_init_sep:
 118   ∀alpha,sep,x.
 119   trans ? (mcc_step alpha sep) 〈〈mcc0,x〉,Some ? sep〉 = 〈〈mcc4,sep〉,None ?〉.
 120 #alpha #sep #x normalize >(\b ?) //
 121 qed.
 122
 123 lemma mcc_trans_init_not_sep:
 124   ∀alpha,sep,x,y.y == sep = false →
 125   trans ? (mcc_step alpha sep) 〈〈mcc0,x〉,Some ? y〉 = 〈〈mcc1,y〉,Some ? 〈y,L〉〉.
 126 #alpha #sep #x #y #H1 normalize >H1 //
 127 qed.
 128
 129 lemma sem_mcc_step :
 130   ∀alpha,sep.
 131   accRealize alpha (mcc_step alpha sep)
 132     〈mcc3,sep〉 (Rmcc_step_true alpha sep) (Rmcc_step_false alpha sep).
 133 #alpha #sep
 134 cut (∀P:Prop.〈mcc4,sep〉=〈mcc3,sep〉→P)
 135   [#P whd in ⊢ ((??(???%?)(???%?))→?); #Hfalse destruct] #Hfalse
 136 *
 137 [@(ex_intro ?? 2)
 138   @(ex_intro … (mk_config ?? 〈mcc4,sep〉 (niltape ?))) %
 139   [% [whd in ⊢ (??%?); % | @Hfalse]
 140   |#H1 #H2 @False_ind @(absurd ?? H2) %]
 141 |#l0 #lt0 @(ex_intro ?? 2)
 142   @(ex_intro … (mk_config ?? 〈mcc4,sep〉 (leftof ? l0 lt0)))%
 143   [% [whd in ⊢ (??%?);% |@Hfalse]
 144   |#H1 #H2 @False_ind @(absurd ?? H2) %]
 145 |#r0 #rt0 @(ex_intro ?? 2)
 146   @(ex_intro … (mk_config ?? 〈mcc4,sep〉 (rightof ? r0 rt0))) %
 147   [% [whd in ⊢ (??%?);% |@Hfalse]
 148   |#H1 #H2 #H3 @False_ind @(absurd ?? H3) %]
 149 | #lt #c #rt cases (true_or_false (c == sep)) #Hc
 150   [ @(ex_intro ?? 2)
 151     @(ex_intro ?? (mk_config ?? 〈mcc4,sep〉 (midtape ? lt c rt)))
 152     % [ %
 153         [ >(\P Hc) >loop_S_false // >loop_S_true
 154          [ @eq_f whd in ⊢ (??%?); >mcc_trans_init_sep %
 155          |>(\P Hc) whd in ⊢(??(???(???%))?); >mcc_trans_init_sep % ]
 156         |@Hfalse]
 157       |#_ #H1 #H2 % // normalize >(\P Hc) % ]
 158   | @(ex_intro ?? 4) cases lt
 159     [ @ex_intro
 160       [|% [ %
 161             [ >loop_S_false // >mcc_q0_q1 //
 162             | normalize in ⊢ (%→?); #Hfalse destruct (Hfalse) ]
 163           | normalize in ⊢ (%→?); #_ #H1 @False_ind @(absurd ?? H1) % ] ]
 164     | #l0 #lt @ex_intro
 165       [| % [ %
 166              [ >loop_S_false // >mcc_q0_q1 //
 167              | #_ #a #b #ls #rs #Hb destruct %
 168                [ @(\Pf Hc)
 169                | >mcc_q1_q2 >mcc_q2_q3 cases rs normalize // ] ]
 170            | normalize in ⊢ (% → ?); * #Hfalse
 171              @False_ind /2/ ]
 172      ]
 173    ]
 174  ]
 175 ]
 176 qed.
 177
 178 (* the move_char (variant c) machine *)
 179 definition move_char_c ≝
 180   λalpha,sep.whileTM alpha (mcc_step alpha sep) 〈mcc3,sep〉.
 181
 182 definition R_move_char_c ≝
 183   λalpha,sep,t1,t2.
 184     ∀b,a,ls,rs. t1 = midtape alpha (a::ls) b rs →
 185     (b = sep → t2 = t1) ∧
 186     (∀rs1,rs2.rs = rs1@sep::rs2 →
 187      b ≠ sep → memb ? sep rs1 = false →
 188      t2 = midtape alpha (a::reverse ? rs1@b::ls) sep rs2).
 189
 190 lemma sem_move_char_c :
 191   ∀alpha,sep.
 192   WRealize alpha (move_char_c alpha sep) (R_move_char_c alpha sep).
 193 #alpha #sep #inc #i #outc #Hloop
 194 lapply (sem_while … (sem_mcc_step alpha sep) inc i outc Hloop) [%]
 195 -Hloop * #t1 * #Hstar @(star_ind_l ??????? Hstar)
 196 [ #tapea whd in ⊢ (% → ?); #H1 #b #a #ls #rs #Htapea
 197   %
 198   [ #Hb >Htapea in H1; >Hb #H1 cases (H1 ??)
 199     [#_ #H2 >H2 % |*: % #H2 normalize in H2; destruct (H2)]
 200   | #rs1 #rs2 #Hrs #Hb #Hrs1
 201     >Htapea in H1; #H1 cases (H1 ??)
 202     [#Hfalse @False_ind @(absurd ?? Hb) normalize in Hfalse; destruct %
 203     |*:% #H2 normalize in H2; destruct (H2) ]
 204   ]
 205 | #tapea #tapeb #tapec #Hstar1 #HRtrue #IH #HRfalse
 206   lapply (IH HRfalse) -IH whd in ⊢ (%→%); #IH
 207   #a0 #b0 #ls #rs #Htapea cases (Hstar1 … Htapea)
 208   #Ha0 #Htapeb %
 209   [ #Hfalse @False_ind @(absurd ?? Ha0) //
 210   | *
 211     [ #rs2 whd in ⊢ (???%→?); #Hrs #_ #_ (* normalize *)
 212       >Hrs in Htapeb; #Htapeb normalize in Htapeb;
 213       cases (IH … Htapeb) #Houtc #_ >Houtc normalize //
 214     | #r0 #rs0 #rs2 #Hrs #_ #Hrs0
 215       cut (r0 ≠ sep ∧ memb … sep rs0 = false)
 216       [ %
 217          [ % #Hr0 >Hr0 in Hrs0; >memb_hd #Hfalse destruct
 218          | whd in Hrs0:(??%?); cases (sep==r0) in Hrs0; normalize #Hfalse
 219            [ destruct
 220            | @Hfalse ]
 221          ]
 222       ] *
 223       #Hr0 -Hrs0 #Hrs0 >Hrs in Htapeb;
 224       normalize in ⊢ (%→?); #Htapeb
 225       cases (IH … Htapeb) -IH #_ #IH
 226       >reverse_cons >associative_append @IH //
 227     ]
 228   ]
 229 qed.
 230
 231 lemma terminate_move_char_c :
 232   ∀alpha,sep.∀t,b,a,ls,rs. t = midtape alpha (a::ls) b rs →
 233   (b = sep ∨ memb ? sep rs = true) → Terminate alpha (move_char_c alpha sep) t.
 234 #alpha #sep #t #b #a #ls #rs #Ht #Hsep
 235 @(terminate_while … (sem_mcc_step alpha sep))
 236   [%
 237   |generalize in match Hsep; -Hsep
 238    generalize in match Ht; -Ht
 239    generalize in match ls; -ls
 240    generalize in match a; -a
 241    generalize in match b; -b
 242    generalize in match t; -t
 243    elim rs
 244     [#t #b #a #ls #Ht #Hsep % #tinit
 245      whd in ⊢ (%→?); #H @False_ind
 246      cases (H … Ht) #Hb #_ cases Hb #eqb @eqb
 247      cases Hsep // whd in ⊢ ((??%?)→?); #abs destruct
 248     |#r0 #rs0 #Hind #t #b #a #ls #Ht #Hsep % #tinit
 249      whd in ⊢ (%→?); #H
 250      cases (H … Ht) #Hbsep #Htinit
 251      @(Hind … Htinit) cases Hsep
 252       [#Hb @False_ind /2/ | #Hmemb cases (orb_true_l … Hmemb)
 253         [#eqsep %1 >(\P eqsep) // | #H %2 //]
 254   ]
 255 qed.