matita/matita/matitaScript.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29 open GrafiteTypes
  30
  31 module TA = GrafiteAst
  32
  33 let debug = false
  34 let debug_print = if debug then prerr_endline else ignore
  35
  36   (** raised when one of the script margins (top or bottom) is reached *)
  37 exception Margin
  38 exception NoUnfinishedProof
  39 exception ActionCancelled of string
  40
  41 let safe_substring s i j =
  42   try String.sub s i j with Invalid_argument _ -> assert false
  43
  44 let heading_nl_RE = Pcre.regexp "^\\s*\n\\s*"
  45 let heading_nl_RE' = Pcre.regexp "^(\\s*\n\\s*)"
  46 let only_dust_RE = Pcre.regexp "^(\\s|\n|%%[^\n]*\n)*$"
  47 let multiline_RE = Pcre.regexp "^\n[^\n]+$"
  48 let newline_RE = Pcre.regexp "\n"
  49 let comment_RE = Pcre.regexp "\\(\\*(.|\n)*\\*\\)\n?" ~flags:[`UNGREEDY]
  50
  51 let comment str =
  52   if Pcre.pmatch ~rex:multiline_RE str then
  53     "\n(** " ^ (Pcre.replace ~rex:newline_RE str) ^ " *)"
  54   else
  55     "\n(**\n" ^ str ^ "\n*)"
  56
  57 let strip_comments str =
  58   Pcre.qreplace ~templ:"\n" ~pat:"\n\n" (Pcre.qreplace ~rex:comment_RE str)
  59 ;;
  60
  61 let first_line s =
  62   let s = Pcre.replace ~rex:heading_nl_RE s in
  63   try
  64     let nl_pos = String.index s '\n' in
  65     String.sub s 0 nl_pos
  66   with Not_found -> s
  67
  68 type guistuff = {
  69   urichooser: NReference.reference list -> NReference.reference list;
  70   ask_confirmation: title:string -> message:string -> [`YES | `NO | `CANCEL];
  71 }
  72
  73 let eval_with_engine include_paths guistuff grafite_status user_goal
  74  skipped_txt nonskipped_txt st
  75 =
  76   let parsed_text_length =
  77     String.length skipped_txt + String.length nonskipped_txt
  78   in
  79   let text = skipped_txt ^ nonskipped_txt in
  80   let prefix_len = MatitaGtkMisc.utf8_string_length skipped_txt in
  81   let enriched_history_fragment =
  82    MatitaEngine.eval_ast ~include_paths ~do_heavy_checks:(Helm_registry.get_bool
  83      "matita.do_heavy_checks")
  84     grafite_status (text,prefix_len,st)
  85   in
  86   let enriched_history_fragment = List.rev enriched_history_fragment in
  87   (* really fragile *)
  88   let res,_ =
  89     List.fold_left
  90       (fun (acc, to_prepend) (status,alias) ->
  91        match alias with
  92        | None -> (status,to_prepend ^ nonskipped_txt)::acc,""
  93        | Some (k,value) ->
  94             let newtxt = GrafiteAstPp.pp_alias value in
  95             (status,to_prepend ^ newtxt ^ "\n")::acc, "")
  96       ([],skipped_txt) enriched_history_fragment
  97   in
  98   res,"",parsed_text_length
  99 ;;
 100
 101 let pp_eager_statement_ast = GrafiteAstPp.pp_statement
 102
 103 let eval_nmacro include_paths (buffer : GText.buffer) guistuff grafite_status user_goal unparsed_text parsed_text script mac =
 104   let parsed_text_length = String.length parsed_text in
 105   match mac with
 106   | TA.Screenshot (_,name) ->
 107        let status = script#grafite_status in
 108        let _,_,menv,subst,_ = status#obj in
 109        let name = Filename.dirname (script#filename) ^ "/" ^ name in
 110        let sequents =
 111          let selected = Continuationals.Stack.head_goals status#stack in
 112          List.filter (fun x,_ -> List.mem x selected) menv
 113        in
 114        CicMathView.screenshot status sequents menv subst name;
 115        [status, parsed_text], "", parsed_text_length
 116   | TA.NCheck (_,t) ->
 117       let status = script#grafite_status in
 118       let _,_,menv,subst,_ = status#obj in
 119       let ctx =
 120        match Continuationals.Stack.head_goals status#stack with
 121           [] -> []
 122         | g::tl ->
 123            if tl <> [] then
 124             HLog.warn
 125              "Many goals focused. Using the context of the first one\n";
 126            let _, ctx, _ = NCicUtils.lookup_meta g menv in
 127             ctx in
 128       let m, s, status, t =
 129         GrafiteDisambiguate.disambiguate_nterm
 130           status None ctx menv subst (parsed_text,parsed_text_length,
 131             NotationPt.Cast (t,NotationPt.Implicit `JustOne))
 132           (* XXX use the metasenv, if possible *)
 133       in
 134       MatitaMathView.show_entry (`NCic (t,ctx,m,s));
 135       [status, parsed_text], "", parsed_text_length
 136   | TA.NIntroGuess _loc ->
 137       let names_ref = ref [] in
 138       let s =
 139         NTactics.intros_tac ~names_ref [] script#grafite_status
 140       in
 141       let rex = Pcre.regexp ~flags:[`MULTILINE] "\\A([\\n\\t\\r ]*).*\\Z" in
 142       let nl = Pcre.replace ~rex ~templ:"$1" parsed_text in
 143       [s, nl ^ "#" ^ String.concat " " !names_ref ^ ";"], "", parsed_text_length
 144   | TA.NAutoInteractive (_loc, (None,a)) ->
 145       let trace_ref = ref [] in
 146       let s =
 147         NnAuto.auto_tac
 148           ~params:(None,a) ~trace_ref script#grafite_status
 149       in
 150       let depth =
 151         try List.assoc "depth" a
 152         with Not_found -> ""
 153       in
 154       let trace = "/"^(if int_of_string depth > 1 then depth else "")^"/ by " in
 155       let thms =
 156         match !trace_ref with
 157         | [] -> "{}"
 158         | thms ->
 159            String.concat ", "
 160              (HExtlib.filter_map (function
 161                | NotationPt.NRef r -> Some (NCicPp.r2s true r)
 162                | _ -> None)
 163              thms)
 164       in
 165       let rex = Pcre.regexp ~flags:[`MULTILINE] "\\A([\\n\\t\\r ]*).*\\Z" in
 166       let nl = Pcre.replace ~rex ~templ:"$1" parsed_text in
 167       [s, nl ^ trace ^ thms ^ ";"], "", parsed_text_length
 168   | TA.NAutoInteractive (_, (Some _,_)) -> assert false
 169
 170 let rec eval_executable include_paths (buffer : GText.buffer) guistuff
 171 grafite_status user_goal unparsed_text skipped_txt nonskipped_txt
 172 script ex loc
 173 =
 174   try
 175    ignore (buffer#move_mark (`NAME "beginning_of_statement")
 176     ~where:((buffer#get_iter_at_mark (`NAME "locked"))#forward_chars
 177        (Glib.Utf8.length skipped_txt))) ;
 178    eval_with_engine include_paths
 179     guistuff grafite_status user_goal skipped_txt nonskipped_txt
 180      (TA.Executable (loc, ex))
 181   with
 182      MatitaTypes.Cancel -> [], "", 0
 183    | GrafiteEngine.NMacro (_loc,macro) ->
 184        eval_nmacro include_paths buffer guistuff grafite_status
 185         user_goal unparsed_text (skipped_txt ^ nonskipped_txt) script macro
 186
 187
 188 and eval_statement include_paths (buffer : GText.buffer) guistuff
 189  grafite_status user_goal script statement
 190 =
 191   let st,unparsed_text =
 192     match statement with
 193     | `Raw text ->
 194         if Pcre.pmatch ~rex:only_dust_RE text then raise Margin;
 195         let strm =
 196          GrafiteParser.parsable_statement grafite_status
 197           (Ulexing.from_utf8_string text) in
 198         let ast = MatitaEngine.get_ast grafite_status include_paths strm in
 199          ast, text
 200     | `Ast (st, text) -> st, text
 201   in
 202   let text_of_loc floc =
 203     let nonskipped_txt,_ = MatitaGtkMisc.utf8_parsed_text unparsed_text floc in
 204     let start, stop = HExtlib.loc_of_floc floc in
 205     let floc = HExtlib.floc_of_loc (0, start) in
 206     let skipped_txt,_ = MatitaGtkMisc.utf8_parsed_text unparsed_text floc in
 207     let floc = HExtlib.floc_of_loc (0, stop) in
 208     let txt,len = MatitaGtkMisc.utf8_parsed_text unparsed_text floc in
 209     txt,nonskipped_txt,skipped_txt,len
 210   in
 211   match st with
 212   | GrafiteAst.Executable (loc, ex) ->
 213      let _, nonskipped, skipped, parsed_text_length = text_of_loc loc in
 214       eval_executable include_paths buffer guistuff
 215        grafite_status user_goal unparsed_text skipped nonskipped script ex loc
 216   | GrafiteAst.Comment (loc, GrafiteAst.Code (_, ex))
 217     when Helm_registry.get_bool "matita.execcomments" ->
 218      let _, nonskipped, skipped, parsed_text_length = text_of_loc loc in
 219       eval_executable include_paths buffer guistuff
 220        grafite_status user_goal unparsed_text skipped nonskipped script ex loc
 221   | GrafiteAst.Comment (loc, _) ->
 222       let parsed_text, _, _, parsed_text_length = text_of_loc loc in
 223       let remain_len = String.length unparsed_text - parsed_text_length in
 224       let s = String.sub unparsed_text parsed_text_length remain_len in
 225       let s,text,len =
 226        try
 227         eval_statement include_paths buffer guistuff
 228          grafite_status user_goal script (`Raw s)
 229        with
 230           HExtlib.Localized (floc, exn) ->
 231            HExtlib.raise_localized_exception
 232              ~offset:(MatitaGtkMisc.utf8_string_length parsed_text) floc exn
 233         | MultiPassDisambiguator.DisambiguationError (offset,errorll) ->
 234            raise
 235             (MultiPassDisambiguator.DisambiguationError
 236               (offset+parsed_text_length, errorll))
 237       in
 238       assert (text=""); (* no macros inside comments, please! *)
 239       (match s with
 240       | (statuses,text)::tl ->
 241          (statuses,parsed_text ^ text)::tl,"",parsed_text_length + len
 242       | [] -> [], "", 0)
 243
 244 let fresh_script_id =
 245   let i = ref 0 in
 246   fun () -> incr i; !i
 247
 248 class script  ~(source_view: GSourceView2.source_view)
 249               ~set_star
 250               ~ask_confirmation
 251               ~urichooser
 252               () =
 253 let buffer = source_view#buffer in
 254 let source_buffer = source_view#source_buffer in
 255 let initial_statuses current baseuri =
 256  let empty_lstatus = new GrafiteDisambiguate.status in
 257  (match current with
 258      Some current ->
 259       NCicLibrary.time_travel
 260        ((new GrafiteTypes.status current#baseuri)#set_disambiguate_db current#disambiguate_db);
 261       (* CSC: there is a known bug in invalidation; temporary fix here *)
 262       NCicEnvironment.invalidate ()
 263    | None -> ());
 264  let lexicon_status = empty_lstatus in
 265  let grafite_status = (new GrafiteTypes.status baseuri)#set_disambiguate_db lexicon_status#disambiguate_db in
 266   grafite_status
 267 in
 268 let read_include_paths file =
 269  try
 270    let root, _buri, _fname, _tgt =
 271      Librarian.baseuri_of_script ~include_paths:[] file
 272    in
 273    let rc =
 274     Str.split (Str.regexp " ")
 275      (List.assoc "include_paths" (Librarian.load_root_file (root^"/root")))
 276    in
 277    List.iter (HLog.debug) rc; rc
 278  with Librarian.NoRootFor _ | Not_found -> []
 279 in
 280 let default_buri = "cic:/matita/tests" in
 281 let default_fname = ".unnamed.ma" in
 282 object (self)
 283   val mutable include_paths_ = []
 284
 285   val scriptId = fresh_script_id ()
 286
 287   val guistuff = {
 288     urichooser = urichooser;
 289     ask_confirmation = ask_confirmation;
 290   }
 291
 292   val mutable filename_ = (None : string option)
 293
 294   method has_name = filename_ <> None
 295
 296   method include_paths =
 297     include_paths_ @
 298     Helm_registry.get_list Helm_registry.string "matita.includes"
 299
 300   method private curdir =
 301     try
 302      let root, _buri, _fname, _tgt =
 303        Librarian.baseuri_of_script ~include_paths:self#include_paths
 304        self#filename
 305      in
 306      root
 307     with Librarian.NoRootFor _ -> Sys.getcwd ()
 308
 309   method buri_of_current_file =
 310     match filename_ with
 311     | None -> default_buri
 312     | Some f ->
 313         try
 314           let _root, buri, _fname, _tgt =
 315             Librarian.baseuri_of_script ~include_paths:self#include_paths f
 316           in
 317           buri
 318         with Librarian.NoRootFor _ -> default_buri
 319
 320   method filename = match filename_ with None -> default_fname | Some f -> f
 321
 322   initializer
 323     ignore (GMain.Timeout.add ~ms:300000
 324        ~callback:(fun _ -> self#_saveToBackupFile ();true));
 325     ignore (buffer#connect#modified_changed
 326       (fun _ -> set_star buffer#modified))
 327
 328   val mutable statements = []    (** executed statements *)
 329
 330   val mutable history = [ initial_statuses None default_buri ]
 331     (** list of states before having executed statements. Head element of this
 332       * list is the current state, last element is the state at the beginning of
 333       * the script.
 334       * Invariant: this list length is 1 + length of statements *)
 335
 336   (** goal as seen by the user (i.e. metano corresponding to current tab) *)
 337   val mutable userGoal = (None : int option)
 338
 339   (** text mark and tag representing locked part of a script *)
 340   val locked_mark =
 341     buffer#create_mark ~name:"locked" ~left_gravity:true buffer#start_iter
 342   val beginning_of_statement_mark =
 343     buffer#create_mark ~name:"beginning_of_statement"
 344      ~left_gravity:true buffer#start_iter
 345   val locked_tag = buffer#create_tag [`BACKGROUND "lightblue"; `EDITABLE false]
 346   val error_tag = buffer#create_tag [`UNDERLINE `SINGLE; `FOREGROUND "red"]
 347
 348   method locked_mark = locked_mark
 349   method locked_tag = locked_tag
 350   method error_tag = error_tag
 351
 352     (* history can't be empty, the invariant above grant that it contains at
 353      * least the init grafite_status *)
 354   method grafite_status = match history with s::_ -> s | _ -> assert false
 355
 356   method private _advance ?statement () =
 357    let s = match statement with Some s -> s | None -> self#getFuture in
 358    if self#bos then LibraryClean.clean_baseuris [self#buri_of_current_file];
 359    HLog.debug ("evaluating: " ^ first_line s ^ " ...");
 360    let time1 = Unix.gettimeofday () in
 361    let entries, newtext, parsed_len =
 362     try
 363      eval_statement self#include_paths buffer guistuff
 364       self#grafite_status userGoal self (`Raw s)
 365     with End_of_file -> raise Margin
 366    in
 367    let time2 = Unix.gettimeofday () in
 368    HLog.debug ("... done in " ^ string_of_float (time2 -. time1) ^ "s");
 369    let new_statuses, new_statements =
 370      let statuses, texts = List.split entries in
 371      statuses, texts
 372    in
 373    history <- new_statuses @ history;
 374    statements <- new_statements @ statements;
 375    let start = buffer#get_iter_at_mark (`MARK locked_mark) in
 376    let new_text = String.concat "" (List.rev new_statements) in
 377    if statement <> None then
 378      buffer#insert ~iter:start new_text
 379    else begin
 380      let parsed_text = String.sub s 0 parsed_len in
 381      if new_text <> parsed_text then begin
 382        let stop = start#copy#forward_chars (Glib.Utf8.length parsed_text) in
 383        buffer#delete ~start ~stop;
 384        buffer#insert ~iter:start new_text;
 385      end;
 386    end;
 387    self#moveMark (Glib.Utf8.length new_text);
 388    buffer#insert ~iter:(buffer#get_iter_at_mark (`MARK locked_mark)) newtext;
 389    (* here we need to set the Goal in case we are going to cursor (or to
 390       bottom) and we will face a macro *)
 391     userGoal <- None
 392
 393   method private _retract offset grafite_status new_statements new_history =
 394     NCicLibrary.time_travel grafite_status;
 395     statements <- new_statements;
 396     history <- new_history;
 397     self#moveMark (- offset)
 398
 399   method advance ?statement () =
 400     try
 401       self#_advance ?statement ();
 402       self#notify
 403     with
 404     | Margin -> self#notify
 405     | Not_found -> assert false
 406     | Invalid_argument "Array.make" -> HLog.error "The script is too big!\n"
 407     | exc -> self#notify; raise exc
 408
 409   method retract () =
 410     try
 411       let cmp,new_statements,new_history,grafite_status =
 412        match statements,history with
 413           stat::statements, _::(status::_ as history) ->
 414            assert (Glib.Utf8.validate stat);
 415            Glib.Utf8.length stat, statements, history, status
 416        | [],[_] -> raise Margin
 417        | _,_ -> assert false
 418       in
 419        self#_retract cmp grafite_status new_statements
 420         new_history;
 421        self#notify
 422     with
 423     | Margin -> self#notify
 424     | Invalid_argument "Array.make" -> HLog.error "The script is too big!\n"
 425     | exc -> self#notify; raise exc
 426
 427   method private getFuture =
 428     let lock = buffer#get_iter_at_mark (`MARK locked_mark) in
 429     let text = buffer#get_text ~start:lock ~stop:buffer#end_iter () in
 430     text
 431
 432   method expandAllVirtuals =
 433     let lock = buffer#get_iter_at_mark (`MARK locked_mark) in
 434     let text = buffer#get_text ~start:lock ~stop:buffer#end_iter () in
 435     buffer#delete ~start:lock ~stop:buffer#end_iter;
 436     let text = Pcre.replace ~pat:":=" ~templ:"\\def" text in
 437     let text = Pcre.replace ~pat:"->" ~templ:"\\to" text in
 438     let text = Pcre.replace ~pat:"=>" ~templ:"\\Rightarrow" text in
 439     let text =
 440       Pcre.substitute_substrings
 441         ~subst:(fun str ->
 442            let pristine = Pcre.get_substring str 0 in
 443            let input =
 444              if pristine.[0] = ' ' then
 445                String.sub pristine 1 (String.length pristine -1)
 446              else pristine
 447            in
 448            let input =
 449              if input.[String.length input-1] = ' ' then
 450                String.sub input 0 (String.length input -1)
 451              else input
 452            in
 453            let before, after =
 454              if input = "\\forall" ||
 455                 input = "\\lambda" ||
 456                 input = "\\exists" then "","" else " ", " "
 457            in
 458            try
 459              before ^ Glib.Utf8.from_unichar
 460                (snd (Virtuals.symbol_of_virtual input)) ^ after
 461            with Virtuals.Not_a_virtual -> pristine)
 462         ~pat:" ?\\\\[a-zA-Z]+ ?" text
 463     in
 464     buffer#insert ~iter:lock text
 465
 466   (** @param rel_offset relative offset from current position of locked_mark *)
 467   method private moveMark rel_offset =
 468     let mark = `MARK locked_mark in
 469     let old_insert = buffer#get_iter_at_mark `INSERT in
 470     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 471     let current_mark_pos = buffer#get_iter_at_mark mark in
 472     let new_mark_pos =
 473       match rel_offset with
 474       | 0 -> current_mark_pos
 475       | n when n > 0 -> current_mark_pos#forward_chars n
 476       | n (* when n < 0 *) -> current_mark_pos#backward_chars (abs n)
 477     in
 478     buffer#move_mark mark ~where:new_mark_pos;
 479     buffer#apply_tag locked_tag ~start:buffer#start_iter ~stop:new_mark_pos;
 480     buffer#move_mark `INSERT old_insert;
 481     let mark_position = buffer#get_iter_at_mark mark in
 482     if source_view#move_mark_onscreen mark then
 483      begin
 484       buffer#move_mark mark mark_position;
 485       source_view#scroll_to_mark ~use_align:true ~xalign:1.0 ~yalign:0.1 mark;
 486      end;
 487     while Glib.Main.pending () do ignore(Glib.Main.iteration false); done
 488
 489   method clean_dirty_lock =
 490     let lock_mark_iter = buffer#get_iter_at_mark (`MARK locked_mark) in
 491     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 492     buffer#apply_tag locked_tag ~start:buffer#start_iter ~stop:lock_mark_iter
 493
 494   val mutable observers = []
 495
 496   method addObserver (o: GrafiteTypes.status -> unit) =
 497     observers <- o :: observers
 498
 499   method private notify =
 500     let grafite_status = self#grafite_status in
 501     List.iter (fun o -> o grafite_status) observers
 502
 503   method loadFromString s =
 504     buffer#set_text s;
 505     self#reset_buffer;
 506     buffer#set_modified true
 507
 508   method loadFromFile f =
 509     buffer#set_text (HExtlib.input_file f);
 510     self#reset_buffer;
 511     buffer#set_modified false
 512
 513   method assignFileName file =
 514     let file =
 515       match file with
 516       | Some f -> Some (Librarian.absolutize f)
 517       | None -> None
 518     in
 519     filename_ <- file;
 520     include_paths_ <-
 521       (match file with Some file -> read_include_paths file | None -> []);
 522     self#reset_buffer;
 523     Sys.chdir self#curdir;
 524     HLog.debug ("Moving to " ^ Sys.getcwd ())
 525
 526   method saveToFile () =
 527     if self#has_name then
 528       let oc = open_out self#filename in
 529       output_string oc (buffer#get_text ~start:buffer#start_iter
 530                         ~stop:buffer#end_iter ());
 531       close_out oc;
 532       set_star false;
 533       buffer#set_modified false
 534     else
 535       HLog.error "Can't save, no filename selected"
 536
 537   method private _saveToBackupFile () =
 538     if buffer#modified then
 539       begin
 540         let f = self#filename in
 541         let oc = open_out f in
 542         output_string oc (buffer#get_text ~start:buffer#start_iter
 543                             ~stop:buffer#end_iter ());
 544         close_out oc;
 545         HLog.debug ("backup " ^ f ^ " saved")
 546       end
 547
 548   method private reset_buffer =
 549     statements <- [];
 550     history <- [ initial_statuses (Some self#grafite_status) self#buri_of_current_file ];
 551     userGoal <- None;
 552     self#notify;
 553     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 554     buffer#move_mark (`MARK locked_mark) ~where:buffer#start_iter
 555
 556   method reset () =
 557     self#reset_buffer;
 558     source_buffer#begin_not_undoable_action ();
 559     buffer#delete ~start:buffer#start_iter ~stop:buffer#end_iter;
 560     source_buffer#end_not_undoable_action ();
 561     buffer#set_modified false;
 562
 563   method template () =
 564     let template = HExtlib.input_file BuildTimeConf.script_template in
 565     buffer#insert ~iter:(buffer#get_iter `START) template;
 566     buffer#set_modified false;
 567     set_star false
 568
 569   method goto (pos: [`Top | `Bottom | `Cursor]) () =
 570   try
 571     let old_locked_mark =
 572      `MARK
 573        (buffer#create_mark ~name:"old_locked_mark"
 574          ~left_gravity:true (buffer#get_iter_at_mark (`MARK locked_mark))) in
 575     let getpos _ = buffer#get_iter_at_mark (`MARK locked_mark) in
 576     let getoldpos _ = buffer#get_iter_at_mark old_locked_mark in
 577     let dispose_old_locked_mark () = buffer#delete_mark old_locked_mark in
 578     match pos with
 579     | `Top ->
 580         dispose_old_locked_mark ();
 581         self#reset_buffer;
 582         self#notify
 583     | `Bottom ->
 584         (try
 585           let rec dowhile () =
 586             self#_advance ();
 587             let newpos = getpos () in
 588             if (getoldpos ())#compare newpos < 0 then
 589               begin
 590                 buffer#move_mark old_locked_mark newpos;
 591                 dowhile ()
 592               end
 593           in
 594           dowhile ();
 595           dispose_old_locked_mark ();
 596           self#notify
 597         with
 598         | Margin -> dispose_old_locked_mark (); self#notify
 599         | exc -> dispose_old_locked_mark (); self#notify; raise exc)
 600     | `Cursor ->
 601         let locked_iter () = buffer#get_iter_at_mark (`NAME "locked") in
 602         let cursor_iter () = buffer#get_iter_at_mark `INSERT in
 603         let remember =
 604          `MARK
 605            (buffer#create_mark ~name:"initial_insert"
 606              ~left_gravity:true (cursor_iter ())) in
 607         let dispose_remember () = buffer#delete_mark remember in
 608         let remember_iter () =
 609          buffer#get_iter_at_mark (`NAME "initial_insert") in
 610         let cmp () = (locked_iter ())#offset - (remember_iter ())#offset in
 611         let icmp = cmp () in
 612         let forward_until_cursor () = (* go forward until locked > cursor *)
 613           let rec aux () =
 614             self#_advance ();
 615             if cmp () < 0 && (getoldpos ())#compare (getpos ()) < 0
 616             then
 617              begin
 618               buffer#move_mark old_locked_mark (getpos ());
 619               aux ()
 620              end
 621           in
 622           aux ()
 623         in
 624         let rec back_until_cursor len = (* go backward until locked < cursor *)
 625          function
 626             statements, ((grafite_status)::_ as history)
 627             when len <= 0 ->
 628              self#_retract (icmp - len) grafite_status statements
 629               history
 630           | statement::tl1, _::tl2 ->
 631              back_until_cursor (len - MatitaGtkMisc.utf8_string_length statement) (tl1,tl2)
 632           | _,_ -> assert false
 633         in
 634         (try
 635           begin
 636            if icmp < 0 then       (* locked < cursor *)
 637              (forward_until_cursor (); self#notify)
 638            else if icmp > 0 then  (* locked > cursor *)
 639              (back_until_cursor icmp (statements,history); self#notify)
 640            else                  (* cursor = locked *)
 641                ()
 642           end ;
 643           dispose_remember ();
 644           dispose_old_locked_mark ();
 645         with
 646         | Margin -> dispose_remember (); dispose_old_locked_mark (); self#notify
 647         | exc -> dispose_remember (); dispose_old_locked_mark ();
 648                  self#notify; raise exc)
 649   with Invalid_argument "Array.make" ->
 650      HLog.error "The script is too big!\n"
 651
 652   method stack = (assert false : Continuationals.Stack.t) (* MATITA 1.0 GrafiteTypes.get_stack
 653   self#grafite_status *)
 654   method setGoal n = userGoal <- n
 655   method goal = userGoal
 656
 657   method bos =
 658     match history with
 659     | _::[] -> true
 660     | _ -> false
 661
 662   method eos =
 663     let rec is_there_only_comments lexicon_status s =
 664       if Pcre.pmatch ~rex:only_dust_RE s then raise Margin;
 665       let strm =
 666        GrafiteParser.parsable_statement lexicon_status
 667         (Ulexing.from_utf8_string s)in
 668       match GrafiteParser.parse_statement lexicon_status strm with
 669       | GrafiteAst.Comment (loc,_) ->
 670           let _,parsed_text_length = MatitaGtkMisc.utf8_parsed_text s loc in
 671           (* CSC: why +1 in the following lines ???? *)
 672           let parsed_text_length = parsed_text_length + 1 in
 673           let remain_len = String.length s - parsed_text_length in
 674           let next = String.sub s parsed_text_length remain_len in
 675           is_there_only_comments lexicon_status next
 676       | GrafiteAst.Executable _ -> false
 677     in
 678     try is_there_only_comments self#grafite_status self#getFuture
 679     with
 680     | NCicLibrary.IncludedFileNotCompiled _
 681     | HExtlib.Localized _
 682     | CicNotationParser.Parse_error _ -> false
 683     | Margin | End_of_file -> true
 684     | Invalid_argument "Array.make" -> false
 685
 686   (* debug *)
 687   method dump () =
 688     HLog.debug "script status:";
 689     HLog.debug ("history size: " ^ string_of_int (List.length history));
 690     HLog.debug (sprintf "%d statements:" (List.length statements));
 691     List.iter HLog.debug statements;
 692     HLog.debug ("Current file name: " ^ self#filename);
 693 end
 694
 695 let _script = ref None
 696
 697 let script ~source_view ~urichooser ~ask_confirmation ~set_star ()
 698 =
 699   let s = new script ~source_view ~ask_confirmation ~urichooser ~set_star () in
 700   _script := Some s;
 701   s
 702
 703 let current () = match !_script with None -> assert false | Some s -> s
 704
 705 let _ =
 706  CicMathView.register_matita_script_current (current :> unit -> < advance: ?statement:string -> unit -> unit; grafite_status: GrafiteTypes.status; setGoal: int option -> unit >)
 707 ;;