matita/matita/matitacLib.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 open GrafiteTypes
  31
  32 exception AttemptToInsertAnAlias of LexiconEngine.status
  33
  34 let slash_n_RE = Pcre.regexp "\\n" ;;
  35
  36 let pp_ast_statement grafite_status stm =
  37   let stm = GrafiteAstPp.pp_statement
  38     ~map_unicode_to_tex:(Helm_registry.get_bool "matita.paste_unicode_as_tex")
  39     ~term_pp:CicNotationPp.pp_term
  40     ~lazy_term_pp:CicNotationPp.pp_term ~obj_pp:(CicNotationPp.pp_obj
  41     CicNotationPp.pp_term) stm
  42   in
  43   let stm = Pcre.replace ~rex:slash_n_RE stm in
  44   let stm =
  45       if String.length stm > 50 then String.sub stm 0 50 ^ " ..."
  46       else stm
  47   in
  48     HLog.debug ("Executing: ``" ^ stm ^ "''")
  49 ;;
  50
  51 let clean_exit baseuri rc =
  52   LibraryClean.clean_baseuris ~verbose:false [baseuri]; rc
  53 ;;
  54
  55 let dump f =
  56    let module G = GrafiteAst in
  57    let module L = LexiconAst in
  58    let module H = HExtlib in
  59    let floc = H.dummy_floc in
  60    let nl_ast = G.Comment (floc, G.Note (floc, "")) in
  61    let pp_statement stm =
  62      GrafiteAstPp.pp_statement ~term_pp:CicNotationPp.pp_term
  63        ~map_unicode_to_tex:(Helm_registry.get_bool
  64          "matita.paste_unicode_as_tex")
  65        ~lazy_term_pp:CicNotationPp.pp_term
  66        ~obj_pp:(CicNotationPp.pp_obj CicNotationPp.pp_term) stm
  67    in
  68    let pp_lexicon = LexiconAstPp.pp_command in
  69    let och = open_out f in
  70    let nl () =  output_string och (pp_statement nl_ast) in
  71    MatitaMisc.out_preamble och;
  72    let grafite_parser_cb = function
  73       | G.Executable (loc, G.Command (_, G.Include (_, false, _, _))) -> ()
  74       | stm ->
  75          output_string och (pp_statement stm); nl (); nl ()
  76    in
  77    let lexicon_parser_cb cmd =
  78          output_string och (pp_lexicon cmd); nl (); nl ()
  79    in
  80    begin fun () ->
  81       Helm_registry.set_bool "matita.moo" false;
  82       GrafiteParser.set_grafite_callback grafite_parser_cb;
  83       GrafiteParser.set_lexicon_callback lexicon_parser_cb
  84    end,
  85    begin fun x ->
  86       close_out och;
  87       GrafiteParser.set_grafite_callback (fun _ -> ());
  88       GrafiteParser.set_lexicon_callback (fun _ -> ());
  89       Helm_registry.set_bool "matita.moo" true;
  90       x
  91    end
  92 ;;
  93
  94 let get_macro_context = function _ -> []
  95 ;;
  96
  97 let pp_times fname rc big_bang big_bang_u big_bang_s =
  98   if not (Helm_registry.get_bool "matita.verbose") then
  99     let { Unix.tms_utime = u ; Unix.tms_stime = s} = Unix.times () in
 100     let r = Unix.gettimeofday () -. big_bang in
 101     let u = u -. big_bang_u in
 102     let s = s -. big_bang_s in
 103     let extra = try Sys.getenv "BENCH_EXTRA_TEXT" with Not_found -> "" in
 104     let rc,rcascii =
 105       if rc then "\e[0;32mOK\e[0m","Ok" else "\e[0;31mFAIL\e[0m","Fail" in
 106     let times =
 107       let fmt t =
 108         let seconds = int_of_float t in
 109         let cents = int_of_float ((t -. floor t) *. 100.0) in
 110         let minutes = seconds / 60 in
 111         let seconds = seconds mod 60 in
 112         Printf.sprintf "%dm%02d.%02ds" minutes seconds cents
 113       in
 114       Printf.sprintf "%s %s %s" (fmt r) (fmt u) (fmt s)
 115     in
 116     let s = Printf.sprintf "%-4s %s %s" rc times extra in
 117     print_endline s;
 118     flush stdout;
 119     HLog.message ("Compilation of "^Filename.basename fname^": "^rc)
 120 ;;
 121
 122 let cut prefix s =
 123   let lenp = String.length prefix in
 124   let lens = String.length s in
 125   assert (lens > lenp);
 126   assert (String.sub s 0 lenp = prefix);
 127   String.sub s lenp (lens-lenp)
 128 ;;
 129
 130 let get_include_paths options =
 131   let include_paths =
 132     try List.assoc "include_paths" options with Not_found -> ""
 133   in
 134   let include_paths = Str.split (Str.regexp " ") include_paths in
 135   let include_paths =
 136     include_paths @
 137     Helm_registry.get_list Helm_registry.string "matita.includes"
 138   in
 139     include_paths
 140 ;;
 141
 142 let activate_extraction baseuri fname =
 143  if Helm_registry.get_bool "matita.extract" then
 144   let mangled_baseuri =
 145    let baseuri = String.sub baseuri 5 (String.length baseuri - 5) in
 146      let baseuri = Pcre.replace ~pat:"/" ~templ:"_" baseuri in
 147       String.uncapitalize baseuri in
 148   let f =
 149     open_out
 150      (Filename.dirname fname ^ "/" ^ mangled_baseuri ^ ".ml") in
 151    LibrarySync.add_object_declaration_hook
 152     (fun ~add_obj ~add_coercion _ obj ->
 153       output_string f (CicExportation.ppobj baseuri obj);
 154       flush f; []);
 155 ;;
 156
 157 let compile atstart options fname =
 158   let matita_debug = Helm_registry.get_bool "matita.debug" in
 159   let include_paths = get_include_paths options in
 160   let root,baseuri,fname,_tgt =
 161     Librarian.baseuri_of_script ~include_paths fname in
 162   if Http_getter_storage.is_read_only baseuri then assert false;
 163   activate_extraction baseuri fname ;
 164   let lexicon_status =
 165     CicNotation2.load_notation ~include_paths:[] (new LexiconEngine.status)
 166       BuildTimeConf.core_notation_script
 167   in
 168   atstart (); (* FG: do not invoke before loading the core notation script *)
 169   let grafite_status = GrafiteSync.init lexicon_status baseuri in
 170   let big_bang = Unix.gettimeofday () in
 171   let { Unix.tms_utime = big_bang_u ; Unix.tms_stime = big_bang_s} =
 172     Unix.times ()
 173   in
 174   let time = Unix.time () in
 175   try
 176     (* sanity checks *)
 177     let moo_fname =
 178      LibraryMisc.obj_file_of_baseuri ~must_exist:false ~baseuri ~writable:true
 179     in
 180     let lexicon_fname=
 181      LibraryMisc.lexicon_file_of_baseuri
 182        ~must_exist:false ~baseuri ~writable:true
 183     in
 184     (* cleanup of previously compiled objects *)
 185     if (not (Http_getter_storage.is_empty ~local:true baseuri) ||
 186         LibraryClean.db_uris_of_baseuri baseuri <> [])
 187       then begin
 188       HLog.message ("baseuri " ^ baseuri ^ " is not empty");
 189       HLog.message ("cleaning baseuri " ^ baseuri);
 190       LibraryClean.clean_baseuris [baseuri];
 191     end;
 192     HLog.message ("compiling " ^ Filename.basename fname ^ " in " ^ baseuri);
 193     if not (Helm_registry.get_bool "matita.verbose") then
 194       (let cc =
 195         let rex = Str.regexp ".*opt$" in
 196         if Str.string_match rex Sys.argv.(0) 0 then "matitac.opt"
 197         else "matitac"
 198       in
 199       let s = Printf.sprintf "%s %-35s " cc (cut (root^"/") fname) in
 200       print_string s; flush stdout);
 201     (* we dalay this error check until we print 'matitac file ' *)
 202     assert (Http_getter_storage.is_empty ~local:true baseuri);
 203     (* create dir for XML files *)
 204     if not (Helm_registry.get_opt_default Helm_registry.bool "matita.nodisk"
 205               ~default:false)
 206     then
 207       HExtlib.mkdir
 208         (Filename.dirname
 209           (Http_getter.filename ~local:true ~writable:true (baseuri ^
 210           "foo.con")));
 211     let buf = Ulexing.from_utf8_channel (open_in fname) in
 212     let print_cb =
 213       if not (Helm_registry.get_bool "matita.verbose") then (fun _ _ -> ())
 214       else pp_ast_statement
 215     in
 216     let grafite_status =
 217      let rec aux_for_dump x grafite_status =
 218      try
 219       match
 220        MatitaEngine.eval_from_stream ~first_statement_only:false ~include_paths
 221         grafite_status buf x
 222       with
 223       | [] -> grafite_status
 224       | (g,None)::_ -> g
 225       | (g,Some _)::_ ->
 226          raise (AttemptToInsertAnAlias (g :> LexiconEngine.status))
 227      with MatitaEngine.EnrichedWithStatus
 228             (GrafiteEngine.Macro (floc, f), grafite) as exn ->
 229             match f (get_macro_context (Some grafite)) with
 230             | _, GrafiteAst.Inline (_, _suri, _params) ->
 231 (*
 232               let str =
 233                ApplyTransformation.txt_of_inline_macro style prefix suri
 234                 ?flavour
 235                 ~map_unicode_to_tex:(Helm_registry.get_bool
 236                   "matita.paste_unicode_as_tex")
 237               in
 238               !out str;
 239 *)
 240               aux_for_dump x grafite
 241             |_-> raise exn
 242      in
 243        aux_for_dump print_cb grafite_status
 244     in
 245     let elapsed = Unix.time () -. time in
 246     let moo_content_rev,lexicon_content_rev =
 247       grafite_status#moo_content_rev,
 248        grafite_status#lstatus.LexiconEngine.lexicon_content_rev
 249     in
 250      (if Helm_registry.get_bool "matita.moo" then begin
 251         (* FG: we do not generate .moo when dumping .mma files *)
 252         GrafiteMarshal.save_moo moo_fname moo_content_rev;
 253         LexiconMarshal.save_lexicon lexicon_fname lexicon_content_rev;
 254         NCicLibrary.Serializer.serialize ~baseuri:(NUri.uri_of_string baseuri)
 255          grafite_status#dump
 256      end;
 257      let tm = Unix.gmtime elapsed in
 258      let sec = string_of_int tm.Unix.tm_sec ^ "''" in
 259      let min =
 260        if tm.Unix.tm_min > 0 then (string_of_int tm.Unix.tm_min^"' ") else ""
 261      in
 262      let hou =
 263        if tm.Unix.tm_hour > 0 then (string_of_int tm.Unix.tm_hour^"h ") else ""
 264      in
 265      HLog.message
 266        (sprintf "execution of %s completed in %s." fname (hou^min^sec));
 267      pp_times fname true big_bang big_bang_u big_bang_s;
 268 (*
 269      LexiconSync.time_travel
 270        ~present:lexicon_status ~past:initial_lexicon_status;
 271 *)
 272      true)
 273   with
 274   (* all exceptions should be wrapped to allow lexicon-undo (LS.time_travel) *)
 275   | AttemptToInsertAnAlias lexicon_status ->
 276      pp_times fname false big_bang big_bang_u big_bang_s;
 277 (*
 278      LexiconSync.time_travel
 279        ~present:lexicon_status ~past:initial_lexicon_status;
 280 *)
 281      clean_exit baseuri false
 282   | MatitaEngine.EnrichedWithStatus (exn, _grafite) as exn' ->
 283       (match exn with
 284       | Sys.Break -> HLog.error "user break!"
 285       | HExtlib.Localized (floc,CicNotationParser.Parse_error err) ->
 286           let (x, y) = HExtlib.loc_of_floc floc in
 287           HLog.error (sprintf "Parse error at %d-%d: %s" x y err)
 288       | exn when matita_debug -> raise exn'
 289       | exn -> HLog.error (snd (MatitaExcPp.to_string exn))
 290       );
 291 (*       LexiconSync.time_travel ~present:lexicon ~past:initial_lexicon_status;
 292  *       *)
 293       pp_times fname false big_bang big_bang_u big_bang_s;
 294       clean_exit baseuri false
 295   | Sys.Break when not matita_debug ->
 296      HLog.error "user break!";
 297      pp_times fname false big_bang big_bang_u big_bang_s;
 298      clean_exit baseuri false
 299   | exn when not matita_debug ->
 300        HLog.error
 301          ("Unwrapped exception, please fix: "^ snd (MatitaExcPp.to_string exn));
 302        pp_times fname false big_bang big_bang_u big_bang_s;
 303        clean_exit baseuri false
 304
 305 module F =
 306   struct
 307     type source_object = string
 308     type target_object = string
 309     let string_of_source_object s = s;;
 310     let string_of_target_object s = s;;
 311
 312     let is_readonly_buri_of opts file =
 313      let buri = List.assoc "baseuri" opts in
 314      Http_getter_storage.is_read_only (Librarian.mk_baseuri buri file)
 315     ;;
 316
 317     let root_and_target_of opts mafile =
 318       try
 319         let include_paths = get_include_paths opts in
 320         let root,baseuri,_,relpath =
 321           Librarian.baseuri_of_script ~include_paths mafile
 322         in
 323         let obj_writeable, obj_read_only =
 324            if Filename.check_suffix mafile ".mma" then
 325               Filename.chop_suffix mafile ".mma" ^ ".ma",
 326               Filename.chop_suffix mafile ".mma" ^ ".ma"
 327            else
 328               LibraryMisc.obj_file_of_baseuri
 329                         ~must_exist:false ~baseuri ~writable:true,
 330               LibraryMisc.obj_file_of_baseuri
 331                         ~must_exist:false ~baseuri ~writable:false
 332         in
 333         Some root, relpath, obj_writeable, obj_read_only
 334       with Librarian.NoRootFor x -> None, "", "", ""
 335     ;;
 336
 337     let mtime_of_source_object s =
 338       try Some (Unix.stat s).Unix.st_mtime
 339       with Unix.Unix_error (Unix.ENOENT, "stat", f) when f = s -> None
 340     ;;
 341
 342     let mtime_of_target_object s =
 343       try Some (Unix.stat s).Unix.st_mtime
 344       with Unix.Unix_error (Unix.ENOENT, "stat", f) when f = s -> None
 345     ;;
 346
 347 (* FG: a problem was noticed in relising memory between subsequent *)
 348 (*     invocations of the compiler. The following might help       *)
 349     let compact r = Gc.compact (); r
 350
 351     let build options fname =
 352       let matita_debug = Helm_registry.get_bool "matita.debug" in
 353       let compile atstart opts fname =
 354         try
 355           GrafiteSync.push ();
 356           GrafiteParser.push ();
 357           let rc = compile atstart opts fname in
 358           GrafiteParser.pop ();
 359           GrafiteSync.pop ();
 360           rc
 361         with
 362         | Sys.Break ->
 363             GrafiteParser.pop ();
 364             GrafiteSync.pop ();
 365             false
 366         | exn when not matita_debug ->
 367             HLog.error ("Unexpected " ^ snd(MatitaExcPp.to_string exn));
 368             assert false
 369       in
 370       if Filename.check_suffix fname ".mma" then
 371          let generated = Filename.chop_suffix fname ".mma" ^ ".ma" in
 372          let atstart, atexit = dump generated in
 373          let res = compile atstart options fname in
 374          let r = compact (atexit res) in
 375          if r then r else begin
 376 (*            Sys.remove generated; *)
 377             Printf.printf "rm %s\n" generated; flush stdout; r
 378          end
 379       else
 380          compact (compile ignore options fname)
 381     ;;
 382
 383     let load_deps_file = Librarian.load_deps_file;;
 384
 385   end
 386
 387 module Make = Librarian.Make(F)
 388