matita/matita/lib/turing/universal/move_char_l.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||
   8     \   /  This file is distributed under the terms of the
   9      \ /   GNU General Public License Version 2
  10       V_____________________________________________________________*)
  11
  12
  13 (* MOVE_CHAR (left) MACHINE
  14
  15 Sposta il carattere binario su cui si trova la testina appena prima del primo # alla sua destra.
  16
  17 Input:
  18 (ls,cs,rs can be empty; # is a parameter)
  19
  20   ls # cs x rs
  21         ^
  22         H
  23
  24 Output:
  25   ls # x cs rs
  26        ^
  27        H
  28
  29 Initial state = 〈0,#〉
  30 Final state = 〈4,#〉
  31
  32 *)
  33
  34 include "turing/while_machine.ma".
  35
  36 definition mcl_states : FinSet → FinSet ≝ λalpha:FinSet.FinProd (initN 5) alpha.
  37
  38 definition mcl_step ≝
  39  λalpha:FinSet.λsep:alpha.
  40  mk_TM alpha (mcl_states alpha)
  41  (λp.let 〈q,a〉 ≝ p in
  42   let 〈q',b〉 ≝ q in
  43   match a with
  44   [ None ⇒ 〈〈4,sep〉,None ?〉
  45   | Some a' ⇒
  46   match q' with
  47   [ O ⇒ (* qinit *)
  48     match a' == sep with
  49     [ true ⇒ 〈〈4,sep〉,None ?〉
  50     | false ⇒ 〈〈1,a'〉,Some ? 〈a',R〉〉 ]
  51   | S q' ⇒ match q' with
  52     [ O ⇒ (* q1 *)
  53       〈〈2,a'〉,Some ? 〈b,L〉〉
  54     | S q' ⇒ match q' with
  55       [ O ⇒ (* q2 *)
  56         〈〈3,sep〉,Some ? 〈b,L〉〉
  57       | S q' ⇒ match q' with
  58         [ O ⇒ (* qacc *)
  59           〈〈3,sep〉,None ?〉
  60         | S q' ⇒ (* qfail *)
  61           〈〈4,sep〉,None ?〉 ] ] ] ] ])
  62   〈0,sep〉
  63   (λq.let 〈q',a〉 ≝ q in q' == 3 ∨ q' == 4).
  64
  65 lemma mcc_q0_q1 :
  66   ∀alpha:FinSet.∀sep,a,ls,a0,rs.
  67   a0 == sep = false →
  68   step alpha (mcl_step alpha sep)
  69     (mk_config ?? 〈0,a〉 (mk_tape … ls (Some ? a0) rs)) =
  70   mk_config alpha (states ? (mcl_step alpha sep)) 〈1,a0〉
  71     (tape_move_right alpha ls a0 rs).
  72 #alpha #sep #a *
  73 [ #a0 #rs #Ha0 whd in ⊢ (??%?);
  74   normalize in match (trans ???); >Ha0 %
  75 | #a1 #ls #a0 #rs #Ha0 whd in ⊢ (??%?);
  76   normalize in match (trans ???); >Ha0 %
  77 ]
  78 qed.
  79
  80 lemma mcl_q1_q2 :
  81   ∀alpha:FinSet.∀sep,a,ls,a0,rs.
  82   step alpha (mcl_step alpha sep)
  83     (mk_config ?? 〈1,a〉 (mk_tape … ls (Some ? a0) rs)) =
  84   mk_config alpha (states ? (mcl_step alpha sep)) 〈2,a0〉
  85     (tape_move_left alpha ls a rs).
  86 #alpha #sep #a #ls #a0 * //
  87 qed.
  88
  89 lemma mcl_q2_q3 :
  90   ∀alpha:FinSet.∀sep,a,ls,a0,rs.
  91   step alpha (mcl_step alpha sep)
  92     (mk_config ?? 〈2,a〉 (mk_tape … ls (Some ? a0) rs)) =
  93   mk_config alpha (states ? (mcl_step alpha sep)) 〈3,sep〉
  94     (tape_move_left alpha ls a rs).
  95 #alpha #sep #a #ls #a0 * //
  96 qed.
  97
  98 definition Rmcl_step_true ≝
  99   λalpha,sep,t1,t2.
 100    ∀a,b,ls,rs.
 101     t1 = midtape alpha ls b (a::rs) →
 102     b ≠ sep ∧
 103     t2 = mk_tape alpha (tail ? ls) (option_hd ? ls) (a::b::rs).
 104
 105 definition Rmcl_step_false ≝
 106   λalpha,sep,t1,t2.
 107     right ? t1 ≠ [] →  current alpha t1 ≠ None alpha →
 108       current alpha t1 = Some alpha sep ∧ t2 = t1.
 109
 110 lemma mcl_trans_init_sep:
 111   ∀alpha,sep,x.
 112   trans ? (mcl_step alpha sep) 〈〈0,x〉,Some ? sep〉 = 〈〈4,sep〉,None ?〉.
 113 #alpha #sep #x normalize >(\b ?) //
 114 qed.
 115
 116 lemma mcl_trans_init_not_sep:
 117   ∀alpha,sep,x,y.y == sep = false →
 118   trans ? (mcl_step alpha sep) 〈〈0,x〉,Some ? y〉 = 〈〈1,y〉,Some ? 〈y,R〉〉.
 119 #alpha #sep #x #y #H1 normalize >H1 //
 120 qed.
 121
 122 lemma sem_mcl_step :
 123   ∀alpha,sep.
 124   accRealize alpha (mcl_step alpha sep)
 125     〈3,sep〉 (Rmcl_step_true alpha sep) (Rmcl_step_false alpha sep).
 126 #alpha #sep *
 127 [@(ex_intro ?? 2)
 128   @(ex_intro … (mk_config ?? 〈4,sep〉 (niltape ?)))
 129   % [% [whd in ⊢ (??%?);% |#Hfalse destruct ] |#H1 #H2 @False_ind @(absurd ?? H2) %]
 130 |#l0 #lt0 @(ex_intro ?? 2)
 131   @(ex_intro … (mk_config ?? 〈4,sep〉 (leftof ? l0 lt0)))
 132   % [% [whd in ⊢ (??%?);% |#Hfalse destruct ] |#H1 #H2 #H3 @False_ind @(absurd ?? H3) %]
 133 |#r0 #rt0 @(ex_intro ?? 2)
 134   @(ex_intro … (mk_config ?? 〈4,sep〉 (rightof ? r0 rt0)))
 135   % [% [whd in ⊢ (??%?);% |#Hfalse destruct ] |#H1 #H2 #H3 @False_ind @(absurd ?? H3) %]
 136 | #lt #c #rt cases (true_or_false (c == sep)) #Hc
 137   [ @(ex_intro ?? 2)
 138     @(ex_intro ?? (mk_config ?? 〈4,sep〉 (midtape ? lt c rt)))
 139     % [ %
 140         [ >(\P Hc) >loop_S_false // >loop_S_true
 141          [ @eq_f whd in ⊢ (??%?); >mcl_trans_init_sep %
 142          |>(\P Hc) whd in ⊢(??(???(???%))?); >mcl_trans_init_sep % ]
 143         |   #Hfalse destruct ]
 144       |#_ #H1 #H2 % // normalize >(\P Hc) % ]
 145   | @(ex_intro ?? 4) cases rt
 146     [ @ex_intro
 147       [|% [ %
 148             [ >loop_S_false // >mcc_q0_q1 //
 149             | normalize in ⊢ (%→?); #Hfalse destruct (Hfalse) ]
 150           | normalize in ⊢ (%→?); #_ #H1 @False_ind @(absurd ?? H1) % ] ]
 151     | #r0 #rt0 @ex_intro
 152       [| % [ %
 153              [ >loop_S_false // >mcc_q0_q1 //
 154              | #_ #a #b #ls #rs #Hb destruct (Hb) %
 155                [ @(\Pf Hc)
 156                | >mcl_q1_q2 >mcl_q2_q3 cases ls normalize // ] ]
 157            | normalize in ⊢ (% → ?); * #Hfalse
 158              @False_ind /2/ ]
 159      ]
 160    ]
 161  ]
 162 ]
 163 qed.
 164
 165 (* the move_char (variant c) machine *)
 166 definition move_char_l ≝
 167   λalpha,sep.whileTM alpha (mcl_step alpha sep) 〈3,sep〉.
 168
 169 definition R_move_char_l ≝
 170   λalpha,sep,t1,t2.
 171     ∀b,a,ls,rs. t1 = midtape alpha ls b (a::rs) →
 172     (b = sep → t2 = t1) ∧
 173     (∀ls1,ls2.ls = ls1@sep::ls2 →
 174      b ≠ sep → memb ? sep ls1 = false →
 175      t2 = midtape alpha ls2 sep (a::reverse ? ls1@b::rs)).
 176
 177 lemma sem_move_char_l :
 178   ∀alpha,sep.
 179   WRealize alpha (move_char_l alpha sep) (R_move_char_l alpha sep).
 180 #alpha #sep #inc #i #outc #Hloop
 181 lapply (sem_while … (sem_mcl_step alpha sep) inc i outc Hloop) [%]
 182 -Hloop * #t1 * #Hstar @(star_ind_l ??????? Hstar)
 183 [ #tapea whd in ⊢ (% → ?); #H1 #b #a #ls #rs #Htapea
 184   %
 185   [ #Hb >Htapea in H1; >Hb normalize in ⊢ (%→?); #H1
 186    cases (H1 ??)
 187    [#_ #H2 >H2 %
 188    |*: % #H2 destruct (H2) ]
 189   | #rs1 #rs2 #Hrs #Hb #Hrs1
 190     >Htapea in H1; normalize in ⊢ (% → ?); #H1
 191     cases (H1 ??)
 192     [ #Hfalse @False_ind @(absurd ?? Hb) destruct %
 193     |*:% #H2 destruct (H2) ]
 194   ]
 195 | #tapea #tapeb #tapec #Hstar1 #HRtrue #IH #HRfalse
 196   lapply (IH HRfalse) -IH whd in ⊢ (%→%); #IH
 197   #a0 #b0 #ls #rs #Htapea cases (Hstar1 … Htapea)
 198   #Ha0 #Htapeb %
 199   [ #Hfalse @False_ind @(absurd ?? Ha0) //
 200   | *
 201     [ #ls2 whd in ⊢ (???%→?); #Hls #_ #_ normalize
 202       >Hls in Htapeb; normalize #Htapeb
 203       cases (IH … Htapeb)
 204       #Houtc #_ >Houtc //
 205     | #l0 #ls0 #ls2 #Hls #_ #Hls0
 206       cut (l0 ≠ sep ∧ memb … sep ls0 = false)
 207       [ %
 208          [ % #Hl0 >Hl0 in Hls0; >memb_hd #Hfalse destruct
 209          | whd in Hls0:(??%?); cases (sep==l0) in Hls0; normalize #Hfalse
 210            [ destruct
 211            | @Hfalse ]
 212          ]
 213       ] *
 214       #Hl0 -Hls0 #Hls0 >Hls in Htapeb;
 215       normalize in ⊢ (%→?); #Htapeb
 216       cases (IH … Htapeb) -IH #_ #IH
 217       >reverse_cons >associative_append @IH //
 218     ]
 219   ]
 220 qed.
 221
 222 lemma terminate_move_char_l :
 223   ∀alpha,sep.∀t,b,a,ls,rs. t = midtape alpha ls b (a::rs) →
 224   (b = sep ∨ memb ? sep ls = true) → Terminate alpha (move_char_l alpha sep) t.
 225 #alpha #sep #t #b #a #ls #rs #Ht #Hsep
 226 @(terminate_while … (sem_mcl_step alpha sep))
 227   [%
 228   |generalize in match Hsep; -Hsep
 229    generalize in match Ht; -Ht
 230    generalize in match rs; -rs
 231    generalize in match a; -a
 232    generalize in match b; -b
 233    generalize in match t; -t
 234    elim ls
 235     [#t #b #a #rs #Ht #Hsep % #tinit
 236      whd in ⊢ (%→?); #H @False_ind
 237      cases (H … Ht) #Hb #_ cases Hb #eqb @eqb
 238      cases Hsep // whd in ⊢ ((??%?)→?); #abs destruct
 239     |#l0 #ls0 #Hind #t #b #a #rs #Ht #Hsep % #tinit
 240      whd in ⊢ (%→?); #H
 241      cases (H … Ht) #Hbsep #Htinit
 242      @(Hind … Htinit) cases Hsep
 243       [#Hb @False_ind /2/ | #Hmemb cases (orb_true_l … Hmemb)
 244         [#eqsep %1 >(\P eqsep) // | #H %2 //]
 245   ]
 246 qed.