matita/matita/matitaScript.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29 open GrafiteTypes
  30
  31 module TA = GrafiteAst
  32
  33 let debug = false
  34 let debug_print = if debug then prerr_endline else ignore
  35
  36   (** raised when one of the script margins (top or bottom) is reached *)
  37 exception Margin
  38 exception NoUnfinishedProof
  39 exception ActionCancelled of string
  40
  41 let safe_substring s i j =
  42   try String.sub s i j with Invalid_argument _ -> assert false
  43
  44 let heading_nl_RE = Pcre.regexp "^\\s*\n\\s*"
  45 let heading_nl_RE' = Pcre.regexp "^(\\s*\n\\s*)"
  46 let only_dust_RE = Pcre.regexp "^(\\s|\n|%%[^\n]*\n)*$"
  47 let multiline_RE = Pcre.regexp "^\n[^\n]+$"
  48 let newline_RE = Pcre.regexp "\n"
  49 let comment_RE = Pcre.regexp "\\(\\*(.|\n)*\\*\\)\n?" ~flags:[`UNGREEDY]
  50
  51 let comment str =
  52   if Pcre.pmatch ~rex:multiline_RE str then
  53     "\n(** " ^ (Pcre.replace ~rex:newline_RE str) ^ " *)"
  54   else
  55     "\n(**\n" ^ str ^ "\n*)"
  56
  57 let strip_comments str =
  58   Pcre.qreplace ~templ:"\n" ~pat:"\n\n" (Pcre.qreplace ~rex:comment_RE str)
  59 ;;
  60
  61 let first_line s =
  62   let s = Pcre.replace ~rex:heading_nl_RE s in
  63   try
  64     let nl_pos = String.index s '\n' in
  65     String.sub s 0 nl_pos
  66   with Not_found -> s
  67
  68 type guistuff = {
  69   mathviewer:MatitaTypes.mathViewer;
  70   urichooser: NReference.reference list -> NReference.reference list;
  71   ask_confirmation: title:string -> message:string -> [`YES | `NO | `CANCEL];
  72 }
  73
  74 let eval_with_engine include_paths guistuff grafite_status user_goal
  75  skipped_txt nonskipped_txt st
  76 =
  77   let parsed_text_length =
  78     String.length skipped_txt + String.length nonskipped_txt
  79   in
  80   let text = skipped_txt ^ nonskipped_txt in
  81   let prefix_len = MatitaGtkMisc.utf8_string_length skipped_txt in
  82   let enriched_history_fragment =
  83    MatitaEngine.eval_ast ~include_paths ~do_heavy_checks:(Helm_registry.get_bool
  84      "matita.do_heavy_checks")
  85     grafite_status (text,prefix_len,st)
  86   in
  87   let enriched_history_fragment = List.rev enriched_history_fragment in
  88   (* really fragile *)
  89   let res,_ =
  90     List.fold_left
  91       (fun (acc, to_prepend) (status,alias) ->
  92        match alias with
  93        | None -> (status,to_prepend ^ nonskipped_txt)::acc,""
  94        | Some (k,value) ->
  95             let newtxt = GrafiteAstPp.pp_alias value in
  96             (status,to_prepend ^ newtxt ^ "\n")::acc, "")
  97       ([],skipped_txt) enriched_history_fragment
  98   in
  99   res,"",parsed_text_length
 100 ;;
 101
 102 (* this function calls the parser in a way that it does not perform inclusions,
 103  * so that we can ensure the inclusion is performed after the included file
 104  * is compiled (if needed). matitac does not need that, since it compiles files
 105  * in the good order, here files may be compiled on demand. *)
 106 let wrap_with_make include_paths f x =
 107   match f x with
 108      GrafiteParser.LSome (GrafiteAst.Executable (_,GrafiteAst.NCommand
 109      (_,GrafiteAst.Include (_,_,mafilename)))) as cmd ->
 110       let root, buri, _, tgt =
 111         try Librarian.baseuri_of_script ~include_paths mafilename
 112         with Librarian.NoRootFor _ ->
 113           HLog.error ("The included file '"^mafilename^"' has no root file,");
 114           HLog.error "please create it.";
 115           raise (Failure ("No root file for "^mafilename))
 116       in
 117       if MatitacLib.Make.make root [tgt] then
 118        cmd
 119       else raise (Failure ("Compiling: " ^ tgt))
 120    | cmd -> cmd
 121 ;;
 122
 123 let pp_eager_statement_ast = GrafiteAstPp.pp_statement
 124
 125 let eval_nmacro include_paths (buffer : GText.buffer) guistuff grafite_status user_goal unparsed_text parsed_text script mac =
 126   let parsed_text_length = String.length parsed_text in
 127   match mac with
 128   | TA.Screenshot (_,name) ->
 129        let status = script#grafite_status in
 130        let _,_,menv,subst,_ = status#obj in
 131        let name = Filename.dirname (script#filename) ^ "/" ^ name in
 132        let sequents =
 133          let selected = Continuationals.Stack.head_goals status#stack in
 134          List.filter (fun x,_ -> List.mem x selected) menv
 135        in
 136        guistuff.mathviewer#screenshot status sequents menv subst name;
 137        [status, parsed_text], "", parsed_text_length
 138   | TA.NCheck (_,t) ->
 139       let status = script#grafite_status in
 140       let _,_,menv,subst,_ = status#obj in
 141       let ctx =
 142         try let _,(_,ctx,_) = List.hd menv in ctx
 143         with Failure "hd" -> []
 144       in
 145       let m, s, status, t =
 146         GrafiteDisambiguate.disambiguate_nterm
 147           None status ctx menv subst (parsed_text,parsed_text_length,
 148             NotationPt.Cast (t,NotationPt.Implicit `JustOne))
 149           (* XXX use the metasenv, if possible *)
 150       in
 151       guistuff.mathviewer#show_entry (`NCic (t,ctx,m,s));
 152       [status, parsed_text], "", parsed_text_length
 153   | TA.NIntroGuess _loc ->
 154       let names_ref = ref [] in
 155       let s =
 156         NTactics.intros_tac ~names_ref [] script#grafite_status
 157       in
 158       let rex = Pcre.regexp ~flags:[`MULTILINE] "\\A([\\n\\t\\r ]*).*\\Z" in
 159       let nl = Pcre.replace ~rex ~templ:"$1" parsed_text in
 160       [s, nl ^ "#" ^ String.concat " " !names_ref ^ ";"], "", parsed_text_length
 161   | TA.NAutoInteractive (_loc, (None,a)) ->
 162       let trace_ref = ref [] in
 163       let s =
 164         NnAuto.auto_tac
 165           ~params:(None,a) ~trace_ref script#grafite_status
 166       in
 167       let depth =
 168         try List.assoc "depth" a
 169         with Not_found -> ""
 170       in
 171       let trace = "/"^(if int_of_string depth > 1 then depth else "")^"/ by " in
 172       let thms =
 173         match !trace_ref with
 174         | [] -> "{}"
 175         | thms ->
 176            String.concat ", "
 177              (HExtlib.filter_map (function
 178                | NotationPt.NRef r -> Some (NCicPp.r2s true r)
 179                | _ -> None)
 180              thms)
 181       in
 182       let rex = Pcre.regexp ~flags:[`MULTILINE] "\\A([\\n\\t\\r ]*).*\\Z" in
 183       let nl = Pcre.replace ~rex ~templ:"$1" parsed_text in
 184       [s, nl ^ trace ^ thms ^ ";"], "", parsed_text_length
 185   | TA.NAutoInteractive (_, (Some _,_)) -> assert false
 186
 187 let rec eval_executable include_paths (buffer : GText.buffer) guistuff
 188 grafite_status user_goal unparsed_text skipped_txt nonskipped_txt
 189 script ex loc
 190 =
 191   try
 192    ignore (buffer#move_mark (`NAME "beginning_of_statement")
 193     ~where:((buffer#get_iter_at_mark (`NAME "locked"))#forward_chars
 194        (Glib.Utf8.length skipped_txt))) ;
 195    eval_with_engine include_paths
 196     guistuff grafite_status user_goal skipped_txt nonskipped_txt
 197      (TA.Executable (loc, ex))
 198   with
 199      MatitaTypes.Cancel -> [], "", 0
 200    | GrafiteEngine.NMacro (_loc,macro) ->
 201        eval_nmacro include_paths buffer guistuff grafite_status
 202         user_goal unparsed_text (skipped_txt ^ nonskipped_txt) script macro
 203
 204
 205 and eval_statement include_paths (buffer : GText.buffer) guistuff
 206  grafite_status user_goal script statement
 207 =
 208   let st,unparsed_text =
 209     match statement with
 210     | `Raw text ->
 211         if Pcre.pmatch ~rex:only_dust_RE text then raise Margin;
 212         let ast =
 213          wrap_with_make include_paths
 214           (GrafiteParser.parse_statement grafite_status)
 215             (Ulexing.from_utf8_string text)
 216         in
 217           ast, text
 218     | `Ast (st, text) -> st, text
 219   in
 220   let text_of_loc floc =
 221     let nonskipped_txt,_ = MatitaGtkMisc.utf8_parsed_text unparsed_text floc in
 222     let start, stop = HExtlib.loc_of_floc floc in
 223     let floc = HExtlib.floc_of_loc (0, start) in
 224     let skipped_txt,_ = MatitaGtkMisc.utf8_parsed_text unparsed_text floc in
 225     let floc = HExtlib.floc_of_loc (0, stop) in
 226     let txt,len = MatitaGtkMisc.utf8_parsed_text unparsed_text floc in
 227     txt,nonskipped_txt,skipped_txt,len
 228   in
 229   match st with
 230   | GrafiteParser.LNone loc ->
 231       let parsed_text, _, _, parsed_text_length = text_of_loc loc in
 232        [grafite_status,parsed_text],"",
 233         parsed_text_length
 234   | GrafiteParser.LSome (GrafiteAst.Executable (loc, ex)) ->
 235      let _, nonskipped, skipped, parsed_text_length = text_of_loc loc in
 236       eval_executable include_paths buffer guistuff
 237        grafite_status user_goal unparsed_text skipped nonskipped script ex loc
 238   | GrafiteParser.LSome (GrafiteAst.Comment (loc, GrafiteAst.Code (_, ex)))
 239     when Helm_registry.get_bool "matita.execcomments" ->
 240      let _, nonskipped, skipped, parsed_text_length = text_of_loc loc in
 241       eval_executable include_paths buffer guistuff
 242        grafite_status user_goal unparsed_text skipped nonskipped script ex loc
 243   | GrafiteParser.LSome (GrafiteAst.Comment (loc, _)) ->
 244       let parsed_text, _, _, parsed_text_length = text_of_loc loc in
 245       let remain_len = String.length unparsed_text - parsed_text_length in
 246       let s = String.sub unparsed_text parsed_text_length remain_len in
 247       let s,text,len =
 248        try
 249         eval_statement include_paths buffer guistuff
 250          grafite_status user_goal script (`Raw s)
 251        with
 252           HExtlib.Localized (floc, exn) ->
 253            HExtlib.raise_localized_exception
 254              ~offset:(MatitaGtkMisc.utf8_string_length parsed_text) floc exn
 255         | MultiPassDisambiguator.DisambiguationError (offset,errorll) ->
 256            raise
 257             (MultiPassDisambiguator.DisambiguationError
 258               (offset+parsed_text_length, errorll))
 259       in
 260       assert (text=""); (* no macros inside comments, please! *)
 261       (match s with
 262       | (statuses,text)::tl ->
 263          (statuses,parsed_text ^ text)::tl,"",parsed_text_length + len
 264       | [] -> [], "", 0)
 265
 266 let fresh_script_id =
 267   let i = ref 0 in
 268   fun () -> incr i; !i
 269
 270 class script  ~(source_view: GSourceView2.source_view)
 271               ~(mathviewer: MatitaTypes.mathViewer)
 272               ~set_star
 273               ~ask_confirmation
 274               ~urichooser
 275               () =
 276 let buffer = source_view#buffer in
 277 let source_buffer = source_view#source_buffer in
 278 let initial_statuses current baseuri =
 279  let empty_lstatus = new LexiconTypes.status in
 280  (match current with
 281      Some current ->
 282       NCicLibrary.time_travel
 283        ((new GrafiteTypes.status current#baseuri)#set_lstatus current#lstatus);
 284       (* CSC: there is a known bug in invalidation; temporary fix here *)
 285       NCicEnvironment.invalidate ()
 286    | None -> ());
 287  let lexicon_status =
 288    CicNotation2.load_notation ~include_paths:[] empty_lstatus
 289      BuildTimeConf.core_notation_script
 290  in
 291  let grafite_status = (new GrafiteTypes.status baseuri)#set_lstatus lexicon_status#lstatus in
 292   grafite_status
 293 in
 294 let read_include_paths file =
 295  try
 296    let root, _buri, _fname, _tgt =
 297      Librarian.baseuri_of_script ~include_paths:[] file
 298    in
 299    let rc =
 300     Str.split (Str.regexp " ")
 301      (List.assoc "include_paths" (Librarian.load_root_file (root^"/root")))
 302    in
 303    List.iter (HLog.debug) rc; rc
 304  with Librarian.NoRootFor _ | Not_found -> []
 305 in
 306 let default_buri = "cic:/matita/tests" in
 307 let default_fname = ".unnamed.ma" in
 308 object (self)
 309   val mutable include_paths_ = []
 310
 311   val scriptId = fresh_script_id ()
 312
 313   val guistuff = {
 314     mathviewer = mathviewer;
 315     urichooser = urichooser;
 316     ask_confirmation = ask_confirmation;
 317   }
 318
 319   val mutable filename_ = (None : string option)
 320
 321   method has_name = filename_ <> None
 322
 323   method include_paths =
 324     include_paths_ @
 325     Helm_registry.get_list Helm_registry.string "matita.includes"
 326
 327   method private curdir =
 328     try
 329      let root, _buri, _fname, _tgt =
 330        Librarian.baseuri_of_script ~include_paths:self#include_paths
 331        self#filename
 332      in
 333      root
 334     with Librarian.NoRootFor _ -> Sys.getcwd ()
 335
 336   method buri_of_current_file =
 337     match filename_ with
 338     | None -> default_buri
 339     | Some f ->
 340         try
 341           let _root, buri, _fname, _tgt =
 342             Librarian.baseuri_of_script ~include_paths:self#include_paths f
 343           in
 344           buri
 345         with Librarian.NoRootFor _ -> default_buri
 346
 347   method filename = match filename_ with None -> default_fname | Some f -> f
 348
 349   initializer
 350     ignore (GMain.Timeout.add ~ms:300000
 351        ~callback:(fun _ -> self#_saveToBackupFile ();true));
 352     ignore (buffer#connect#modified_changed
 353       (fun _ -> set_star buffer#modified))
 354
 355   val mutable statements = []    (** executed statements *)
 356
 357   val mutable history = [ initial_statuses None default_buri ]
 358     (** list of states before having executed statements. Head element of this
 359       * list is the current state, last element is the state at the beginning of
 360       * the script.
 361       * Invariant: this list length is 1 + length of statements *)
 362
 363   (** goal as seen by the user (i.e. metano corresponding to current tab) *)
 364   val mutable userGoal = (None : int option)
 365
 366   (** text mark and tag representing locked part of a script *)
 367   val locked_mark =
 368     buffer#create_mark ~name:"locked" ~left_gravity:true buffer#start_iter
 369   val beginning_of_statement_mark =
 370     buffer#create_mark ~name:"beginning_of_statement"
 371      ~left_gravity:true buffer#start_iter
 372   val locked_tag = buffer#create_tag [`BACKGROUND "lightblue"; `EDITABLE false]
 373   val error_tag = buffer#create_tag [`UNDERLINE `SINGLE; `FOREGROUND "red"]
 374
 375   method locked_mark = locked_mark
 376   method locked_tag = locked_tag
 377   method error_tag = error_tag
 378
 379     (* history can't be empty, the invariant above grant that it contains at
 380      * least the init grafite_status *)
 381   method grafite_status = match history with s::_ -> s | _ -> assert false
 382
 383   method private _advance ?statement () =
 384    let s = match statement with Some s -> s | None -> self#getFuture in
 385    if self#bos then LibraryClean.clean_baseuris [self#buri_of_current_file];
 386    HLog.debug ("evaluating: " ^ first_line s ^ " ...");
 387    let time1 = Unix.gettimeofday () in
 388    let entries, newtext, parsed_len =
 389     try
 390      eval_statement self#include_paths buffer guistuff
 391       self#grafite_status userGoal self (`Raw s)
 392     with End_of_file -> raise Margin
 393    in
 394    let time2 = Unix.gettimeofday () in
 395    HLog.debug ("... done in " ^ string_of_float (time2 -. time1) ^ "s");
 396    let new_statuses, new_statements =
 397      let statuses, texts = List.split entries in
 398      statuses, texts
 399    in
 400    history <- new_statuses @ history;
 401    statements <- new_statements @ statements;
 402    let start = buffer#get_iter_at_mark (`MARK locked_mark) in
 403    let new_text = String.concat "" (List.rev new_statements) in
 404    if statement <> None then
 405      buffer#insert ~iter:start new_text
 406    else begin
 407      let parsed_text = String.sub s 0 parsed_len in
 408      if new_text <> parsed_text then begin
 409        let stop = start#copy#forward_chars (Glib.Utf8.length parsed_text) in
 410        buffer#delete ~start ~stop;
 411        buffer#insert ~iter:start new_text;
 412      end;
 413    end;
 414    self#moveMark (Glib.Utf8.length new_text);
 415    buffer#insert ~iter:(buffer#get_iter_at_mark (`MARK locked_mark)) newtext;
 416    (* here we need to set the Goal in case we are going to cursor (or to
 417       bottom) and we will face a macro *)
 418     userGoal <- None
 419
 420   method private _retract offset grafite_status new_statements new_history =
 421     NCicLibrary.time_travel grafite_status;
 422     statements <- new_statements;
 423     history <- new_history;
 424     self#moveMark (- offset)
 425
 426   method advance ?statement () =
 427     try
 428       self#_advance ?statement ();
 429       self#notify
 430     with
 431     | Margin -> self#notify
 432     | Not_found -> assert false
 433     | Invalid_argument "Array.make" -> HLog.error "The script is too big!\n"
 434     | exc -> self#notify; raise exc
 435
 436   method retract () =
 437     try
 438       let cmp,new_statements,new_history,grafite_status =
 439        match statements,history with
 440           stat::statements, _::(status::_ as history) ->
 441            assert (Glib.Utf8.validate stat);
 442            Glib.Utf8.length stat, statements, history, status
 443        | [],[_] -> raise Margin
 444        | _,_ -> assert false
 445       in
 446        self#_retract cmp grafite_status new_statements
 447         new_history;
 448        self#notify
 449     with
 450     | Margin -> self#notify
 451     | Invalid_argument "Array.make" -> HLog.error "The script is too big!\n"
 452     | exc -> self#notify; raise exc
 453
 454   method private getFuture =
 455     let lock = buffer#get_iter_at_mark (`MARK locked_mark) in
 456     let text = buffer#get_text ~start:lock ~stop:buffer#end_iter () in
 457     text
 458
 459   method expandAllVirtuals =
 460     let lock = buffer#get_iter_at_mark (`MARK locked_mark) in
 461     let text = buffer#get_text ~start:lock ~stop:buffer#end_iter () in
 462     buffer#delete ~start:lock ~stop:buffer#end_iter;
 463     let text = Pcre.replace ~pat:":=" ~templ:"\\def" text in
 464     let text = Pcre.replace ~pat:"->" ~templ:"\\to" text in
 465     let text = Pcre.replace ~pat:"=>" ~templ:"\\Rightarrow" text in
 466     let text =
 467       Pcre.substitute_substrings
 468         ~subst:(fun str ->
 469            let pristine = Pcre.get_substring str 0 in
 470            let input =
 471              if pristine.[0] = ' ' then
 472                String.sub pristine 1 (String.length pristine -1)
 473              else pristine
 474            in
 475            let input =
 476              if input.[String.length input-1] = ' ' then
 477                String.sub input 0 (String.length input -1)
 478              else input
 479            in
 480            let before, after =
 481              if input = "\\forall" ||
 482                 input = "\\lambda" ||
 483                 input = "\\exists" then "","" else " ", " "
 484            in
 485            try
 486              before ^ Glib.Utf8.from_unichar
 487                (snd (Virtuals.symbol_of_virtual input)) ^ after
 488            with Virtuals.Not_a_virtual -> pristine)
 489         ~pat:" ?\\\\[a-zA-Z]+ ?" text
 490     in
 491     buffer#insert ~iter:lock text
 492
 493   (** @param rel_offset relative offset from current position of locked_mark *)
 494   method private moveMark rel_offset =
 495     let mark = `MARK locked_mark in
 496     let old_insert = buffer#get_iter_at_mark `INSERT in
 497     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 498     let current_mark_pos = buffer#get_iter_at_mark mark in
 499     let new_mark_pos =
 500       match rel_offset with
 501       | 0 -> current_mark_pos
 502       | n when n > 0 -> current_mark_pos#forward_chars n
 503       | n (* when n < 0 *) -> current_mark_pos#backward_chars (abs n)
 504     in
 505     buffer#move_mark mark ~where:new_mark_pos;
 506     buffer#apply_tag locked_tag ~start:buffer#start_iter ~stop:new_mark_pos;
 507     buffer#move_mark `INSERT old_insert;
 508     let mark_position = buffer#get_iter_at_mark mark in
 509     if source_view#move_mark_onscreen mark then
 510      begin
 511       buffer#move_mark mark mark_position;
 512       source_view#scroll_to_mark ~use_align:true ~xalign:1.0 ~yalign:0.1 mark;
 513      end;
 514     while Glib.Main.pending () do ignore(Glib.Main.iteration false); done
 515
 516   method clean_dirty_lock =
 517     let lock_mark_iter = buffer#get_iter_at_mark (`MARK locked_mark) in
 518     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 519     buffer#apply_tag locked_tag ~start:buffer#start_iter ~stop:lock_mark_iter
 520
 521   val mutable observers = []
 522
 523   method addObserver (o: GrafiteTypes.status -> unit) =
 524     observers <- o :: observers
 525
 526   method private notify =
 527     let grafite_status = self#grafite_status in
 528     List.iter (fun o -> o grafite_status) observers
 529
 530   method loadFromString s =
 531     buffer#set_text s;
 532     self#reset_buffer;
 533     buffer#set_modified true
 534
 535   method loadFromFile f =
 536     buffer#set_text (HExtlib.input_file f);
 537     self#reset_buffer;
 538     buffer#set_modified false
 539
 540   method assignFileName file =
 541     let file =
 542       match file with
 543       | Some f -> Some (Librarian.absolutize f)
 544       | None -> None
 545     in
 546     filename_ <- file;
 547     include_paths_ <-
 548       (match file with Some file -> read_include_paths file | None -> []);
 549     self#reset_buffer;
 550     Sys.chdir self#curdir;
 551     HLog.debug ("Moving to " ^ Sys.getcwd ())
 552
 553   method saveToFile () =
 554     if self#has_name then
 555       let oc = open_out self#filename in
 556       output_string oc (buffer#get_text ~start:buffer#start_iter
 557                         ~stop:buffer#end_iter ());
 558       close_out oc;
 559       set_star false;
 560       buffer#set_modified false
 561     else
 562       HLog.error "Can't save, no filename selected"
 563
 564   method private _saveToBackupFile () =
 565     if buffer#modified then
 566       begin
 567         let f = self#filename in
 568         let oc = open_out f in
 569         output_string oc (buffer#get_text ~start:buffer#start_iter
 570                             ~stop:buffer#end_iter ());
 571         close_out oc;
 572         HLog.debug ("backup " ^ f ^ " saved")
 573       end
 574
 575   method private reset_buffer =
 576     statements <- [];
 577     history <- [ initial_statuses (Some self#grafite_status) self#buri_of_current_file ];
 578     userGoal <- None;
 579     self#notify;
 580     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 581     buffer#move_mark (`MARK locked_mark) ~where:buffer#start_iter
 582
 583   method reset () =
 584     self#reset_buffer;
 585     source_buffer#begin_not_undoable_action ();
 586     buffer#delete ~start:buffer#start_iter ~stop:buffer#end_iter;
 587     source_buffer#end_not_undoable_action ();
 588     buffer#set_modified false;
 589
 590   method template () =
 591     let template = HExtlib.input_file BuildTimeConf.script_template in
 592     buffer#insert ~iter:(buffer#get_iter `START) template;
 593     buffer#set_modified false;
 594     set_star false
 595
 596   method goto (pos: [`Top | `Bottom | `Cursor]) () =
 597   try
 598     let old_locked_mark =
 599      `MARK
 600        (buffer#create_mark ~name:"old_locked_mark"
 601          ~left_gravity:true (buffer#get_iter_at_mark (`MARK locked_mark))) in
 602     let getpos _ = buffer#get_iter_at_mark (`MARK locked_mark) in
 603     let getoldpos _ = buffer#get_iter_at_mark old_locked_mark in
 604     let dispose_old_locked_mark () = buffer#delete_mark old_locked_mark in
 605     match pos with
 606     | `Top ->
 607         dispose_old_locked_mark ();
 608         self#reset_buffer;
 609         self#notify
 610     | `Bottom ->
 611         (try
 612           let rec dowhile () =
 613             self#_advance ();
 614             let newpos = getpos () in
 615             if (getoldpos ())#compare newpos < 0 then
 616               begin
 617                 buffer#move_mark old_locked_mark newpos;
 618                 dowhile ()
 619               end
 620           in
 621           dowhile ();
 622           dispose_old_locked_mark ();
 623           self#notify
 624         with
 625         | Margin -> dispose_old_locked_mark (); self#notify
 626         | exc -> dispose_old_locked_mark (); self#notify; raise exc)
 627     | `Cursor ->
 628         let locked_iter () = buffer#get_iter_at_mark (`NAME "locked") in
 629         let cursor_iter () = buffer#get_iter_at_mark `INSERT in
 630         let remember =
 631          `MARK
 632            (buffer#create_mark ~name:"initial_insert"
 633              ~left_gravity:true (cursor_iter ())) in
 634         let dispose_remember () = buffer#delete_mark remember in
 635         let remember_iter () =
 636          buffer#get_iter_at_mark (`NAME "initial_insert") in
 637         let cmp () = (locked_iter ())#offset - (remember_iter ())#offset in
 638         let icmp = cmp () in
 639         let forward_until_cursor () = (* go forward until locked > cursor *)
 640           let rec aux () =
 641             self#_advance ();
 642             if cmp () < 0 && (getoldpos ())#compare (getpos ()) < 0
 643             then
 644              begin
 645               buffer#move_mark old_locked_mark (getpos ());
 646               aux ()
 647              end
 648           in
 649           aux ()
 650         in
 651         let rec back_until_cursor len = (* go backward until locked < cursor *)
 652          function
 653             statements, ((grafite_status)::_ as history)
 654             when len <= 0 ->
 655              self#_retract (icmp - len) grafite_status statements
 656               history
 657           | statement::tl1, _::tl2 ->
 658              back_until_cursor (len - MatitaGtkMisc.utf8_string_length statement) (tl1,tl2)
 659           | _,_ -> assert false
 660         in
 661         (try
 662           begin
 663            if icmp < 0 then       (* locked < cursor *)
 664              (forward_until_cursor (); self#notify)
 665            else if icmp > 0 then  (* locked > cursor *)
 666              (back_until_cursor icmp (statements,history); self#notify)
 667            else                  (* cursor = locked *)
 668                ()
 669           end ;
 670           dispose_remember ();
 671           dispose_old_locked_mark ();
 672         with
 673         | Margin -> dispose_remember (); dispose_old_locked_mark (); self#notify
 674         | exc -> dispose_remember (); dispose_old_locked_mark ();
 675                  self#notify; raise exc)
 676   with Invalid_argument "Array.make" ->
 677      HLog.error "The script is too big!\n"
 678
 679   method stack = (assert false : Continuationals.Stack.t) (* MATITA 1.0 GrafiteTypes.get_stack
 680   self#grafite_status *)
 681   method setGoal n = userGoal <- n
 682   method goal = userGoal
 683
 684   method bos =
 685     match history with
 686     | _::[] -> true
 687     | _ -> false
 688
 689   method eos =
 690     let rec is_there_only_comments lexicon_status s =
 691       if Pcre.pmatch ~rex:only_dust_RE s then raise Margin;
 692       match
 693        GrafiteParser.parse_statement lexicon_status (Ulexing.from_utf8_string s)
 694       with
 695       | GrafiteParser.LSome (GrafiteAst.Comment (loc,_)) ->
 696           let _,parsed_text_length = MatitaGtkMisc.utf8_parsed_text s loc in
 697           (* CSC: why +1 in the following lines ???? *)
 698           let parsed_text_length = parsed_text_length + 1 in
 699           let remain_len = String.length s - parsed_text_length in
 700           let next = String.sub s parsed_text_length remain_len in
 701           is_there_only_comments lexicon_status next
 702       | GrafiteParser.LNone _
 703       | GrafiteParser.LSome (GrafiteAst.Executable _) -> false
 704     in
 705     try is_there_only_comments self#grafite_status self#getFuture
 706     with
 707     | NCicLibrary.IncludedFileNotCompiled _
 708     | HExtlib.Localized _
 709     | CicNotationParser.Parse_error _ -> false
 710     | Margin | End_of_file -> true
 711     | Invalid_argument "Array.make" -> false
 712
 713   (* debug *)
 714   method dump () =
 715     HLog.debug "script status:";
 716     HLog.debug ("history size: " ^ string_of_int (List.length history));
 717     HLog.debug (sprintf "%d statements:" (List.length statements));
 718     List.iter HLog.debug statements;
 719     HLog.debug ("Current file name: " ^ self#filename);
 720 end
 721
 722 let _script = ref None
 723
 724 let script ~source_view ~mathviewer ~urichooser ~ask_confirmation ~set_star ()
 725 =
 726   let s = new script
 727     ~source_view ~mathviewer ~ask_confirmation ~urichooser ~set_star ()
 728   in
 729   _script := Some s;
 730   s
 731
 732 let current () = match !_script with None -> assert false | Some s -> s
 733