matita/matita/lib/tutorial/chapter6.ma

   1 (*
   2 Formal Languages
   3
   4 In this chapter we shall apply our notion of DeqSet, and the list operations
   5 defined in Chapter 4 to formal languages. A formal language is an arbitrary set
   6 of words over a given alphabet, that we shall represent as a predicate over words.
   7 *)
   8 include "tutorial/chapter5.ma".
   9
  10 (* A word (or string) over an alphabet S is just a list of elements of S.*)
  11 definition word ≝ λS:DeqSet.list S.
  12
  13 (* For any alphabet there is only one word of length 0, the empty word, which is
  14 denoted by ϵ .*)
  15
  16 notation "ϵ" non associative with precedence 90 for @{ 'epsilon }.
  17 interpretation "epsilon" 'epsilon = (nil ?).
  18
  19 (* The operation that consists in appending two words to form a new word, whose
  20 length is the sum of the lengths of the original words is called concatenation.
  21 String concatenation is just the append operation over lists, hence there is no
  22 point to define it. Similarly, many of its properties, such as the fact that
  23 concatenating a word with the empty word gives the original word, follow by
  24 general results over lists.
  25 *)
  26
  27 (*
  28 Operations over languages
  29
  30 Languages inherit all the basic operations for sets, namely union, intersection,
  31 complementation, substraction, and so on. In addition, we may define some new
  32 operations induced by string concatenation, and in particular the concatenation
  33 A · B of two languages A and B, the so called Kleene's star A* of A and the
  34 derivative of a language A w.r.t. a given character a. *)
  35
  36 definition cat : ∀S,l1,l2,w.Prop ≝
  37   λS.λl1,l2.λw:word S.∃w1,w2.w1 @ w2 = w ∧ l1 w1 ∧ l2 w2.
  38
  39 notation "a · b" non associative with precedence 60 for @{ 'middot $a $b}.
  40 interpretation "cat lang" 'middot a b = (cat ? a b).
  41
  42
  43 (* Given a language l, the Kleene's star of l, denoted by l*, is the set of
  44 finite-length strings that can be generated by concatenating arbitrary strings of
  45 l. In other words, w belongs to l* is and only if there exists a list of strings
  46 w1,w2,...wk all belonging to l, such that l = w1w2...wk.
  47 We need to define the latter operations. The following flatten function takes in
  48 input a list of words and concatenates them together. *)
  49
  50 let rec flatten (S : DeqSet) (l : list (word S)) on l : word S ≝
  51 match l with [ nil ⇒ [ ] | cons w tl ⇒ w @ flatten ? tl ].
  52
  53 (* Given a list of words l and a language r, (conjunct l r) is true if and only if
  54 all words in l are in r, that is for every w in l, r w holds. *)
  55
  56 let rec conjunct (S : DeqSet) (l : list (word S)) (r : word S → Prop) on l: Prop ≝
  57 match l with [ nil ⇒ True | cons w tl ⇒ r w ∧ conjunct ? tl r ].
  58
  59 (* We are ready to give the formal definition of the Kleene's star of l:
  60 a word w belongs to l* is and only if there exists a list of strings
  61 lw such that (conjunct lw l) and  l = flatten lw. *)
  62
  63 definition star ≝ λS.λl.λw:word S.∃lw.flatten ? lw = w ∧ conjunct ? lw l.
  64 notation "a ^ *" non associative with precedence 90 for @{ 'star $a}.
  65 interpretation "star lang" 'star l = (star ? l).
  66
  67 (* The derivative of a language A with respect to a character a is the set of
  68 all strings w such that aw is in A. *)
  69
  70 definition deriv ≝ λS.λA:word S → Prop.λa,w. A (a::w).
  71
  72 (*
  73 Language equalities
  74
  75 Equality between languages is just the usual extensional equality between
  76 sets. The operation of concatenation behaves well with respect to this equality. *)
  77
  78 lemma cat_ext_l: ∀S.∀A,B,C:word S →Prop.
  79   A =1 C  → A · B =1 C · B.
  80 #S #A #B #C #H #w % * #w1 * #w2 * * #eqw #inw1 #inw2
  81 cases (H w1) /6/
  82 qed.
  83
  84 lemma cat_ext_r: ∀S.∀A,B,C:word S →Prop.
  85   B =1 C → A · B =1 A · C.
  86 #S #A #B #C #H #w % * #w1 * #w2 * * #eqw #inw1 #inw2
  87 cases (H w2) /6/
  88 qed.
  89
  90 (* Concatenating a language with the empty language results in the
  91 empty language. *)
  92 lemma cat_empty_l: ∀S.∀A:word S→Prop. ∅ · A =1 ∅.
  93 #S #A #w % [|*] * #w1 * #w2 * * #_ *
  94 qed.
  95
  96 (* Concatenating a language l with the singleton language containing the
  97 empty string, results in the language l; that is {ϵ} is a left and right
  98 unit with respect to concatenation. *)
  99
 100 lemma epsilon_cat_r: ∀S.∀A:word S →Prop.
 101   A · {ϵ} =1  A.
 102 #S #A #w %
 103   [* #w1 * #w2 * * #eqw #inw1 normalize #eqw2 <eqw //
 104   |#inA @(ex_intro … w) @(ex_intro … [ ]) /3/
 105   ]
 106 qed.
 107
 108 lemma epsilon_cat_l: ∀S.∀A:word S →Prop.
 109   {ϵ} · A =1  A.
 110 #S #A #w %
 111   [* #w1 * #w2 * * #eqw normalize #eqw2 <eqw <eqw2 //
 112   |#inA @(ex_intro … ϵ) @(ex_intro … w) /3/
 113   ]
 114   qed.
 115
 116 (* Concatenation is distributive w.r.t. union. *)
 117
 118 lemma distr_cat_r: ∀S.∀A,B,C:word S →Prop.
 119   (A ∪ B) · C =1  A · C ∪ B · C.
 120 #S #A #B #C #w %
 121   [* #w1 * #w2 * * #eqw * /6/ |* * #w1 * #w2 * * /6/]
 122 qed.
 123
 124 lemma distr_cat_r_eps: ∀S.∀A,C:word S →Prop.
 125   (A ∪ {ϵ}) · C =1  A · C ∪ C.
 126   #S #A #C @eqP_trans [|@distr_cat_r |@eqP_union_l @epsilon_cat_l]
 127 qed.
 128
 129 (* The following is a major property of derivatives *)
 130
 131 lemma deriv_middot: ∀S,A,B,a. ¬ A ϵ → deriv S (A·B) a =1 (deriv S A a) · B.
 132 #S #A #B #a #noteps #w normalize %
 133   [* #w1 cases w1
 134     [* #w2 * * #_ #Aeps @False_ind /2/
 135     |#b #w2 * #w3 * * whd in ⊢ ((??%?)→?); #H destruct
 136      #H #H1 @(ex_intro … w2) @(ex_intro … w3) % // % //
 137     ]
 138   |* #w1 * #w2 * * #H #H1 #H2 @(ex_intro … (a::w1))
 139    @(ex_intro … w2) % // % normalize //
 140   ]
 141 qed.
 142
 143 (*
 144 Main Properties of Kleene's star
 145
 146 We conclude this section with some important properties of Kleene's
 147 star that will be used in the following chapters. *)
 148
 149 lemma espilon_in_star: ∀S.∀A:word S → Prop.
 150   A^* ϵ.
 151 #S #A @(ex_intro … [ ]) normalize /2/
 152 qed.
 153
 154 lemma cat_to_star:∀S.∀A:word S → Prop.
 155   ∀w1,w2. A w1 → A^* w2 → A^* (w1@w2).
 156 #S #A #w1 #w2 #Aw * #l * #H #H1 @(ex_intro … (w1::l))
 157 % normalize /2/
 158 qed.
 159
 160 lemma fix_star: ∀S.∀A:word S → Prop.
 161   A^* =1 A · A^* ∪ {ϵ}.
 162 #S #A #w %
 163   [* #l generalize in match w; -w cases l [normalize #w * /2/]
 164    #w1 #tl #w * whd in ⊢ ((??%?)→?); #eqw whd in ⊢ (%→?); *
 165    #w1A #cw1 %1 @(ex_intro … w1) @(ex_intro … (flatten S tl))
 166    % /2/ whd @(ex_intro … tl) /2/
 167   |* [2: whd in ⊢ (%→?); #eqw <eqw //]
 168    * #w1 * #w2 * * #eqw <eqw @cat_to_star
 169   ]
 170 qed.
 171
 172 lemma star_fix_eps : ∀S.∀A:word S → Prop.
 173   A^* =1 (A - {ϵ}) · A^* ∪ {ϵ}.
 174 #S #A #w %
 175   [* #l elim l
 176     [* whd in ⊢ ((??%?)→?); #eqw #_ %2 <eqw //
 177     |* [#tl #Hind * #H * #_ #H2 @Hind % [@H | //]
 178        |#a #w1 #tl #Hind * whd in ⊢ ((??%?)→?); #H1 * #H2 #H3 %1
 179         @(ex_intro … (a::w1)) @(ex_intro … (flatten S tl)) %
 180          [% [@H1 | normalize % /2/] |whd @(ex_intro … tl) /2/]
 181        ]
 182     ]
 183   |* [* #w1 * #w2 * * #eqw * #H1 #_ <eqw @cat_to_star //
 184      | whd in ⊢ (%→?); #H <H //
 185      ]
 186   ]
 187 qed.
 188
 189 lemma star_epsilon: ∀S:DeqSet.∀A:word S → Prop.
 190   A^* ∪ {ϵ} =1 A^*.
 191 #S #A #w % /2/ * //
 192 qed.
 193