matita/matitaScript.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29 open GrafiteTypes
  30
  31 module TA = GrafiteAst
  32
  33 let debug = false
  34 let debug_print = if debug then prerr_endline else ignore
  35
  36   (** raised when one of the script margins (top or bottom) is reached *)
  37 exception Margin
  38 exception NoUnfinishedProof
  39 exception ActionCancelled of string
  40
  41 let safe_substring s i j =
  42   try String.sub s i j with Invalid_argument _ -> assert false
  43
  44 let heading_nl_RE = Pcre.regexp "^\\s*\n\\s*"
  45 let heading_nl_RE' = Pcre.regexp "^(\\s*\n\\s*)"
  46 let only_dust_RE = Pcre.regexp "^(\\s|\n|%%[^\n]*\n)*$"
  47 let multiline_RE = Pcre.regexp "^\n[^\n]+$"
  48 let newline_RE = Pcre.regexp "\n"
  49
  50 let comment str =
  51   if Pcre.pmatch ~rex:multiline_RE str then
  52     "\n(** " ^ (Pcre.replace ~rex:newline_RE str) ^ " *)"
  53   else
  54     "\n(**\n" ^ str ^ "\n*)"
  55
  56 let first_line s =
  57   let s = Pcre.replace ~rex:heading_nl_RE s in
  58   try
  59     let nl_pos = String.index s '\n' in
  60     String.sub s 0 nl_pos
  61   with Not_found -> s
  62
  63   (** creates a statement AST for the Goal tactic, e.g. "goal 7" *)
  64 let goal_ast n =
  65   let module A = GrafiteAst in
  66   let loc = HExtlib.dummy_floc in
  67   A.Executable (loc, A.Tactical (loc,
  68     A.Tactic (loc, A.Goal (loc, n)),
  69     Some (A.Dot loc)))
  70
  71 type guistuff = {
  72   mathviewer:MatitaTypes.mathViewer;
  73   urichooser: UriManager.uri list -> UriManager.uri list;
  74   ask_confirmation: title:string -> message:string -> [`YES | `NO | `CANCEL];
  75   develcreator: containing:string option -> unit;
  76   mutable filenamedata: string option * MatitamakeLib.development option
  77 }
  78
  79 let eval_with_engine guistuff lexicon_status grafite_status user_goal
  80  skipped_txt nonskipped_txt st
  81 =
  82   let module TAPp = GrafiteAstPp in
  83   let module DTE = DisambiguateTypes.Environment in
  84   let module DP = DisambiguatePp in
  85   let parsed_text_length =
  86     String.length skipped_txt + String.length nonskipped_txt
  87   in
  88   let text = skipped_txt ^ nonskipped_txt in
  89   let prefix_len = MatitaGtkMisc.utf8_string_length skipped_txt in
  90   let enriched_history_fragment =
  91    MatitaEngine.eval_ast ~do_heavy_checks:true
  92     lexicon_status grafite_status (text,prefix_len,st)
  93   in
  94   let enriched_history_fragment = List.rev enriched_history_fragment in
  95   (* really fragile *)
  96   let res,_ =
  97     List.fold_left
  98       (fun (acc, to_prepend) (status,alias) ->
  99        match alias with
 100        | None -> (status,to_prepend ^ nonskipped_txt)::acc,""
 101        | Some (k,((v,_) as value)) ->
 102             let newtxt = DP.pp_environment (DTE.add k value DTE.empty) in
 103             (status,to_prepend ^ newtxt ^ "\n")::acc, "")
 104       ([],skipped_txt) enriched_history_fragment
 105   in
 106   res,parsed_text_length
 107
 108 let wrap_with_developments guistuff f arg =
 109   let compile_needed_and_go_on lexiconfile d exc =
 110     let target = Pcre.replace ~pat:"lexicon$" ~templ:"moo" lexiconfile in
 111     let target = Pcre.replace ~pat:"metadata$" ~templ:"moo" target in
 112     let refresh_cb () =
 113       while Glib.Main.pending () do ignore(Glib.Main.iteration false); done
 114     in
 115     if not(MatitamakeLib.build_development_in_bg ~target refresh_cb d) then
 116       raise exc
 117     else
 118       f arg
 119   in
 120   let do_nothing () = raise (ActionCancelled "Inclusion not performed") in
 121   let check_if_file_is_exists f =
 122     assert(Pcre.pmatch ~pat:"ma$" f);
 123     let pwd = Sys.getcwd () in
 124     let f_pwd = pwd ^ "/" ^ f in
 125     if not (HExtlib.is_regular f_pwd) then
 126       raise (ActionCancelled ("File "^f_pwd^" does not exists!"))
 127     else
 128       raise
 129         (ActionCancelled
 130           ("Internal error: "^f_pwd^" exists but I'm unable to include it!"))
 131   in
 132   let handle_with_devel d lexiconfile exc =
 133     let name = MatitamakeLib.name_for_development d in
 134     let title = "Unable to include " ^ lexiconfile in
 135     let message =
 136       lexiconfile ^ " is handled by development <b>" ^ name ^ "</b>.\n\n" ^
 137       "<i>Should I compile it and Its dependencies?</i>"
 138     in
 139     (match guistuff.ask_confirmation ~title ~message with
 140     | `YES -> compile_needed_and_go_on lexiconfile d exc
 141     | `NO -> raise exc
 142     | `CANCEL -> do_nothing ())
 143   in
 144   let handle_without_devel mafilename exc =
 145     let title = "Unable to include " ^ mafilename in
 146     let message =
 147      mafilename ^ " is <b>not</b> handled by a development.\n" ^
 148      "All dependencies are automatically solved for a development.\n\n" ^
 149      "<i>Do you want to set up a development?</i>"
 150     in
 151     (match guistuff.ask_confirmation ~title ~message with
 152     | `YES ->
 153         guistuff.develcreator ~containing:(Some (Filename.dirname mafilename));
 154         do_nothing ()
 155     | `NO -> raise exc
 156     | `CANCEL -> do_nothing())
 157   in
 158   try
 159     f arg
 160   with
 161   | DependenciesParser.UnableToInclude mafilename ->
 162       assert (Pcre.pmatch ~pat:"ma$" mafilename);
 163       check_if_file_is_exists mafilename
 164   | LexiconEngine.IncludedFileNotCompiled (xfilename,mafilename)
 165   | GrafiteEngine.IncludedFileNotCompiled (xfilename,mafilename) as exn ->
 166       assert (Pcre.pmatch ~pat:"ma$" mafilename);
 167       assert (Pcre.pmatch ~pat:"lexicon$" xfilename ||
 168               Pcre.pmatch ~pat:"mo$" xfilename );
 169       (* we know that someone was able to include the .ma, get the baseuri
 170        * but was unable to get the compilation output 'xfilename' *)
 171       match MatitamakeLib.development_for_dir (Filename.dirname mafilename) with
 172       | None -> handle_without_devel mafilename exn
 173       | Some d -> handle_with_devel d xfilename exn
 174 ;;
 175
 176 let eval_with_engine
 177      guistuff lexicon_status grafite_status user_goal
 178        skipped_txt nonskipped_txt st
 179 =
 180   wrap_with_developments guistuff
 181     (eval_with_engine
 182       guistuff lexicon_status grafite_status user_goal
 183         skipped_txt nonskipped_txt) st
 184 ;;
 185
 186 let pp_eager_statement_ast =
 187   GrafiteAstPp.pp_statement ~term_pp:CicNotationPp.pp_term
 188     ~lazy_term_pp:(fun _ -> assert false) ~obj_pp:(fun _ -> assert false)
 189
 190 let rec eval_macro include_paths (buffer : GText.buffer) guistuff lexicon_status grafite_status user_goal unparsed_text parsed_text script mac =
 191   let module TAPp = GrafiteAstPp in
 192   let module MQ = MetadataQuery in
 193   let module MDB = LibraryDb in
 194   let module CTC = CicTypeChecker in
 195   let module CU = CicUniv in
 196   (* no idea why ocaml wants this *)
 197   let parsed_text_length = String.length parsed_text in
 198   let dbd = LibraryDb.instance () in
 199   let pp_macro =
 200     let f t = ProofEngineReduction.replace
 201       ~equality:(fun _ t -> match t with Cic.Meta _ -> true | _ -> false)
 202       ~what:[()] ~with_what:[Cic.Implicit None] ~where:t
 203     in
 204     let metasenv = GrafiteTypes.get_proof_metasenv grafite_status in
 205     TAPp.pp_macro
 206       ~term_pp:(fun x ->
 207         ApplyTransformation.txt_of_cic_term max_int metasenv [] (f x))
 208   in
 209   match mac with
 210   (* WHELP's stuff *)
 211   | TA.WMatch (loc, term) ->
 212      let l =  Whelp.match_term ~dbd term in
 213      let entry = `Whelp (pp_macro mac, l) in
 214      guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
 215      [], parsed_text_length
 216   | TA.WInstance (loc, term) ->
 217      let l = Whelp.instance ~dbd term in
 218      let entry = `Whelp (pp_macro mac, l) in
 219      guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
 220      [], parsed_text_length
 221   | TA.WLocate (loc, s) ->
 222      let l = Whelp.locate ~dbd s in
 223      let entry = `Whelp (pp_macro mac, l) in
 224      guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
 225      [], parsed_text_length
 226   | TA.WElim (loc, term) ->
 227      let uri =
 228        match term with
 229        | Cic.MutInd (uri,n,_) -> UriManager.uri_of_uriref uri n None
 230        | _ -> failwith "Not a MutInd"
 231      in
 232      let l = Whelp.elim ~dbd uri in
 233      let entry = `Whelp (pp_macro mac, l) in
 234      guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
 235      [], parsed_text_length
 236   | TA.WHint (loc, term) ->
 237      let s = ((None,[0,[],term], Cic.Meta (0,[]) ,term),0) in
 238      let l = List.map fst (MQ.experimental_hint ~dbd s) in
 239      let entry = `Whelp (pp_macro mac, l) in
 240      guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
 241      [], parsed_text_length
 242   (* REAL macro *)
 243   | TA.Hint loc ->
 244       let user_goal' =
 245        match user_goal with
 246           Some n -> n
 247         | None -> raise NoUnfinishedProof
 248       in
 249       let proof = GrafiteTypes.get_current_proof grafite_status in
 250       let proof_status = proof,user_goal' in
 251       let l = List.map fst (MQ.experimental_hint ~dbd proof_status) in
 252       let selected = guistuff.urichooser l in
 253       (match selected with
 254       | [] -> [], parsed_text_length
 255       | [uri] ->
 256           let suri = UriManager.string_of_uri uri in
 257           let ast loc =
 258             TA.Executable (loc, (TA.Tactical (loc,
 259               TA.Tactic (loc,
 260                 TA.Apply (loc, CicNotationPt.Uri (suri, None))),
 261                 Some (TA.Dot loc)))) in
 262           let text =
 263            comment parsed_text ^ "\n" ^
 264             pp_eager_statement_ast (ast HExtlib.dummy_floc) in
 265           let text_len = MatitaGtkMisc.utf8_string_length text in
 266           let loc = HExtlib.floc_of_loc (0,text_len) in
 267           let statement = `Ast (GrafiteParser.LSome (ast loc),text) in
 268           let res,_parsed_text_len =
 269            eval_statement include_paths buffer guistuff lexicon_status
 270             grafite_status user_goal script statement
 271           in
 272            (* we need to replace all the parsed_text *)
 273            res,String.length parsed_text
 274       | _ ->
 275           HLog.error
 276             "The result of the urichooser should be only 1 uri, not:\n";
 277           List.iter (
 278             fun u -> HLog.error (UriManager.string_of_uri u ^ "\n")
 279           ) selected;
 280           assert false)
 281   | TA.Check (_,term) ->
 282       let metasenv = GrafiteTypes.get_proof_metasenv grafite_status in
 283       let context =
 284        match user_goal with
 285           None -> []
 286         | Some n -> GrafiteTypes.get_proof_context grafite_status n in
 287       let ty,_ = CTC.type_of_aux' metasenv context term CicUniv.empty_ugraph in
 288       let t_and_ty = Cic.Cast (term,ty) in
 289       guistuff.mathviewer#show_entry (`Cic (t_and_ty,metasenv));
 290       [], parsed_text_length
 291   (* TODO *)
 292   | TA.Quit _ -> failwith "not implemented"
 293   | TA.Print (_,kind) -> failwith "not implemented"
 294   | TA.Search_pat (_, search_kind, str) -> failwith "not implemented"
 295   | TA.Search_term (_, search_kind, term) -> failwith "not implemented"
 296
 297 and eval_executable include_paths (buffer : GText.buffer) guistuff
 298 lexicon_status grafite_status user_goal unparsed_text skipped_txt nonskipped_txt
 299 script ex loc
 300 =
 301  let module TAPp = GrafiteAstPp in
 302  let module MD = GrafiteDisambiguator in
 303  let module ML = MatitaMisc in
 304   try
 305    begin
 306     match ex with
 307      | TA.Command (_,TA.Set (_,"baseuri",u)) ->
 308         if  Http_getter_storage.is_read_only u then
 309           raise (ActionCancelled ("baseuri " ^ u ^ " is readonly"));
 310         if not (Http_getter_storage.is_empty u) then
 311          (match
 312             guistuff.ask_confirmation
 313               ~title:"Baseuri redefinition"
 314               ~message:(
 315                 "Baseuri " ^ u ^ " already exists.\n" ^
 316                 "Do you want to redefine the corresponding "^
 317                 "part of the library?")
 318           with
 319            | `YES -> LibraryClean.clean_baseuris [u]
 320            | `NO -> ()
 321            | `CANCEL -> raise MatitaTypes.Cancel)
 322      | _ -> ()
 323    end;
 324    eval_with_engine
 325     guistuff lexicon_status grafite_status user_goal skipped_txt nonskipped_txt
 326      (TA.Executable (loc, ex))
 327   with
 328      MatitaTypes.Cancel -> [], 0
 329    | GrafiteEngine.Macro (_loc,lazy_macro) ->
 330       let context =
 331        match user_goal with
 332           None -> []
 333         | Some n -> GrafiteTypes.get_proof_context grafite_status n in
 334       let grafite_status,macro = lazy_macro context in
 335        eval_macro include_paths buffer guistuff lexicon_status grafite_status
 336         user_goal unparsed_text (skipped_txt ^ nonskipped_txt) script macro
 337
 338 and eval_statement include_paths (buffer : GText.buffer) guistuff lexicon_status
 339  grafite_status user_goal script statement
 340 =
 341   let (lexicon_status,st), unparsed_text =
 342     match statement with
 343     | `Raw text ->
 344         if Pcre.pmatch ~rex:only_dust_RE text then raise Margin;
 345         let ast =
 346           wrap_with_developments guistuff
 347             (GrafiteParser.parse_statement
 348               (Ulexing.from_utf8_string text) ~include_paths) lexicon_status
 349         in
 350           ast, text
 351     | `Ast (st, text) -> (lexicon_status, st), text
 352   in
 353   let text_of_loc floc =
 354     let nonskipped_txt,_ = MatitaGtkMisc.utf8_parsed_text unparsed_text floc in
 355     let start, stop = HExtlib.loc_of_floc floc in
 356     let floc = HExtlib.floc_of_loc (0, start) in
 357     let skipped_txt,_ = MatitaGtkMisc.utf8_parsed_text unparsed_text floc in
 358     let floc = HExtlib.floc_of_loc (0, stop) in
 359     let txt,len = MatitaGtkMisc.utf8_parsed_text unparsed_text floc in
 360     txt,nonskipped_txt,skipped_txt,len
 361   in
 362   match st with
 363   | GrafiteParser.LNone loc ->
 364       let parsed_text, _, _, parsed_text_length = text_of_loc loc in
 365        [(grafite_status,lexicon_status),parsed_text],
 366         parsed_text_length
 367   | GrafiteParser.LSome (GrafiteAst.Comment (loc, _)) ->
 368       let parsed_text, _, _, parsed_text_length = text_of_loc loc in
 369       let remain_len = String.length unparsed_text - parsed_text_length in
 370       let s = String.sub unparsed_text parsed_text_length remain_len in
 371       let s,len =
 372        try
 373         eval_statement include_paths buffer guistuff lexicon_status
 374          grafite_status user_goal script (`Raw s)
 375        with
 376           HExtlib.Localized (floc, exn) ->
 377            HExtlib.raise_localized_exception
 378              ~offset:(MatitaGtkMisc.utf8_string_length parsed_text) floc exn
 379         | GrafiteDisambiguator.DisambiguationError (offset,errorll) ->
 380            raise
 381             (GrafiteDisambiguator.DisambiguationError
 382               (offset+parsed_text_length, errorll))
 383       in
 384       (match s with
 385       | (statuses,text)::tl ->
 386          (statuses,parsed_text ^ text)::tl,parsed_text_length + len
 387       | [] -> [], 0)
 388   | GrafiteParser.LSome (GrafiteAst.Executable (loc, ex)) ->
 389      let _, nonskipped, skipped, parsed_text_length =
 390        text_of_loc loc
 391      in
 392       eval_executable include_paths buffer guistuff lexicon_status
 393        grafite_status user_goal unparsed_text skipped nonskipped script ex loc
 394
 395 let fresh_script_id =
 396   let i = ref 0 in
 397   fun () -> incr i; !i
 398
 399 class script  ~(source_view: GSourceView.source_view)
 400               ~(mathviewer: MatitaTypes.mathViewer)
 401               ~set_star
 402               ~ask_confirmation
 403               ~urichooser
 404               ~develcreator
 405               () =
 406 let buffer = source_view#buffer in
 407 let source_buffer = source_view#source_buffer in
 408 let initial_statuses () =
 409  (* these include_paths are used only to load the initial notation *)
 410  let include_paths =
 411   Helm_registry.get_list Helm_registry.string "matita.includes" in
 412  let lexicon_status =
 413   CicNotation2.load_notation ~include_paths
 414    BuildTimeConf.core_notation_script in
 415  let grafite_status = GrafiteSync.init () in
 416   grafite_status,lexicon_status
 417 in
 418 object (self)
 419   val mutable include_paths =
 420    Helm_registry.get_list Helm_registry.string "matita.includes"
 421
 422   val scriptId = fresh_script_id ()
 423
 424   val guistuff = {
 425     mathviewer = mathviewer;
 426     urichooser = urichooser;
 427     ask_confirmation = ask_confirmation;
 428     develcreator = develcreator;
 429     filenamedata = (None, None)}
 430
 431   method private getFilename =
 432     match guistuff.filenamedata with Some f,_ -> f | _ -> assert false
 433
 434   method filename = self#getFilename
 435
 436   method private ppFilename =
 437     match guistuff.filenamedata with
 438     | Some f,_ -> f
 439     | None,_ -> sprintf ".unnamed%d.ma" scriptId
 440
 441   initializer
 442     ignore (GMain.Timeout.add ~ms:300000
 443        ~callback:(fun _ -> self#_saveToBackupFile ();true));
 444     ignore (buffer#connect#modified_changed
 445       (fun _ -> set_star (Filename.basename self#ppFilename) buffer#modified))
 446
 447   val mutable statements = []    (** executed statements *)
 448
 449   val mutable history = [ initial_statuses () ]
 450     (** list of states before having executed statements. Head element of this
 451       * list is the current state, last element is the state at the beginning of
 452       * the script.
 453       * Invariant: this list length is 1 + length of statements *)
 454
 455   (** goal as seen by the user (i.e. metano corresponding to current tab) *)
 456   val mutable userGoal = None
 457
 458   (** text mark and tag representing locked part of a script *)
 459   val locked_mark =
 460     buffer#create_mark ~name:"locked" ~left_gravity:true buffer#start_iter
 461   val locked_tag = buffer#create_tag [`BACKGROUND "lightblue"; `EDITABLE false]
 462   val error_tag = buffer#create_tag [`UNDERLINE `SINGLE; `FOREGROUND "red"]
 463
 464   method locked_mark = locked_mark
 465   method locked_tag = locked_tag
 466   method error_tag = error_tag
 467
 468     (* history can't be empty, the invariant above grant that it contains at
 469      * least the init grafite_status *)
 470   method grafite_status = match history with (s,_)::_ -> s | _ -> assert false
 471   method lexicon_status = match history with (_,ss)::_ -> ss | _ -> assert false
 472
 473   method private _advance ?statement () =
 474    let s = match statement with Some s -> s | None -> self#getFuture in
 475    HLog.debug ("evaluating: " ^ first_line s ^ " ...");
 476    let (entries, parsed_len) =
 477     try
 478      eval_statement include_paths buffer guistuff self#lexicon_status
 479       self#grafite_status userGoal self (`Raw s)
 480     with End_of_file -> raise Margin
 481    in
 482    let new_statuses, new_statements =
 483      let statuses, texts = List.split entries in
 484      statuses, texts
 485    in
 486    history <- new_statuses @ history;
 487    statements <- new_statements @ statements;
 488    let start = buffer#get_iter_at_mark (`MARK locked_mark) in
 489    let new_text = String.concat "" (List.rev new_statements) in
 490    if statement <> None then
 491      buffer#insert ~iter:start new_text
 492    else begin
 493      let parsed_text = String.sub s 0 parsed_len in
 494      if new_text <> parsed_text then begin
 495        let stop = start#copy#forward_chars (Glib.Utf8.length parsed_text) in
 496        buffer#delete ~start ~stop;
 497        buffer#insert ~iter:start new_text;
 498      end;
 499    end;
 500    self#moveMark (Glib.Utf8.length  new_text);
 501    (* here we need to set the Goal in case we are going to cursor (or to
 502       bottom) and we will face a macro *)
 503    match self#grafite_status.proof_status with
 504       Incomplete_proof p ->
 505        userGoal <-
 506          (try Some (Continuationals.Stack.find_goal p.stack)
 507          with Failure _ -> None)
 508     | _ -> userGoal <- None
 509
 510   method private _retract offset lexicon_status grafite_status new_statements
 511    new_history
 512   =
 513    let cur_grafite_status,cur_lexicon_status =
 514     match history with s::_ -> s | [] -> assert false
 515    in
 516     LexiconSync.time_travel ~present:cur_lexicon_status ~past:lexicon_status;
 517     GrafiteSync.time_travel ~present:cur_grafite_status ~past:grafite_status;
 518     statements <- new_statements;
 519     history <- new_history;
 520     self#moveMark (- offset)
 521
 522   method advance ?statement () =
 523     try
 524       self#_advance ?statement ();
 525       self#notify
 526     with
 527     | Margin -> self#notify
 528     | Not_found -> assert false
 529     | exc -> self#notify; raise exc
 530
 531   method retract () =
 532     try
 533       let cmp,new_statements,new_history,(grafite_status,lexicon_status) =
 534        match statements,history with
 535           stat::statements, _::(status::_ as history) ->
 536            assert (Glib.Utf8.validate stat);
 537            Glib.Utf8.length stat, statements, history, status
 538        | [],[_] -> raise Margin
 539        | _,_ -> assert false
 540       in
 541        self#_retract cmp lexicon_status grafite_status new_statements
 542         new_history;
 543        self#notify
 544     with
 545     | Margin -> self#notify
 546     | exc -> self#notify; raise exc
 547
 548   method private getFuture =
 549     buffer#get_text ~start:(buffer#get_iter_at_mark (`MARK locked_mark))
 550       ~stop:buffer#end_iter ()
 551
 552
 553   (** @param rel_offset relative offset from current position of locked_mark *)
 554   method private moveMark rel_offset =
 555     let mark = `MARK locked_mark in
 556     let old_insert = buffer#get_iter_at_mark `INSERT in
 557     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 558     let current_mark_pos = buffer#get_iter_at_mark mark in
 559     let new_mark_pos =
 560       match rel_offset with
 561       | 0 -> current_mark_pos
 562       | n when n > 0 -> current_mark_pos#forward_chars n
 563       | n (* when n < 0 *) -> current_mark_pos#backward_chars (abs n)
 564     in
 565     buffer#move_mark mark ~where:new_mark_pos;
 566     buffer#apply_tag locked_tag ~start:buffer#start_iter ~stop:new_mark_pos;
 567     buffer#move_mark `INSERT old_insert;
 568     let mark_position = buffer#get_iter_at_mark mark in
 569     if source_view#move_mark_onscreen mark then
 570      begin
 571       buffer#move_mark mark mark_position;
 572       source_view#scroll_to_mark ~use_align:true ~xalign:1.0 ~yalign:0.1 mark;
 573      end;
 574     while Glib.Main.pending () do ignore(Glib.Main.iteration false); done
 575
 576   method clean_dirty_lock =
 577     let lock_mark_iter = buffer#get_iter_at_mark (`MARK locked_mark) in
 578     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 579     buffer#apply_tag locked_tag ~start:buffer#start_iter ~stop:lock_mark_iter
 580
 581   val mutable observers = []
 582
 583   method addObserver (o: LexiconEngine.status -> GrafiteTypes.status -> unit) =
 584     observers <- o :: observers
 585
 586   method private notify =
 587     let lexicon_status = self#lexicon_status in
 588     let grafite_status = self#grafite_status in
 589     List.iter (fun o -> o lexicon_status grafite_status) observers
 590
 591   method loadFromFile f =
 592     buffer#set_text (HExtlib.input_file f);
 593     self#reset_buffer;
 594     buffer#set_modified false
 595
 596   method assignFileName file =
 597     let abspath = MatitaMisc.absolute_path file in
 598     let dirname = Filename.dirname abspath in
 599     let devel = MatitamakeLib.development_for_dir dirname in
 600     guistuff.filenamedata <- Some abspath, devel;
 601     let include_ =
 602      match MatitamakeLib.development_for_dir dirname with
 603         None -> []
 604       | Some devel -> [MatitamakeLib.root_for_development devel] in
 605     let include_ =
 606      include_ @ (Helm_registry.get_list Helm_registry.string "matita.includes")
 607     in
 608      include_paths <- include_
 609
 610   method saveToFile () =
 611     let oc = open_out self#getFilename in
 612     output_string oc (buffer#get_text ~start:buffer#start_iter
 613                         ~stop:buffer#end_iter ());
 614     close_out oc;
 615     buffer#set_modified false
 616
 617   method private _saveToBackupFile () =
 618     if buffer#modified then
 619       begin
 620         let f = self#ppFilename ^ "~" in
 621         let oc = open_out f in
 622         output_string oc (buffer#get_text ~start:buffer#start_iter
 623                             ~stop:buffer#end_iter ());
 624         close_out oc;
 625         HLog.debug ("backup " ^ f ^ " saved")
 626       end
 627
 628   method private goto_top =
 629     let grafite_status,lexicon_status =
 630       let rec last x = function
 631       | [] -> x
 632       | hd::tl -> last hd tl
 633       in
 634       last (self#grafite_status,self#lexicon_status) history
 635     in
 636     (* FIXME: this is not correct since there is no undo for
 637      * library_objects.set_default... *)
 638     GrafiteSync.time_travel ~present:self#grafite_status ~past:grafite_status;
 639     LexiconSync.time_travel ~present:self#lexicon_status ~past:lexicon_status
 640
 641   method private reset_buffer =
 642     statements <- [];
 643     history <- [ initial_statuses () ];
 644     userGoal <- None;
 645     self#notify;
 646     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 647     buffer#move_mark (`MARK locked_mark) ~where:buffer#start_iter
 648
 649   method reset () =
 650     self#reset_buffer;
 651     source_buffer#begin_not_undoable_action ();
 652     buffer#delete ~start:buffer#start_iter ~stop:buffer#end_iter;
 653     source_buffer#end_not_undoable_action ();
 654     buffer#set_modified false;
 655
 656   method template () =
 657     let template = HExtlib.input_file BuildTimeConf.script_template in
 658     buffer#insert ~iter:(buffer#get_iter `START) template;
 659     let development = MatitamakeLib.development_for_dir (Unix.getcwd ()) in
 660     guistuff.filenamedata <- (None,development);
 661     let include_ =
 662      match development with
 663         None -> []
 664       | Some devel -> [MatitamakeLib.root_for_development devel ]
 665     in
 666     let include_ =
 667      include_ @ (Helm_registry.get_list Helm_registry.string "matita.includes")
 668     in
 669      include_paths <- include_ ;
 670      buffer#set_modified false;
 671      set_star (Filename.basename self#ppFilename) false
 672
 673   method goto (pos: [`Top | `Bottom | `Cursor]) () =
 674     let old_locked_mark =
 675      `MARK
 676        (buffer#create_mark ~name:"old_locked_mark"
 677          ~left_gravity:true (buffer#get_iter_at_mark (`MARK locked_mark))) in
 678     let getpos _ = buffer#get_iter_at_mark (`MARK locked_mark) in
 679     let getoldpos _ = buffer#get_iter_at_mark old_locked_mark in
 680     let dispose_old_locked_mark () = buffer#delete_mark old_locked_mark in
 681     match pos with
 682     | `Top ->
 683         dispose_old_locked_mark ();
 684         self#goto_top;
 685         self#reset_buffer;
 686         self#notify
 687     | `Bottom ->
 688         (try
 689           let rec dowhile () =
 690             self#_advance ();
 691             let newpos = getpos () in
 692             if (getoldpos ())#compare newpos < 0 then
 693               begin
 694                 buffer#move_mark old_locked_mark newpos;
 695                 dowhile ()
 696               end
 697           in
 698           dowhile ();
 699           dispose_old_locked_mark ();
 700           self#notify
 701         with
 702         | Margin -> dispose_old_locked_mark (); self#notify
 703         | exc -> dispose_old_locked_mark (); self#notify; raise exc)
 704     | `Cursor ->
 705         let locked_iter () = buffer#get_iter_at_mark (`NAME "locked") in
 706         let cursor_iter () = buffer#get_iter_at_mark `INSERT in
 707         let remember =
 708          `MARK
 709            (buffer#create_mark ~name:"initial_insert"
 710              ~left_gravity:true (cursor_iter ())) in
 711         let dispose_remember () = buffer#delete_mark remember in
 712         let remember_iter () =
 713          buffer#get_iter_at_mark (`NAME "initial_insert") in
 714         let cmp () = (locked_iter ())#offset - (remember_iter ())#offset in
 715         let icmp = cmp () in
 716         let forward_until_cursor () = (* go forward until locked > cursor *)
 717           let rec aux () =
 718             self#_advance ();
 719             if cmp () < 0 && (getoldpos ())#compare (getpos ()) < 0
 720             then
 721              begin
 722               buffer#move_mark old_locked_mark (getpos ());
 723               aux ()
 724              end
 725           in
 726           aux ()
 727         in
 728         let rec back_until_cursor len = (* go backward until locked < cursor *)
 729          function
 730             statements, ((grafite_status,lexicon_status)::_ as history)
 731             when len <= 0 ->
 732              self#_retract (icmp - len) lexicon_status grafite_status statements
 733               history
 734           | statement::tl1, _::tl2 ->
 735              back_until_cursor (len - MatitaGtkMisc.utf8_string_length statement) (tl1,tl2)
 736           | _,_ -> assert false
 737         in
 738         (try
 739           begin
 740            if icmp < 0 then       (* locked < cursor *)
 741              (forward_until_cursor (); self#notify)
 742            else if icmp > 0 then  (* locked > cursor *)
 743              (back_until_cursor icmp (statements,history); self#notify)
 744            else                  (* cursor = locked *)
 745                ()
 746           end ;
 747           dispose_remember ();
 748           dispose_old_locked_mark ();
 749         with
 750         | Margin -> dispose_remember (); dispose_old_locked_mark (); self#notify
 751         | exc -> dispose_remember (); dispose_old_locked_mark ();
 752                  self#notify; raise exc)
 753
 754   method onGoingProof () =
 755     match self#grafite_status.proof_status with
 756     | No_proof | Proof _ -> false
 757     | Incomplete_proof _ -> true
 758     | Intermediate _ -> assert false
 759
 760 (*   method proofStatus = MatitaTypes.get_proof_status self#status *)
 761   method proofMetasenv = GrafiteTypes.get_proof_metasenv self#grafite_status
 762
 763   method proofContext =
 764    match userGoal with
 765       None -> []
 766     | Some n -> GrafiteTypes.get_proof_context self#grafite_status n
 767
 768   method proofConclusion =
 769    match userGoal with
 770       None -> assert false
 771     | Some n ->
 772        GrafiteTypes.get_proof_conclusion self#grafite_status n
 773
 774   method stack = GrafiteTypes.get_stack self#grafite_status
 775   method setGoal n = userGoal <- n
 776   method goal = userGoal
 777
 778   method eos =
 779     let rec is_there_only_comments lexicon_status s =
 780       if Pcre.pmatch ~rex:only_dust_RE s then raise Margin;
 781       let lexicon_status,st =
 782        GrafiteParser.parse_statement (Ulexing.from_utf8_string s)
 783         ~include_paths lexicon_status
 784       in
 785       match st with
 786       | GrafiteParser.LSome (GrafiteAst.Comment (loc,_)) ->
 787           let _,parsed_text_length = MatitaGtkMisc.utf8_parsed_text s loc in
 788           (* CSC: why +1 in the following lines ???? *)
 789           let parsed_text_length = parsed_text_length + 1 in
 790 prerr_endline ("## " ^ string_of_int parsed_text_length);
 791           let remain_len = String.length s - parsed_text_length in
 792           let next = String.sub s parsed_text_length remain_len in
 793           is_there_only_comments lexicon_status next
 794       | GrafiteParser.LNone _
 795       | GrafiteParser.LSome (GrafiteAst.Executable _) -> false
 796     in
 797     try
 798       is_there_only_comments self#lexicon_status self#getFuture
 799     with
 800     | LexiconEngine.IncludedFileNotCompiled _
 801     | HExtlib.Localized _
 802     | CicNotationParser.Parse_error _ -> false
 803     | Margin | End_of_file -> true
 804
 805   (* debug *)
 806   method dump () =
 807     HLog.debug "script status:";
 808     HLog.debug ("history size: " ^ string_of_int (List.length history));
 809     HLog.debug (sprintf "%d statements:" (List.length statements));
 810     List.iter HLog.debug statements;
 811     HLog.debug ("Current file name: " ^
 812       (match guistuff.filenamedata with
 813       |None,_ -> "[ no name ]"
 814       | Some f,_ -> f));
 815
 816 end
 817
 818 let _script = ref None
 819
 820 let script ~source_view ~mathviewer ~urichooser ~develcreator ~ask_confirmation ~set_star ()
 821 =
 822   let s = new script
 823     ~source_view ~mathviewer ~ask_confirmation ~urichooser ~develcreator ~set_star ()
 824   in
 825   _script := Some s;
 826   s
 827
 828 let current () = match !_script with None -> assert false | Some s -> s
 829