matita/matita/lib/tutorial/chapter7.ma

   1 (*
   2 Formal Languages
   3
   4 In this chapter we shall apply our notion of DeqSet, and the list operations
   5 defined in Chapter 4 to formal languages. A formal language is an arbitrary set
   6 of words over a given alphabet, that we shall represent as a predicate over words.
   7 *)
   8 include "tutorial/chapter6.ma".
   9
  10 (* A word (or string) over an alphabet S is just a list of elements of S.*)
  11 definition word ≝ λS:DeqSet.list S.
  12
  13 (* For any alphabet there is only one word of length 0, the empty word, which is
  14 denoted by ϵ .*)
  15
  16 notation "ϵ" non associative with precedence 90 for @{ 'epsilon }.
  17 interpretation "epsilon" 'epsilon = (nil ?).
  18
  19 (* The operation that consists in appending two words to form a new word, whose
  20 length is the sum of the lengths of the original words is called concatenation.
  21 String concatenation is just the append operation over lists, hence there is no
  22 point to define it. Similarly, many of its properties, such as the fact that
  23 concatenating a word with the empty word gives the original word, follow by
  24 general results over lists.
  25 *)
  26
  27 (*
  28 Operations over languages
  29
  30 Languages inherit all the basic operations for sets, namely union, intersection,
  31 complementation, substraction, and so on. In addition, we may define some new
  32 operations induced by string concatenation, and in particular the concatenation
  33 A · B of two languages A and B, the so called Kleene's star A* of A and the
  34 derivative of a language A w.r.t. a given character a. *)
  35
  36 definition cat : ∀S,l1,l2,w.Prop ≝
  37   λS.λl1,l2.λw:word S.∃w1,w2.w1 @ w2 = w ∧ l1 w1 ∧ l2 w2.
  38 (*
  39 notation "a · b" non associative with precedence 60 for @{ 'middot $a $b}.
  40 *)
  41 interpretation "cat lang" 'middot a b = (cat ? a b).
  42
  43 (* Given a language l, the Kleene's star of l, denoted by l*, is the set of
  44 finite-length strings that can be generated by concatenating arbitrary strings of
  45 l. In other words, w belongs to l* is and only if there exists a list of strings
  46 w1,w2,...wk all belonging to l, such that l = w1w2...wk.
  47 We need to define the latter operations. The following flatten function takes in
  48 input a list of words and concatenates them together. *)
  49
  50 (* Already in the library
  51 let rec flatten (S : DeqSet) (l : list (word S)) on l : word S ≝
  52 match l with [ nil ⇒ [ ] | cons w tl ⇒ w @ flatten ? tl ].
  53 *)
  54
  55 (* Given a list of words l and a language r, (conjunct l r) is true if and only
  56 if all words in l are in r, that is for every w in l, r w holds. *)
  57
  58 let rec conjunct (S : DeqSet) (l : list (word S)) (r : word S → Prop) on l: Prop ≝
  59 match l with [ nil ⇒ True | cons w tl ⇒ r w ∧ conjunct ? tl r ].
  60
  61 (* We are ready to give the formal definition of the Kleene's star of l:
  62 a word w belongs to l* is and only if there exists a list of strings
  63 lw such that (conjunct lw l) and  l = flatten lw. *)
  64
  65 definition flatten ≝ λA.foldr (list A) (list A) (append A) [].
  66
  67 definition star ≝ λS.λl.λw:word S.∃lw.flatten ? lw = w ∧ conjunct ? lw l.
  68
  69 notation "a ^ *" non associative with precedence 90 for @{ 'star $a}.
  70 interpretation "star lang" 'star l = (star ? l).
  71
  72 (* The derivative of a language A with respect to a character a is the set of
  73 all strings w such that aw is in A. *)
  74
  75 definition deriv ≝ λS.λA:word S → Prop.λa,w. A (a::w).
  76
  77 (*
  78 Language equalities
  79
  80 Equality between languages is just the usual extensional equality between
  81 sets. The operation of concatenation behaves well with respect to this equality. *)
  82
  83 lemma cat_ext_l: ∀S.∀A,B,C:word S →Prop.
  84   A ≐ C  → A · B ≐ C · B.
  85 #S #A #B #C #H #w % * #w1 * #w2 * * #eqw #inw1 #inw2
  86 cases (H w1) /6/
  87 qed.
  88
  89 lemma cat_ext_r: ∀S.∀A,B,C:word S →Prop.
  90   B ≐ C → A · B ≐ A · C.
  91 #S #A #B #C #H #w % * #w1 * #w2 * * #eqw #inw1 #inw2
  92 cases (H w2) /6/
  93 qed.
  94
  95 (* Concatenating a language with the empty language results in the
  96 empty language. *)
  97 lemma cat_empty_l: ∀S.∀A:word S→Prop. ∅ · A ≐ ∅.
  98 #S #A #w % [|*] * #w1 * #w2 * * #_ *
  99 qed.
 100
 101 (* Concatenating a language l with the singleton language containing the
 102 empty string, results in the language l; that is {ϵ} is a left and right
 103 unit with respect to concatenation. *)
 104
 105 lemma epsilon_cat_r: ∀S.∀A:word S →Prop.
 106   A · {ϵ} ≐ A.
 107 #S #A #w %
 108   [* #w1 * #w2 * * #eqw #inw1 normalize #eqw2 <eqw //
 109   |#inA @(ex_intro … w) @(ex_intro … [ ]) /3/
 110   ]
 111 qed.
 112
 113 lemma epsilon_cat_l: ∀S.∀A:word S →Prop.
 114   {ϵ} · A ≐  A.
 115 #S #A #w %
 116   [* #w1 * #w2 * * #eqw normalize #eqw2 <eqw <eqw2 //
 117   |#inA @(ex_intro … ϵ) @(ex_intro … w) /3/
 118   ]
 119 qed.
 120
 121 (* Concatenation is distributive w.r.t. union. *)
 122
 123 lemma distr_cat_r: ∀S.∀A,B,C:word S →Prop.
 124   (A ∪ B) · C ≐  A · C ∪ B · C.
 125 #S #A #B #C #w %
 126   [* #w1 * #w2 * * #eqw * /6/ |* * #w1 * #w2 * * /6/]
 127 qed.
 128
 129 lemma distr_cat_r_eps: ∀S.∀A,C:word S →Prop.
 130   (A ∪ {ϵ}) · C ≐  A · C ∪ C.
 131   #S #A #C @eqP_trans [|@distr_cat_r |@eqP_union_l @epsilon_cat_l]
 132 qed.
 133
 134 (* The following is a major property of derivatives *)
 135
 136 lemma deriv_middot: ∀S,A,B,a. ¬ A ϵ → deriv S (A·B) a ≐ (deriv S A a) · B.
 137 #S #A #B #a #noteps #w normalize %
 138   [* #w1 cases w1
 139     [* #w2 * * #_ #Aeps @False_ind /2/
 140     |#b #w2 * #w3 * * whd in ⊢ ((??%?)→?); #H destruct
 141      #H #H1 @(ex_intro … w2) @(ex_intro … w3) % // % //
 142     ]
 143   |* #w1 * #w2 * * #H #H1 #H2 @(ex_intro … (a::w1))
 144    @(ex_intro … w2) % // % normalize //
 145   ]
 146 qed.
 147
 148 (*
 149 Main Properties of Kleene's star
 150
 151 We conclude this section with some important properties of Kleene's
 152 star that will be used in the following chapters. *)
 153
 154 lemma espilon_in_star: ∀S.∀A:word S → Prop.
 155   A^* ϵ.
 156 #S #A @(ex_intro … [ ]) normalize /2/
 157 qed.
 158
 159 lemma cat_to_star:∀S.∀A:word S → Prop.
 160   ∀w1,w2. A w1 → A^* w2 → A^* (w1@w2).
 161 #S #A #w1 #w2 #Aw * #l * #H #H1 @(ex_intro … (w1::l))
 162 % normalize destruct /2/
 163 qed.
 164
 165 lemma fix_star: ∀S.∀A:word S → Prop.
 166   A^* ≐ A · A^* ∪ {ϵ}.
 167 #S #A #w %
 168   [* #l generalize in match w; -w cases l [normalize #w * /2/]
 169    #w1 #tl #w * whd in ⊢ ((??%?)→?); #eqw whd in ⊢ (%→?); *
 170    #w1A #cw1 %1 @(ex_intro … w1) @(ex_intro … (flatten S tl))
 171    % destruct /2/ whd @(ex_intro … tl) /2/
 172   |* [2: whd in ⊢ (%→?); #eqw <eqw //]
 173    * #w1 * #w2 * * #eqw <eqw @cat_to_star
 174   ]
 175 qed.
 176
 177 lemma star_fix_eps : ∀S.∀A:word S → Prop.
 178   A^* ≐ (A - {ϵ}) · A^* ∪ {ϵ}.
 179 #S #A #w %
 180   [* #l elim l
 181     [* whd in ⊢ ((??%?)→?); #eqw #_ %2 <eqw //
 182     |* [#tl #Hind * #H * #_ #H2 @Hind % [@H | //]
 183        |#a #w1 #tl #Hind * whd in ⊢ ((??%?)→?); #H1 * #H2 #H3 %1
 184         @(ex_intro … (a::w1)) @(ex_intro … (flatten S tl)) %
 185          [% [@H1 | normalize % [@H2 | % #H4 destruct (H4)] ]
 186          |whd @(ex_intro … tl) /2/]
 187        ]
 188     ]
 189   |* [* #w1 * #w2 * * #eqw * #H1 #_ <eqw @cat_to_star //
 190      | whd in ⊢ (%→?); #H <H //
 191      ]
 192   ]
 193 qed.
 194
 195 lemma star_epsilon: ∀S:DeqSet.∀A:word S → Prop.
 196   A^* ∪ {ϵ} ≐ A^*.
 197 #S #A #w % /2/ * //
 198 qed.
 199