matita/matita/re_complete/re.ma

   1 include "lang.ma".
   2
   3 inductive re (S: DeqSet) : Type[0] ≝
   4    z: re S
   5  | e: re S
   6  | s: S → re S
   7  | c: re S → re S → re S
   8  | o: re S → re S → re S
   9  | k: re S → re S.
  10
  11 interpretation "re epsilon" 'epsilon = (e ?).
  12 interpretation "re or" 'plus a b = (o ? a b).
  13 interpretation "re cat" 'middot a b = (c ? a b).
  14 interpretation "re star" 'star a = (k ? a).
  15
  16 notation < "a" non associative with precedence 90 for @{ 'ps $a}.
  17 notation > "` term 90 a" non associative with precedence 90 for @{ 'ps $a}.
  18 interpretation "atom" 'ps a = (s ? a).
  19
  20 notation "`∅" non associative with precedence 90 for @{ 'empty }.
  21 interpretation "empty" 'empty = (z ?).
  22
  23 let rec in_l (S : DeqSet) (r : re S) on r : word S → Prop ≝
  24 match r with
  25 [ z ⇒ ∅
  26 | e ⇒ {ϵ}
  27 | s x ⇒ {[x]}
  28 | c r1 r2 ⇒ (in_l ? r1) · (in_l ? r2)
  29 | o r1 r2 ⇒ (in_l ? r1) ∪ (in_l ? r2)
  30 | k r1 ⇒ (in_l ? r1) ^*].
  31
  32 notation "\sem{term 19 E}" non associative with precedence 75 for @{'in_l $E}.
  33 interpretation "in_l" 'in_l E = (in_l ? E).
  34 interpretation "in_l mem" 'mem w l = (in_l ? l w).
  35
  36 lemma rsem_star : ∀S.∀r: re S. \sem{r^*} = \sem{r}^*.
  37 // qed.
  38
  39
  40 (* pointed items *)
  41 inductive pitem (S: DeqSet) : Type[0] ≝
  42    pz: pitem S
  43  | pe: pitem S
  44  | ps: S → pitem S
  45  | pp: S → pitem S
  46  | pc: pitem S → pitem S → pitem S
  47  | po: pitem S → pitem S → pitem S
  48  | pk: pitem S → pitem S.
  49
  50 definition pre ≝ λS.pitem S × bool.
  51
  52 interpretation "pitem star" 'star a = (pk ? a).
  53 interpretation "pitem or" 'plus a b = (po ? a b).
  54 interpretation "pitem cat" 'middot a b = (pc ? a b).
  55 notation < ".a" non associative with precedence 90 for @{ 'pp $a}.
  56 notation > "`. term 90 a" non associative with precedence 90 for @{ 'pp $a}.
  57 interpretation "pitem pp" 'pp a = (pp ? a).
  58 interpretation "pitem ps" 'ps a = (ps ? a).
  59 interpretation "pitem epsilon" 'epsilon = (pe ?).
  60 interpretation "pitem empty" 'empty = (pz ?).
  61
  62 let rec forget (S: DeqSet) (l : pitem S) on l: re S ≝
  63  match l with
  64   [ pz ⇒ `∅
  65   | pe ⇒ ϵ
  66   | ps x ⇒ `x
  67   | pp x ⇒ `x
  68   | pc E1 E2 ⇒ (forget ? E1) · (forget ? E2)
  69   | po E1 E2 ⇒ (forget ? E1) + (forget ? E2)
  70   | pk E ⇒ (forget ? E)^* ].
  71
  72 (* notation < "|term 19 e|" non associative with precedence 70 for @{'forget $e}.*)
  73 interpretation "forget" 'norm a = (forget ? a).
  74
  75 lemma erase_dot : ∀S.∀e1,e2:pitem S. |e1 · e2| = c ? (|e1|) (|e2|).
  76 // qed.
  77
  78 lemma erase_plus : ∀S.∀i1,i2:pitem S.
  79   |i1 + i2| = |i1| + |i2|.
  80 // qed.
  81
  82 lemma erase_star : ∀S.∀i:pitem S.|i^*| = |i|^*.
  83 // qed.
  84
  85 (* boolean equality *)
  86 let rec beqitem S (i1,i2: pitem S) on i1 ≝
  87   match i1 with
  88   [ pz ⇒ match i2 with [ pz ⇒ true | _ ⇒ false]
  89   | pe ⇒ match i2 with [ pe ⇒ true | _ ⇒ false]
  90   | ps y1 ⇒ match i2 with [ ps y2 ⇒ y1==y2 | _ ⇒ false]
  91   | pp y1 ⇒ match i2 with [ pp y2 ⇒ y1==y2 | _ ⇒ false]
  92   | po i11 i12 ⇒ match i2 with
  93     [ po i21 i22 ⇒ beqitem S i11 i21 ∧ beqitem S i12 i22
  94     | _ ⇒ false]
  95   | pc i11 i12 ⇒ match i2 with
  96     [ pc i21 i22 ⇒ beqitem S i11 i21 ∧ beqitem S i12 i22
  97     | _ ⇒ false]
  98   | pk i11 ⇒ match i2 with [ pk i21 ⇒ beqitem S i11 i21 | _ ⇒ false]
  99   ].
 100
 101 lemma beqitem_true: ∀S,i1,i2. iff (beqitem S i1 i2 = true) (i1 = i2).
 102 #S #i1 elim i1
 103   [#i2 cases i2 [||#a|#a|#i21 #i22| #i21 #i22|#i3] % // normalize #H destruct
 104   |#i2 cases i2 [||#a|#a|#i21 #i22| #i21 #i22|#i3] % // normalize #H destruct
 105   |#x #i2 cases i2 [||#a|#a|#i21 #i22| #i21 #i22|#i3] % normalize #H destruct
 106     [>(\P H) // | @(\b (refl …))]
 107   |#x #i2 cases i2 [||#a|#a|#i21 #i22| #i21 #i22|#i3] % normalize #H destruct
 108     [>(\P H) // | @(\b (refl …))]
 109   |#i11 #i12 #Hind1 #Hind2 #i2 cases i2 [||#a|#a|#i21 #i22| #i21 #i22|#i3] %
 110    normalize #H destruct
 111     [cases (true_or_false (beqitem S i11 i21)) #H1
 112       [>(proj1 … (Hind1 i21) H1) >(proj1 … (Hind2 i22)) // >H1 in H; #H @H
 113       |>H1 in H; normalize #abs @False_ind /2/
 114       ]
 115     |>(proj2 … (Hind1 i21) (refl …)) >(proj2 … (Hind2 i22) (refl …)) //
 116     ]
 117   |#i11 #i12 #Hind1 #Hind2 #i2 cases i2 [||#a|#a|#i21 #i22| #i21 #i22|#i3] %
 118    normalize #H destruct
 119     [cases (true_or_false (beqitem S i11 i21)) #H1
 120       [>(proj1 … (Hind1 i21) H1) >(proj1 … (Hind2 i22)) // >H1 in H; #H @H
 121       |>H1 in H; normalize #abs @False_ind /2/
 122       ]
 123     |>(proj2 … (Hind1 i21) (refl …)) >(proj2 … (Hind2 i22) (refl …)) //
 124     ]
 125   |#i3 #Hind #i2 cases i2 [||#a|#a|#i21 #i22| #i21 #i22|#i4] %
 126    normalize #H destruct
 127     [>(proj1 … (Hind i4) H) // |>(proj2 … (Hind i4) (refl …)) //]
 128   ]
 129 qed.
 130
 131 definition DeqItem ≝ λS.
 132   mk_DeqSet (pitem S) (beqitem S) (beqitem_true S).
 133
 134 unification hint  0 ≔ S;
 135     X ≟ mk_DeqSet (pitem S) (beqitem S) (beqitem_true S)
 136 (* ---------------------------------------- *) ⊢
 137     pitem S ≡ carr X.
 138
 139 unification hint  0 ≔ S,i1,i2;
 140     X ≟ mk_DeqSet (pitem S) (beqitem S) (beqitem_true S)
 141 (* ---------------------------------------- *) ⊢
 142     beqitem S i1 i2 ≡ eqb X i1 i2.
 143
 144 (* semantics *)
 145
 146 let rec in_pl (S : DeqSet) (r : pitem S) on r : word S → Prop ≝
 147 match r with
 148 [ pz ⇒ ∅
 149 | pe ⇒ ∅
 150 | ps _ ⇒ ∅
 151 | pp x ⇒ { [x] }
 152 | pc r1 r2 ⇒ (in_pl ? r1) · \sem{forget ? r2} ∪ (in_pl ? r2)
 153 | po r1 r2 ⇒ (in_pl ? r1) ∪ (in_pl ? r2)
 154 | pk r1 ⇒ (in_pl ? r1) · \sem{forget ? r1}^*  ].
 155
 156 interpretation "in_pl" 'in_l E = (in_pl ? E).
 157 interpretation "in_pl mem" 'mem w l = (in_pl ? l w).
 158
 159 definition in_prl ≝ λS : DeqSet.λp:pre S.
 160   if (\snd p) then \sem{\fst p} ∪ {ϵ} else \sem{\fst p}.
 161
 162 interpretation "in_prl mem" 'mem w l = (in_prl ? l w).
 163 interpretation "in_prl" 'in_l E = (in_prl ? E).
 164
 165 lemma sem_pre_true : ∀S.∀i:pitem S.
 166   \sem{〈i,true〉} = \sem{i} ∪ {ϵ}.
 167 // qed.
 168
 169 lemma sem_pre_false : ∀S.∀i:pitem S.
 170   \sem{〈i,false〉} = \sem{i}.
 171 // qed.
 172
 173 lemma sem_cat: ∀S.∀i1,i2:pitem S.
 174   \sem{i1 · i2} = \sem{i1} · \sem{|i2|} ∪ \sem{i2}.
 175 // qed.
 176
 177 lemma sem_cat_w: ∀S.∀i1,i2:pitem S.∀w.
 178   \sem{i1 · i2} w = ((\sem{i1} · \sem{|i2|}) w ∨ \sem{i2} w).
 179 // qed.
 180
 181 lemma sem_plus: ∀S.∀i1,i2:pitem S.
 182   \sem{i1 + i2} = \sem{i1} ∪ \sem{i2}.
 183 // qed.
 184
 185 lemma sem_plus_w: ∀S.∀i1,i2:pitem S.∀w.
 186   \sem{i1 + i2} w = (\sem{i1} w ∨ \sem{i2} w).
 187 // qed.
 188
 189 lemma sem_star : ∀S.∀i:pitem S.
 190   \sem{i^*} = \sem{i} · \sem{|i|}^*.
 191 // qed.
 192
 193 lemma sem_star_w : ∀S.∀i:pitem S.∀w.
 194   \sem{i^*} w = (∃w1,w2.w1 @ w2 = w ∧ \sem{i} w1 ∧ \sem{|i|}^* w2).
 195 // qed.
 196
 197 lemma append_eq_nil : ∀S.∀w1,w2:word S. w1 @ w2 = ϵ → w1 = ϵ.
 198 #S #w1 #w2 cases w1 // #a #tl normalize #H destruct qed.
 199
 200 lemma not_epsilon_lp : ∀S:DeqSet.∀e:pitem S. ¬ (ϵ ∈ e).
 201 #S #e elim e normalize /2/
 202   [#r1 #r2 * #n1 #n2 % * /2/ * #w1 * #w2 * * #H
 203    >(append_eq_nil …H…) /2/
 204   |#r1 #r2 #n1 #n2 % * /2/
 205   |#r #n % * #w1 * #w2 * * #H >(append_eq_nil …H…) /2/
 206   ]
 207 qed.
 208
 209 (* lemma 12 *)
 210 lemma epsilon_to_true : ∀S.∀e:pre S. ϵ ∈ e → \snd e = true.
 211 #S * #i #b cases b // normalize #H @False_ind /2/
 212 qed.
 213
 214 lemma true_to_epsilon : ∀S.∀e:pre S. \snd e = true → ϵ ∈ e.
 215 #S * #i #b #btrue normalize in btrue; >btrue %2 //
 216 qed.
 217
 218 lemma minus_eps_item: ∀S.∀i:pitem S. \sem{i} =1 \sem{i}-{[ ]}.
 219 #S #i #w %
 220   [#H whd % // normalize @(not_to_not … (not_epsilon_lp …i)) //
 221   |* //
 222   ]
 223 qed.
 224
 225 lemma minus_eps_pre: ∀S.∀e:pre S. \sem{\fst e} =1 \sem{e}-{[ ]}.
 226 #S * #i *
 227   [>sem_pre_true normalize in ⊢ (??%?); #w %
 228     [/3/ | * * // #H1 #H2 @False_ind @(absurd …H1 H2)]
 229   |>sem_pre_false normalize in ⊢ (??%?); #w % [ /3/ | * // ]
 230   ]
 231 qed.
 232
 233 definition lo ≝ λS:DeqSet.λa,b:pre S.〈\fst a + \fst b,\snd a ∨ \snd b〉.
 234 notation "a ⊕ b" left associative with precedence 65 for @{'oplus $a $b}.
 235 interpretation "oplus" 'oplus a b = (lo ? a b).
 236
 237 lemma lo_def: ∀S.∀i1,i2:pitem S.∀b1,b2. 〈i1,b1〉⊕〈i2,b2〉=〈i1+i2,b1∨b2〉.
 238 // qed.
 239
 240 definition pre_concat_r ≝ λS:DeqSet.λi:pitem S.λe:pre S.
 241   match e with [ mk_Prod i1 b ⇒ 〈i · i1, b〉].
 242
 243 notation "i ◃ e" left associative with precedence 65 for @{'lhd $i $e}.
 244 interpretation "pre_concat_r" 'lhd i e = (pre_concat_r ? i e).
 245
 246 lemma eq_to_ex_eq: ∀S.∀A,B:word S → Prop.
 247   A = B → A =1 B.
 248 #S #A #B #H >H /2/ qed.
 249
 250 lemma sem_pre_concat_r : ∀S,i.∀e:pre S.
 251   \sem{i ◃ e} =1 \sem{i} · \sem{|\fst e|} ∪ \sem{e}.
 252 #S #i * #i1 #b1 cases b1 [2: @eq_to_ex_eq //]
 253 >sem_pre_true >sem_cat >sem_pre_true /2/
 254 qed.
 255
 256 definition pre_concat_l ≝ λS:DeqSet.λbcast:∀S:DeqSet.pitem S → pre S.λe1:pre S.λi2:pitem S.
 257   match e1 with
 258   [ mk_Prod i1 b1 ⇒ match b1 with
 259     [ true ⇒ (i1 ◃ (bcast ? i2))
 260     | false ⇒ 〈i1 · i2,false〉
 261     ]
 262   ].
 263
 264 notation "a ▹ b" left associative with precedence 65 for @{'tril eclose $a $b}.
 265 interpretation "item-pre concat" 'tril op a b = (pre_concat_l ? op a b).
 266
 267 notation "•" non associative with precedence 65 for @{eclose ?}.
 268
 269 let rec eclose (S: DeqSet) (i: pitem S) on i : pre S ≝
 270  match i with
 271   [ pz ⇒ 〈 `∅, false 〉
 272   | pe ⇒ 〈 ϵ,  true 〉
 273   | ps x ⇒ 〈 `.x, false〉
 274   | pp x ⇒ 〈 `.x, false 〉
 275   | po i1 i2 ⇒ •i1 ⊕ •i2
 276   | pc i1 i2 ⇒ •i1 ▹ i2
 277   | pk i ⇒ 〈(\fst (•i))^*,true〉].
 278
 279 notation "• x" non associative with precedence 65 for @{'eclose $x}.
 280 interpretation "eclose" 'eclose x = (eclose ? x).
 281
 282 lemma eclose_plus: ∀S:DeqSet.∀i1,i2:pitem S.
 283   •(i1 + i2) = •i1 ⊕ •i2.
 284 // qed.
 285
 286 lemma eclose_dot: ∀S:DeqSet.∀i1,i2:pitem S.
 287   •(i1 · i2) = •i1 ▹ i2.
 288 // qed.
 289
 290 lemma eclose_star: ∀S:DeqSet.∀i:pitem S.
 291   •i^* = 〈(\fst(•i))^*,true〉.
 292 // qed.
 293
 294 definition lift ≝ λS.λf:pitem S →pre S.λe:pre S.
 295   match e with
 296   [ mk_Prod i b ⇒ 〈\fst (f i), \snd (f i) ∨ b〉].
 297
 298 definition preclose ≝ λS. lift S (eclose S).
 299 interpretation "preclose" 'eclose x = (preclose ? x).
 300
 301 (* theorem 16: 2 *)
 302 lemma sem_oplus: ∀S:DeqSet.∀e1,e2:pre S.
 303   \sem{e1 ⊕ e2} =1 \sem{e1} ∪ \sem{e2}.
 304 #S * #i1 #b1 * #i2 #b2 #w %
 305   [cases b1 cases b2 normalize /2/ * /3/ * /3/
 306   |cases b1 cases b2 normalize /2/ * /3/ * /3/
 307   ]
 308 qed.
 309
 310 lemma odot_true :
 311   ∀S.∀i1,i2:pitem S.
 312   〈i1,true〉 ▹ i2 = i1 ◃ (•i2).
 313 // qed.
 314
 315 lemma odot_true_bis :
 316   ∀S.∀i1,i2:pitem S.
 317   〈i1,true〉 ▹ i2 = 〈i1 · \fst (•i2), \snd (•i2)〉.
 318 #S #i1 #i2 normalize cases (•i2) // qed.
 319
 320 lemma odot_false:
 321   ∀S.∀i1,i2:pitem S.
 322   〈i1,false〉 ▹ i2 = 〈i1 · i2, false〉.
 323 // qed.
 324
 325 lemma LcatE : ∀S.∀e1,e2:pitem S.
 326   \sem{e1 · e2} = \sem{e1} · \sem{|e2|} ∪ \sem{e2}.
 327 // qed.
 328
 329 lemma erase_bull : ∀S.∀i:pitem S. |\fst (•i)| = |i|.
 330 #S #i elim i //
 331   [ #i1 #i2 #IH1 #IH2 >erase_dot <IH1 >eclose_dot
 332     cases (•i1) #i11 #b1 cases b1 // <IH2 >odot_true_bis //
 333   | #i1 #i2 #IH1 #IH2 >eclose_plus >(erase_plus … i1) <IH1 <IH2
 334     cases (•i1) #i11 #b1 cases (•i2) #i21 #b2 //
 335   | #i #IH >eclose_star >(erase_star … i) <IH cases (•i) //
 336   ]
 337 qed.
 338
 339 (*
 340 lemma sem_eclose_star: ∀S:DeqSet.∀i:pitem S.
 341   \sem{〈i^*,true〉} =1 \sem{〈i,false〉}·\sem{|i|}^* ∪ {ϵ}.
 342 /2/ qed.
 343 *)
 344
 345 (* theorem 16: 1 → 3 *)
 346 lemma odot_dot_aux : ∀S.∀e1:pre S.∀i2:pitem S.
 347    \sem{•i2} =1  \sem{i2} ∪ \sem{|i2|} →
 348    \sem{e1 ▹ i2} =1  \sem{e1} · \sem{|i2|} ∪ \sem{i2}.
 349 #S * #i1 #b1 #i2 cases b1
 350   [2:#th >odot_false >sem_pre_false >sem_pre_false >sem_cat /2/
 351   |#H >odot_true >sem_pre_true @(eqP_trans … (sem_pre_concat_r …))
 352    >erase_bull @eqP_trans [|@(eqP_union_l … H)]
 353     @eqP_trans [|@eqP_union_l[|@union_comm ]]
 354     @eqP_trans [|@eqP_sym @union_assoc ] /3/
 355   ]
 356 qed.
 357
 358 lemma minus_eps_pre_aux: ∀S.∀e:pre S.∀i:pitem S.∀A.
 359  \sem{e} =1 \sem{i} ∪ A → \sem{\fst e} =1 \sem{i} ∪ (A - {[ ]}).
 360 #S #e #i #A #seme
 361 @eqP_trans [|@minus_eps_pre]
 362 @eqP_trans [||@eqP_union_r [|@eqP_sym @minus_eps_item]]
 363 @eqP_trans [||@distribute_substract]
 364 @eqP_substract_r //
 365 qed.
 366
 367 (* theorem 16: 1 *)
 368 theorem sem_bull: ∀S:DeqSet. ∀i:pitem S.  \sem{•i} =1 \sem{i} ∪ \sem{|i|}.
 369 #S #e elim e
 370   [#w normalize % [/2/ | * //]
 371   |/2/
 372   |#x normalize #w % [ /2/ | * [@False_ind | //]]
 373   |#x normalize #w % [ /2/ | * // ]
 374   |#i1 #i2 #IH1 #IH2 >eclose_dot
 375    @eqP_trans [|@odot_dot_aux //] >sem_cat
 376    @eqP_trans
 377      [|@eqP_union_r
 378        [|@eqP_trans [|@(cat_ext_l … IH1)] @distr_cat_r]]
 379    @eqP_trans [|@union_assoc]
 380    @eqP_trans [||@eqP_sym @union_assoc]
 381    @eqP_union_l //
 382   |#i1 #i2 #IH1 #IH2 >eclose_plus
 383    @eqP_trans [|@sem_oplus] >sem_plus >erase_plus
 384    @eqP_trans [|@(eqP_union_l … IH2)]
 385    @eqP_trans [|@eqP_sym @union_assoc]
 386    @eqP_trans [||@union_assoc] @eqP_union_r
 387    @eqP_trans [||@eqP_sym @union_assoc]
 388    @eqP_trans [||@eqP_union_l [|@union_comm]]
 389    @eqP_trans [||@union_assoc] /2/
 390   |#i #H >sem_pre_true >sem_star >erase_bull >sem_star
 391    @eqP_trans [|@eqP_union_r [|@cat_ext_l [|@minus_eps_pre_aux //]]]
 392    @eqP_trans [|@eqP_union_r [|@distr_cat_r]]
 393    @eqP_trans [|@union_assoc] @eqP_union_l >erase_star
 394    @eqP_sym @star_fix_eps
 395   ]
 396 qed.
 397
 398 (* blank item *)
 399 let rec blank (S: DeqSet) (i: re S) on i :pitem S ≝
 400  match i with
 401   [ z ⇒ `∅
 402   | e ⇒ ϵ
 403   | s y ⇒ `y
 404   | o e1 e2 ⇒ (blank S e1) + (blank S e2)
 405   | c e1 e2 ⇒ (blank S e1) · (blank S e2)
 406   | k e ⇒ (blank S e)^* ].
 407
 408 lemma forget_blank: ∀S.∀e:re S.|blank S e| = e.
 409 #S #e elim e normalize //
 410 qed.
 411
 412 lemma sem_blank: ∀S.∀e:re S.\sem{blank S e} =1 ∅.
 413 #S #e elim e
 414   [1,2:@eq_to_ex_eq //
 415   |#s @eq_to_ex_eq //
 416   |#e1 #e2 #Hind1 #Hind2 >sem_cat
 417    @eqP_trans [||@(union_empty_r … ∅)]
 418    @eqP_trans [|@eqP_union_l[|@Hind2]] @eqP_union_r
 419    @eqP_trans [||@(cat_empty_l … ?)] @cat_ext_l @Hind1
 420   |#e1 #e2 #Hind1 #Hind2 >sem_plus
 421    @eqP_trans [||@(union_empty_r … ∅)]
 422    @eqP_trans [|@eqP_union_l[|@Hind2]] @eqP_union_r @Hind1
 423   |#e #Hind >sem_star
 424    @eqP_trans [||@(cat_empty_l … ?)] @cat_ext_l @Hind
 425   ]
 426 qed.
 427
 428 theorem re_embedding: ∀S.∀e:re S.
 429   \sem{•(blank S e)} =1 \sem{e}.
 430 #S #e @eqP_trans [|@sem_bull] >forget_blank
 431 @eqP_trans [|@eqP_union_r [|@sem_blank]]
 432 @eqP_trans [|@union_comm] @union_empty_r.
 433 qed.
 434
 435 (* lefted operations *)
 436 definition lifted_cat ≝ λS:DeqSet.λe:pre S.
 437   lift S (pre_concat_l S eclose e).
 438
 439 notation "e1 ⊙ e2" left associative with precedence 70 for @{'odot $e1 $e2}.
 440
 441 interpretation "lifted cat" 'odot e1 e2 = (lifted_cat ? e1 e2).
 442
 443 lemma odot_true_b : ∀S.∀i1,i2:pitem S.∀b.
 444   〈i1,true〉 ⊙ 〈i2,b〉 = 〈i1 · (\fst (•i2)),\snd (•i2) ∨ b〉.
 445 #S #i1 #i2 #b normalize in ⊢ (??%?); cases (•i2) //
 446 qed.
 447
 448 lemma odot_false_b : ∀S.∀i1,i2:pitem S.∀b.
 449   〈i1,false〉 ⊙ 〈i2,b〉 = 〈i1 · i2 ,b〉.
 450 //
 451 qed.
 452
 453 lemma erase_odot:∀S.∀e1,e2:pre S.
 454   |\fst (e1 ⊙ e2)| = |\fst e1| · (|\fst e2|).
 455 #S * #i1 * * #i2 #b2 // >odot_true_b >erase_dot //
 456 qed.
 457
 458 definition lk ≝ λS:DeqSet.λe:pre S.
 459   match e with
 460   [ mk_Prod i1 b1 ⇒
 461     match b1 with
 462     [true ⇒ 〈(\fst (eclose ? i1))^*, true〉
 463     |false ⇒ 〈i1^*,false〉
 464     ]
 465   ].
 466
 467 (* notation < "a \sup ⊛" non associative with precedence 90 for @{'lk $a}.*)
 468 interpretation "lk" 'lk a = (lk ? a).
 469 notation "a^⊛" non associative with precedence 90 for @{'lk $a}.
 470
 471
 472 lemma ostar_true: ∀S.∀i:pitem S.
 473   〈i,true〉^⊛ = 〈(\fst (•i))^*, true〉.
 474 // qed.
 475
 476 lemma ostar_false: ∀S.∀i:pitem S.
 477   〈i,false〉^⊛ = 〈i^*, false〉.
 478 // qed.
 479
 480 lemma erase_ostar: ∀S.∀e:pre S.
 481   |\fst (e^⊛)| = |\fst e|^*.
 482 #S * #i * // qed.
 483
 484 lemma sem_odot_true: ∀S:DeqSet.∀e1:pre S.∀i.
 485   \sem{e1 ⊙ 〈i,true〉} =1 \sem{e1 ▹ i} ∪ { [ ] }.
 486 #S #e1 #i
 487 cut (e1 ⊙ 〈i,true〉 = 〈\fst (e1 ▹ i), \snd(e1 ▹ i) ∨ true〉) [//]
 488 #H >H cases (e1 ▹ i) #i1 #b1 cases b1
 489   [>sem_pre_true @eqP_trans [||@eqP_sym @union_assoc]
 490    @eqP_union_l /2/
 491   |/2/
 492   ]
 493 qed.
 494
 495 lemma eq_odot_false: ∀S:DeqSet.∀e1:pre S.∀i.
 496   e1 ⊙ 〈i,false〉 = e1 ▹ i.
 497 #S #e1 #i
 498 cut (e1 ⊙ 〈i,false〉 = 〈\fst (e1 ▹ i), \snd(e1 ▹ i) ∨ false〉) [//]
 499 cases (e1 ▹ i) #i1 #b1 cases b1 #H @H
 500 qed.
 501
 502 lemma sem_odot:
 503   ∀S.∀e1,e2: pre S. \sem{e1 ⊙ e2} =1 \sem{e1}· \sem{|\fst e2|} ∪ \sem{e2}.
 504 #S #e1 * #i2 *
 505   [>sem_pre_true
 506    @eqP_trans [|@sem_odot_true]
 507    @eqP_trans [||@union_assoc] @eqP_union_r @odot_dot_aux //
 508   |>sem_pre_false >eq_odot_false @odot_dot_aux //
 509   ]
 510 qed.
 511
 512 (* theorem 16: 4 *)
 513 theorem sem_ostar: ∀S.∀e:pre S.
 514   \sem{e^⊛} =1  \sem{e} · \sem{|\fst e|}^*.
 515 #S * #i #b cases b
 516   [>sem_pre_true >sem_pre_true >sem_star >erase_bull
 517    @eqP_trans [|@eqP_union_r[|@cat_ext_l [|@minus_eps_pre_aux //]]]
 518    @eqP_trans [|@eqP_union_r [|@distr_cat_r]]
 519    @eqP_trans [||@eqP_sym @distr_cat_r]
 520    @eqP_trans [|@union_assoc] @eqP_union_l
 521    @eqP_trans [||@eqP_sym @epsilon_cat_l] @eqP_sym @star_fix_eps
 522   |>sem_pre_false >sem_pre_false >sem_star /2/
 523   ]
 524 qed.
 525