matita/matita/lib/turing/universal/move_char_c.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||
   8     \   /  This file is distributed under the terms of the
   9      \ /   GNU General Public License Version 2
  10       V_____________________________________________________________*)
  11
  12
  13 (* MOVE_CHAR (variant c) MACHINE
  14
  15 Sposta il carattere binario su cui si trova la testina appena prima del primo # alla sua destra.
  16
  17 Input:
  18 (ls,cs,rs can be empty; # is a parameter)
  19
  20   ls x cs # rs
  21        ^
  22        H
  23
  24 Output:
  25   ls cs x # rs
  26         ^
  27         H
  28
  29 Initial state = 〈0,#〉
  30 Final state = 〈4,#〉
  31
  32 *)
  33
  34 include "turing/while_machine.ma".
  35
  36 definition mcc_states : FinSet → FinSet ≝ λalpha:FinSet.FinProd (initN 5) alpha.
  37
  38 definition mcc_step ≝
  39  λalpha:FinSet.λsep:alpha.
  40  mk_TM alpha (mcc_states alpha)
  41  (λp.let 〈q,a〉 ≝ p in
  42   let 〈q',b〉 ≝ q in
  43   match a with
  44   [ None ⇒ 〈〈4,sep〉,None ?〉
  45   | Some a' ⇒
  46   match q' with
  47   [ O ⇒ (* qinit *)
  48     match a' == sep with
  49     [ true ⇒ 〈〈4,sep〉,None ?〉
  50     | false ⇒ 〈〈1,a'〉,Some ? 〈a',L〉〉 ]
  51   | S q' ⇒ match q' with
  52     [ O ⇒ (* q1 *)
  53       〈〈2,a'〉,Some ? 〈b,R〉〉
  54     | S q' ⇒ match q' with
  55       [ O ⇒ (* q2 *)
  56         〈〈3,sep〉,Some ? 〈b,R〉〉
  57       | S q' ⇒ match q' with
  58         [ O ⇒ (* qacc *)
  59           〈〈3,sep〉,None ?〉
  60         | S q' ⇒ (* qfail *)
  61           〈〈4,sep〉,None ?〉 ] ] ] ] ])
  62   〈0,sep〉
  63   (λq.let 〈q',a〉 ≝ q in q' == 3 ∨ q' == 4).
  64
  65 lemma mcc_q0_q1 :
  66   ∀alpha:FinSet.∀sep,a,ls,a0,rs.
  67   a0 == sep = false →
  68   step alpha (mcc_step alpha sep)
  69     (mk_config ?? 〈0,a〉 (mk_tape … ls (Some ? a0) rs)) =
  70   mk_config alpha (states ? (mcc_step alpha sep)) 〈1,a0〉
  71     (tape_move_left alpha ls a0 rs).
  72 #alpha #sep #a *
  73 [ #a0 #rs #Ha0 whd in ⊢ (??%?);
  74   normalize in match (trans ???); >Ha0 %
  75 | #a1 #ls #a0 #rs #Ha0 whd in ⊢ (??%?);
  76   normalize in match (trans ???); >Ha0 %
  77 ]
  78 qed.
  79
  80 lemma mcc_q1_q2 :
  81   ∀alpha:FinSet.∀sep,a,ls,a0,rs.
  82   step alpha (mcc_step alpha sep)
  83     (mk_config ?? 〈1,a〉 (mk_tape … ls (Some ? a0) rs)) =
  84   mk_config alpha (states ? (mcc_step alpha sep)) 〈2,a0〉
  85     (tape_move_right alpha ls a rs).
  86 #alpha #sep #a #ls #a0 * //
  87 qed.
  88
  89 lemma mcc_q2_q3 :
  90   ∀alpha:FinSet.∀sep,a,ls,a0,rs.
  91   step alpha (mcc_step alpha sep)
  92     (mk_config ?? 〈2,a〉 (mk_tape … ls (Some ? a0) rs)) =
  93   mk_config alpha (states ? (mcc_step alpha sep)) 〈3,sep〉
  94     (tape_move_right alpha ls a rs).
  95 #alpha #sep #a #ls #a0 * //
  96 qed.
  97
  98 definition Rmcc_step_true ≝
  99   λalpha,sep,t1,t2.
 100    ∀a,b,ls,rs.
 101     t1 = midtape alpha (a::ls) b rs →
 102     b ≠ sep ∧
 103     t2 = mk_tape alpha (a::b::ls) (option_hd ? rs) (tail ? rs).
 104
 105 definition Rmcc_step_false ≝
 106   λalpha,sep,t1,t2.
 107     left ? t1 ≠ [] →  current alpha t1 ≠ None alpha →
 108       current alpha t1 = Some alpha sep ∧ t2 = t1.
 109
 110 lemma loop_S_true :
 111   ∀A,n,f,p,a.  p a = true →
 112   loop A (S n) f p a = Some ? a. /2/
 113 qed.
 114
 115 lemma loop_S_false :
 116   ∀A,n,f,p,a.  p a = false →
 117   loop A (S n) f p a = loop A n f p (f a).
 118 normalize #A #n #f #p #a #Hpa >Hpa %
 119 qed.
 120
 121 lemma trans_init_sep:
 122   ∀alpha,sep,x.
 123   trans ? (mcc_step alpha sep) 〈〈0,x〉,Some ? sep〉 = 〈〈4,sep〉,None ?〉.
 124 #alpha #sep #x normalize >(\b ?) //
 125 qed.
 126
 127 lemma trans_init_not_sep:
 128   ∀alpha,sep,x,y.y == sep = false →
 129   trans ? (mcc_step alpha sep) 〈〈0,x〉,Some ? y〉 = 〈〈1,y〉,Some ? 〈y,L〉〉.
 130 #alpha #sep #x #y #H1 normalize >H1 //
 131 qed.
 132
 133 lemma sem_mcc_step :
 134   ∀alpha,sep.
 135   accRealize alpha (mcc_step alpha sep)
 136     〈3,sep〉 (Rmcc_step_true alpha sep) (Rmcc_step_false alpha sep).
 137 #alpha #sep *
 138 [@(ex_intro ?? 2)
 139   @(ex_intro … (mk_config ?? 〈4,sep〉 (niltape ?)))
 140   % [% [whd in ⊢ (??%?);% |#Hfalse destruct ] |#H1 #H2 @False_ind @(absurd ?? H2) %]
 141 |#l0 #lt0 @(ex_intro ?? 2)
 142   @(ex_intro … (mk_config ?? 〈4,sep〉 (leftof ? l0 lt0)))
 143   % [% [whd in ⊢ (??%?);% |#Hfalse destruct ] |#H1 #H2 @False_ind @(absurd ?? H2) %]
 144 |#r0 #rt0 @(ex_intro ?? 2)
 145   @(ex_intro … (mk_config ?? 〈4,sep〉 (rightof ? r0 rt0)))
 146   % [% [whd in ⊢ (??%?);% |#Hfalse destruct ] |#H1 #H2 #H3 @False_ind @(absurd ?? H3) %]
 147 | #lt #c #rt cases (true_or_false (c == sep)) #Hc
 148   [ @(ex_intro ?? 2)
 149     @(ex_intro ?? (mk_config ?? 〈4,sep〉 (midtape ? lt c rt)))
 150     % [ %
 151         [ >(\P Hc) >loop_S_false // >loop_S_true
 152          [ @eq_f whd in ⊢ (??%?); >trans_init_sep %
 153          |>(\P Hc) whd in ⊢(??(???(???%))?); >trans_init_sep % ]
 154         |   #Hfalse destruct ]
 155       |#_ #H1 #H2 % // normalize >(\P Hc) % ]
 156   | @(ex_intro ?? 4) cases lt
 157     [ @ex_intro
 158       [|% [ %
 159             [ >loop_S_false // >mcc_q0_q1 //
 160             | normalize in ⊢ (%→?); #Hfalse destruct (Hfalse) ]
 161           | normalize in ⊢ (%→?); #_ #H1 @False_ind @(absurd ?? H1) % ] ]
 162     | #l0 #lt @ex_intro
 163       [| % [ %
 164              [ >loop_S_false // >mcc_q0_q1 //
 165              | #_ #a #b #ls #rs #Hb destruct %
 166                [ @(\Pf Hc)
 167                | >mcc_q1_q2 >mcc_q2_q3 cases rs normalize // ] ]
 168            | normalize in ⊢ (% → ?); * #Hfalse
 169              @False_ind /2/ ]
 170      ]
 171    ]
 172  ]
 173 ]
 174 qed.
 175
 176 (* the move_char (variant c) machine *)
 177 definition move_char_c ≝
 178   λalpha,sep.whileTM alpha (mcc_step alpha sep) 〈3,sep〉.
 179
 180 definition R_move_char_c ≝
 181   λalpha,sep,t1,t2.
 182     ∀b,a,ls,rs. t1 = midtape alpha (a::ls) b rs →
 183     (b = sep → t2 = t1) ∧
 184     (∀rs1,rs2.rs = rs1@sep::rs2 →
 185      b ≠ sep → memb ? sep rs1 = false →
 186      t2 = midtape alpha (a::reverse ? rs1@b::ls) sep rs2).
 187
 188 lemma sem_while_move_char :
 189   ∀alpha,sep.
 190   WRealize alpha (move_char_c alpha sep) (R_move_char_c alpha sep).
 191 #alpha #sep #inc #i #outc #Hloop
 192 lapply (sem_while … (sem_mcc_step alpha sep) inc i outc Hloop) [%]
 193 -Hloop * #t1 * #Hstar @(star_ind_l ??????? Hstar)
 194 [ #tapea whd in ⊢ (% → ?); #H1 #b #a #ls #rs #Htapea
 195   %
 196   [ #Hb >Htapea in H1; >Hb normalize in ⊢ (%→?); #H1
 197    cases (H1 ??)
 198    [#_ #H2 >H2 %
 199    |*: % #H2 destruct (H2) ]
 200   | #rs1 #rs2 #Hrs #Hb #Hrs1
 201     >Htapea in H1; normalize in ⊢ (% → ?); #H1
 202     cases (H1 ??)
 203     [ #Hfalse @False_ind @(absurd ?? Hb) destruct %
 204     |*:% #H2 destruct (H2) ]
 205   ]
 206 | #tapea #tapeb #tapec #Hstar1 #HRtrue #IH #HRfalse
 207   lapply (IH HRfalse) -IH whd in ⊢ (%→%); #IH
 208   #a0 #b0 #ls #rs #Htapea cases (Hstar1 … Htapea)
 209   #Ha0 #Htapeb %
 210   [ #Hfalse @False_ind @(absurd ?? Ha0) //
 211   | *
 212     [ #rs2 whd in ⊢ (???%→?); #Hrs #_ #_ normalize
 213       >Hrs in Htapeb; normalize #Htapeb
 214       cases (IH … Htapeb)
 215       #Houtc #_ >Houtc //
 216     | #r0 #rs0 #rs2 #Hrs #_ #Hrs0
 217       cut (r0 ≠ sep ∧ memb … sep rs0 = false)
 218       [ %
 219          [ % #Hr0 >Hr0 in Hrs0; >memb_hd #Hfalse destruct
 220          | whd in Hrs0:(??%?); cases (sep==r0) in Hrs0; normalize #Hfalse
 221            [ destruct
 222            | @Hfalse ]
 223          ]
 224       ] *
 225       #Hr0 -Hrs0 #Hrs0 >Hrs in Htapeb;
 226       normalize in ⊢ (%→?); #Htapeb
 227       cases (IH … Htapeb) -IH #_ #IH
 228       >reverse_cons >associative_append @IH //
 229     ]
 230   ]
 231 qed.
 232
 233 lemma terminate_move_char_c :
 234   ∀alpha,sep.∀t,b,a,ls,rs. t = midtape alpha (a::ls) b rs →
 235   (b = sep ∨ memb ? sep rs = true) → Terminate alpha (move_char_c alpha sep) t.
 236 #alpha #sep #t #b #a #ls #rs #Ht #Hsep
 237 @(terminate_while … (sem_mcc_step alpha sep))
 238   [%
 239   |generalize in match Hsep; -Hsep
 240    generalize in match Ht; -Ht
 241    generalize in match ls; -ls
 242    generalize in match a; -a
 243    generalize in match b; -b
 244    generalize in match t; -t
 245    elim rs
 246     [#t #b #a #ls #Ht #Hsep % #tinit
 247      whd in ⊢ (%→?); #H @False_ind
 248      cases (H … Ht) #Hb #_ cases Hb #eqb @eqb
 249      cases Hsep // whd in ⊢ ((??%?)→?); #abs destruct
 250     |#r0 #rs0 #Hind #t #b #a #ls #Ht #Hsep % #tinit
 251      whd in ⊢ (%→?); #H
 252      cases (H … Ht) #Hbsep #Htinit
 253      @(Hind … Htinit) cases Hsep
 254       [#Hb @False_ind /2/ | #Hmemb cases (orb_true_l … Hmemb)
 255         [#eqsep %1 >(\P eqsep) // | #H %2 //]
 256   ]
 257 qed.