matitaB/components/ng_tactics/nTactics.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id: nCic.ml 9058 2008-10-13 17:42:30Z tassi $ *)
  13
  14 open Printf
  15
  16 let debug = false
  17 let debug_print s = if debug then prerr_endline (Lazy.force s) else ()
  18
  19 open Continuationals.Stack
  20 open NTacStatus
  21 module Ast = NotationPt
  22
  23 let id_tac status = status ;;
  24 let print_tac print_status message status =
  25   if print_status then pp_tac_status status;
  26   prerr_endline message;
  27   status
  28 ;;
  29
  30 let dot_tac status =
  31   let gstatus =
  32     match status#stack with
  33     | [] -> assert false
  34     | ([], _, [], _) :: _ as stack ->
  35         (* backward compatibility: do-nothing-dot *)
  36         stack
  37     | (g, t, k, tag) :: s ->
  38         match filter_open g, k with
  39         | loc :: loc_tl, _ ->
  40              (([ loc ], t, loc_tl @+ k, tag) :: s)
  41         | [], loc :: k ->
  42             assert (is_open loc);
  43             (([ loc ], t, k, tag) :: s)
  44         | _ -> fail (lazy "can't use \".\" here")
  45   in
  46    status#set_stack gstatus
  47 ;;
  48
  49 let branch_tac ?(force=false) status =
  50   let gstatus =
  51     match status#stack with
  52     | [] -> assert false
  53     | (g, t, k, tag) :: s ->
  54           match init_pos g with (* TODO *)
  55           | [] -> fail (lazy "empty goals")
  56           | [_] when (not force) -> fail (lazy "too few goals to branch")
  57           | loc :: loc_tl ->
  58                ([ loc ], [], [], `BranchTag) :: (loc_tl, t, k, tag) :: s
  59   in
  60    status#set_stack gstatus
  61 ;;
  62
  63 let shift_tac status =
  64   let gstatus =
  65     match status#stack with
  66     | (g, t, k, `BranchTag) :: (g', t', k', tag) :: s ->
  67           (match g' with
  68           | [] -> fail (lazy "no more goals to shift")
  69           | loc :: loc_tl ->
  70                 (([ loc ], t @+ filter_open g @+ k, [],`BranchTag)
  71                 :: (loc_tl, t', k', tag) :: s))
  72      | _ -> fail (lazy "can't shift goals here")
  73   in
  74    status#set_stack gstatus
  75 ;;
  76
  77 let pos_tac i_s status =
  78   let gstatus =
  79     match status#stack with
  80     | [] -> assert false
  81     | ([ loc ], t, [],`BranchTag) :: (g', t', k', tag) :: s
  82       when is_fresh loc ->
  83         let l_js = List.filter (fun (i, _) -> List.mem i i_s) ([loc] @+ g') in
  84           ((l_js, t , [],`BranchTag)
  85            :: (([ loc ] @+ g') @- l_js, t', k', tag) :: s)
  86     | _ -> fail (lazy "can't use relative positioning here")
  87   in
  88    status#set_stack gstatus
  89 ;;
  90
  91 let case_tac lab status =
  92   let gstatus =
  93     match status#stack with
  94     | [] -> assert false
  95     | ([ loc ], t, [],`BranchTag) :: (g', t', k', tag) :: s
  96       when is_fresh loc ->
  97         let l_js =
  98           List.filter
  99            (fun curloc ->
 100               let _,_,metasenv,_,_ = status#obj in
 101               match NCicUtils.lookup_meta (goal_of_loc curloc) metasenv with
 102                   attrs,_,_ when List.mem (`Name lab) attrs -> true
 103                 | _ -> false) ([loc] @+ g') in
 104           ((l_js, t , [],`BranchTag)
 105            :: (([ loc ] @+ g') @- l_js, t', k', tag) :: s)
 106     | _ -> fail (lazy "can't use relative positioning here")
 107   in
 108    status#set_stack gstatus
 109 ;;
 110
 111 let wildcard_tac status =
 112   let gstatus =
 113     match status#stack with
 114     | [] -> assert false
 115     | ([ loc ] , t, [], `BranchTag) :: (g', t', k', tag) :: s
 116        when is_fresh loc ->
 117             (([loc] @+ g', t, [], `BranchTag) :: ([], t', k', tag) :: s)
 118     | _ -> fail (lazy "can't use wildcard here")
 119   in
 120    status#set_stack gstatus
 121 ;;
 122
 123 let merge_tac status =
 124   let gstatus =
 125     match status#stack with
 126     | [] -> assert false
 127     | (g, t, k,`BranchTag) :: (g', t', k', tag) :: s ->
 128         ((t @+ filter_open g @+ g' @+ k, t', k', tag) :: s)
 129     | _ -> fail (lazy "can't merge goals here")
 130   in
 131    status#set_stack gstatus
 132 ;;
 133
 134 let focus_tac gs status =
 135   let gstatus =
 136     match status#stack with
 137     | [] -> assert false
 138     | s -> assert(gs <> []);
 139           let stack_locs =
 140             let add_l acc _ _ l = if is_open l then l :: acc else acc in
 141             fold ~env:add_l ~cont:add_l ~todo:add_l [] s
 142           in
 143           List.iter
 144             (fun g ->
 145               if not (List.exists (fun l -> goal_of_loc l = g) stack_locs) then
 146                 fail (lazy (sprintf "goal %d not found (or closed)" g)))
 147             gs;
 148           (zero_pos gs, [], [], `FocusTag) :: deep_close gs s
 149   in
 150    status#set_stack gstatus
 151 ;;
 152
 153 let unfocus_tac status =
 154   let gstatus =
 155     match status#stack with
 156     | [] -> assert false
 157     | (g, [], [], `FocusTag) :: s when filter_open g = [] -> s
 158     | _ as s -> fail (lazy ("can't unfocus, some goals are still open:\n"^
 159       Continuationals.Stack.pp s))
 160   in
 161    status#set_stack gstatus
 162 ;;
 163
 164 let skip_tac status =
 165   let gstatus =
 166     match status#stack with
 167     | [] -> assert false
 168     | (gl, t, k, tag) :: s ->
 169         let gl = List.map switch_of_loc gl in
 170         if List.exists (function Open _ -> true | Closed _ -> false) gl then
 171           fail (lazy "cannot skip an open goal")
 172         else
 173           ([],t,k,tag) :: s
 174   in
 175    status#set_stack gstatus
 176 ;;
 177
 178 let block_tac l status =
 179   List.fold_left (fun status tac -> tac status) status l
 180 ;;
 181
 182
 183 let compare_statuses ~past ~present =
 184  let _,_,past,_,_ = past#obj in
 185  let _,_,present,_,_ = present#obj in
 186  List.map fst (List.filter (fun (i,_) -> not(List.mem_assoc i past)) present),
 187  List.map fst (List.filter (fun (i,_) -> not (List.mem_assoc i present)) past)
 188 ;;
 189
 190
 191
 192 (* Exec and distribute_tac form a retraction pair:
 193     1) exec (distribute_tac low_tac) (s,i) = low_tac (s,i)
 194     2) tac [s]::G = G1::...::Gn::G' && G' is G with some goals closed =>
 195          distribute_tac (exec tac) [s]::G = (G1@...Gn)::G'
 196     3) tac G = distribute_tac (exec tac) G if
 197        tac = distribute_tac lowtac
 198     4) atomic_tac t === distribute_tac (exec t)
 199
 200    Note that executing an high tactic on a set of goals may be stronger
 201    than executing the same tactic on those goals, but once at a time
 202    (e.g. the tactic could perform a global analysis of the set of goals)
 203 *)
 204
 205 (* CSC: potential bug here: the new methods still use the instance variables
 206    of the old status and not the instance variables of the new one *)
 207 let change_stack_type (status : 'a #NTacStatus.status) (stack: 'b) : 'b NTacStatus.status =
 208  let uid = status#user in
 209  let o =
 210   object
 211    inherit ['b] NTacStatus.status uid status#obj stack
 212    method ppterm = status#ppterm
 213    method ppcontext = status#ppcontext
 214    method ppsubst = status#ppsubst
 215    method ppobj = status#ppobj
 216    method ppmetasenv = status#ppmetasenv
 217   end
 218  in
 219   o#set_pstatus status
 220 ;;
 221
 222 let exec tac (low_status : #lowtac_status) g =
 223   let stack = [ [0,Open g], [], [], `NoTag ] in
 224   let status = change_stack_type low_status stack in
 225   let status = tac status in
 226    (low_status#set_pstatus status)#set_obj status#obj
 227 ;;
 228
 229 let distribute_tac tac (status : #tac_status) =
 230   match status#stack with
 231   | [] -> assert false
 232   | (g, t, k, tag) :: s ->
 233       debug_print (lazy ("context length " ^string_of_int (List.length g)));
 234       let rec aux s go gc =
 235         function
 236         | [] ->
 237             debug_print (lazy "no selected goals");
 238             s, go, gc
 239         | loc :: loc_tl ->
 240             debug_print (lazy "inner eval tactical");
 241             let s, go, gc =
 242               if List.exists ((=) (goal_of_loc loc)) gc then
 243                 s, go, gc
 244               else
 245                 match switch_of_loc loc with
 246                 | Closed _ -> fail (lazy "cannot apply to a Closed goal")
 247                 | Open n ->
 248                    let sn = tac s n in
 249                    let go', gc' = compare_statuses ~past:s ~present:sn in
 250                    sn, ((go @+ [n]) @- gc') @+ go', gc @+ gc'
 251             in
 252             aux s go gc loc_tl
 253       in
 254       let s0 = change_stack_type status () in
 255       let s0, go0, gc0 = s0, [], [] in
 256       let sn, gon, gcn = aux s0 go0 gc0 g in
 257       debug_print (lazy ("opened: "
 258         ^ String.concat " " (List.map string_of_int gon)));
 259       debug_print (lazy ("closed: "
 260         ^ String.concat " " (List.map string_of_int gcn)));
 261       let stack =
 262         (zero_pos gon, t @~- gcn, k @~- gcn, tag) :: deep_close gcn s
 263       in
 264        ((status#set_stack stack)#set_obj(sn:>lowtac_status)#obj)#set_pstatus sn
 265 ;;
 266
 267 let atomic_tac htac: #tac_status as 'a -> 'a = distribute_tac (exec htac) ;;
 268
 269 let repeat_tac t s =
 270   let rec repeat t (status : #tac_status as 'a) : 'a =
 271     try repeat t (t status)
 272     with NTacStatus.Error _ -> status
 273   in
 274     atomic_tac (repeat t) s
 275 ;;
 276
 277
 278 let try_tac tac status =
 279  let try_tac status =
 280   try
 281     tac status
 282   with NTacStatus.Error _ ->
 283     status
 284  in
 285   atomic_tac try_tac status
 286 ;;
 287
 288 let first_tac tacl status =
 289   let res =
 290    HExtlib.list_findopt
 291     (fun tac _ -> try Some (tac status) with NTacStatus.Error _ -> None) tacl
 292   in
 293     match res with
 294       | None -> fail (lazy "No tactics left")
 295       | Some x -> x
 296 ;;
 297
 298 let exact_tac t : 's tactic = distribute_tac (fun status goal ->
 299  instantiate_with_ast status goal t)
 300 ;;
 301
 302 let assumption_tac status = distribute_tac (fun status goal ->
 303   let gty = get_goalty status goal in
 304   let context = ctx_of gty in
 305   let htac =
 306    first_tac
 307     (List.map (fun (name,_) -> exact_tac ("",0,(Ast.Ident (name,`Ambiguous))))
 308       context)
 309   in
 310     exec htac status goal) status
 311 ;;
 312
 313 let find_in_context name context =
 314   let rec aux acc = function
 315     | [] -> raise Not_found
 316     | (hd,_) :: tl when hd = name -> acc
 317     | _ :: tl ->  aux (acc + 1) tl
 318   in
 319   aux 1 context
 320 ;;
 321
 322 let clear_tac names =
 323  if names = [] then id_tac
 324  else
 325   distribute_tac (fun status goal ->
 326    let goalty = get_goalty status goal in
 327    let js =
 328      List.map
 329      (fun name ->
 330         try find_in_context name (ctx_of goalty)
 331         with Not_found ->
 332           fail (lazy ("hypothesis '" ^ name ^ "' not found")))
 333      names
 334    in
 335    let n,h,metasenv,subst,o = status#obj in
 336    let metasenv,subst,_,_ = NCicMetaSubst.restrict status metasenv subst goal js in
 337     status#set_obj (n,h,metasenv,subst,o))
 338 ;;
 339
 340 let generalize0_tac args =
 341  if args = [] then id_tac
 342  else exact_tac ("",0,Ast.Appl (Ast.Implicit `JustOne :: args))
 343 ;;
 344
 345 let select0_tac ~where ~job  =
 346  let found, postprocess =
 347    match job with
 348    | `Substexpand argsno -> mk_in_scope, mk_out_scope argsno
 349    | `Collect l -> (fun s t -> l := t::!l; mk_in_scope s t), mk_out_scope 1
 350    | `ChangeWith f -> f,(fun s t -> s, t)
 351  in
 352  distribute_tac (fun status goal ->
 353    let wanted,hyps,where =
 354     GrafiteDisambiguate.disambiguate_npattern status where in
 355    let goalty = get_goalty status goal in
 356    let path =
 357      match where with None -> NCic.Implicit `Term | Some where -> where
 358    in
 359    let status, newgoalctx =
 360       List.fold_right
 361        (fun (name,d as entry) (status,ctx) ->
 362          try
 363           let path = List.assoc name hyps in
 364            match d with
 365               NCic.Decl ty ->
 366                let status,ty =
 367                 select_term status ~found ~postprocess (mk_cic_term ctx ty)
 368                  (wanted,path) in
 369                let status,ty = term_of_cic_term status ty ctx in
 370                 status,(name,NCic.Decl ty)::ctx
 371             | NCic.Def (bo,ty) ->
 372                let status,bo =
 373                 select_term status ~found ~postprocess (mk_cic_term ctx bo)
 374                  (wanted,path) in
 375                let status,bo = term_of_cic_term status bo ctx in
 376                 status,(name,NCic.Def (bo,ty))::ctx
 377          with
 378           Not_found -> status, entry::ctx
 379        ) (ctx_of goalty) (status,[])
 380    in
 381    let status, newgoalty =
 382      select_term status ~found ~postprocess goalty (wanted,path) in
 383    (* WARNING: the next two lines simply change the context of newgoalty
 384       from the old to the new one. Otherwise mk_meta will do that herself,
 385       calling relocate that calls delift. However, newgoalty is now
 386       ?[out_scope] and thus the delift would trigger the special unification
 387       case, which is wrong now :-( *)
 388    let status,newgoalty = term_of_cic_term status newgoalty (ctx_of goalty) in
 389    let newgoalty = mk_cic_term newgoalctx newgoalty in
 390
 391    let status, instance =
 392      mk_meta status newgoalctx (`Decl newgoalty) `IsTerm
 393    in
 394    instantiate ~refine:false status goal instance)
 395 ;;
 396
 397 let select_tac ~where:((txt,txtlen,(wanted,hyps,path)) as where) ~job
 398  move_down_hyps
 399 =
 400  if not move_down_hyps then
 401   select0_tac ~where ~job
 402  else
 403   let path =
 404    List.fold_left
 405     (fun path (name,ty) ->
 406       NotationPt.Binder (`Forall, (NotationPt.Ident (name,`Ambiguous),Some ty),path))
 407     (match path with Some x -> x | None -> NotationPt.UserInput) (List.rev hyps)
 408   in
 409    block_tac [
 410      generalize0_tac (List.map (fun (name,_) -> Ast.Ident (name,`Ambiguous)) hyps);
 411      select0_tac ~where:(txt,txtlen,(wanted,[],Some path)) ~job;
 412      clear_tac (List.map fst hyps) ]
 413 ;;
 414
 415 let generalize_tac ~where =
 416  let l = ref [] in
 417  block_tac [
 418    select_tac ~where ~job:(`Collect l) true;
 419    (fun s -> distribute_tac (fun status goal ->
 420       let goalty = get_goalty status goal in
 421       let status,canon,rest =
 422        match !l with
 423           [] ->
 424            (match where with
 425                _,_,(None,_,_)  -> fail (lazy "No term to generalize")
 426              | txt,txtlen,(Some what,_,_) ->
 427                 let status, what =
 428                  disambiguate status (ctx_of goalty) (txt,txtlen,what) None
 429                 in
 430                  status,what,[]
 431            )
 432         | he::tl -> status,he,tl in
 433       let status =
 434        List.fold_left
 435          (fun s t -> unify s (ctx_of goalty) canon t) status rest in
 436       let status, canon = term_of_cic_term status canon (ctx_of goalty) in
 437       instantiate status goal
 438        (mk_cic_term (ctx_of goalty) (NCic.Appl [NCic.Implicit `Term ; canon ]))
 439    ) s) ]
 440 ;;
 441
 442 let cut_tac t =
 443  atomic_tac (block_tac [
 444   exact_tac ("",0, Ast.Appl [Ast.Implicit `JustOne; Ast.Implicit `JustOne]);
 445   branch_tac;
 446    pos_tac [3]; exact_tac t;
 447    shift_tac; pos_tac [2]; skip_tac;
 448   merge_tac ])
 449 ;;
 450
 451 let lapply_tac (s,n,t) =
 452  exact_tac (s,n, Ast.Appl [Ast.Implicit `JustOne; t])
 453 ;;
 454
 455 let reduce_tac ~reduction ~where =
 456   let change status t =
 457     match reduction with
 458     | `Normalize perform_delta ->
 459         normalize status
 460          ?delta:(if perform_delta then None else Some max_int) (ctx_of t) t
 461     | `Whd perform_delta ->
 462         whd status
 463          ?delta:(if perform_delta then None else Some max_int) (ctx_of t) t
 464   in
 465   select_tac ~where ~job:(`ChangeWith change) false
 466 ;;
 467
 468 let change_tac ~where ~with_what =
 469   let change status t =
 470     let status, ww = disambiguate status (ctx_of t) with_what  None in
 471     let status = unify status (ctx_of t) t ww in
 472     status, ww
 473   in
 474   select_tac ~where ~job:(`ChangeWith change) false
 475 ;;
 476
 477 let letin_tac ~where ~what:(_,_,w) name =
 478  block_tac [
 479   select_tac ~where ~job:(`Substexpand 1) true;
 480   exact_tac
 481    ("",0,Ast.LetIn((Ast.Ident (name,`Ambiguous),None),w,Ast.Implicit `JustOne));
 482  ]
 483 ;;
 484
 485 let apply_tac (s,n,t) =
 486   let t = Ast.Appl [t; Ast.Implicit `Vector] in
 487   exact_tac (s,n,t)
 488 ;;
 489
 490 type indtyinfo = {
 491         rightno: int;
 492         leftno: int;
 493         consno: int;
 494         reference: NReference.reference;
 495  }
 496 ;;
 497
 498 let ref_of_indtyinfo iti = iti.reference;;
 499
 500 let analyze_indty_tac ~what indtyref =
 501  distribute_tac (fun (status as orig_status) goal ->
 502   let goalty = get_goalty status goal in
 503   let status, what = disambiguate status (ctx_of goalty) what None in
 504   let status, ty_what = typeof status (ctx_of what) what in
 505   let status, (r,consno,lefts,rights) = analyse_indty status ty_what in
 506   let leftno = List.length lefts in
 507   let rightno = List.length rights in
 508   indtyref := Some {
 509     rightno = rightno; leftno = leftno; consno = consno; reference = r;
 510   };
 511   exec id_tac orig_status goal)
 512 ;;
 513
 514 let sort_of_goal_tac sortref = distribute_tac (fun status goal ->
 515   let goalty = get_goalty status goal in
 516   let status,sort = typeof status (ctx_of goalty) goalty in
 517   let status, sort = fix_sorts status sort in
 518   let status, sort = term_of_cic_term status sort (ctx_of goalty) in
 519    sortref := sort;
 520    status)
 521 ;;
 522
 523 let elim_tac ~what:(txt,len,what) ~where =
 524   let what = txt, len, Ast.Appl [what; Ast.Implicit `Vector] in
 525   let indtyinfo = ref None in
 526   let sort = ref (NCic.Rel 1) in
 527   atomic_tac (block_tac [
 528     analyze_indty_tac ~what indtyinfo;
 529     (fun s -> select_tac
 530       ~where ~job:(`Substexpand ((HExtlib.unopt !indtyinfo).rightno+1)) true s);
 531     sort_of_goal_tac sort;
 532     (fun status ->
 533      let ity = HExtlib.unopt !indtyinfo in
 534      let NReference.Ref (uri, _) = ity.reference in
 535      let name =
 536        NUri.name_of_uri uri ^ "_" ^
 537         snd (NCicElim.ast_of_sort
 538           (match !sort with NCic.Sort x -> x | _ -> assert false))
 539      in
 540      let eliminator =
 541        let _,_,w = what in
 542        Ast.Appl [ Ast.Ident (name,`Ambiguous) ; Ast.Implicit `Vector ; w ]
 543      in
 544      exact_tac ("",0,eliminator) status) ])
 545 ;;
 546
 547 let rewrite_tac ~dir ~what:(_,_,what) ~where status =
 548  let sortref = ref (NCic.Rel 1) in
 549  let status = sort_of_goal_tac sortref status in
 550  let suffix = "_" ^ snd (NCicElim.ast_of_sort
 551    (match !sortref with NCic.Sort x -> x | _ -> assert false))
 552  in
 553  let name =
 554   match dir with
 555      `LeftToRight -> "eq" ^ suffix ^ "_r"
 556    | `RightToLeft -> "eq" ^ suffix
 557  in
 558  let what = Ast.Appl [what; Ast.Implicit `Vector] in
 559   block_tac
 560    [ select_tac ~where ~job:(`Substexpand 2) true;
 561      exact_tac
 562       ("",0,
 563        Ast.Appl(Ast.Ident(name,`Ambiguous)::HExtlib.mk_list (Ast.Implicit `JustOne) 5@
 564         [what]))] status
 565 ;;
 566
 567 let intro_tac name =
 568  block_tac
 569   [ exact_tac
 570      ("",0,(Ast.Binder (`Lambda,
 571       (Ast.Ident (name,`Ambiguous),None),Ast.Implicit `JustOne)));
 572     if name = "_" then clear_tac [name] else id_tac ]
 573 ;;
 574
 575 let name_counter = ref 0;;
 576 let intros_tac ?names_ref names s =
 577   let names_ref, prefix =
 578     match names_ref with | None -> ref [], "__" | Some r -> r, "H"
 579   in
 580   if names = [] then
 581    repeat_tac
 582      (fun s ->
 583         incr name_counter;
 584         (* TODO: generate better names *)
 585         let name = prefix ^ string_of_int !name_counter in
 586         let s = intro_tac name s in
 587         names_ref := !names_ref @ [name];
 588         s)
 589      s
 590    else
 591      block_tac (List.map intro_tac names) s
 592 ;;
 593
 594 let cases ~what status goal =
 595  let gty = get_goalty status goal in
 596  let status, what = disambiguate status (ctx_of gty) what None in
 597  let status, ty = typeof status (ctx_of what) what in
 598  let status, (ref, consno, _, _) = analyse_indty status ty in
 599  let status, what = term_of_cic_term status what (ctx_of gty) in
 600  let t =
 601   NCic.Match (ref,NCic.Implicit `Term, what,
 602     HExtlib.mk_list (NCic.Implicit `Term) consno)
 603  in
 604  instantiate status goal (mk_cic_term (ctx_of gty) t)
 605 ;;
 606
 607 let cases_tac ~what:(txt,len,what) ~where =
 608   let what = txt, len, Ast.Appl [what; Ast.Implicit `Vector] in
 609   let indtyinfo = ref None in
 610   atomic_tac
 611    (block_tac [
 612       analyze_indty_tac ~what indtyinfo;
 613       (fun s -> select_tac
 614        ~where ~job:(`Substexpand ((HExtlib.unopt !indtyinfo).rightno+1))true s);
 615       distribute_tac (cases ~what) ])
 616 ;;
 617
 618 let case1_tac name =
 619  let name = if name = "_" then "_clearme" else name in
 620  block_tac [ intro_tac name;
 621              cases_tac
 622               ~where:("",0,(None,[],None))
 623               ~what:("",0,Ast.Ident (name,`Ambiguous));
 624              if name = "_clearme" then clear_tac ["_clearme"] else id_tac ]
 625 ;;
 626
 627 let constructor_tac ?(num=1) ~args = distribute_tac (fun status goal ->
 628   if num < 1 then fail (lazy "constructor numbers begin with 1");
 629   let gty = get_goalty status goal in
 630   let status, (r,_,_,_) = analyse_indty status gty in
 631   let ref = NReference.mk_constructor num r in
 632   let t =
 633     if args = [] then Ast.NRef ref else
 634     Ast.Appl (HExtlib.list_concat ~sep:[Ast.Implicit `Vector]
 635       ([Ast.NRef ref] :: List.map (fun _,_,x -> [x]) args))
 636   in
 637   exec (apply_tac ("",0,t)) status goal)
 638 ;;
 639
 640 let assert0_tac (hyps,concl) = distribute_tac (fun status goal ->
 641  let gty = get_goalty status goal in
 642  let eq status ctx t1 t2 =
 643   let status,t1 = disambiguate status ctx t1 None in
 644   let status,t1 = apply_subst status ctx t1 in
 645   let status,t1 = term_of_cic_term status t1 ctx in
 646   let t2 = mk_cic_term ctx t2 in
 647   let status,t2 = apply_subst status ctx t2 in
 648   let status,t2 = term_of_cic_term status t2 ctx in
 649   prerr_endline ("COMPARING: " ^ status#ppterm ~subst:[] ~metasenv:[] ~context:ctx t1 ^ " vs " ^ status#ppterm ~subst:[] ~metasenv:[] ~context:ctx t2);
 650   assert (t1=t2);
 651   status
 652  in
 653  let status,gty' = term_of_cic_term status gty (ctx_of gty) in
 654  let status = eq status (ctx_of gty) concl gty' in
 655  let status,_ =
 656   List.fold_right2
 657    (fun (id1,e1) ((id2,e2) as item) (status,ctx) ->
 658      assert (id1=id2 || (prerr_endline (id1 ^ " vs " ^ id2); false));
 659      match e1,e2 with
 660         `Decl t1, NCic.Decl t2 ->
 661           let status = eq status ctx t1 t2 in
 662           status,item::ctx
 663       | `Def (b1,t1), NCic.Def (b2,t2) ->
 664           let status = eq status ctx t1 t2 in
 665           let status = eq status ctx b1 b2 in
 666           status,item::ctx
 667       | _ -> assert false
 668    ) hyps (ctx_of gty) (status,[])
 669  in
 670   exec id_tac status goal)
 671 ;;
 672
 673 let assert_tac seqs status =
 674  match status#stack with
 675   | [] -> assert false
 676   | (g,_,_,_) :: s ->
 677      assert (List.length g = List.length seqs);
 678      (match seqs with
 679          [] -> id_tac
 680        | [seq] -> assert0_tac seq
 681        | _ ->
 682          block_tac
 683           ((branch_tac ~force:false)::
 684           HExtlib.list_concat ~sep:[shift_tac]
 685             (List.map (fun seq -> [assert0_tac seq]) seqs)@
 686           [merge_tac])
 687      ) status
 688 ;;
 689
 690 let inversion_tac ~what:(txt,len,what) ~where =
 691   let what = txt, len, Ast.Appl [what; Ast.Implicit `Vector] in
 692   let indtyinfo = ref None in
 693   let sort = ref (NCic.Rel 1) in
 694   atomic_tac (block_tac [
 695     analyze_indty_tac ~what indtyinfo;
 696     (fun s -> select_tac
 697       ~where ~job:(`Substexpand ((HExtlib.unopt !indtyinfo).rightno+1)) true s);
 698     sort_of_goal_tac sort;
 699     (fun status ->
 700      let ity = HExtlib.unopt !indtyinfo in
 701      let NReference.Ref (uri, _) = ity.reference in
 702      let name =
 703        NUri.name_of_uri uri ^ "_inv_" ^
 704         snd (NCicElim.ast_of_sort
 705           (match !sort with NCic.Sort x -> x | _ -> assert false))
 706      in
 707      let eliminator =
 708        let _,_,w = what in
 709        Ast.Appl [ Ast.Ident (name,`Ambiguous) ; Ast.Implicit `Vector ; w ]
 710      in
 711      exact_tac ("",0,eliminator) status) ])
 712 ;;