matitaB/components/content/notationPp.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 module Ast = NotationPt
  31 module Env = NotationEnv
  32
  33   (* when set to true debugging information, not in sync with input syntax, will
  34    * be added to the output of pp_term.
  35    * set to false if you need, for example, cut and paste from matitac output to
  36    * matitatop *)
  37 let debug_printing = false
  38
  39 let pp_binder = function
  40   | `Lambda -> "lambda"
  41   | `Pi -> "Pi"
  42   | `Exists -> "exists"
  43   | `Forall -> "forall"
  44
  45 let pp_literal =
  46   if debug_printing then
  47     (function (* debugging version *)
  48       | `Symbol s -> sprintf "symbol(%s)" s
  49       | `Keyword s -> sprintf "keyword(%s)" s
  50       | `Number s -> sprintf "number(%s)" s)
  51   else
  52     (function
  53       | `Symbol s
  54       | `Keyword s
  55       | `Number s -> s)
  56
  57 let pp_pos =
  58   function
  59 (*      `None -> "`None" *)
  60     | `Left -> "`Left"
  61     | `Right -> "`Right"
  62     | `Inner -> "`Inner"
  63
  64 let pp_attribute =
  65   function
  66   | `IdRef id -> sprintf "x(%s)" id
  67   | `XmlAttrs attrs ->
  68       sprintf "X(%s)"
  69         (String.concat ";"
  70           (List.map (fun (_, n, v) -> sprintf "%s=%s" n v) attrs))
  71   | `Level (prec) -> sprintf "L(%d)" prec
  72   | `Raw _ -> "R"
  73   | `Loc l -> let x,y = HExtlib.loc_of_floc l in
  74               "@" ^ (string_of_int x) ^ "," ^ (string_of_int y)
  75   | `ChildPos p -> sprintf "P(%s)" (pp_pos p)
  76
  77 let pp_capture_variable pp_term =
  78   function
  79   | term, None -> pp_term (* ~pp_parens:false *) term
  80   | term, Some typ -> "(" ^ pp_term (* ~pp_parens:false *) term ^ ": " ^ pp_term typ ^ ")"
  81
  82 let rec pp_term (status : #NCic.status) ?(pp_parens = true) t =
  83  let debug_printing = true in
  84   let pp_ident = function
  85   | Ast.Ident (id,`Ambiguous) -> "A:" ^ id
  86   | Ast.Ident (id,`Rel) -> "R:" ^ id
  87   | Ast.Ident (id,`Uri u) -> ("U:(" ^ id ^ "," ^ u ^ ")")
  88   | _ -> "E"
  89   in
  90   let pp_term = pp_term status in
  91   let t_pp =
  92     match t with
  93     | Ast.AttributedTerm (attr, term) when debug_printing ->
  94         sprintf "%s[%s]" (pp_attribute attr) (pp_term ~pp_parens:false term)
  95     | Ast.AttributedTerm (`Raw text, t) -> "RAW:(" ^ (pp_term t) ^ ")"
  96     | Ast.AttributedTerm (_, term) -> pp_term ~pp_parens:false term
  97     | Ast.Appl terms ->
  98         sprintf "%s" (String.concat " " (List.map pp_term terms))
  99     | Ast.Binder (`Forall, (Ast.Ident ("_", `Ambiguous), typ), body)
 100     | Ast.Binder (`Forall, (Ast.Ident ("_", `Rel), typ), body)
 101     | Ast.Binder (`Pi, (Ast.Ident ("_", `Ambiguous), typ), body)
 102     | Ast.Binder (`Pi, (Ast.Ident ("_", `Rel), typ), body) ->
 103         sprintf "%s \\to %s"
 104           (match typ with None -> "?" | Some typ -> pp_term typ)
 105           (pp_term ~pp_parens:true body)
 106     | Ast.Binder (kind, var, body) ->
 107 (*
 108  * sprintf "\\%s[%s] %s.%s" (pp_binder kind) (pp_ident var) (pp_capture_variable pp_term var)
 109  *)
 110         sprintf "\\%s %s.%s" (pp_binder kind) (pp_capture_variable pp_term var)
 111           (pp_term ~pp_parens:true body)
 112     | Ast.Case (term, indtype, typ, patterns) ->
 113         sprintf "match %s%s%s with %s"
 114           (pp_term term)
 115           (match indtype with
 116           | None -> ""
 117           | Some (ty, href_opt) ->
 118               sprintf " in %s%s" ty
 119               (match (*debug_printing*) true, href_opt with
 120               | true, Some uri ->
 121                   sprintf "(i.e.%s)" (NReference.string_of_reference uri)
 122               | _ -> ""))
 123           (match typ with None -> "" | Some t -> sprintf " return %s" (pp_term t))
 124           (pp_patterns status patterns)
 125     | Ast.Cast (t1, t2) -> sprintf "(%s: %s)" (pp_term ~pp_parens:true t1) (pp_term ~pp_parens:true t2)
 126     | Ast.LetIn ((var,t2), t1, t3) ->
 127 (*       let t2 = match t2 with None -> Ast.Implicit | Some t -> t in *)
 128         sprintf "let %s \\def %s in %s" (pp_term var)
 129 (*           (pp_term ~pp_parens:true t2) *)
 130           (pp_term ~pp_parens:true t1)
 131           (pp_term ~pp_parens:true t3)
 132     | Ast.LetRec (kind, definitions, term) ->
 133         let rec get_guard i = function
 134            | []                   -> (*assert false*) Ast.Implicit `JustOne
 135            | [term, _] when i = 1 -> term
 136            | _ :: tl              -> get_guard (pred i) tl
 137         in
 138         let map (params, (id,typ), body, i) =
 139          let typ =
 140           match typ with
 141              None -> Ast.Implicit `JustOne
 142            | Some typ -> typ
 143          in
 144            sprintf "%s %s on %s: %s \\def %s"
 145               (pp_term ~pp_parens:false term)
 146               (String.concat " " (List.map (pp_capture_variable pp_term) params))
 147               (pp_term ~pp_parens:false (get_guard i params))
 148               (pp_term typ) (pp_term body)
 149         in
 150         sprintf "let %s %s in %s"
 151           (match kind with `Inductive -> "rec" | `CoInductive -> "corec")
 152           (String.concat " and " (List.map map definitions))
 153           (pp_term term)
 154     | Ast.Ident (name, _ ) -> pp_ident t
 155     | Ast.NRef nref -> NReference.string_of_reference nref
 156     | Ast.NCic cic -> status#ppterm ~metasenv:[] ~context:[] ~subst:[] cic
 157     | Ast.Implicit `Vector -> "…"
 158     | Ast.Implicit `JustOne -> "?"
 159     | Ast.Implicit (`Tagged name) -> "?"^name
 160     | Ast.Meta (index, substs) ->
 161         sprintf "%d[%s]" index
 162           (String.concat "; "
 163             (List.map (function None -> "?" | Some t -> pp_term t) substs))
 164     | Ast.Num (num, _) -> num
 165     | Ast.Sort `Set -> "Set"
 166     | Ast.Sort `Prop -> "Prop"
 167     | Ast.Sort (`NType s)-> "Type[" ^ s ^ "]"
 168     | Ast.Sort (`NCProp s)-> "CProp[" ^ s ^ "]"
 169     | Ast.Symbol (name, None) -> "'" ^ name
 170     | Ast.Symbol (name, Some (_,desc)) -> "'" ^ name ^ ":" ^ desc
 171
 172     | Ast.UserInput -> "%"
 173
 174     | Ast.Literal l -> "literal:(" ^ (pp_literal l) ^ ")"
 175     | Ast.Layout l -> "layout:(" ^ (pp_layout status l) ^ ")"
 176     | Ast.Magic m -> "magic:(" ^ (pp_magic status m) ^ ")"
 177     | Ast.Variable v -> "variable:" ^ (pp_variable v)
 178   in
 179   match pp_parens, t with
 180     | false, _
 181     | true, Ast.Implicit _
 182     | true, Ast.UserInput
 183     | true, Ast.Sort _
 184     | true, Ast.Ident _    -> t_pp
 185     | _                    -> sprintf "(%s)" t_pp
 186
 187 and pp_subst status (name, term) =
 188  sprintf "%s \\Assign %s" name (pp_term status term)
 189 and pp_substs status substs = String.concat "; " (List.map (pp_subst status) substs)
 190
 191 and pp_pattern status =
 192  function
 193     Ast.Pattern (head, href, vars), term ->
 194      let head_pp =
 195        head ^
 196        (match (*debug_printing*)true, href with
 197        | true, Some uri -> sprintf "(i.e.%s)" (NReference.string_of_reference uri)
 198        | true, None -> "(i.e.ambiguous)"
 199        | _ -> "")
 200      in
 201      sprintf "%s \\Rightarrow %s"
 202        (match vars with
 203        | [] -> head_pp
 204        | _ ->
 205            sprintf "(%s %s)" head_pp
 206              (String.concat " " (List.map (pp_capture_variable (pp_term status)) vars)))
 207        (pp_term status term)
 208   | Ast.Wildcard, term ->
 209      sprintf "_ \\Rightarrow %s" (pp_term status term)
 210
 211 and pp_patterns status patterns =
 212   sprintf "[%s]" (String.concat " | " (List.map (pp_pattern status) patterns))
 213
 214 and pp_box_spec (kind, spacing, indent) =
 215   let int_of_bool b = if b then 1 else 0 in
 216   let kind_string =
 217     match kind with
 218     Ast.H -> "H" | Ast.V -> "V" | Ast.HV -> "HV" | Ast.HOV -> "HOV"
 219   in
 220   sprintf "%sBOX%d%d" kind_string (int_of_bool spacing) (int_of_bool indent)
 221
 222 and pp_layout status =
 223  let pp_term = pp_term status in
 224  function
 225   | Ast.Sub (t1, t2) -> sprintf "%s \\SUB %s" (pp_term t1) (pp_term t2)
 226   | Ast.Sup (t1, t2) -> sprintf "%s \\SUP %s" (pp_term t1) (pp_term t2)
 227   | Ast.Below (t1, t2) -> sprintf "%s \\BELOW %s" (pp_term t1) (pp_term t2)
 228   | Ast.Above (t1, t2) -> sprintf "%s \\ABOVE %s" (pp_term t1) (pp_term t2)
 229   | Ast.Over (t1, t2) -> sprintf "[%s \\OVER %s]" (pp_term t1) (pp_term t2)
 230   | Ast.Atop (t1, t2) -> sprintf "[%s \\ATOP %s]" (pp_term t1) (pp_term t2)
 231   | Ast.Frac (t1, t2) -> sprintf "\\FRAC %s %s" (pp_term t1) (pp_term t2)
 232   | Ast.InfRule (t1, t2, t3) -> sprintf "\\INFRULE %s %s %s" (pp_term t1)
 233   (pp_term t2) (pp_term t3)
 234   | Ast.Maction l -> sprintf "\\MACTION (%s)"
 235      (String.concat "," (List.map pp_term l))
 236   | Ast.Sqrt t -> sprintf "\\SQRT %s" (pp_term t)
 237   | Ast.Root (arg, index) ->
 238       sprintf "\\ROOT %s \\OF %s" (pp_term index) (pp_term arg)
 239   | Ast.Break -> "\\BREAK"
 240 (*   | Space -> "\\SPACE" *)
 241   | Ast.Box (box_spec, terms) ->
 242       sprintf "\\%s [%s]" (pp_box_spec box_spec)
 243         (String.concat " " (List.map pp_term terms))
 244   | Ast.Group terms ->
 245       sprintf "\\GROUP [%s]" (String.concat " " (List.map pp_term terms))
 246   | Ast.Mstyle (l,terms) ->
 247       sprintf "\\MSTYLE %s [%s]"
 248         (String.concat " " (List.map (fun (k,v) -> k^"="^v) l))
 249         (String.concat " " (List.map pp_term terms))
 250   | Ast.Mpadded (l,terms) ->
 251       sprintf "\\MSTYLE %s [%s]"
 252         (String.concat " " (List.map (fun (k,v) -> k^"="^v) l))
 253         (String.concat " " (List.map pp_term terms))
 254
 255 and pp_magic status =
 256  let pp_term = pp_term status in
 257  function
 258   | Ast.List0 (t, sep_opt) ->
 259       sprintf "list0 %s%s" (pp_term t) (pp_sep_opt sep_opt)
 260   | Ast.List1 (t, sep_opt) ->
 261       sprintf "list1 %s%s" (pp_term t) (pp_sep_opt sep_opt)
 262   | Ast.Opt t -> sprintf "opt %s" (pp_term t)
 263   | Ast.Fold (kind, p_base, names, p_rec) ->
 264       let acc = match names with acc :: _ -> acc | _ -> assert false in
 265       sprintf "fold %s %s rec %s %s"
 266         (pp_fold_kind kind) (pp_term p_base) acc (pp_term p_rec)
 267   | Ast.Default (p_some, p_none) ->
 268       sprintf "default %s %s" (pp_term p_some) (pp_term p_none)
 269   | Ast.If (p_test, p_true, p_false) ->
 270       sprintf "if %s then %s else %s"
 271         (pp_term p_test) (pp_term p_true) (pp_term p_false)
 272   | Ast.Fail -> "fail"
 273
 274 and pp_fold_kind = function
 275   | `Left -> "left"
 276   | `Right -> "right"
 277
 278 and pp_sep_opt = function
 279   | None -> ""
 280   | Some sep -> sprintf " sep %s" (pp_literal sep)
 281
 282 and pp_variable = function
 283   | Ast.NumVar s -> "number " ^ s
 284   | Ast.IdentVar s -> "ident " ^ s
 285   | Ast.TermVar (s,Ast.Self _) -> s
 286   | Ast.TermVar (s,Ast.Level l) -> "term " ^string_of_int l
 287   | Ast.Ascription (t, n) -> assert false
 288   | Ast.FreshVar n -> "fresh " ^ n
 289
 290 let _pp_term = ref (pp_term ~pp_parens:false)
 291 let pp_term status t = !_pp_term (status :> NCic.status) t
 292 let set_pp_term f = _pp_term := f
 293
 294 let pp_params pp_term = function
 295   | [] -> ""
 296   | params -> " " ^ String.concat " " (List.map (pp_capture_variable pp_term) params)
 297
 298 let pp_fields pp_term fields =
 299   (if fields <> [] then "\n" else "") ^
 300   String.concat ";\n"
 301     (List.map
 302       (fun (name,ty,coercion,arity) ->
 303         " " ^ name ^
 304         (if coercion then
 305           (":" ^ (if arity > 0 then string_of_int arity else "") ^ "> ")
 306         else ": ") ^
 307       pp_term ty)
 308     fields)
 309
 310 let pp_obj pp_term = function
 311  | Ast.Inductive (params, types) ->
 312     let pp_constructors constructors =
 313       String.concat "\n"
 314         (List.map (fun (name, typ) -> sprintf "| %s: %s" name (pp_term typ))
 315           constructors)
 316     in
 317     let pp_type (name, _, typ, constructors) =
 318       sprintf "\nwith %s: %s \\def\n%s" name (pp_term typ)
 319         (pp_constructors constructors)
 320     in
 321     (match types with
 322     | [] -> assert false
 323     | (name, inductive, typ, constructors) :: tl ->
 324         let fst_typ_pp =
 325           sprintf "%sinductive %s%s: %s \\def\n%s"
 326             (if inductive then "" else "co") name (pp_params pp_term params)
 327             (pp_term typ) (pp_constructors constructors)
 328         in
 329         fst_typ_pp ^ String.concat "" (List.map pp_type tl))
 330  | Ast.Theorem (flavour, name, typ, body,_) ->
 331     sprintf "%s %s:\n %s\n%s"
 332       (NCicPp.string_of_flavour flavour)
 333       name
 334       (pp_term typ)
 335       (match body with
 336       | None -> ""
 337       | Some body -> "\\def\n " ^ pp_term body)
 338  | Ast.Record (params,name,ty,fields) ->
 339     "record " ^ name ^ " " ^ pp_params pp_term params ^ ": " ^ pp_term ty ^
 340     " \\def {" ^ pp_fields pp_term fields ^ "\n}"
 341
 342 let rec pp_value (status: #NCic.status) = function
 343   | Env.TermValue t -> sprintf "$%s$" (pp_term status t)
 344   | Env.StringValue (Env.Ident s) -> sprintf "\"%s\"" s
 345   | Env.StringValue (Env.Var s) -> sprintf "\"${ident %s}\"" s
 346   | Env.NumValue n -> n
 347   | Env.OptValue (Some v) -> "Some " ^ pp_value status v
 348   | Env.OptValue None -> "None"
 349   | Env.ListValue l -> sprintf "[%s]" (String.concat "; " (List.map (pp_value status) l))
 350   | Env.DisambiguationValue _ -> sprintf "#"
 351
 352 let rec pp_value_type =
 353   function
 354   | Env.TermType l -> "Term "^string_of_int l
 355   | Env.StringType -> "String"
 356   | Env.NumType -> "Number"
 357   | Env.OptType t -> "Maybe " ^ pp_value_type t
 358   | Env.ListType l -> "List " ^ pp_value_type l
 359   | Env.NoType -> "NoType"
 360
 361 let pp_env status env =
 362   String.concat "; "
 363     (List.map
 364       (fun (name, (ty, value)) ->
 365         sprintf "%s : %s = %s" name (pp_value_type ty) (pp_value status value))
 366       env)
 367
 368 let rec pp_cic_appl_pattern = function
 369   | Ast.NRefPattern nref -> NReference.string_of_reference nref
 370   | Ast.VarPattern name -> name
 371   | Ast.ImplicitPattern -> "?"
 372   | Ast.ApplPattern aps ->
 373       sprintf "(%s)" (String.concat " " (List.map pp_cic_appl_pattern aps))
 374