matita/matita/matitaScript.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29 open GrafiteTypes
  30
  31 module TA = GrafiteAst
  32
  33 let debug = false
  34 let debug_print = if debug then prerr_endline else ignore
  35
  36   (** raised when one of the script margins (top or bottom) is reached *)
  37 exception Margin
  38 exception NoUnfinishedProof
  39 exception ActionCancelled of string
  40
  41 let safe_substring s i j =
  42   try String.sub s i j with Invalid_argument _ -> assert false
  43
  44 let heading_nl_RE = Pcre.regexp "^\\s*\n\\s*"
  45 let heading_nl_RE' = Pcre.regexp "^(\\s*\n\\s*)"
  46 let only_dust_RE = Pcre.regexp "^(\\s|\n|%%[^\n]*\n)*$"
  47 let multiline_RE = Pcre.regexp "^\n[^\n]+$"
  48 let newline_RE = Pcre.regexp "\n"
  49 let comment_RE = Pcre.regexp "\\(\\*(.|\n)*\\*\\)\n?" ~flags:[`UNGREEDY]
  50
  51 let comment str =
  52   if Pcre.pmatch ~rex:multiline_RE str then
  53     "\n(** " ^ (Pcre.replace ~rex:newline_RE str) ^ " *)"
  54   else
  55     "\n(**\n" ^ str ^ "\n*)"
  56
  57 let strip_comments str =
  58   Pcre.qreplace ~templ:"\n" ~pat:"\n\n" (Pcre.qreplace ~rex:comment_RE str)
  59 ;;
  60
  61 let first_line s =
  62   let s = Pcre.replace ~rex:heading_nl_RE s in
  63   try
  64     let nl_pos = String.index s '\n' in
  65     String.sub s 0 nl_pos
  66   with Not_found -> s
  67
  68 type guistuff = {
  69   mathviewer:MatitaTypes.mathViewer;
  70   urichooser: NReference.reference list -> NReference.reference list;
  71   ask_confirmation: title:string -> message:string -> [`YES | `NO | `CANCEL];
  72 }
  73
  74 let eval_with_engine include_paths guistuff grafite_status user_goal
  75  skipped_txt nonskipped_txt st
  76 =
  77   let parsed_text_length =
  78     String.length skipped_txt + String.length nonskipped_txt
  79   in
  80   let text = skipped_txt ^ nonskipped_txt in
  81   let prefix_len = MatitaGtkMisc.utf8_string_length skipped_txt in
  82   let enriched_history_fragment =
  83    MatitaEngine.eval_ast ~do_heavy_checks:(Helm_registry.get_bool
  84      "matita.do_heavy_checks")
  85     grafite_status (text,prefix_len,st)
  86   in
  87   let enriched_history_fragment = List.rev enriched_history_fragment in
  88   (* really fragile *)
  89   let res,_ =
  90     List.fold_left
  91       (fun (acc, to_prepend) (status,alias) ->
  92        match alias with
  93        | None -> (status,to_prepend ^ nonskipped_txt)::acc,""
  94        | Some (k,value) ->
  95             let newtxt = LexiconAstPp.pp_alias value in
  96             (status,to_prepend ^ newtxt ^ "\n")::acc, "")
  97       ([],skipped_txt) enriched_history_fragment
  98   in
  99   res,"",parsed_text_length
 100 ;;
 101
 102 (* this function calls the parser in a way that it does not perform inclusions,
 103  * so that we can ensure the inclusion is performed after the included file
 104  * is compiled (if needed). matitac does not need that, since it compiles files
 105  * in the good order, here files may be compiled on demand. *)
 106 let wrap_with_make include_paths (f : #LexiconEngine.status GrafiteParser.statement) x =
 107   try
 108     f ~never_include:true ~include_paths x
 109   with
 110   | GrafiteParser.NoInclusionPerformed mafilename ->
 111       let root, buri, _, tgt =
 112         try Librarian.baseuri_of_script ~include_paths mafilename
 113         with Librarian.NoRootFor _ ->
 114           HLog.error ("The included file '"^mafilename^"' has no root file,");
 115           HLog.error "please create it.";
 116           raise (Failure ("No root file for "^mafilename))
 117       in
 118       let b = MatitacLib.Make.make root [tgt] in
 119       if b then
 120         try f ~include_paths x with LexiconEngine.IncludedFileNotCompiled _ ->
 121          raise
 122            (Failure ("Including: "^tgt^
 123              "\nNothing to do... did you run matitadep?"))
 124       else raise (Failure ("Compiling: " ^ tgt))
 125 ;;
 126
 127 let pp_eager_statement_ast = GrafiteAstPp.pp_statement
 128
 129 let eval_nmacro include_paths (buffer : GText.buffer) guistuff grafite_status user_goal unparsed_text parsed_text script mac =
 130   let parsed_text_length = String.length parsed_text in
 131   match mac with
 132   | TA.Screenshot (_,name) ->
 133        let status = script#grafite_status in
 134        let _,_,menv,subst,_ = status#obj in
 135        let name = Filename.dirname (script#filename) ^ "/" ^ name in
 136        let sequents =
 137          let selected = Continuationals.Stack.head_goals status#stack in
 138          List.filter (fun x,_ -> List.mem x selected) menv
 139        in
 140        guistuff.mathviewer#screenshot status sequents menv subst name;
 141        [status, parsed_text], "", parsed_text_length
 142   | TA.NCheck (_,t) ->
 143       let status = script#grafite_status in
 144       let _,_,menv,subst,_ = status#obj in
 145       let ctx =
 146         try let _,(_,ctx,_) = List.hd menv in ctx
 147         with Failure "hd" -> []
 148       in
 149       let m, s, status, t =
 150         GrafiteDisambiguate.disambiguate_nterm
 151           None status ctx menv subst (parsed_text,parsed_text_length,
 152             NotationPt.Cast (t,NotationPt.Implicit `JustOne))
 153           (* XXX use the metasenv, if possible *)
 154       in
 155       guistuff.mathviewer#show_entry (`NCic (t,ctx,m,s));
 156       [status, parsed_text], "", parsed_text_length
 157   | TA.NIntroGuess _loc ->
 158       let names_ref = ref [] in
 159       let s =
 160         NTactics.intros_tac ~names_ref [] script#grafite_status
 161       in
 162       let rex = Pcre.regexp ~flags:[`MULTILINE] "\\A([\\n\\t\\r ]*).*\\Z" in
 163       let nl = Pcre.replace ~rex ~templ:"$1" parsed_text in
 164       [s, nl ^ "#" ^ String.concat " " !names_ref ^ ";"], "", parsed_text_length
 165   | TA.NAutoInteractive (_loc, (None,a)) ->
 166       let trace_ref = ref [] in
 167       let s =
 168         NnAuto.auto_tac
 169           ~params:(None,a) ~trace_ref script#grafite_status
 170       in
 171       let depth =
 172         try List.assoc "depth" a
 173         with Not_found -> ""
 174       in
 175       let trace = "/"^(if int_of_string depth > 1 then depth else "")^"/ by " in
 176       let thms =
 177         match !trace_ref with
 178         | [] -> "{}"
 179         | thms ->
 180            String.concat ", "
 181              (HExtlib.filter_map (function
 182                | NotationPt.NRef r -> Some (NCicPp.r2s true r)
 183                | _ -> None)
 184              thms)
 185       in
 186       let rex = Pcre.regexp ~flags:[`MULTILINE] "\\A([\\n\\t\\r ]*).*\\Z" in
 187       let nl = Pcre.replace ~rex ~templ:"$1" parsed_text in
 188       [s, nl ^ trace ^ thms ^ ";"], "", parsed_text_length
 189   | TA.NAutoInteractive (_, (Some _,_)) -> assert false
 190
 191 let rec eval_executable include_paths (buffer : GText.buffer) guistuff
 192 grafite_status user_goal unparsed_text skipped_txt nonskipped_txt
 193 script ex loc
 194 =
 195   try
 196    ignore (buffer#move_mark (`NAME "beginning_of_statement")
 197     ~where:((buffer#get_iter_at_mark (`NAME "locked"))#forward_chars
 198        (Glib.Utf8.length skipped_txt))) ;
 199    eval_with_engine include_paths
 200     guistuff grafite_status user_goal skipped_txt nonskipped_txt
 201      (TA.Executable (loc, ex))
 202   with
 203      MatitaTypes.Cancel -> [], "", 0
 204    | GrafiteEngine.NMacro (_loc,macro) ->
 205        eval_nmacro include_paths buffer guistuff grafite_status
 206         user_goal unparsed_text (skipped_txt ^ nonskipped_txt) script macro
 207
 208
 209 and eval_statement include_paths (buffer : GText.buffer) guistuff
 210  grafite_status user_goal script statement
 211 =
 212   let (grafite_status,st), unparsed_text =
 213     match statement with
 214     | `Raw text ->
 215         if Pcre.pmatch ~rex:only_dust_RE text then raise Margin;
 216         let ast =
 217          wrap_with_make include_paths
 218           (GrafiteParser.parse_statement (Ulexing.from_utf8_string text))
 219             grafite_status
 220         in
 221           ast, text
 222     | `Ast (st, text) -> (grafite_status, st), text
 223   in
 224   let text_of_loc floc =
 225     let nonskipped_txt,_ = MatitaGtkMisc.utf8_parsed_text unparsed_text floc in
 226     let start, stop = HExtlib.loc_of_floc floc in
 227     let floc = HExtlib.floc_of_loc (0, start) in
 228     let skipped_txt,_ = MatitaGtkMisc.utf8_parsed_text unparsed_text floc in
 229     let floc = HExtlib.floc_of_loc (0, stop) in
 230     let txt,len = MatitaGtkMisc.utf8_parsed_text unparsed_text floc in
 231     txt,nonskipped_txt,skipped_txt,len
 232   in
 233   match st with
 234   | GrafiteParser.LNone loc ->
 235       let parsed_text, _, _, parsed_text_length = text_of_loc loc in
 236        [grafite_status,parsed_text],"",
 237         parsed_text_length
 238   | GrafiteParser.LSome (GrafiteAst.Executable (loc, ex)) ->
 239      let _, nonskipped, skipped, parsed_text_length = text_of_loc loc in
 240       eval_executable include_paths buffer guistuff
 241        grafite_status user_goal unparsed_text skipped nonskipped script ex loc
 242   | GrafiteParser.LSome (GrafiteAst.Comment (loc, GrafiteAst.Code (_, ex)))
 243     when Helm_registry.get_bool "matita.execcomments" ->
 244      let _, nonskipped, skipped, parsed_text_length = text_of_loc loc in
 245       eval_executable include_paths buffer guistuff
 246        grafite_status user_goal unparsed_text skipped nonskipped script ex loc
 247   | GrafiteParser.LSome (GrafiteAst.Comment (loc, _)) ->
 248       let parsed_text, _, _, parsed_text_length = text_of_loc loc in
 249       let remain_len = String.length unparsed_text - parsed_text_length in
 250       let s = String.sub unparsed_text parsed_text_length remain_len in
 251       let s,text,len =
 252        try
 253         eval_statement include_paths buffer guistuff
 254          grafite_status user_goal script (`Raw s)
 255        with
 256           HExtlib.Localized (floc, exn) ->
 257            HExtlib.raise_localized_exception
 258              ~offset:(MatitaGtkMisc.utf8_string_length parsed_text) floc exn
 259         | MultiPassDisambiguator.DisambiguationError (offset,errorll) ->
 260            raise
 261             (MultiPassDisambiguator.DisambiguationError
 262               (offset+parsed_text_length, errorll))
 263       in
 264       assert (text=""); (* no macros inside comments, please! *)
 265       (match s with
 266       | (statuses,text)::tl ->
 267          (statuses,parsed_text ^ text)::tl,"",parsed_text_length + len
 268       | [] -> [], "", 0)
 269
 270 let fresh_script_id =
 271   let i = ref 0 in
 272   fun () -> incr i; !i
 273
 274 class script  ~(source_view: GSourceView2.source_view)
 275               ~(mathviewer: MatitaTypes.mathViewer)
 276               ~set_star
 277               ~ask_confirmation
 278               ~urichooser
 279               () =
 280 let buffer = source_view#buffer in
 281 let source_buffer = source_view#source_buffer in
 282 let initial_statuses current baseuri =
 283  let empty_lstatus = new LexiconEngine.status in
 284  (match current with
 285      Some current ->
 286       LexiconSync.time_travel ~present:current ~past:empty_lstatus;
 287       NCicLibrary.time_travel
 288        ((new GrafiteTypes.status current#baseuri)#set_lstatus current#lstatus);
 289       (* CSC: there is a known bug in invalidation; temporary fix here *)
 290       NCicEnvironment.invalidate ()
 291    | None -> ());
 292  let lexicon_status =
 293    CicNotation2.load_notation ~include_paths:[] empty_lstatus
 294      BuildTimeConf.core_notation_script
 295  in
 296  let grafite_status = (new GrafiteTypes.status baseuri)#set_lstatus lexicon_status#lstatus in
 297   grafite_status
 298 in
 299 let read_include_paths file =
 300  try
 301    let root, _buri, _fname, _tgt =
 302      Librarian.baseuri_of_script ~include_paths:[] file
 303    in
 304    let rc =
 305     Str.split (Str.regexp " ")
 306      (List.assoc "include_paths" (Librarian.load_root_file (root^"/root")))
 307    in
 308    List.iter (HLog.debug) rc; rc
 309  with Librarian.NoRootFor _ | Not_found -> []
 310 in
 311 let default_buri = "cic:/matita/tests" in
 312 let default_fname = ".unnamed.ma" in
 313 object (self)
 314   val mutable include_paths_ = []
 315
 316   val scriptId = fresh_script_id ()
 317
 318   val guistuff = {
 319     mathviewer = mathviewer;
 320     urichooser = urichooser;
 321     ask_confirmation = ask_confirmation;
 322   }
 323
 324   val mutable filename_ = (None : string option)
 325
 326   method has_name = filename_ <> None
 327
 328   method include_paths =
 329     include_paths_ @
 330     Helm_registry.get_list Helm_registry.string "matita.includes"
 331
 332   method private curdir =
 333     try
 334      let root, _buri, _fname, _tgt =
 335        Librarian.baseuri_of_script ~include_paths:self#include_paths
 336        self#filename
 337      in
 338      root
 339     with Librarian.NoRootFor _ -> Sys.getcwd ()
 340
 341   method buri_of_current_file =
 342     match filename_ with
 343     | None -> default_buri
 344     | Some f ->
 345         try
 346           let _root, buri, _fname, _tgt =
 347             Librarian.baseuri_of_script ~include_paths:self#include_paths f
 348           in
 349           buri
 350         with Librarian.NoRootFor _ -> default_buri
 351
 352   method filename = match filename_ with None -> default_fname | Some f -> f
 353
 354   initializer
 355     ignore (GMain.Timeout.add ~ms:300000
 356        ~callback:(fun _ -> self#_saveToBackupFile ();true));
 357     ignore (buffer#connect#modified_changed
 358       (fun _ -> set_star buffer#modified))
 359
 360   val mutable statements = []    (** executed statements *)
 361
 362   val mutable history = [ initial_statuses None default_buri ]
 363     (** list of states before having executed statements. Head element of this
 364       * list is the current state, last element is the state at the beginning of
 365       * the script.
 366       * Invariant: this list length is 1 + length of statements *)
 367
 368   (** goal as seen by the user (i.e. metano corresponding to current tab) *)
 369   val mutable userGoal = (None : int option)
 370
 371   (** text mark and tag representing locked part of a script *)
 372   val locked_mark =
 373     buffer#create_mark ~name:"locked" ~left_gravity:true buffer#start_iter
 374   val beginning_of_statement_mark =
 375     buffer#create_mark ~name:"beginning_of_statement"
 376      ~left_gravity:true buffer#start_iter
 377   val locked_tag = buffer#create_tag [`BACKGROUND "lightblue"; `EDITABLE false]
 378   val error_tag = buffer#create_tag [`UNDERLINE `SINGLE; `FOREGROUND "red"]
 379
 380   method locked_mark = locked_mark
 381   method locked_tag = locked_tag
 382   method error_tag = error_tag
 383
 384     (* history can't be empty, the invariant above grant that it contains at
 385      * least the init grafite_status *)
 386   method grafite_status = match history with s::_ -> s | _ -> assert false
 387
 388   method private _advance ?statement () =
 389    let s = match statement with Some s -> s | None -> self#getFuture in
 390    if self#bos then LibraryClean.clean_baseuris [self#buri_of_current_file];
 391    HLog.debug ("evaluating: " ^ first_line s ^ " ...");
 392    let time1 = Unix.gettimeofday () in
 393    let entries, newtext, parsed_len =
 394     try
 395      eval_statement self#include_paths buffer guistuff
 396       self#grafite_status userGoal self (`Raw s)
 397     with End_of_file -> raise Margin
 398    in
 399    let time2 = Unix.gettimeofday () in
 400    HLog.debug ("... done in " ^ string_of_float (time2 -. time1) ^ "s");
 401    let new_statuses, new_statements =
 402      let statuses, texts = List.split entries in
 403      statuses, texts
 404    in
 405    history <- new_statuses @ history;
 406    statements <- new_statements @ statements;
 407    let start = buffer#get_iter_at_mark (`MARK locked_mark) in
 408    let new_text = String.concat "" (List.rev new_statements) in
 409    if statement <> None then
 410      buffer#insert ~iter:start new_text
 411    else begin
 412      let parsed_text = String.sub s 0 parsed_len in
 413      if new_text <> parsed_text then begin
 414        let stop = start#copy#forward_chars (Glib.Utf8.length parsed_text) in
 415        buffer#delete ~start ~stop;
 416        buffer#insert ~iter:start new_text;
 417      end;
 418    end;
 419    self#moveMark (Glib.Utf8.length new_text);
 420    buffer#insert ~iter:(buffer#get_iter_at_mark (`MARK locked_mark)) newtext;
 421    (* here we need to set the Goal in case we are going to cursor (or to
 422       bottom) and we will face a macro *)
 423     userGoal <- None
 424
 425   method private _retract offset grafite_status new_statements
 426    new_history
 427   =
 428    let cur_grafite_status =
 429     match history with s::_ -> s | [] -> assert false
 430    in
 431     LexiconSync.time_travel ~present:cur_grafite_status ~past:grafite_status;
 432     NCicLibrary.time_travel grafite_status;
 433     statements <- new_statements;
 434     history <- new_history;
 435     self#moveMark (- offset)
 436
 437   method advance ?statement () =
 438     try
 439       self#_advance ?statement ();
 440       self#notify
 441     with
 442     | Margin -> self#notify
 443     | Not_found -> assert false
 444     | Invalid_argument "Array.make" -> HLog.error "The script is too big!\n"
 445     | exc -> self#notify; raise exc
 446
 447   method retract () =
 448     try
 449       let cmp,new_statements,new_history,grafite_status =
 450        match statements,history with
 451           stat::statements, _::(status::_ as history) ->
 452            assert (Glib.Utf8.validate stat);
 453            Glib.Utf8.length stat, statements, history, status
 454        | [],[_] -> raise Margin
 455        | _,_ -> assert false
 456       in
 457        self#_retract cmp grafite_status new_statements
 458         new_history;
 459        self#notify
 460     with
 461     | Margin -> self#notify
 462     | Invalid_argument "Array.make" -> HLog.error "The script is too big!\n"
 463     | exc -> self#notify; raise exc
 464
 465   method private getFuture =
 466     let lock = buffer#get_iter_at_mark (`MARK locked_mark) in
 467     let text = buffer#get_text ~start:lock ~stop:buffer#end_iter () in
 468     text
 469
 470   method expandAllVirtuals =
 471     let lock = buffer#get_iter_at_mark (`MARK locked_mark) in
 472     let text = buffer#get_text ~start:lock ~stop:buffer#end_iter () in
 473     buffer#delete ~start:lock ~stop:buffer#end_iter;
 474     let text = Pcre.replace ~pat:":=" ~templ:"\\def" text in
 475     let text = Pcre.replace ~pat:"->" ~templ:"\\to" text in
 476     let text = Pcre.replace ~pat:"=>" ~templ:"\\Rightarrow" text in
 477     let text =
 478       Pcre.substitute_substrings
 479         ~subst:(fun str ->
 480            let pristine = Pcre.get_substring str 0 in
 481            let input =
 482              if pristine.[0] = ' ' then
 483                String.sub pristine 1 (String.length pristine -1)
 484              else pristine
 485            in
 486            let input =
 487              if input.[String.length input-1] = ' ' then
 488                String.sub input 0 (String.length input -1)
 489              else input
 490            in
 491            let before, after =
 492              if input = "\\forall" ||
 493                 input = "\\lambda" ||
 494                 input = "\\exists" then "","" else " ", " "
 495            in
 496            try
 497              before ^ Glib.Utf8.from_unichar
 498                (snd (Virtuals.symbol_of_virtual input)) ^ after
 499            with Virtuals.Not_a_virtual -> pristine)
 500         ~pat:" ?\\\\[a-zA-Z]+ ?" text
 501     in
 502     buffer#insert ~iter:lock text
 503
 504   (** @param rel_offset relative offset from current position of locked_mark *)
 505   method private moveMark rel_offset =
 506     let mark = `MARK locked_mark in
 507     let old_insert = buffer#get_iter_at_mark `INSERT in
 508     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 509     let current_mark_pos = buffer#get_iter_at_mark mark in
 510     let new_mark_pos =
 511       match rel_offset with
 512       | 0 -> current_mark_pos
 513       | n when n > 0 -> current_mark_pos#forward_chars n
 514       | n (* when n < 0 *) -> current_mark_pos#backward_chars (abs n)
 515     in
 516     buffer#move_mark mark ~where:new_mark_pos;
 517     buffer#apply_tag locked_tag ~start:buffer#start_iter ~stop:new_mark_pos;
 518     buffer#move_mark `INSERT old_insert;
 519     let mark_position = buffer#get_iter_at_mark mark in
 520     if source_view#move_mark_onscreen mark then
 521      begin
 522       buffer#move_mark mark mark_position;
 523       source_view#scroll_to_mark ~use_align:true ~xalign:1.0 ~yalign:0.1 mark;
 524      end;
 525     while Glib.Main.pending () do ignore(Glib.Main.iteration false); done
 526
 527   method clean_dirty_lock =
 528     let lock_mark_iter = buffer#get_iter_at_mark (`MARK locked_mark) in
 529     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 530     buffer#apply_tag locked_tag ~start:buffer#start_iter ~stop:lock_mark_iter
 531
 532   val mutable observers = []
 533
 534   method addObserver (o: GrafiteTypes.status -> unit) =
 535     observers <- o :: observers
 536
 537   method private notify =
 538     let grafite_status = self#grafite_status in
 539     List.iter (fun o -> o grafite_status) observers
 540
 541   method loadFromString s =
 542     buffer#set_text s;
 543     self#reset_buffer;
 544     buffer#set_modified true
 545
 546   method loadFromFile f =
 547     buffer#set_text (HExtlib.input_file f);
 548     self#reset_buffer;
 549     buffer#set_modified false
 550
 551   method assignFileName file =
 552     let file =
 553       match file with
 554       | Some f -> Some (Librarian.absolutize f)
 555       | None -> None
 556     in
 557     filename_ <- file;
 558     include_paths_ <-
 559       (match file with Some file -> read_include_paths file | None -> []);
 560     self#reset_buffer;
 561     Sys.chdir self#curdir;
 562     HLog.debug ("Moving to " ^ Sys.getcwd ())
 563
 564   method saveToFile () =
 565     if self#has_name then
 566       let oc = open_out self#filename in
 567       output_string oc (buffer#get_text ~start:buffer#start_iter
 568                         ~stop:buffer#end_iter ());
 569       close_out oc;
 570       set_star false;
 571       buffer#set_modified false
 572     else
 573       HLog.error "Can't save, no filename selected"
 574
 575   method private _saveToBackupFile () =
 576     if buffer#modified then
 577       begin
 578         let f = self#filename in
 579         let oc = open_out f in
 580         output_string oc (buffer#get_text ~start:buffer#start_iter
 581                             ~stop:buffer#end_iter ());
 582         close_out oc;
 583         HLog.debug ("backup " ^ f ^ " saved")
 584       end
 585
 586   method private reset_buffer =
 587     statements <- [];
 588     history <- [ initial_statuses (Some self#grafite_status) self#buri_of_current_file ];
 589     userGoal <- None;
 590     self#notify;
 591     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 592     buffer#move_mark (`MARK locked_mark) ~where:buffer#start_iter
 593
 594   method reset () =
 595     self#reset_buffer;
 596     source_buffer#begin_not_undoable_action ();
 597     buffer#delete ~start:buffer#start_iter ~stop:buffer#end_iter;
 598     source_buffer#end_not_undoable_action ();
 599     buffer#set_modified false;
 600
 601   method template () =
 602     let template = HExtlib.input_file BuildTimeConf.script_template in
 603     buffer#insert ~iter:(buffer#get_iter `START) template;
 604     buffer#set_modified false;
 605     set_star false
 606
 607   method goto (pos: [`Top | `Bottom | `Cursor]) () =
 608   try
 609     let old_locked_mark =
 610      `MARK
 611        (buffer#create_mark ~name:"old_locked_mark"
 612          ~left_gravity:true (buffer#get_iter_at_mark (`MARK locked_mark))) in
 613     let getpos _ = buffer#get_iter_at_mark (`MARK locked_mark) in
 614     let getoldpos _ = buffer#get_iter_at_mark old_locked_mark in
 615     let dispose_old_locked_mark () = buffer#delete_mark old_locked_mark in
 616     match pos with
 617     | `Top ->
 618         dispose_old_locked_mark ();
 619         self#reset_buffer;
 620         self#notify
 621     | `Bottom ->
 622         (try
 623           let rec dowhile () =
 624             self#_advance ();
 625             let newpos = getpos () in
 626             if (getoldpos ())#compare newpos < 0 then
 627               begin
 628                 buffer#move_mark old_locked_mark newpos;
 629                 dowhile ()
 630               end
 631           in
 632           dowhile ();
 633           dispose_old_locked_mark ();
 634           self#notify
 635         with
 636         | Margin -> dispose_old_locked_mark (); self#notify
 637         | exc -> dispose_old_locked_mark (); self#notify; raise exc)
 638     | `Cursor ->
 639         let locked_iter () = buffer#get_iter_at_mark (`NAME "locked") in
 640         let cursor_iter () = buffer#get_iter_at_mark `INSERT in
 641         let remember =
 642          `MARK
 643            (buffer#create_mark ~name:"initial_insert"
 644              ~left_gravity:true (cursor_iter ())) in
 645         let dispose_remember () = buffer#delete_mark remember in
 646         let remember_iter () =
 647          buffer#get_iter_at_mark (`NAME "initial_insert") in
 648         let cmp () = (locked_iter ())#offset - (remember_iter ())#offset in
 649         let icmp = cmp () in
 650         let forward_until_cursor () = (* go forward until locked > cursor *)
 651           let rec aux () =
 652             self#_advance ();
 653             if cmp () < 0 && (getoldpos ())#compare (getpos ()) < 0
 654             then
 655              begin
 656               buffer#move_mark old_locked_mark (getpos ());
 657               aux ()
 658              end
 659           in
 660           aux ()
 661         in
 662         let rec back_until_cursor len = (* go backward until locked < cursor *)
 663          function
 664             statements, ((grafite_status)::_ as history)
 665             when len <= 0 ->
 666              self#_retract (icmp - len) grafite_status statements
 667               history
 668           | statement::tl1, _::tl2 ->
 669              back_until_cursor (len - MatitaGtkMisc.utf8_string_length statement) (tl1,tl2)
 670           | _,_ -> assert false
 671         in
 672         (try
 673           begin
 674            if icmp < 0 then       (* locked < cursor *)
 675              (forward_until_cursor (); self#notify)
 676            else if icmp > 0 then  (* locked > cursor *)
 677              (back_until_cursor icmp (statements,history); self#notify)
 678            else                  (* cursor = locked *)
 679                ()
 680           end ;
 681           dispose_remember ();
 682           dispose_old_locked_mark ();
 683         with
 684         | Margin -> dispose_remember (); dispose_old_locked_mark (); self#notify
 685         | exc -> dispose_remember (); dispose_old_locked_mark ();
 686                  self#notify; raise exc)
 687   with Invalid_argument "Array.make" ->
 688      HLog.error "The script is too big!\n"
 689
 690   method stack = (assert false : Continuationals.Stack.t) (* MATITA 1.0 GrafiteTypes.get_stack
 691   self#grafite_status *)
 692   method setGoal n = userGoal <- n
 693   method goal = userGoal
 694
 695   method bos =
 696     match history with
 697     | _::[] -> true
 698     | _ -> false
 699
 700   method eos =
 701     let rec is_there_only_comments lexicon_status s =
 702       if Pcre.pmatch ~rex:only_dust_RE s then raise Margin;
 703       let lexicon_status,st =
 704        GrafiteParser.parse_statement (Ulexing.from_utf8_string s)
 705         ~include_paths:self#include_paths lexicon_status
 706       in
 707       match st with
 708       | GrafiteParser.LSome (GrafiteAst.Comment (loc,_)) ->
 709           let _,parsed_text_length = MatitaGtkMisc.utf8_parsed_text s loc in
 710           (* CSC: why +1 in the following lines ???? *)
 711           let parsed_text_length = parsed_text_length + 1 in
 712           let remain_len = String.length s - parsed_text_length in
 713           let next = String.sub s parsed_text_length remain_len in
 714           is_there_only_comments lexicon_status next
 715       | GrafiteParser.LNone _
 716       | GrafiteParser.LSome (GrafiteAst.Executable _) -> false
 717     in
 718     try is_there_only_comments self#grafite_status self#getFuture
 719     with
 720     | LexiconEngine.IncludedFileNotCompiled _
 721     | HExtlib.Localized _
 722     | CicNotationParser.Parse_error _ -> false
 723     | Margin | End_of_file -> true
 724     | Invalid_argument "Array.make" -> false
 725
 726   (* debug *)
 727   method dump () =
 728     HLog.debug "script status:";
 729     HLog.debug ("history size: " ^ string_of_int (List.length history));
 730     HLog.debug (sprintf "%d statements:" (List.length statements));
 731     List.iter HLog.debug statements;
 732     HLog.debug ("Current file name: " ^ self#filename);
 733 end
 734
 735 let _script = ref None
 736
 737 let script ~source_view ~mathviewer ~urichooser ~ask_confirmation ~set_star ()
 738 =
 739   let s = new script
 740     ~source_view ~mathviewer ~ask_confirmation ~urichooser ~set_star ()
 741   in
 742   _script := Some s;
 743   s
 744
 745 let current () = match !_script with None -> assert false | Some s -> s
 746