matita/tests/decl.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 set "baseuri" "cic:/matita/test/decl".
  16
  17 include "nat/times.ma".
  18 include "nat/orders.ma".
  19
  20 theorem easy: ∀n,m. n * m = O → n = O ∨ m = O.
  21  assume n: nat.
  22  assume m: nat.
  23  (* base case *)
  24  by (refl_eq ? O) we proved (O = O) (trivial).
  25  by (or_introl ? ? trivial) we proved (O = O ∨ m = O) (trivial2).
  26  by (λ_.trivial2) we proved (O*m=O → O=O ∨ m=O) (base_case).
  27  (* inductive case *)
  28  we need to prove
  29   (∀n1. (n1 * m = O → n1 = O ∨ m = O) → (S n1) * m = O → (S n1) = O ∨ m = O)
  30   (inductive_case).
  31    assume n1: nat.
  32    suppose (n1 * m = O → n1 = O ∨ m = O) (inductive_hyp).
  33    (* base case *)
  34    by (or_intror ? ? trivial) we proved (S n1 = O ∨ O = O) (pre_base_case2).
  35    by (λ_.pre_base_case2) we proved (S n1*O = O → S n1 = O ∨ O = O) (base_case2).
  36    (* inductive case *)
  37    we need to prove
  38     (∀m1. (S n1 * m1 = O → S n1 = O ∨ m1 = O) →
  39       (S n1 * S m1 = O → S n1 = O ∨ S m1 = O)) (inductive_hyp2).
  40      assume m1: nat.
  41      suppose (S n1 * m1 = O → S n1 = O ∨ m1 = O) (useless).
  42      suppose (S n1 * S m1 = O) (absurd_hyp).
  43      simplify in absurd_hyp.
  44      by (sym_eq ? ? ? absurd_hyp) we proved (O = S (m1+n1*S m1)) (absurd_hyp').
  45      by (not_eq_O_S ? absurd_hyp') we proved False (the_absurd).
  46      by (False_ind ? the_absurd)
  47    done.
  48    (* the induction *)
  49    by (nat_ind (λm.S n1 * m = O → S n1 = O ∨ m = O) base_case2 inductive_hyp2 m)
  50  done.
  51  (* the induction *)
  52  by (nat_ind (λn.n*m=O → n=O ∨ m=O) base_case inductive_case n)
  53 done.
  54 qed.
  55
  56 theorem easy2: ∀n,m. n * m = O → n = O ∨ m = O.
  57  intros 2.
  58  elim n 0
  59   [ intro;
  60     left;
  61     reflexivity
  62   | intro;
  63     elim m 0
  64     [ intros;
  65       right;
  66       reflexivity
  67     | intros;
  68       simplify in H2;
  69       lapply (sym_eq ? ? ? H2);
  70       elim (not_eq_O_S ? Hletin)
  71     ]
  72   ]
  73 qed.
  74
  75
  76 theorem easy3: ∀A:Prop. (A ∧ ∃n:nat.n ≠ n) → True.
  77  assume P: Prop.
  78  suppose (P ∧ ∃m:nat.m ≠ m) (H).
  79  by H we have P (H1) and (∃x:nat.x≠x) (H2).
  80  (*BUG:
  81  by H2 let q:nat such that (q ≠ q) (Ineq).
  82  *)
  83  (* the next line is wrong, but for the moment it does the job *)
  84  by H2 let q:nat such that False (Ineq).
  85  by I done.
  86 qed.
  87
  88 theorem easy4: ∀n,m,p. n = m → S m = S p → n = S p → S n = n.
  89 assume n: nat.
  90 assume m:nat.
  91 assume p:nat.
  92 suppose (n=m) (H).
  93 suppose (S m = S p) (K).
  94 suppose (n = S p) (L).
  95 obtain (S n) = (S m) by (eq_f ? ? ? ? ? H).
  96              = (S p) by K.
  97              = n by (sym_eq ? ? ? L)
  98 done.
  99 qed.
 100
 101 theorem easy5: ∀n:nat. n*O=O.
 102 assume n: nat.
 103 (* Bug here: False should be n*0=0 *)
 104 we proceed by induction on n to prove False.
 105  case O.
 106    the thesis becomes (O*O=O).
 107    by (refl_eq ? O) done.
 108  case S (m:nat).
 109   by induction hypothesis we know (m*O=O) (I).
 110   the thesis becomes (S m * O = O).
 111   (* Bug here: missing that is equivalent to *)
 112   simplify.
 113   by I done.
 114 qed.
 115
 116 inductive tree : Type ≝
 117    Empty: tree
 118  | Node: tree → tree → tree.
 119
 120 let rec size t ≝
 121  match t with
 122   [ Empty ⇒ O
 123   | (Node t1 t2) ⇒ S ((size t1) + (size t2))
 124   ].
 125
 126 theorem easy6: ∀t. O ≮ O → O < size t → t ≠ Empty.
 127  assume t: tree.
 128  suppose (O ≮ O) (trivial).
 129  (*Bug here: False should be something else *)
 130  we proceed by induction on t to prove False.
 131   case Empty.
 132     the thesis becomes (O < size Empty → Empty ≠ Empty).
 133      suppose (O < size Empty) (absurd).
 134      (*Bug here: missing that is equivalent to *)
 135      simplify in absurd.
 136      (* Here the "natural" language is not natural at all *)
 137      we proceed by induction on (trivial absurd) to prove False.
 138   (*Bug here: this is what we want
 139   case Node (t1:tree) (t2:tree).
 140      by induction hypothesis we know (O < size t1 → t1 ≠ Empty) (Ht1).
 141      by induction hypothesis we know (O < size t2 → t2 ≠ Empty) (Ht2). *)
 142   (*This is the best we can do right now*)
 143   case Node.
 144    assume t1: tree.
 145    by induction hypothesis we know (O < size t1 → t1 ≠ Empty) (Ht1).
 146    assume t2: tree.
 147    by induction hypothesis we know (O < size t2 → t2 ≠ Empty) (Ht2).
 148    suppose (O < size (Node t1 t2)) (Hyp).
 149    (*BUG: that is equivalent to missed here *)
 150    unfold Not.
 151    suppose (Node t1 t2 = Empty) (absurd).
 152    (* Discriminate should really generate a theorem to be useful with
 153       declarative tactics *)
 154    discriminate absurd.
 155 qed.