matita/matita/matitaScript.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29 open GrafiteTypes
  30
  31 module TA = GrafiteAst
  32
  33 let debug = false
  34 let debug_print = if debug then prerr_endline else ignore
  35
  36   (** raised when one of the script margins (top or bottom) is reached *)
  37 exception Margin
  38 exception NoUnfinishedProof
  39 exception ActionCancelled of string
  40
  41 let safe_substring s i j =
  42   try String.sub s i j with Invalid_argument _ -> assert false
  43
  44 let heading_nl_RE = Pcre.regexp "^\\s*\n\\s*"
  45 let heading_nl_RE' = Pcre.regexp "^(\\s*\n\\s*)"
  46 let only_dust_RE = Pcre.regexp "^(\\s|\n|%%[^\n]*\n)*$"
  47 let multiline_RE = Pcre.regexp "^\n[^\n]+$"
  48 let newline_RE = Pcre.regexp "\n"
  49 let comment_RE = Pcre.regexp "\\(\\*(.|\n)*\\*\\)\n?" ~flags:[`UNGREEDY]
  50
  51 let comment str =
  52   if Pcre.pmatch ~rex:multiline_RE str then
  53     "\n(** " ^ (Pcre.replace ~rex:newline_RE str) ^ " *)"
  54   else
  55     "\n(**\n" ^ str ^ "\n*)"
  56
  57 let strip_comments str =
  58   Pcre.qreplace ~templ:"\n" ~pat:"\n\n" (Pcre.qreplace ~rex:comment_RE str)
  59 ;;
  60
  61 let first_line s =
  62   let s = Pcre.replace ~rex:heading_nl_RE s in
  63   try
  64     let nl_pos = String.index s '\n' in
  65     String.sub s 0 nl_pos
  66   with Not_found -> s
  67
  68 type guistuff = {
  69   urichooser: NReference.reference list -> NReference.reference list;
  70   ask_confirmation: title:string -> message:string -> [`YES | `NO | `CANCEL];
  71 }
  72
  73 let eval_with_engine include_paths guistuff grafite_status skipped_txt nonskipped_txt st
  74 =
  75   let parsed_text_length =
  76     String.length skipped_txt + String.length nonskipped_txt
  77   in
  78   let text = skipped_txt ^ nonskipped_txt in
  79   let prefix_len = MatitaGtkMisc.utf8_string_length skipped_txt in
  80   let enriched_history_fragment =
  81    MatitaEngine.eval_ast ~include_paths ~do_heavy_checks:(Helm_registry.get_bool
  82      "matita.do_heavy_checks")
  83     grafite_status (text,prefix_len,st)
  84   in
  85   let enriched_history_fragment = List.rev enriched_history_fragment in
  86   (* really fragile *)
  87   let res,_ =
  88     List.fold_left
  89       (fun (acc, to_prepend) (status,alias) ->
  90        match alias with
  91        | None -> (status,to_prepend ^ nonskipped_txt)::acc,""
  92        | Some (k,value) ->
  93             let newtxt = GrafiteAstPp.pp_alias value in
  94             (status,to_prepend ^ newtxt ^ "\n")::acc, "")
  95       ([],skipped_txt) enriched_history_fragment
  96   in
  97   res,"",parsed_text_length
  98 ;;
  99
 100 let pp_eager_statement_ast = GrafiteAstPp.pp_statement
 101
 102 let eval_nmacro include_paths (buffer : GText.buffer) guistuff grafite_status unparsed_text parsed_text script mac =
 103   let parsed_text_length = String.length parsed_text in
 104   match mac with
 105   | TA.Screenshot (_,name) ->
 106        let status = script#grafite_status in
 107        let _,_,menv,subst,_ = status#obj in
 108        let name = Filename.dirname (script#filename) ^ "/" ^ name in
 109        let sequents =
 110          let selected = Continuationals.Stack.head_goals status#stack in
 111          List.filter (fun x,_ -> List.mem x selected) menv
 112        in
 113        CicMathView.screenshot status sequents menv subst name;
 114        [status, parsed_text], "", parsed_text_length
 115   | TA.NCheck (_,t) ->
 116       let status = script#grafite_status in
 117       let _,_,menv,subst,_ = status#obj in
 118       let ctx =
 119        match Continuationals.Stack.head_goals status#stack with
 120           [] -> []
 121         | g::tl ->
 122            if tl <> [] then
 123             HLog.warn
 124              "Many goals focused. Using the context of the first one\n";
 125            let _, ctx, _ = NCicUtils.lookup_meta g menv in
 126             ctx in
 127       let m, s, status, t =
 128         GrafiteDisambiguate.disambiguate_nterm
 129           status None ctx menv subst (parsed_text,parsed_text_length,
 130             NotationPt.Cast (t,NotationPt.Implicit `JustOne))
 131           (* XXX use the metasenv, if possible *)
 132       in
 133       MatitaMathView.show_entry (`NCic (t,ctx,m,s));
 134       [status, parsed_text], "", parsed_text_length
 135   | TA.NIntroGuess _loc ->
 136       let names_ref = ref [] in
 137       let s =
 138         NTactics.intros_tac ~names_ref [] script#grafite_status
 139       in
 140       let rex = Pcre.regexp ~flags:[`MULTILINE] "\\A([\\n\\t\\r ]*).*\\Z" in
 141       let nl = Pcre.replace ~rex ~templ:"$1" parsed_text in
 142       [s, nl ^ "#" ^ String.concat " " !names_ref ^ ";"], "", parsed_text_length
 143   | TA.NAutoInteractive (_loc, (None,a)) ->
 144       let trace_ref = ref [] in
 145       let s =
 146         NnAuto.auto_tac
 147           ~params:(None,a) ~trace_ref script#grafite_status
 148       in
 149       let depth =
 150         try List.assoc "depth" a
 151         with Not_found -> ""
 152       in
 153       let trace = "/"^(if int_of_string depth > 1 then depth else "")^"/ by " in
 154       let thms =
 155         match !trace_ref with
 156         | [] -> "{}"
 157         | thms ->
 158            String.concat ", "
 159              (HExtlib.filter_map (function
 160                | NotationPt.NRef r -> Some (NCicPp.r2s true r)
 161                | _ -> None)
 162              thms)
 163       in
 164       let rex = Pcre.regexp ~flags:[`MULTILINE] "\\A([\\n\\t\\r ]*).*\\Z" in
 165       let nl = Pcre.replace ~rex ~templ:"$1" parsed_text in
 166       [s, nl ^ trace ^ thms ^ ";"], "", parsed_text_length
 167   | TA.NAutoInteractive (_, (Some _,_)) -> assert false
 168
 169 let rec eval_executable include_paths (buffer : GText.buffer) guistuff
 170 grafite_status unparsed_text skipped_txt nonskipped_txt script ex loc
 171 =
 172   try
 173    ignore (buffer#move_mark (`NAME "beginning_of_statement")
 174     ~where:((buffer#get_iter_at_mark (`NAME "locked"))#forward_chars
 175        (Glib.Utf8.length skipped_txt))) ;
 176    eval_with_engine include_paths
 177     guistuff grafite_status skipped_txt nonskipped_txt
 178      (TA.Executable (loc, ex))
 179   with
 180      MatitaTypes.Cancel -> [], "", 0
 181    | GrafiteEngine.NMacro (_loc,macro) ->
 182        eval_nmacro include_paths buffer guistuff grafite_status
 183         unparsed_text (skipped_txt ^ nonskipped_txt) script macro
 184
 185
 186 and eval_statement include_paths (buffer : GText.buffer) guistuff
 187  grafite_status script statement
 188 =
 189   let st,unparsed_text =
 190     match statement with
 191     | `Raw text ->
 192         if Pcre.pmatch ~rex:only_dust_RE text then raise Margin;
 193         let strm =
 194          GrafiteParser.parsable_statement grafite_status
 195           (Ulexing.from_utf8_string text) in
 196         let ast = MatitaEngine.get_ast grafite_status include_paths strm in
 197          ast, text
 198     | `Ast (st, text) -> st, text
 199   in
 200   let text_of_loc floc =
 201     let nonskipped_txt,_ = MatitaGtkMisc.utf8_parsed_text unparsed_text floc in
 202     let start, stop = HExtlib.loc_of_floc floc in
 203     let floc = HExtlib.floc_of_loc (0, start) in
 204     let skipped_txt,_ = MatitaGtkMisc.utf8_parsed_text unparsed_text floc in
 205     let floc = HExtlib.floc_of_loc (0, stop) in
 206     let txt,len = MatitaGtkMisc.utf8_parsed_text unparsed_text floc in
 207     txt,nonskipped_txt,skipped_txt,len
 208   in
 209   match st with
 210   | GrafiteAst.Executable (loc, ex) ->
 211      let _, nonskipped, skipped, parsed_text_length = text_of_loc loc in
 212       eval_executable include_paths buffer guistuff
 213        grafite_status unparsed_text skipped nonskipped script ex loc
 214   | GrafiteAst.Comment (loc, GrafiteAst.Code (_, ex))
 215     when Helm_registry.get_bool "matita.execcomments" ->
 216      let _, nonskipped, skipped, parsed_text_length = text_of_loc loc in
 217       eval_executable include_paths buffer guistuff
 218        grafite_status unparsed_text skipped nonskipped script ex loc
 219   | GrafiteAst.Comment (loc, _) ->
 220       let parsed_text, _, _, parsed_text_length = text_of_loc loc in
 221       let remain_len = String.length unparsed_text - parsed_text_length in
 222       let s = String.sub unparsed_text parsed_text_length remain_len in
 223       let s,text,len =
 224        try
 225         eval_statement include_paths buffer guistuff
 226          grafite_status script (`Raw s)
 227        with
 228           HExtlib.Localized (floc, exn) ->
 229            HExtlib.raise_localized_exception
 230              ~offset:(MatitaGtkMisc.utf8_string_length parsed_text) floc exn
 231         | MultiPassDisambiguator.DisambiguationError (offset,errorll) ->
 232            raise
 233             (MultiPassDisambiguator.DisambiguationError
 234               (offset+parsed_text_length, errorll))
 235       in
 236       assert (text=""); (* no macros inside comments, please! *)
 237       (match s with
 238       | (statuses,text)::tl ->
 239          (statuses,parsed_text ^ text)::tl,"",parsed_text_length + len
 240       | [] -> [], "", 0)
 241
 242 let fresh_script_id =
 243   let i = ref 0 in
 244   fun () -> incr i; !i
 245
 246 (** Selection handling
 247  * Two clipboards are used: "clipboard" and "primary".
 248  * "primary" is used by X, when you hit the middle button mouse is content is
 249  *    pasted between applications. In Matita this selection always contain the
 250  *    textual version of the selected term.
 251  * "clipboard" is used inside Matita only and support ATM two different targets:
 252  *    "TERM" and "PATTERN", in the future other targets like "MATHMLCONTENT" may
 253  *    be added
 254  *)
 255 class script ~ask_confirmation ~urichooser ~(parent:GBin.scrolled_window) ~tab_label () =
 256 let source_view =
 257   GSourceView2.source_view
 258     ~auto_indent:true
 259     ~insert_spaces_instead_of_tabs:true ~tab_width:2
 260     ~right_margin_position:80 ~show_right_margin:true
 261     ~smart_home_end:`AFTER
 262     ~packing:parent#add_with_viewport
 263     () in
 264 let buffer = source_view#buffer in
 265 let source_buffer = source_view#source_buffer in
 266 let similarsymbols_tag_name = "similarsymbolos" in
 267 let similarsymbols_tag = `NAME similarsymbols_tag_name in
 268 let initial_statuses current baseuri =
 269  let empty_lstatus = new GrafiteDisambiguate.status in
 270  (match current with
 271      Some current ->
 272       NCicLibrary.time_travel
 273        ((new GrafiteTypes.status current#baseuri)#set_disambiguate_db current#disambiguate_db);
 274       (* CSC: there is a known bug in invalidation; temporary fix here *)
 275       NCicEnvironment.invalidate ()
 276    | None -> ());
 277  let lexicon_status = empty_lstatus in
 278  let grafite_status = (new GrafiteTypes.status baseuri)#set_disambiguate_db lexicon_status#disambiguate_db in
 279   grafite_status
 280 in
 281 let read_include_paths file =
 282  try
 283    let root, _buri, _fname, _tgt =
 284      Librarian.baseuri_of_script ~include_paths:[] file in
 285    let includes =
 286     try
 287      Str.split (Str.regexp " ")
 288       (List.assoc "include_paths" (Librarian.load_root_file (root^"/root")))
 289     with Not_found -> []
 290    in
 291    let rc = root :: includes in
 292     List.iter (HLog.debug) rc; rc
 293  with Librarian.NoRootFor _ | Librarian.FileNotFound _ ->
 294   []
 295 in
 296 let default_buri = "cic:/matita/tests" in
 297 let default_fname = ".unnamed.ma" in
 298 object (self)
 299   val mutable include_paths_ = []
 300   val clipboard = GData.clipboard Gdk.Atom.clipboard
 301   (*val primary = GData.clipboard Gdk.Atom.primary*)
 302   val mutable similarsymbols = []
 303   val mutable similarsymbols_orig = []
 304   val similar_memory = Hashtbl.create 97
 305   val mutable old_used_memory = false
 306
 307   val scriptId = fresh_script_id ()
 308
 309   val guistuff = {
 310     urichooser = urichooser source_view;
 311     ask_confirmation = ask_confirmation;
 312   }
 313
 314   val mutable filename_ = (None : string option)
 315
 316   method has_name = filename_ <> None
 317
 318   method source_view = source_view
 319
 320   method include_paths =
 321     include_paths_ @
 322     Helm_registry.get_list Helm_registry.string "matita.includes"
 323
 324   method private curdir =
 325     try
 326      let root, _buri, _fname, _tgt =
 327       Librarian.baseuri_of_script ~include_paths:self#include_paths
 328        self#filename
 329      in
 330      root
 331     with Librarian.NoRootFor _ -> Sys.getcwd ()
 332
 333   method buri_of_current_file =
 334     match filename_ with
 335     | None -> default_buri
 336     | Some f ->
 337         try
 338           let _root, buri, _fname, _tgt =
 339             Librarian.baseuri_of_script ~include_paths:self#include_paths f
 340           in
 341           buri
 342         with Librarian.NoRootFor _ | Librarian.FileNotFound _ -> default_buri
 343
 344   method filename = match filename_ with None -> default_fname | Some f -> f
 345
 346   initializer
 347     ignore
 348      (source_view#source_buffer#begin_not_undoable_action ();
 349       self#reset ();
 350       self#template ();
 351       source_view#source_buffer#end_not_undoable_action ());
 352     MatitaMisc.observe_font_size (fun font_size ->
 353      source_view#misc#modify_font_by_name
 354         (sprintf "%s %d" BuildTimeConf.script_font font_size));
 355     source_view#misc#grab_focus ();
 356     ignore(source_view#source_buffer#set_language
 357      (Some MatitaGtkMisc.matita_lang));
 358     ignore(source_view#source_buffer#set_highlight_syntax true);
 359     ignore(source_view#connect#after#paste_clipboard
 360         ~callback:(fun () -> self#clean_dirty_lock));
 361     ignore (GMain.Timeout.add ~ms:300000
 362        ~callback:(fun _ -> self#_saveToBackupFile ();true));
 363     ignore (buffer#connect#modified_changed
 364       (fun _ -> self#set_star buffer#modified));
 365     (* clean_locked is set to true only "during" a PRIMARY paste
 366        operation (i.e. by clicking with the second mouse button) *)
 367     let clean_locked = ref false in
 368     ignore(source_view#event#connect#button_press
 369       ~callback:
 370         (fun button ->
 371           if GdkEvent.Button.button button = 2 then
 372            clean_locked := true;
 373           false
 374         ));
 375     ignore(source_view#event#connect#button_release
 376       ~callback:(fun button -> clean_locked := false; false));
 377     ignore(source_view#buffer#connect#after#apply_tag
 378      ~callback:(
 379        fun tag ~start:_ ~stop:_ ->
 380         if !clean_locked &&
 381            tag#get_oid = self#locked_tag#get_oid
 382         then
 383          begin
 384           clean_locked := false;
 385           self#clean_dirty_lock;
 386           clean_locked := true
 387          end));
 388     ignore(source_view#source_buffer#connect#after#insert_text
 389      ~callback:(fun iter str ->
 390         if (MatitaMisc.get_gui ())#main#menuitemAutoAltL#active && (str = " " || str = "\n") then
 391           ignore(self#expand_virtual_if_any iter str)));
 392     ignore(source_view#connect#after#populate_popup
 393      ~callback:(fun pre_menu ->
 394        let menu = new GMenu.menu pre_menu in
 395        let menuItems = menu#children in
 396        let undoMenuItem, redoMenuItem =
 397         match menuItems with
 398            [undo;redo;sep1;cut;copy;paste;delete;sep2;
 399             selectall;sep3;inputmethod;insertunicodecharacter] ->
 400               List.iter menu#remove [ copy; cut; delete; paste ];
 401               undo,redo
 402          | _ -> assert false in
 403        let add_menu_item =
 404          let i = ref 2 in (* last occupied position *)
 405          fun ?label ?stock () ->
 406            incr i;
 407            GMenu.image_menu_item ?label ?stock ~packing:(menu#insert ~pos:!i)
 408             ()
 409        in
 410        let copy = add_menu_item ~stock:`COPY () in
 411        let cut = add_menu_item ~stock:`CUT () in
 412        let delete = add_menu_item ~stock:`DELETE () in
 413        let paste = add_menu_item ~stock:`PASTE () in
 414        let paste_pattern = add_menu_item ~label:"Paste as pattern" () in
 415        copy#misc#set_sensitive self#canCopy;
 416        cut#misc#set_sensitive self#canCut;
 417        delete#misc#set_sensitive self#canDelete;
 418        paste#misc#set_sensitive self#canPaste;
 419        paste_pattern#misc#set_sensitive self#canPastePattern;
 420        MatitaGtkMisc.connect_menu_item copy self#copy;
 421        MatitaGtkMisc.connect_menu_item cut self#cut;
 422        MatitaGtkMisc.connect_menu_item delete self#delete;
 423        MatitaGtkMisc.connect_menu_item paste self#paste;
 424        MatitaGtkMisc.connect_menu_item paste_pattern self#pastePattern;
 425        let new_undoMenuItem =
 426         GMenu.image_menu_item
 427          ~image:(GMisc.image ~stock:`UNDO ())
 428          ~use_mnemonic:true
 429          ~label:"_Undo"
 430          ~packing:(menu#insert ~pos:0) () in
 431        new_undoMenuItem#misc#set_sensitive
 432         (undoMenuItem#misc#get_flag `SENSITIVE);
 433        menu#remove (undoMenuItem :> GMenu.menu_item);
 434        MatitaGtkMisc.connect_menu_item new_undoMenuItem
 435         (fun () -> self#safe_undo);
 436        let new_redoMenuItem =
 437         GMenu.image_menu_item
 438          ~image:(GMisc.image ~stock:`REDO ())
 439          ~use_mnemonic:true
 440          ~label:"_Redo"
 441          ~packing:(menu#insert ~pos:1) () in
 442        new_redoMenuItem#misc#set_sensitive
 443         (redoMenuItem#misc#get_flag `SENSITIVE);
 444         menu#remove (redoMenuItem :> GMenu.menu_item);
 445         MatitaGtkMisc.connect_menu_item new_redoMenuItem
 446          (fun () -> self#safe_redo)));
 447
 448   val mutable statements = []    (** executed statements *)
 449
 450   val mutable history = [ initial_statuses None default_buri ]
 451     (** list of states before having executed statements. Head element of this
 452       * list is the current state, last element is the state at the beginning of
 453       * the script.
 454       * Invariant: this list length is 1 + length of statements *)
 455
 456   (** text mark and tag representing locked part of a script *)
 457   val locked_mark =
 458     buffer#create_mark ~name:"locked" ~left_gravity:true buffer#start_iter
 459   val beginning_of_statement_mark =
 460     buffer#create_mark ~name:"beginning_of_statement"
 461      ~left_gravity:true buffer#start_iter
 462   val locked_tag = buffer#create_tag [`BACKGROUND "lightblue"; `EDITABLE false]
 463   val error_tag = buffer#create_tag [`UNDERLINE `SINGLE; `FOREGROUND "red"]
 464
 465   (** unicode handling *)
 466   method nextSimilarSymbol =
 467     let write_similarsymbol s =
 468       let s = Glib.Utf8.from_unichar s in
 469       let iter = source_view#source_buffer#get_iter_at_mark `INSERT in
 470       assert(Glib.Utf8.validate s);
 471       source_view#source_buffer#delete ~start:iter ~stop:(iter#copy#backward_chars 1);
 472       source_view#source_buffer#insert ~iter:(source_view#source_buffer#get_iter_at_mark `INSERT) s;
 473       (try source_view#source_buffer#delete_mark similarsymbols_tag
 474        with GText.No_such_mark _ -> ());
 475       ignore(source_view#source_buffer#create_mark ~name:similarsymbols_tag_name
 476         (source_view#source_buffer#get_iter_at_mark `INSERT));
 477     in
 478     let new_similarsymbol =
 479       try
 480         let iter_ins = source_view#source_buffer#get_iter_at_mark `INSERT in
 481         let iter_lig = source_view#source_buffer#get_iter_at_mark similarsymbols_tag in
 482         not (iter_ins#equal iter_lig)
 483       with GText.No_such_mark _ -> true
 484     in
 485     if new_similarsymbol then
 486       (if not(self#expand_virtual_if_any (source_view#source_buffer#get_iter_at_mark `INSERT) "")then
 487         let last_symbol =
 488           let i = source_view#source_buffer#get_iter_at_mark `INSERT in
 489           Glib.Utf8.first_char (i#get_slice ~stop:(i#copy#backward_chars 1))
 490         in
 491         (match Virtuals.similar_symbols last_symbol with
 492         | [] ->  ()
 493         | eqclass ->
 494             similarsymbols_orig <- eqclass;
 495             let is_used =
 496               try Hashtbl.find similar_memory similarsymbols_orig
 497               with Not_found ->
 498                 let is_used = List.map (fun x -> x,false) eqclass in
 499                 Hashtbl.add similar_memory eqclass is_used;
 500                 is_used
 501             in
 502             let hd, next, tl =
 503               let used, unused =
 504                 List.partition (fun s -> List.assoc s is_used) eqclass
 505               in
 506               match used @ unused with a::b::c -> a,b,c | _ -> assert false
 507             in
 508             let hd, tl =
 509               if hd = last_symbol then next, tl @ [hd] else hd, (next::tl)
 510             in
 511             old_used_memory <- List.assoc hd is_used;
 512             let is_used =
 513               (hd,true) :: List.filter (fun (x,_) -> x <> hd) is_used
 514             in
 515             Hashtbl.replace similar_memory similarsymbols_orig is_used;
 516             write_similarsymbol hd;
 517             similarsymbols <- tl @ [ hd ]))
 518     else
 519       match similarsymbols with
 520       | [] -> ()
 521       | hd :: tl ->
 522           let is_used = Hashtbl.find similar_memory similarsymbols_orig in
 523           let last = HExtlib.list_last tl in
 524           let old_used_for_last = old_used_memory in
 525           old_used_memory <- List.assoc hd is_used;
 526           let is_used =
 527             (hd, true) :: (last,old_used_for_last) ::
 528               List.filter (fun (x,_) -> x <> last && x <> hd) is_used
 529           in
 530           Hashtbl.replace similar_memory similarsymbols_orig is_used;
 531           similarsymbols <- tl @ [ hd ];
 532           write_similarsymbol hd
 533
 534   method private reset_similarsymbols =
 535    similarsymbols <- [];
 536    similarsymbols_orig <- [];
 537    try source_view#source_buffer#delete_mark similarsymbols_tag
 538    with GText.No_such_mark _ -> ()
 539
 540   method private expand_virtual_if_any iter tok =
 541     try
 542      let len = MatitaGtkMisc.utf8_string_length tok in
 543      let last_word =
 544       let prev = iter#copy#backward_chars len in
 545        prev#get_slice ~stop:(prev#copy#backward_find_char
 546         (fun x -> Glib.Unichar.isspace x || x = Glib.Utf8.first_char "\\"))
 547      in
 548      let inplaceof, symb = Virtuals.symbol_of_virtual last_word in
 549      self#reset_similarsymbols;
 550      let s = Glib.Utf8.from_unichar symb in
 551      assert(Glib.Utf8.validate s);
 552      source_view#source_buffer#delete ~start:iter
 553        ~stop:(iter#copy#backward_chars
 554          (MatitaGtkMisc.utf8_string_length inplaceof + len));
 555      source_view#source_buffer#insert ~iter
 556        (if inplaceof.[0] = '\\' then s else (s ^ tok));
 557      true
 558     with Virtuals.Not_a_virtual -> false
 559
 560   (** selections / clipboards handling *)
 561
 562   method markupSelected = MatitaMathView.has_selection ()
 563   method private textSelected =
 564     (source_view#source_buffer#get_iter_at_mark `INSERT)#compare
 565       (source_view#source_buffer#get_iter_at_mark `SEL_BOUND) <> 0
 566   method private markupStored = MatitaMathView.has_clipboard ()
 567   method private textStored = clipboard#text <> None
 568   method canCopy = self#textSelected
 569   method canCut = self#textSelected
 570   method canDelete = self#textSelected
 571   (*CSC: WRONG CODE: we should look in the clipboard instead! *)
 572   method canPaste = self#markupStored || self#textStored
 573   method canPastePattern = self#markupStored
 574
 575   method safe_undo =
 576    (* phase 1: we save the actual status of the marks and we undo *)
 577    let locked_mark = `MARK (self#locked_mark) in
 578    let locked_iter = source_view#buffer#get_iter_at_mark locked_mark in
 579    let locked_iter_offset = locked_iter#offset in
 580    let mark2 =
 581     `MARK
 582       (source_view#buffer#create_mark ~name:"lock_point"
 583         ~left_gravity:true locked_iter) in
 584    source_view#source_buffer#undo ();
 585    (* phase 2: we save the cursor position and we redo, restoring
 586       the previous status of all the marks *)
 587    let cursor_iter = source_view#buffer#get_iter_at_mark `INSERT in
 588    let mark =
 589     `MARK
 590       (source_view#buffer#create_mark ~name:"undo_point"
 591         ~left_gravity:true cursor_iter)
 592    in
 593     source_view#source_buffer#redo ();
 594     let mark_iter = source_view#buffer#get_iter_at_mark mark in
 595     let mark2_iter = source_view#buffer#get_iter_at_mark mark2 in
 596     let mark2_iter = mark2_iter#set_offset locked_iter_offset in
 597      source_view#buffer#move_mark locked_mark ~where:mark2_iter;
 598      source_view#buffer#delete_mark mark;
 599      source_view#buffer#delete_mark mark2;
 600      (* phase 3: if after the undo the cursor was in the locked area,
 601         then we move it there again and we perform a goto *)
 602      if mark_iter#offset < locked_iter_offset then
 603       begin
 604        source_view#buffer#move_mark `INSERT ~where:mark_iter;
 605        self#goto `Cursor ();
 606       end;
 607      (* phase 4: we perform again the undo. This time we are sure that
 608         the text to undo is not locked *)
 609      source_view#source_buffer#undo ();
 610      source_view#misc#grab_focus ()
 611
 612   method safe_redo =
 613    (* phase 1: we save the actual status of the marks, we redo and
 614       we undo *)
 615    let locked_mark = `MARK (self#locked_mark) in
 616    let locked_iter = source_view#buffer#get_iter_at_mark locked_mark in
 617    let locked_iter_offset = locked_iter#offset in
 618    let mark2 =
 619     `MARK
 620       (source_view#buffer#create_mark ~name:"lock_point"
 621         ~left_gravity:true locked_iter) in
 622    source_view#source_buffer#redo ();
 623    source_view#source_buffer#undo ();
 624    (* phase 2: we save the cursor position and we restore
 625       the previous status of all the marks *)
 626    let cursor_iter = source_view#buffer#get_iter_at_mark `INSERT in
 627    let mark =
 628     `MARK
 629       (source_view#buffer#create_mark ~name:"undo_point"
 630         ~left_gravity:true cursor_iter)
 631    in
 632     let mark_iter = source_view#buffer#get_iter_at_mark mark in
 633     let mark2_iter = source_view#buffer#get_iter_at_mark mark2 in
 634     let mark2_iter = mark2_iter#set_offset locked_iter_offset in
 635      source_view#buffer#move_mark locked_mark ~where:mark2_iter;
 636      source_view#buffer#delete_mark mark;
 637      source_view#buffer#delete_mark mark2;
 638      (* phase 3: if after the undo the cursor is in the locked area,
 639         then we move it there again and we perform a goto *)
 640      if mark_iter#offset < locked_iter_offset then
 641       begin
 642        source_view#buffer#move_mark `INSERT ~where:mark_iter;
 643        self#goto `Cursor ();
 644       end;
 645      (* phase 4: we perform again the redo. This time we are sure that
 646         the text to redo is not locked *)
 647      source_view#source_buffer#redo ();
 648      source_view#misc#grab_focus ()
 649
 650
 651   method copy () =
 652    if self#textSelected
 653    then begin
 654      MatitaMathView.empty_clipboard ();
 655      source_view#buffer#copy_clipboard clipboard;
 656    end else
 657      MatitaMathView.copy_selection ()
 658
 659   method cut () =
 660    source_view#buffer#cut_clipboard clipboard;
 661    MatitaMathView.empty_clipboard ()
 662
 663   method delete () =
 664    ignore (source_view#buffer#delete_selection ())
 665
 666   method paste () =
 667     if MatitaMathView.has_clipboard ()
 668     then source_view#buffer#insert (MatitaMathView.paste_clipboard `Term)
 669     else source_view#buffer#paste_clipboard clipboard;
 670     self#clean_dirty_lock
 671
 672   method pastePattern () =
 673     source_view#buffer#insert (MatitaMathView.paste_clipboard `Pattern)
 674
 675   method locked_mark = locked_mark
 676   method locked_tag = locked_tag
 677   method error_tag = error_tag
 678
 679     (* history can't be empty, the invariant above grant that it contains at
 680      * least the init grafite_status *)
 681   method grafite_status = match history with s::_ -> s | _ -> assert false
 682
 683   method private _advance ?statement () =
 684    let s = match statement with Some s -> s | None -> self#getFuture in
 685    if self#bos then LibraryClean.clean_baseuris [self#buri_of_current_file];
 686    HLog.debug ("evaluating: " ^ first_line s ^ " ...");
 687    let time1 = Unix.gettimeofday () in
 688    let entries, newtext, parsed_len =
 689     try
 690      eval_statement self#include_paths buffer guistuff
 691       self#grafite_status self (`Raw s)
 692     with End_of_file -> raise Margin
 693    in
 694    let time2 = Unix.gettimeofday () in
 695    HLog.debug ("... done in " ^ string_of_float (time2 -. time1) ^ "s");
 696    let new_statuses, new_statements =
 697      let statuses, texts = List.split entries in
 698      statuses, texts
 699    in
 700    history <- new_statuses @ history;
 701    statements <- new_statements @ statements;
 702    let start = buffer#get_iter_at_mark (`MARK locked_mark) in
 703    let new_text = String.concat "" (List.rev new_statements) in
 704    if statement <> None then
 705      buffer#insert ~iter:start new_text
 706    else begin
 707      let parsed_text = String.sub s 0 parsed_len in
 708      if new_text <> parsed_text then begin
 709        let stop = start#copy#forward_chars (Glib.Utf8.length parsed_text) in
 710        buffer#delete ~start ~stop;
 711        buffer#insert ~iter:start new_text;
 712      end;
 713    end;
 714    self#moveMark (Glib.Utf8.length new_text);
 715    buffer#insert ~iter:(buffer#get_iter_at_mark (`MARK locked_mark)) newtext
 716
 717   method private _retract offset grafite_status new_statements new_history =
 718     NCicLibrary.time_travel grafite_status;
 719     statements <- new_statements;
 720     history <- new_history;
 721     self#moveMark (- offset)
 722
 723   method advance ?statement () =
 724     try
 725       self#_advance ?statement ();
 726       self#notify
 727     with
 728     | Margin -> self#notify
 729     | Not_found -> assert false
 730     | Invalid_argument "Array.make" -> HLog.error "The script is too big!\n"
 731     | exc -> self#notify; raise exc
 732
 733   method retract () =
 734     try
 735       let cmp,new_statements,new_history,grafite_status =
 736        match statements,history with
 737           stat::statements, _::(status::_ as history) ->
 738            assert (Glib.Utf8.validate stat);
 739            Glib.Utf8.length stat, statements, history, status
 740        | [],[_] -> raise Margin
 741        | _,_ -> assert false
 742       in
 743        self#_retract cmp grafite_status new_statements
 744         new_history;
 745        self#notify
 746     with
 747     | Margin -> self#notify
 748     | Invalid_argument "Array.make" -> HLog.error "The script is too big!\n"
 749     | exc -> self#notify; raise exc
 750
 751   method private getFuture =
 752     let lock = buffer#get_iter_at_mark (`MARK locked_mark) in
 753     let text = buffer#get_text ~start:lock ~stop:buffer#end_iter () in
 754     text
 755
 756   method expandAllVirtuals =
 757     let lock = buffer#get_iter_at_mark (`MARK locked_mark) in
 758     let text = buffer#get_text ~start:lock ~stop:buffer#end_iter () in
 759     buffer#delete ~start:lock ~stop:buffer#end_iter;
 760     let text = Pcre.replace ~pat:":=" ~templ:"\\def" text in
 761     let text = Pcre.replace ~pat:"->" ~templ:"\\to" text in
 762     let text = Pcre.replace ~pat:"=>" ~templ:"\\Rightarrow" text in
 763     let text =
 764       Pcre.substitute_substrings
 765         ~subst:(fun str ->
 766            let pristine = Pcre.get_substring str 0 in
 767            let input =
 768              if pristine.[0] = ' ' then
 769                String.sub pristine 1 (String.length pristine -1)
 770              else pristine
 771            in
 772            let input =
 773              if input.[String.length input-1] = ' ' then
 774                String.sub input 0 (String.length input -1)
 775              else input
 776            in
 777            let before, after =
 778              if input = "\\forall" ||
 779                 input = "\\lambda" ||
 780                 input = "\\exists" then "","" else " ", " "
 781            in
 782            try
 783              before ^ Glib.Utf8.from_unichar
 784                (snd (Virtuals.symbol_of_virtual input)) ^ after
 785            with Virtuals.Not_a_virtual -> pristine)
 786         ~pat:" ?\\\\[a-zA-Z]+ ?" text
 787     in
 788     buffer#insert ~iter:lock text
 789
 790   (** @param rel_offset relative offset from current position of locked_mark *)
 791   method private moveMark rel_offset =
 792     let mark = `MARK locked_mark in
 793     let old_insert = buffer#get_iter_at_mark `INSERT in
 794     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 795     let current_mark_pos = buffer#get_iter_at_mark mark in
 796     let new_mark_pos =
 797       match rel_offset with
 798       | 0 -> current_mark_pos
 799       | n when n > 0 -> current_mark_pos#forward_chars n
 800       | n (* when n < 0 *) -> current_mark_pos#backward_chars (abs n)
 801     in
 802     buffer#move_mark mark ~where:new_mark_pos;
 803     buffer#apply_tag locked_tag ~start:buffer#start_iter ~stop:new_mark_pos;
 804     buffer#move_mark `INSERT old_insert;
 805     let mark_position = buffer#get_iter_at_mark mark in
 806     if source_view#move_mark_onscreen mark then
 807      begin
 808       buffer#move_mark mark mark_position;
 809       source_view#scroll_to_mark ~use_align:true ~xalign:1.0 ~yalign:0.1 mark;
 810      end;
 811     while Glib.Main.pending () do ignore(Glib.Main.iteration false); done
 812
 813   method clean_dirty_lock =
 814     let lock_mark_iter = buffer#get_iter_at_mark (`MARK locked_mark) in
 815     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 816     buffer#apply_tag locked_tag ~start:buffer#start_iter ~stop:lock_mark_iter
 817
 818   val mutable observers = []
 819
 820   method addObserver (o: GrafiteTypes.status -> unit) =
 821     observers <- o :: observers
 822
 823   method private notify =
 824     let grafite_status = self#grafite_status in
 825     List.iter (fun o -> o grafite_status) observers
 826
 827   method activate =
 828     self#notify
 829
 830   method loadFromFile f =
 831     buffer#set_text (HExtlib.input_file f);
 832     self#reset_buffer;
 833     buffer#set_modified false
 834
 835   method assignFileName file =
 836    match file with
 837       None ->
 838        tab_label#set_text default_fname;
 839        filename_ <- None;
 840        include_paths_ <- [];
 841        self#reset_buffer
 842     | Some file ->
 843        let f = Librarian.absolutize file in
 844         tab_label#set_text (Filename.basename f);
 845         filename_ <- Some f;
 846         include_paths_ <- read_include_paths f;
 847         self#reset_buffer
 848
 849   method set_star b =
 850    tab_label#set_text ((if b then "*" else "")^Filename.basename self#filename);
 851    tab_label#misc#set_tooltip_text
 852     ("URI: " ^ self#buri_of_current_file ^ "\nPATH: " ^ self#filename);
 853
 854   method saveToFile () =
 855     if self#has_name then
 856       let oc = open_out self#filename in
 857       output_string oc (buffer#get_text ~start:buffer#start_iter
 858                         ~stop:buffer#end_iter ());
 859       close_out oc;
 860       self#set_star false;
 861       buffer#set_modified false
 862     else
 863       HLog.error "Can't save, no filename selected"
 864
 865   method private _saveToBackupFile () =
 866     if buffer#modified then
 867       begin
 868         let f = self#filename in
 869         let oc = open_out f in
 870         output_string oc (buffer#get_text ~start:buffer#start_iter
 871                             ~stop:buffer#end_iter ());
 872         close_out oc;
 873         HLog.debug ("backup " ^ f ^ " saved")
 874       end
 875
 876   method private reset_buffer =
 877     statements <- [];
 878     history <- [ initial_statuses (Some self#grafite_status) self#buri_of_current_file ];
 879     self#notify;
 880     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 881     buffer#move_mark (`MARK locked_mark) ~where:buffer#start_iter
 882
 883   method reset () =
 884     self#reset_buffer;
 885     source_buffer#begin_not_undoable_action ();
 886     buffer#delete ~start:buffer#start_iter ~stop:buffer#end_iter;
 887     source_buffer#end_not_undoable_action ();
 888     buffer#set_modified false;
 889
 890   method template () =
 891     let template = HExtlib.input_file BuildTimeConf.script_template in
 892     buffer#insert ~iter:(buffer#get_iter `START) template;
 893     buffer#set_modified false;
 894     self#set_star false;
 895
 896   method goto (pos: [`Top | `Bottom | `Cursor]) () =
 897   try
 898     let old_locked_mark =
 899      `MARK
 900        (buffer#create_mark ~name:"old_locked_mark"
 901          ~left_gravity:true (buffer#get_iter_at_mark (`MARK locked_mark))) in
 902     let getpos _ = buffer#get_iter_at_mark (`MARK locked_mark) in
 903     let getoldpos _ = buffer#get_iter_at_mark old_locked_mark in
 904     let dispose_old_locked_mark () = buffer#delete_mark old_locked_mark in
 905     match pos with
 906     | `Top ->
 907         dispose_old_locked_mark ();
 908         self#reset_buffer;
 909         self#notify
 910     | `Bottom ->
 911         (try
 912           let rec dowhile () =
 913             self#_advance ();
 914             let newpos = getpos () in
 915             if (getoldpos ())#compare newpos < 0 then
 916               begin
 917                 buffer#move_mark old_locked_mark newpos;
 918                 dowhile ()
 919               end
 920           in
 921           dowhile ();
 922           dispose_old_locked_mark ();
 923           self#notify
 924         with
 925         | Margin -> dispose_old_locked_mark (); self#notify
 926         | exc -> dispose_old_locked_mark (); self#notify; raise exc)
 927     | `Cursor ->
 928         let locked_iter () = buffer#get_iter_at_mark (`NAME "locked") in
 929         let cursor_iter () = buffer#get_iter_at_mark `INSERT in
 930         let remember =
 931          `MARK
 932            (buffer#create_mark ~name:"initial_insert"
 933              ~left_gravity:true (cursor_iter ())) in
 934         let dispose_remember () = buffer#delete_mark remember in
 935         let remember_iter () =
 936          buffer#get_iter_at_mark (`NAME "initial_insert") in
 937         let cmp () = (locked_iter ())#offset - (remember_iter ())#offset in
 938         let icmp = cmp () in
 939         let forward_until_cursor () = (* go forward until locked > cursor *)
 940           let rec aux () =
 941             self#_advance ();
 942             if cmp () < 0 && (getoldpos ())#compare (getpos ()) < 0
 943             then
 944              begin
 945               buffer#move_mark old_locked_mark (getpos ());
 946               aux ()
 947              end
 948           in
 949           aux ()
 950         in
 951         let rec back_until_cursor len = (* go backward until locked < cursor *)
 952          function
 953             statements, ((grafite_status)::_ as history)
 954             when len <= 0 ->
 955              self#_retract (icmp - len) grafite_status statements
 956               history
 957           | statement::tl1, _::tl2 ->
 958              back_until_cursor (len - MatitaGtkMisc.utf8_string_length statement) (tl1,tl2)
 959           | _,_ -> assert false
 960         in
 961         (try
 962           begin
 963            if icmp < 0 then       (* locked < cursor *)
 964              (forward_until_cursor (); self#notify)
 965            else if icmp > 0 then  (* locked > cursor *)
 966              (back_until_cursor icmp (statements,history); self#notify)
 967            else                  (* cursor = locked *)
 968                ()
 969           end ;
 970           dispose_remember ();
 971           dispose_old_locked_mark ();
 972         with
 973         | Margin -> dispose_remember (); dispose_old_locked_mark (); self#notify
 974         | exc -> dispose_remember (); dispose_old_locked_mark ();
 975                  self#notify; raise exc)
 976   with Invalid_argument "Array.make" ->
 977      HLog.error "The script is too big!\n"
 978
 979   method bos =
 980     match history with
 981     | _::[] -> true
 982     | _ -> false
 983
 984   method eos =
 985     let rec is_there_only_comments lexicon_status s =
 986       if Pcre.pmatch ~rex:only_dust_RE s then raise Margin;
 987       let strm =
 988        GrafiteParser.parsable_statement lexicon_status
 989         (Ulexing.from_utf8_string s)in
 990       match GrafiteParser.parse_statement lexicon_status strm with
 991       | GrafiteAst.Comment (loc,_) ->
 992           let _,parsed_text_length = MatitaGtkMisc.utf8_parsed_text s loc in
 993           (* CSC: why +1 in the following lines ???? *)
 994           let parsed_text_length = parsed_text_length + 1 in
 995           let remain_len = String.length s - parsed_text_length in
 996           let next = String.sub s parsed_text_length remain_len in
 997           is_there_only_comments lexicon_status next
 998       | GrafiteAst.Executable _ -> false
 999     in
1000     try is_there_only_comments self#grafite_status self#getFuture
1001     with
1002     | NCicLibrary.IncludedFileNotCompiled _
1003     | HExtlib.Localized _
1004     | CicNotationParser.Parse_error _ -> false
1005     | Margin | End_of_file -> true
1006     | Invalid_argument "Array.make" -> false
1007
1008   (* debug *)
1009   method dump () =
1010     HLog.debug "script status:";
1011     HLog.debug ("history size: " ^ string_of_int (List.length history));
1012     HLog.debug (sprintf "%d statements:" (List.length statements));
1013     List.iter HLog.debug statements;
1014     HLog.debug ("Current file name: " ^ self#filename);
1015
1016   method has_parent (p : GObj.widget) = parent#coerce#misc#get_oid = p#misc#get_oid
1017 end
1018
1019 let _script = ref []
1020
1021 let script ~urichooser ~ask_confirmation ~parent ~tab_label ()
1022 =
1023   let s = new script ~ask_confirmation ~urichooser ~parent ~tab_label () in
1024   _script := s::!_script;
1025   s
1026
1027 let at_page page =
1028  let notebook = (MatitaMisc.get_gui ())#main#scriptNotebook in
1029  let parent = notebook#get_nth_page page in
1030   try
1031    List.find (fun s -> s#has_parent parent) !_script
1032   with
1033    Not_found -> assert false
1034 ;;
1035
1036 let current () =
1037  at_page ((MatitaMisc.get_gui ())#main#scriptNotebook#current_page)
1038
1039 let iter_scripts f = List.iter f !_script;;
1040
1041 let _ =
1042  CicMathView.register_matita_script_current (current :> unit -> < advance: ?statement:string -> unit -> unit; grafite_status: GrafiteTypes.status >)
1043 ;;