matita/matitaScript.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29 open GrafiteTypes
  30
  31 module TA = GrafiteAst
  32
  33 let debug = false
  34 let debug_print = if debug then prerr_endline else ignore
  35
  36   (** raised when one of the script margins (top or bottom) is reached *)
  37 exception Margin
  38 exception NoUnfinishedProof
  39 exception ActionCancelled of string
  40
  41 let safe_substring s i j =
  42   try String.sub s i j with Invalid_argument _ -> assert false
  43
  44 let heading_nl_RE = Pcre.regexp "^\\s*\n\\s*"
  45 let heading_nl_RE' = Pcre.regexp "^(\\s*\n\\s*)"
  46 let only_dust_RE = Pcre.regexp "^(\\s|\n|%%[^\n]*\n)*$"
  47 let multiline_RE = Pcre.regexp "^\n[^\n]+$"
  48 let newline_RE = Pcre.regexp "\n"
  49
  50 let comment str =
  51   if Pcre.pmatch ~rex:multiline_RE str then
  52     "\n(** " ^ (Pcre.replace ~rex:newline_RE str) ^ " *)"
  53   else
  54     "\n(**\n" ^ str ^ "\n*)"
  55
  56 let first_line s =
  57   let s = Pcre.replace ~rex:heading_nl_RE s in
  58   try
  59     let nl_pos = String.index s '\n' in
  60     String.sub s 0 nl_pos
  61   with Not_found -> s
  62
  63   (** creates a statement AST for the Goal tactic, e.g. "goal 7" *)
  64 let goal_ast n =
  65   let module A = GrafiteAst in
  66   let loc = HExtlib.dummy_floc in
  67   A.Executable (loc, A.Tactical (loc,
  68     A.Tactic (loc, A.Goal (loc, n)),
  69     Some (A.Dot loc)))
  70
  71 type guistuff = {
  72   mathviewer:MatitaTypes.mathViewer;
  73   urichooser: UriManager.uri list -> UriManager.uri list;
  74   ask_confirmation: title:string -> message:string -> [`YES | `NO | `CANCEL];
  75   develcreator: containing:string option -> unit;
  76   mutable filenamedata: string option * MatitamakeLib.development option
  77 }
  78
  79 let eval_with_engine guistuff lexicon_status grafite_status user_goal
  80  skipped_txt nonskipped_txt st
  81 =
  82   let module TAPp = GrafiteAstPp in
  83   let module DTE = DisambiguateTypes.Environment in
  84   let module DP = DisambiguatePp in
  85   let parsed_text_length =
  86     String.length skipped_txt + String.length nonskipped_txt
  87   in
  88   let text = skipped_txt ^ nonskipped_txt in
  89   let prefix_len = MatitaGtkMisc.utf8_string_length skipped_txt in
  90   let enriched_history_fragment =
  91    MatitaEngine.eval_ast ~do_heavy_checks:true
  92     lexicon_status grafite_status (text,prefix_len,st)
  93   in
  94   let enriched_history_fragment = List.rev enriched_history_fragment in
  95   (* really fragile *)
  96   let res,_ =
  97     List.fold_left
  98       (fun (acc, to_prepend) (status,alias) ->
  99        match alias with
 100        | None -> (status,to_prepend ^ nonskipped_txt)::acc,""
 101        | Some (k,((v,_) as value)) ->
 102             let newtxt = DP.pp_environment (DTE.add k value DTE.empty) in
 103             (status,to_prepend ^ newtxt ^ "\n")::acc, "")
 104       ([],skipped_txt) enriched_history_fragment
 105   in
 106   res,"",parsed_text_length
 107
 108 let wrap_with_developments guistuff f arg =
 109   let compile_needed_and_go_on lexiconfile d exc =
 110     let target = Pcre.replace ~pat:"lexicon$" ~templ:"moo" lexiconfile in
 111     let target = Pcre.replace ~pat:"metadata$" ~templ:"moo" target in
 112     let refresh_cb () =
 113       while Glib.Main.pending () do ignore(Glib.Main.iteration false); done
 114     in
 115     if not(MatitamakeLib.build_development_in_bg ~target refresh_cb d) then
 116       raise exc
 117     else
 118       f arg
 119   in
 120   let do_nothing () = raise (ActionCancelled "Inclusion not performed") in
 121   let check_if_file_is_exists f =
 122     assert(Pcre.pmatch ~pat:"ma$" f);
 123     let pwd = Sys.getcwd () in
 124     let f_pwd = pwd ^ "/" ^ f in
 125     if not (HExtlib.is_regular f_pwd) then
 126       raise (ActionCancelled ("File "^f_pwd^" does not exists!"))
 127     else
 128       raise
 129         (ActionCancelled
 130           ("Internal error: "^f_pwd^" exists but I'm unable to include it!"))
 131   in
 132   let handle_with_devel d lexiconfile mafile exc =
 133     let name = MatitamakeLib.name_for_development d in
 134     let title = "Unable to include " ^ lexiconfile in
 135     let message =
 136       mafile ^ " is handled by development <b>" ^ name ^ "</b>.\n\n" ^
 137       "<i>Should I compile it and Its dependencies?</i>"
 138     in
 139     (match guistuff.ask_confirmation ~title ~message with
 140     | `YES -> compile_needed_and_go_on lexiconfile d exc
 141     | `NO -> raise exc
 142     | `CANCEL -> do_nothing ())
 143   in
 144   let handle_without_devel mafilename exc =
 145     let title = "Unable to include " ^ mafilename in
 146     let message =
 147      mafilename ^ " is <b>not</b> handled by a development.\n" ^
 148      "All dependencies are automatically solved for a development.\n\n" ^
 149      "<i>Do you want to set up a development?</i>"
 150     in
 151     (match guistuff.ask_confirmation ~title ~message with
 152     | `YES ->
 153         guistuff.develcreator ~containing:(Some (Filename.dirname mafilename));
 154         do_nothing ()
 155     | `NO -> raise exc
 156     | `CANCEL -> do_nothing())
 157   in
 158   try
 159     f arg
 160   with
 161   | DependenciesParser.UnableToInclude mafilename ->
 162       assert (Pcre.pmatch ~pat:"ma$" mafilename);
 163       check_if_file_is_exists mafilename
 164   | LexiconEngine.IncludedFileNotCompiled (xfilename,mafilename)
 165   | GrafiteEngine.IncludedFileNotCompiled (xfilename,mafilename) as exn ->
 166       assert (Pcre.pmatch ~pat:"ma$" mafilename);
 167       assert (Pcre.pmatch ~pat:"lexicon$" xfilename ||
 168               Pcre.pmatch ~pat:"mo$" xfilename );
 169       (* we know that someone was able to include the .ma, get the baseuri
 170        * but was unable to get the compilation output 'xfilename' *)
 171       match MatitamakeLib.development_for_dir (Filename.dirname mafilename) with
 172       | None -> handle_without_devel mafilename exn
 173       | Some d -> handle_with_devel d xfilename mafilename exn
 174 ;;
 175
 176 let eval_with_engine
 177      guistuff lexicon_status grafite_status user_goal
 178        skipped_txt nonskipped_txt st
 179 =
 180   wrap_with_developments guistuff
 181     (eval_with_engine
 182       guistuff lexicon_status grafite_status user_goal
 183         skipped_txt nonskipped_txt) st
 184 ;;
 185
 186 let pp_eager_statement_ast =
 187   GrafiteAstPp.pp_statement ~term_pp:CicNotationPp.pp_term
 188     ~lazy_term_pp:(fun _ -> assert false) ~obj_pp:(fun _ -> assert false)
 189
 190 let rec eval_macro include_paths (buffer : GText.buffer) guistuff lexicon_status grafite_status user_goal unparsed_text parsed_text script mac =
 191   let module TAPp = GrafiteAstPp in
 192   let module MQ = MetadataQuery in
 193   let module MDB = LibraryDb in
 194   let module CTC = CicTypeChecker in
 195   let module CU = CicUniv in
 196   (* no idea why ocaml wants this *)
 197   let parsed_text_length = String.length parsed_text in
 198   let dbd = LibraryDb.instance () in
 199   let pp_macro =
 200     let f t = ProofEngineReduction.replace
 201       ~equality:(fun _ t -> match t with Cic.Meta _ -> true | _ -> false)
 202       ~what:[()] ~with_what:[Cic.Implicit None] ~where:t
 203     in
 204     let metasenv = GrafiteTypes.get_proof_metasenv grafite_status in
 205     TAPp.pp_macro
 206       ~term_pp:(fun x ->
 207         ApplyTransformation.txt_of_cic_term max_int metasenv [] (f x))
 208   in
 209   match mac with
 210   (* WHELP's stuff *)
 211   | TA.WMatch (loc, term) ->
 212      let l =  Whelp.match_term ~dbd term in
 213      let entry = `Whelp (pp_macro mac, l) in
 214      guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
 215      [], "", parsed_text_length
 216   | TA.WInstance (loc, term) ->
 217      let l = Whelp.instance ~dbd term in
 218      let entry = `Whelp (pp_macro mac, l) in
 219      guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
 220      [], "", parsed_text_length
 221   | TA.WLocate (loc, s) ->
 222      let l = Whelp.locate ~dbd s in
 223      let entry = `Whelp (pp_macro mac, l) in
 224      guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
 225      [], "", parsed_text_length
 226   | TA.WElim (loc, term) ->
 227      let uri =
 228        match term with
 229        | Cic.MutInd (uri,n,_) -> UriManager.uri_of_uriref uri n None
 230        | _ -> failwith "Not a MutInd"
 231      in
 232      let l = Whelp.elim ~dbd uri in
 233      let entry = `Whelp (pp_macro mac, l) in
 234      guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
 235      [], "", parsed_text_length
 236   | TA.WHint (loc, term) ->
 237      let s = ((None,[0,[],term], Cic.Meta (0,[]) ,term),0) in
 238      let l = List.map fst (MQ.experimental_hint ~dbd s) in
 239      let entry = `Whelp (pp_macro mac, l) in
 240      guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
 241      [], "", parsed_text_length
 242   (* REAL macro *)
 243   | TA.Hint loc ->
 244       let user_goal' =
 245        match user_goal with
 246           Some n -> n
 247         | None -> raise NoUnfinishedProof
 248       in
 249       let proof = GrafiteTypes.get_current_proof grafite_status in
 250       let proof_status = proof,user_goal' in
 251       let l = List.map fst (MQ.experimental_hint ~dbd proof_status) in
 252       let selected = guistuff.urichooser l in
 253       (match selected with
 254       | [] -> [], "", parsed_text_length
 255       | [uri] ->
 256           let suri = UriManager.string_of_uri uri in
 257           let ast loc =
 258             TA.Executable (loc, (TA.Tactical (loc,
 259               TA.Tactic (loc,
 260                 TA.Apply (loc, CicNotationPt.Uri (suri, None))),
 261                 Some (TA.Dot loc)))) in
 262           let text =
 263            comment parsed_text ^ "\n" ^
 264             pp_eager_statement_ast (ast HExtlib.dummy_floc) in
 265           let text_len = MatitaGtkMisc.utf8_string_length text in
 266           let loc = HExtlib.floc_of_loc (0,text_len) in
 267           let statement = `Ast (GrafiteParser.LSome (ast loc),text) in
 268           let res,_,_parsed_text_len =
 269            eval_statement include_paths buffer guistuff lexicon_status
 270             grafite_status user_goal script statement
 271           in
 272            (* we need to replace all the parsed_text *)
 273            res,"",String.length parsed_text
 274       | _ ->
 275           HLog.error
 276             "The result of the urichooser should be only 1 uri, not:\n";
 277           List.iter (
 278             fun u -> HLog.error (UriManager.string_of_uri u ^ "\n")
 279           ) selected;
 280           assert false)
 281   | TA.Check (_,term) ->
 282       let metasenv = GrafiteTypes.get_proof_metasenv grafite_status in
 283       let context =
 284        match user_goal with
 285           None -> []
 286         | Some n -> GrafiteTypes.get_proof_context grafite_status n in
 287       let ty,_ = CTC.type_of_aux' metasenv context term CicUniv.empty_ugraph in
 288       let t_and_ty = Cic.Cast (term,ty) in
 289       guistuff.mathviewer#show_entry (`Cic (t_and_ty,metasenv));
 290       [], "", parsed_text_length
 291   | TA.Inline (_,suri) ->
 292      let dbd = LibraryDb.instance () in
 293      let uris =
 294       let sql_pat =
 295        (Pcre.replace ~rex:(Pcre.regexp "_") ~templ:"\\_" suri) ^ "%" in
 296       let query =
 297        sprintf ("SELECT source FROM %s WHERE source LIKE \"%s\" UNION "^^
 298                 "SELECT source FROM %s WHERE source LIKE \"%s\"")
 299          (MetadataTypes.name_tbl ()) sql_pat
 300          MetadataTypes.library_name_tbl sql_pat in
 301       let result = HMysql.exec dbd query in
 302        HMysql.map result
 303         (function cols ->
 304           match cols.(0) with
 305              Some s -> UriManager.uri_of_string s
 306            | _ -> assert false)
 307      in
 308 prerr_endline "Inizio sorting";
 309       let sorted_uris = MetadataDeps.topological_sort ~dbd uris in
 310 prerr_endline "Fine sorting";
 311       let sorted_uris_without_xpointer =
 312        HExtlib.filter_map
 313         (function uri ->
 314           let s =
 315            Pcre.replace ~rex:(Pcre.regexp "#xpointer\\(1/1\\)") ~templ:""
 316             (UriManager.string_of_uri uri) in
 317           try
 318            ignore (Pcre.exec ~rex:(Pcre.regexp"#xpointer") s);
 319            None
 320           with
 321            Not_found ->
 322             Some (UriManager.uri_of_string s)
 323         ) sorted_uris
 324       in
 325       let declarative =
 326        String.concat "\n\n"
 327         (List.map
 328           (fun uri ->
 329 prerr_endline ("Stampo " ^ UriManager.string_of_uri uri);
 330             try
 331              ObjPp.obj_to_string 80
 332               (fst (CicEnvironment.get_obj CicUniv.empty_ugraph uri))
 333             with
 334              _ (* BRRRRRRRRR *) -> "ERRORE IN STAMPA DI " ^ UriManager.string_of_uri uri
 335           ) sorted_uris_without_xpointer)
 336       in
 337        [],declarative,String.length parsed_text
 338
 339 and eval_executable include_paths (buffer : GText.buffer) guistuff
 340 lexicon_status grafite_status user_goal unparsed_text skipped_txt nonskipped_txt
 341 script ex loc
 342 =
 343  let module TAPp = GrafiteAstPp in
 344  let module MD = GrafiteDisambiguator in
 345  let module ML = MatitaMisc in
 346   try
 347    begin
 348     match ex with
 349      | TA.Command (_,TA.Set (_,"baseuri",u)) ->
 350         if  Http_getter_storage.is_read_only u then
 351           raise (ActionCancelled ("baseuri " ^ u ^ " is readonly"));
 352         if not (Http_getter_storage.is_empty u) then
 353          (match
 354             guistuff.ask_confirmation
 355               ~title:"Baseuri redefinition"
 356               ~message:(
 357                 "Baseuri " ^ u ^ " already exists.\n" ^
 358                 "Do you want to redefine the corresponding "^
 359                 "part of the library?")
 360           with
 361            | `YES -> LibraryClean.clean_baseuris [u]
 362            | `NO -> ()
 363            | `CANCEL -> raise MatitaTypes.Cancel)
 364      | _ -> ()
 365    end;
 366    eval_with_engine
 367     guistuff lexicon_status grafite_status user_goal skipped_txt nonskipped_txt
 368      (TA.Executable (loc, ex))
 369   with
 370      MatitaTypes.Cancel -> [], "", 0
 371    | GrafiteEngine.Macro (_loc,lazy_macro) ->
 372       let context =
 373        match user_goal with
 374           None -> []
 375         | Some n -> GrafiteTypes.get_proof_context grafite_status n in
 376       let grafite_status,macro = lazy_macro context in
 377        eval_macro include_paths buffer guistuff lexicon_status grafite_status
 378         user_goal unparsed_text (skipped_txt ^ nonskipped_txt) script macro
 379
 380 and eval_statement include_paths (buffer : GText.buffer) guistuff lexicon_status
 381  grafite_status user_goal script statement
 382 =
 383   let (lexicon_status,st), unparsed_text =
 384     match statement with
 385     | `Raw text ->
 386         if Pcre.pmatch ~rex:only_dust_RE text then raise Margin;
 387         let ast =
 388           wrap_with_developments guistuff
 389             (GrafiteParser.parse_statement
 390               (Ulexing.from_utf8_string text) ~include_paths) lexicon_status
 391         in
 392           ast, text
 393     | `Ast (st, text) -> (lexicon_status, st), text
 394   in
 395   let text_of_loc floc =
 396     let nonskipped_txt,_ = MatitaGtkMisc.utf8_parsed_text unparsed_text floc in
 397     let start, stop = HExtlib.loc_of_floc floc in
 398     let floc = HExtlib.floc_of_loc (0, start) in
 399     let skipped_txt,_ = MatitaGtkMisc.utf8_parsed_text unparsed_text floc in
 400     let floc = HExtlib.floc_of_loc (0, stop) in
 401     let txt,len = MatitaGtkMisc.utf8_parsed_text unparsed_text floc in
 402     txt,nonskipped_txt,skipped_txt,len
 403   in
 404   match st with
 405   | GrafiteParser.LNone loc ->
 406       let parsed_text, _, _, parsed_text_length = text_of_loc loc in
 407        [(grafite_status,lexicon_status),parsed_text],"",
 408         parsed_text_length
 409   | GrafiteParser.LSome (GrafiteAst.Comment (loc, _)) ->
 410       let parsed_text, _, _, parsed_text_length = text_of_loc loc in
 411       let remain_len = String.length unparsed_text - parsed_text_length in
 412       let s = String.sub unparsed_text parsed_text_length remain_len in
 413       let s,text,len =
 414        try
 415         eval_statement include_paths buffer guistuff lexicon_status
 416          grafite_status user_goal script (`Raw s)
 417        with
 418           HExtlib.Localized (floc, exn) ->
 419            HExtlib.raise_localized_exception
 420              ~offset:(MatitaGtkMisc.utf8_string_length parsed_text) floc exn
 421         | GrafiteDisambiguator.DisambiguationError (offset,errorll) ->
 422            raise
 423             (GrafiteDisambiguator.DisambiguationError
 424               (offset+parsed_text_length, errorll))
 425       in
 426       assert (text=""); (* no macros inside comments, please! *)
 427       (match s with
 428       | (statuses,text)::tl ->
 429          (statuses,parsed_text ^ text)::tl,"",parsed_text_length + len
 430       | [] -> [], "", 0)
 431   | GrafiteParser.LSome (GrafiteAst.Executable (loc, ex)) ->
 432      let _, nonskipped, skipped, parsed_text_length =
 433        text_of_loc loc
 434      in
 435       eval_executable include_paths buffer guistuff lexicon_status
 436        grafite_status user_goal unparsed_text skipped nonskipped script ex loc
 437
 438 let fresh_script_id =
 439   let i = ref 0 in
 440   fun () -> incr i; !i
 441
 442 class script  ~(source_view: GSourceView.source_view)
 443               ~(mathviewer: MatitaTypes.mathViewer)
 444               ~set_star
 445               ~ask_confirmation
 446               ~urichooser
 447               ~develcreator
 448               () =
 449 let buffer = source_view#buffer in
 450 let source_buffer = source_view#source_buffer in
 451 let initial_statuses () =
 452  (* these include_paths are used only to load the initial notation *)
 453  let include_paths =
 454   Helm_registry.get_list Helm_registry.string "matita.includes" in
 455  let lexicon_status =
 456   CicNotation2.load_notation ~include_paths
 457    BuildTimeConf.core_notation_script in
 458  let grafite_status = GrafiteSync.init () in
 459   grafite_status,lexicon_status
 460 in
 461 object (self)
 462   val mutable include_paths =
 463    Helm_registry.get_list Helm_registry.string "matita.includes"
 464
 465   val scriptId = fresh_script_id ()
 466
 467   val guistuff = {
 468     mathviewer = mathviewer;
 469     urichooser = urichooser;
 470     ask_confirmation = ask_confirmation;
 471     develcreator = develcreator;
 472     filenamedata = (None, None)}
 473
 474   method private getFilename =
 475     match guistuff.filenamedata with Some f,_ -> f | _ -> assert false
 476
 477   method filename = self#getFilename
 478
 479   method private ppFilename =
 480     match guistuff.filenamedata with
 481     | Some f,_ -> f
 482     | None,_ -> sprintf ".unnamed%d.ma" scriptId
 483
 484   initializer
 485     ignore (GMain.Timeout.add ~ms:300000
 486        ~callback:(fun _ -> self#_saveToBackupFile ();true));
 487     ignore (buffer#connect#modified_changed
 488       (fun _ -> set_star (Filename.basename self#ppFilename) buffer#modified))
 489
 490   val mutable statements = []    (** executed statements *)
 491
 492   val mutable history = [ initial_statuses () ]
 493     (** list of states before having executed statements. Head element of this
 494       * list is the current state, last element is the state at the beginning of
 495       * the script.
 496       * Invariant: this list length is 1 + length of statements *)
 497
 498   (** goal as seen by the user (i.e. metano corresponding to current tab) *)
 499   val mutable userGoal = None
 500
 501   (** text mark and tag representing locked part of a script *)
 502   val locked_mark =
 503     buffer#create_mark ~name:"locked" ~left_gravity:true buffer#start_iter
 504   val locked_tag = buffer#create_tag [`BACKGROUND "lightblue"; `EDITABLE false]
 505   val error_tag = buffer#create_tag [`UNDERLINE `SINGLE; `FOREGROUND "red"]
 506
 507   method locked_mark = locked_mark
 508   method locked_tag = locked_tag
 509   method error_tag = error_tag
 510
 511     (* history can't be empty, the invariant above grant that it contains at
 512      * least the init grafite_status *)
 513   method grafite_status = match history with (s,_)::_ -> s | _ -> assert false
 514   method lexicon_status = match history with (_,ss)::_ -> ss | _ -> assert false
 515
 516   method private _advance ?statement () =
 517    let s = match statement with Some s -> s | None -> self#getFuture in
 518    HLog.debug ("evaluating: " ^ first_line s ^ " ...");
 519    let entries, newtext, parsed_len =
 520     try
 521      eval_statement include_paths buffer guistuff self#lexicon_status
 522       self#grafite_status userGoal self (`Raw s)
 523     with End_of_file -> raise Margin
 524    in
 525    let new_statuses, new_statements =
 526      let statuses, texts = List.split entries in
 527      statuses, texts
 528    in
 529    history <- new_statuses @ history;
 530    statements <- new_statements @ statements;
 531    let start = buffer#get_iter_at_mark (`MARK locked_mark) in
 532    let new_text = String.concat "" (List.rev new_statements) in
 533    if statement <> None then
 534      buffer#insert ~iter:start new_text
 535    else begin
 536      let parsed_text = String.sub s 0 parsed_len in
 537      if new_text <> parsed_text then begin
 538        let stop = start#copy#forward_chars (Glib.Utf8.length parsed_text) in
 539        buffer#delete ~start ~stop;
 540        buffer#insert ~iter:start new_text;
 541      end;
 542    end;
 543    self#moveMark (Glib.Utf8.length new_text);
 544    buffer#insert ~iter:(buffer#get_iter_at_mark (`MARK locked_mark)) newtext;
 545    (* here we need to set the Goal in case we are going to cursor (or to
 546       bottom) and we will face a macro *)
 547    match self#grafite_status.proof_status with
 548       Incomplete_proof p ->
 549        userGoal <-
 550          (try Some (Continuationals.Stack.find_goal p.stack)
 551          with Failure _ -> None)
 552     | _ -> userGoal <- None
 553
 554   method private _retract offset lexicon_status grafite_status new_statements
 555    new_history
 556   =
 557    let cur_grafite_status,cur_lexicon_status =
 558     match history with s::_ -> s | [] -> assert false
 559    in
 560     LexiconSync.time_travel ~present:cur_lexicon_status ~past:lexicon_status;
 561     GrafiteSync.time_travel ~present:cur_grafite_status ~past:grafite_status;
 562     statements <- new_statements;
 563     history <- new_history;
 564     self#moveMark (- offset)
 565
 566   method advance ?statement () =
 567     try
 568       self#_advance ?statement ();
 569       self#notify
 570     with
 571     | Margin -> self#notify
 572     | Not_found -> assert false
 573     | exc -> self#notify; raise exc
 574
 575   method retract () =
 576     try
 577       let cmp,new_statements,new_history,(grafite_status,lexicon_status) =
 578        match statements,history with
 579           stat::statements, _::(status::_ as history) ->
 580            assert (Glib.Utf8.validate stat);
 581            Glib.Utf8.length stat, statements, history, status
 582        | [],[_] -> raise Margin
 583        | _,_ -> assert false
 584       in
 585        self#_retract cmp lexicon_status grafite_status new_statements
 586         new_history;
 587        self#notify
 588     with
 589     | Margin -> self#notify
 590     | exc -> self#notify; raise exc
 591
 592   method private getFuture =
 593     buffer#get_text ~start:(buffer#get_iter_at_mark (`MARK locked_mark))
 594       ~stop:buffer#end_iter ()
 595
 596
 597   (** @param rel_offset relative offset from current position of locked_mark *)
 598   method private moveMark rel_offset =
 599     let mark = `MARK locked_mark in
 600     let old_insert = buffer#get_iter_at_mark `INSERT in
 601     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 602     let current_mark_pos = buffer#get_iter_at_mark mark in
 603     let new_mark_pos =
 604       match rel_offset with
 605       | 0 -> current_mark_pos
 606       | n when n > 0 -> current_mark_pos#forward_chars n
 607       | n (* when n < 0 *) -> current_mark_pos#backward_chars (abs n)
 608     in
 609     buffer#move_mark mark ~where:new_mark_pos;
 610     buffer#apply_tag locked_tag ~start:buffer#start_iter ~stop:new_mark_pos;
 611     buffer#move_mark `INSERT old_insert;
 612     let mark_position = buffer#get_iter_at_mark mark in
 613     if source_view#move_mark_onscreen mark then
 614      begin
 615       buffer#move_mark mark mark_position;
 616       source_view#scroll_to_mark ~use_align:true ~xalign:1.0 ~yalign:0.1 mark;
 617      end;
 618     while Glib.Main.pending () do ignore(Glib.Main.iteration false); done
 619
 620   method clean_dirty_lock =
 621     let lock_mark_iter = buffer#get_iter_at_mark (`MARK locked_mark) in
 622     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 623     buffer#apply_tag locked_tag ~start:buffer#start_iter ~stop:lock_mark_iter
 624
 625   val mutable observers = []
 626
 627   method addObserver (o: LexiconEngine.status -> GrafiteTypes.status -> unit) =
 628     observers <- o :: observers
 629
 630   method private notify =
 631     let lexicon_status = self#lexicon_status in
 632     let grafite_status = self#grafite_status in
 633     List.iter (fun o -> o lexicon_status grafite_status) observers
 634
 635   method loadFromString s =
 636     buffer#set_text s;
 637     self#reset_buffer;
 638     buffer#set_modified true
 639
 640   method loadFromFile f =
 641     buffer#set_text (HExtlib.input_file f);
 642     self#reset_buffer;
 643     buffer#set_modified false
 644
 645   method assignFileName file =
 646     let abspath = MatitaMisc.absolute_path file in
 647     let dirname = Filename.dirname abspath in
 648     let devel = MatitamakeLib.development_for_dir dirname in
 649     guistuff.filenamedata <- Some abspath, devel;
 650     let include_ =
 651      match MatitamakeLib.development_for_dir dirname with
 652         None -> []
 653       | Some devel -> [MatitamakeLib.root_for_development devel] in
 654     let include_ =
 655      include_ @ (Helm_registry.get_list Helm_registry.string "matita.includes")
 656     in
 657      include_paths <- include_
 658
 659   method saveToFile () =
 660     let oc = open_out self#getFilename in
 661     output_string oc (buffer#get_text ~start:buffer#start_iter
 662                         ~stop:buffer#end_iter ());
 663     close_out oc;
 664     buffer#set_modified false
 665
 666   method private _saveToBackupFile () =
 667     if buffer#modified then
 668       begin
 669         let f = self#ppFilename ^ "~" in
 670         let oc = open_out f in
 671         output_string oc (buffer#get_text ~start:buffer#start_iter
 672                             ~stop:buffer#end_iter ());
 673         close_out oc;
 674         HLog.debug ("backup " ^ f ^ " saved")
 675       end
 676
 677   method private goto_top =
 678     let grafite_status,lexicon_status =
 679       let rec last x = function
 680       | [] -> x
 681       | hd::tl -> last hd tl
 682       in
 683       last (self#grafite_status,self#lexicon_status) history
 684     in
 685     (* FIXME: this is not correct since there is no undo for
 686      * library_objects.set_default... *)
 687     GrafiteSync.time_travel ~present:self#grafite_status ~past:grafite_status;
 688     LexiconSync.time_travel ~present:self#lexicon_status ~past:lexicon_status
 689
 690   method private reset_buffer =
 691     statements <- [];
 692     history <- [ initial_statuses () ];
 693     userGoal <- None;
 694     self#notify;
 695     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 696     buffer#move_mark (`MARK locked_mark) ~where:buffer#start_iter
 697
 698   method reset () =
 699     self#reset_buffer;
 700     source_buffer#begin_not_undoable_action ();
 701     buffer#delete ~start:buffer#start_iter ~stop:buffer#end_iter;
 702     source_buffer#end_not_undoable_action ();
 703     buffer#set_modified false;
 704
 705   method template () =
 706     let template = HExtlib.input_file BuildTimeConf.script_template in
 707     buffer#insert ~iter:(buffer#get_iter `START) template;
 708     let development = MatitamakeLib.development_for_dir (Unix.getcwd ()) in
 709     guistuff.filenamedata <- (None,development);
 710     let include_ =
 711      match development with
 712         None -> []
 713       | Some devel -> [MatitamakeLib.root_for_development devel ]
 714     in
 715     let include_ =
 716      include_ @ (Helm_registry.get_list Helm_registry.string "matita.includes")
 717     in
 718      include_paths <- include_ ;
 719      buffer#set_modified false;
 720      set_star (Filename.basename self#ppFilename) false
 721
 722   method goto (pos: [`Top | `Bottom | `Cursor]) () =
 723     let old_locked_mark =
 724      `MARK
 725        (buffer#create_mark ~name:"old_locked_mark"
 726          ~left_gravity:true (buffer#get_iter_at_mark (`MARK locked_mark))) in
 727     let getpos _ = buffer#get_iter_at_mark (`MARK locked_mark) in
 728     let getoldpos _ = buffer#get_iter_at_mark old_locked_mark in
 729     let dispose_old_locked_mark () = buffer#delete_mark old_locked_mark in
 730     match pos with
 731     | `Top ->
 732         dispose_old_locked_mark ();
 733         self#goto_top;
 734         self#reset_buffer;
 735         self#notify
 736     | `Bottom ->
 737         (try
 738           let rec dowhile () =
 739             self#_advance ();
 740             let newpos = getpos () in
 741             if (getoldpos ())#compare newpos < 0 then
 742               begin
 743                 buffer#move_mark old_locked_mark newpos;
 744                 dowhile ()
 745               end
 746           in
 747           dowhile ();
 748           dispose_old_locked_mark ();
 749           self#notify
 750         with
 751         | Margin -> dispose_old_locked_mark (); self#notify
 752         | exc -> dispose_old_locked_mark (); self#notify; raise exc)
 753     | `Cursor ->
 754         let locked_iter () = buffer#get_iter_at_mark (`NAME "locked") in
 755         let cursor_iter () = buffer#get_iter_at_mark `INSERT in
 756         let remember =
 757          `MARK
 758            (buffer#create_mark ~name:"initial_insert"
 759              ~left_gravity:true (cursor_iter ())) in
 760         let dispose_remember () = buffer#delete_mark remember in
 761         let remember_iter () =
 762          buffer#get_iter_at_mark (`NAME "initial_insert") in
 763         let cmp () = (locked_iter ())#offset - (remember_iter ())#offset in
 764         let icmp = cmp () in
 765         let forward_until_cursor () = (* go forward until locked > cursor *)
 766           let rec aux () =
 767             self#_advance ();
 768             if cmp () < 0 && (getoldpos ())#compare (getpos ()) < 0
 769             then
 770              begin
 771               buffer#move_mark old_locked_mark (getpos ());
 772               aux ()
 773              end
 774           in
 775           aux ()
 776         in
 777         let rec back_until_cursor len = (* go backward until locked < cursor *)
 778          function
 779             statements, ((grafite_status,lexicon_status)::_ as history)
 780             when len <= 0 ->
 781              self#_retract (icmp - len) lexicon_status grafite_status statements
 782               history
 783           | statement::tl1, _::tl2 ->
 784              back_until_cursor (len - MatitaGtkMisc.utf8_string_length statement) (tl1,tl2)
 785           | _,_ -> assert false
 786         in
 787         (try
 788           begin
 789            if icmp < 0 then       (* locked < cursor *)
 790              (forward_until_cursor (); self#notify)
 791            else if icmp > 0 then  (* locked > cursor *)
 792              (back_until_cursor icmp (statements,history); self#notify)
 793            else                  (* cursor = locked *)
 794                ()
 795           end ;
 796           dispose_remember ();
 797           dispose_old_locked_mark ();
 798         with
 799         | Margin -> dispose_remember (); dispose_old_locked_mark (); self#notify
 800         | exc -> dispose_remember (); dispose_old_locked_mark ();
 801                  self#notify; raise exc)
 802
 803   method onGoingProof () =
 804     match self#grafite_status.proof_status with
 805     | No_proof | Proof _ -> false
 806     | Incomplete_proof _ -> true
 807     | Intermediate _ -> assert false
 808
 809 (*   method proofStatus = MatitaTypes.get_proof_status self#status *)
 810   method proofMetasenv = GrafiteTypes.get_proof_metasenv self#grafite_status
 811
 812   method proofContext =
 813    match userGoal with
 814       None -> []
 815     | Some n -> GrafiteTypes.get_proof_context self#grafite_status n
 816
 817   method proofConclusion =
 818    match userGoal with
 819       None -> assert false
 820     | Some n ->
 821        GrafiteTypes.get_proof_conclusion self#grafite_status n
 822
 823   method stack = GrafiteTypes.get_stack self#grafite_status
 824   method setGoal n = userGoal <- n
 825   method goal = userGoal
 826
 827   method eos =
 828     let rec is_there_only_comments lexicon_status s =
 829       if Pcre.pmatch ~rex:only_dust_RE s then raise Margin;
 830       let lexicon_status,st =
 831        GrafiteParser.parse_statement (Ulexing.from_utf8_string s)
 832         ~include_paths lexicon_status
 833       in
 834       match st with
 835       | GrafiteParser.LSome (GrafiteAst.Comment (loc,_)) ->
 836           let _,parsed_text_length = MatitaGtkMisc.utf8_parsed_text s loc in
 837           (* CSC: why +1 in the following lines ???? *)
 838           let parsed_text_length = parsed_text_length + 1 in
 839 prerr_endline ("## " ^ string_of_int parsed_text_length);
 840           let remain_len = String.length s - parsed_text_length in
 841           let next = String.sub s parsed_text_length remain_len in
 842           is_there_only_comments lexicon_status next
 843       | GrafiteParser.LNone _
 844       | GrafiteParser.LSome (GrafiteAst.Executable _) -> false
 845     in
 846     try
 847       is_there_only_comments self#lexicon_status self#getFuture
 848     with
 849     | LexiconEngine.IncludedFileNotCompiled _
 850     | HExtlib.Localized _
 851     | CicNotationParser.Parse_error _ -> false
 852     | Margin | End_of_file -> true
 853
 854   (* debug *)
 855   method dump () =
 856     HLog.debug "script status:";
 857     HLog.debug ("history size: " ^ string_of_int (List.length history));
 858     HLog.debug (sprintf "%d statements:" (List.length statements));
 859     List.iter HLog.debug statements;
 860     HLog.debug ("Current file name: " ^
 861       (match guistuff.filenamedata with
 862       |None,_ -> "[ no name ]"
 863       | Some f,_ -> f));
 864
 865 end
 866
 867 let _script = ref None
 868
 869 let script ~source_view ~mathviewer ~urichooser ~develcreator ~ask_confirmation ~set_star ()
 870 =
 871   let s = new script
 872     ~source_view ~mathviewer ~ask_confirmation ~urichooser ~develcreator ~set_star ()
 873   in
 874   _script := Some s;
 875   s
 876
 877 let current () = match !_script with None -> assert false | Some s -> s
 878