matita/matita/lib/tutorial/chapter6.ma

   1 (*
   2 Formal Languages
   3
   4 In this chapter we shall apply our notion of DeqSet, and the list operations
   5 defined in Chapter 4 to formal languages. A formal language is an arbitrary set
   6 of words over a given alphabet, that we shall represent as a predicate over words.
   7 *)
   8 include "tutorial/chapter5.ma".
   9
  10 (* A word (or string) over an alphabet S is just a list of elements of S.*)
  11 definition word ≝ λS:DeqSet.list S.
  12
  13 (* For any alphabet there is only one word of length 0, the empty word, which is
  14 denoted by ϵ .*)
  15
  16 notation "ϵ" non associative with precedence 90 for @{ 'epsilon }.
  17 interpretation "epsilon" 'epsilon = (nil ?).
  18
  19 (* The operation that consists in appending two words to form a new word, whose
  20 length is the sum of the lengths of the original words is called concatenation.
  21 String concatenation is just the append operation over lists, hence there is no
  22 point to define it. Similarly, many of its properties, such as the fact that
  23 concatenating a word with the empty word gives the original word, follow by
  24 general results over lists.
  25 *)
  26
  27 (*
  28 Operations over languages
  29
  30 Languages inherit all the basic operations for sets, namely union, intersection,
  31 complementation, substraction, and so on. In addition, we may define some new
  32 operations induced by string concatenation, and in particular the concatenation
  33 A · B of two languages A and B, the so called Kleene's star A* of A and the
  34 derivative of a language A w.r.t. a given character a. *)
  35
  36 definition cat : ∀S,l1,l2,w.Prop ≝
  37   λS.λl1,l2.λw:word S.∃w1,w2.w1 @ w2 = w ∧ l1 w1 ∧ l2 w2.
  38 (*
  39 notation "a · b" non associative with precedence 60 for @{ 'middot $a $b}.
  40 *)
  41 interpretation "cat lang" 'middot a b = (cat ? a b).
  42
  43
  44 (* Given a language l, the Kleene's star of l, denoted by l*, is the set of
  45 finite-length strings that can be generated by concatenating arbitrary strings of
  46 l. In other words, w belongs to l* is and only if there exists a list of strings
  47 w1,w2,...wk all belonging to l, such that l = w1w2...wk.
  48 We need to define the latter operations. The following flatten function takes in
  49 input a list of words and concatenates them together. *)
  50
  51 (* Already in the library
  52 let rec flatten (S : DeqSet) (l : list (word S)) on l : word S ≝
  53 match l with [ nil ⇒ [ ] | cons w tl ⇒ w @ flatten ? tl ].
  54 *)
  55
  56 (* Given a list of words l and a language r, (conjunct l r) is true if and only if
  57 all words in l are in r, that is for every w in l, r w holds. *)
  58
  59 let rec conjunct (S : DeqSet) (l : list (word S)) (r : word S → Prop) on l: Prop ≝
  60 match l with [ nil ⇒ True | cons w tl ⇒ r w ∧ conjunct ? tl r ].
  61
  62 (* We are ready to give the formal definition of the Kleene's star of l:
  63 a word w belongs to l* is and only if there exists a list of strings
  64 lw such that (conjunct lw l) and  l = flatten lw. *)
  65
  66
  67 definition star ≝ λS.λl.λw:word S.∃lw.flatten ? lw = w ∧ conjunct ? lw l.
  68 notation "a ^ *" non associative with precedence 90 for @{ 'star $a}.
  69 interpretation "star lang" 'star l = (star ? l).
  70
  71 (* The derivative of a language A with respect to a character a is the set of
  72 all strings w such that aw is in A. *)
  73
  74 definition deriv ≝ λS.λA:word S → Prop.λa,w. A (a::w).
  75
  76 (*
  77 Language equalities
  78
  79 Equality between languages is just the usual extensional equality between
  80 sets. The operation of concatenation behaves well with respect to this equality. *)
  81
  82 lemma cat_ext_l: ∀S.∀A,B,C:word S →Prop.
  83   A =1 C  → A · B =1 C · B.
  84 #S #A #B #C #H #w % * #w1 * #w2 * * #eqw #inw1 #inw2
  85 cases (H w1) /6/
  86 qed.
  87
  88 lemma cat_ext_r: ∀S.∀A,B,C:word S →Prop.
  89   B =1 C → A · B =1 A · C.
  90 #S #A #B #C #H #w % * #w1 * #w2 * * #eqw #inw1 #inw2
  91 cases (H w2) /6/
  92 qed.
  93
  94 (* Concatenating a language with the empty language results in the
  95 empty language. *)
  96 lemma cat_empty_l: ∀S.∀A:word S→Prop. ∅ · A =1 ∅.
  97 #S #A #w % [|*] * #w1 * #w2 * * #_ *
  98 qed.
  99
 100 (* Concatenating a language l with the singleton language containing the
 101 empty string, results in the language l; that is {ϵ} is a left and right
 102 unit with respect to concatenation. *)
 103
 104 lemma epsilon_cat_r: ∀S.∀A:word S →Prop.
 105   A · {ϵ} =1  A.
 106 #S #A #w %
 107   [* #w1 * #w2 * * #eqw #inw1 normalize #eqw2 <eqw //
 108   |#inA @(ex_intro … w) @(ex_intro … [ ]) /3/
 109   ]
 110 qed.
 111
 112 lemma epsilon_cat_l: ∀S.∀A:word S →Prop.
 113   {ϵ} · A =1  A.
 114 #S #A #w %
 115   [* #w1 * #w2 * * #eqw normalize #eqw2 <eqw <eqw2 //
 116   |#inA @(ex_intro … ϵ) @(ex_intro … w) /3/
 117   ]
 118   qed.
 119
 120 (* Concatenation is distributive w.r.t. union. *)
 121
 122 lemma distr_cat_r: ∀S.∀A,B,C:word S →Prop.
 123   (A ∪ B) · C =1  A · C ∪ B · C.
 124 #S #A #B #C #w %
 125   [* #w1 * #w2 * * #eqw * /6/ |* * #w1 * #w2 * * /6/]
 126 qed.
 127
 128 lemma distr_cat_r_eps: ∀S.∀A,C:word S →Prop.
 129   (A ∪ {ϵ}) · C =1  A · C ∪ C.
 130   #S #A #C @eqP_trans [|@distr_cat_r |@eqP_union_l @epsilon_cat_l]
 131 qed.
 132
 133 (* The following is a major property of derivatives *)
 134
 135 lemma deriv_middot: ∀S,A,B,a. ¬ A ϵ → deriv S (A·B) a =1 (deriv S A a) · B.
 136 #S #A #B #a #noteps #w normalize %
 137   [* #w1 cases w1
 138     [* #w2 * * #_ #Aeps @False_ind /2/
 139     |#b #w2 * #w3 * * whd in ⊢ ((??%?)→?); #H destruct
 140      #H #H1 @(ex_intro … w2) @(ex_intro … w3) % // % //
 141     ]
 142   |* #w1 * #w2 * * #H #H1 #H2 @(ex_intro … (a::w1))
 143    @(ex_intro … w2) % // % normalize //
 144   ]
 145 qed.
 146
 147 (*
 148 Main Properties of Kleene's star
 149
 150 We conclude this section with some important properties of Kleene's
 151 star that will be used in the following chapters. *)
 152
 153 lemma espilon_in_star: ∀S.∀A:word S → Prop.
 154   A^* ϵ.
 155 #S #A @(ex_intro … [ ]) normalize /2/
 156 qed.
 157
 158 lemma cat_to_star:∀S.∀A:word S → Prop.
 159   ∀w1,w2. A w1 → A^* w2 → A^* (w1@w2).
 160 #S #A #w1 #w2 #Aw * #l * #H #H1 @(ex_intro … (w1::l))
 161 % normalize destruct /2/ (* destruct added *)
 162 qed.
 163
 164 lemma fix_star: ∀S.∀A:word S → Prop.
 165   A^* =1 A · A^* ∪ {ϵ}.
 166 #S #A #w %
 167   [* #l generalize in match w; -w cases l [normalize #w * /2/]
 168    #w1 #tl #w * whd in ⊢ ((??%?)→?); #eqw whd in ⊢ (%→?); *
 169    #w1A #cw1 %1 @(ex_intro … w1) @(ex_intro … (flatten S tl))
 170    % destruct /2/ whd @(ex_intro … tl) /2/ (* destruct added *)
 171   |* [2: whd in ⊢ (%→?); #eqw <eqw //]
 172    * #w1 * #w2 * * #eqw <eqw @cat_to_star
 173   ]
 174 qed.
 175
 176 lemma star_fix_eps : ∀S.∀A:word S → Prop.
 177   A^* =1 (A - {ϵ}) · A^* ∪ {ϵ}.
 178 #S #A #w %
 179   [* #l elim l
 180     [* whd in ⊢ ((??%?)→?); #eqw #_ %2 <eqw //
 181     |* [#tl #Hind * #H * #_ #H2 @Hind % [@H | //]
 182        |#a #w1 #tl #Hind * whd in ⊢ ((??%?)→?); #H1 * #H2 #H3 %1
 183         @(ex_intro … (a::w1)) @(ex_intro … (flatten S tl)) %
 184          [% [@H1 | normalize % /2/] |whd @(ex_intro … tl) /2/]
 185        ]
 186     ]
 187   |* [* #w1 * #w2 * * #eqw * #H1 #_ <eqw @cat_to_star //
 188      | whd in ⊢ (%→?); #H <H //
 189      ]
 190   ]
 191 qed.
 192
 193 lemma star_epsilon: ∀S:DeqSet.∀A:word S → Prop.
 194   A^* ∪ {ϵ} =1 A^*.
 195 #S #A #w % /2/ * //
 196 qed.
 197