matitaB/components/extlib/graphvizPp.ml

   1 (* Copyright (C) 2006, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 type attribute = string * string  (* <key, value> pair *)
  29
  30 module type GraphvizFormatter =
  31   sig
  32     val header:
  33       ?graph_type:string ->
  34       ?name:string -> ?graph_attrs:(attribute list) ->
  35       ?node_attrs:(attribute list) -> ?edge_attrs:(attribute list) ->
  36       Format.formatter ->
  37         unit
  38     val node: string -> ?attrs:(attribute list) -> Format.formatter -> unit
  39     val edge:
  40       string -> string -> ?attrs:(attribute list) -> Format.formatter ->
  41         unit
  42     val raw: string -> Format.formatter -> unit
  43     val trailer: Format.formatter -> unit
  44   end
  45
  46 open Format
  47
  48 module Dot =
  49   struct
  50     let attribute fmt (k, v) = fprintf fmt "@[<hv2>%s=@,\"%s\",@]" k v
  51     let attributes attrs fmt = List.iter (attribute fmt) attrs
  52     let quote_string quote s = if quote then "\"" ^s ^ "\"" else s
  53
  54     let node name ~quote ?(attrs = []) fmt =
  55       fprintf fmt "@[<hov2>%s@ [" (quote_string quote name);
  56       attributes attrs fmt;
  57       fprintf fmt "];@]@,"
  58
  59     let edge ~quote name1 name2 ?(attrs = []) fmt =
  60       fprintf fmt "@[<hov2>%s ->@ %s@ ["
  61          (quote_string quote name1) (quote_string quote name2);
  62       attributes attrs fmt;
  63       fprintf fmt "];@]@,"
  64
  65     let header ?(graph_type = "digraph") ?(name = "g") ?(graph_attrs = []) ?node_attrs ?edge_attrs fmt =
  66       fprintf fmt "@[<hv2>%s %s {@," graph_type name;
  67       List.iter (fun (k, v) -> fprintf fmt "@[<hv2>%s=@,%s;@]@," k v)
  68         graph_attrs;
  69       (match node_attrs with
  70       | Some attrs -> node "node" ~quote:false ~attrs fmt
  71       | None -> ());
  72       (match edge_attrs with
  73       | Some attrs -> node "edge" ~quote:false ~attrs fmt
  74       | None -> ())
  75
  76     let node = node ~quote:true
  77     let edge = edge ~quote:true
  78     let raw s fmt = pp_print_string fmt s
  79     let trailer fmt = fprintf fmt "@,}@]%!"
  80   end
  81