matitaB/matita/matitaScript.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29 open GrafiteTypes
  30
  31 module TA = GrafiteAst
  32
  33 let debug = false
  34 let debug_print = if debug then prerr_endline else ignore
  35
  36   (** raised when one of the script margins (top or bottom) is reached *)
  37 exception Margin
  38 exception NoUnfinishedProof
  39 exception ActionCancelled of string
  40
  41 let safe_substring s i j =
  42   try String.sub s i j with Invalid_argument _ -> assert false
  43
  44 let heading_nl_RE = Pcre.regexp "^\\s*\n\\s*"
  45 let heading_nl_RE' = Pcre.regexp "^(\\s*\n\\s*)"
  46 let only_dust_RE = Pcre.regexp "^(\\s|\n|%%[^\n]*\n)*$"
  47 let multiline_RE = Pcre.regexp "^\n[^\n]+$"
  48 let newline_RE = Pcre.regexp "\n"
  49 let comment_RE = Pcre.regexp "\\(\\*(.|\n)*\\*\\)\n?" ~flags:[`UNGREEDY]
  50
  51 let comment str =
  52   if Pcre.pmatch ~rex:multiline_RE str then
  53     "\n(** " ^ (Pcre.replace ~rex:newline_RE str) ^ " *)"
  54   else
  55     "\n(**\n" ^ str ^ "\n*)"
  56
  57 let strip_comments str =
  58   Pcre.qreplace ~templ:"\n" ~pat:"\n\n" (Pcre.qreplace ~rex:comment_RE str)
  59 ;;
  60
  61 let first_line s =
  62   let s = Pcre.replace ~rex:heading_nl_RE s in
  63   try
  64     let nl_pos = String.index s '\n' in
  65     String.sub s 0 nl_pos
  66   with Not_found -> s
  67
  68 let eval_with_engine include_paths status skipped_txt nonskipped_txt st
  69 =
  70   let parsed_text_length =
  71     String.length skipped_txt + String.length nonskipped_txt
  72   in
  73   let text = skipped_txt ^ nonskipped_txt in
  74   let prefix_len = MatitaGtkMisc.utf8_string_length skipped_txt in
  75   let enriched_history_fragment =
  76    MatitaEngine.eval_ast ~include_paths ~do_heavy_checks:(Helm_registry.get_bool
  77      "matita.do_heavy_checks")
  78     status (text,prefix_len,st)
  79   in
  80   let enriched_history_fragment = List.rev enriched_history_fragment in
  81   (* really fragile *)
  82   let res,_ =
  83     List.fold_left
  84       (fun (acc, to_prepend) (status,alias) ->
  85        match alias with
  86        | None -> (status,to_prepend ^ nonskipped_txt)::acc,""
  87        | Some (k,value) ->
  88             let newtxt = GrafiteAstPp.pp_alias value in
  89             (status,to_prepend ^ newtxt ^ "\n")::acc, "")
  90       ([],skipped_txt) enriched_history_fragment
  91   in
  92   res,"",parsed_text_length
  93 ;;
  94
  95 let pp_eager_statement_ast = GrafiteAstPp.pp_statement
  96
  97 let eval_nmacro include_paths (buffer : GText.buffer) status unparsed_text parsed_text script mac =
  98   let parsed_text_length = String.length parsed_text in
  99   match mac with
 100   | TA.Screenshot (_,name) ->
 101        let status = script#status in
 102        let _,_,menv,subst,_ = status#obj in
 103        let name = Filename.dirname (script#filename) ^ "/" ^ name in
 104        let sequents =
 105          let selected = Continuationals.Stack.head_goals status#stack in
 106          List.filter (fun x,_ -> List.mem x selected) menv
 107        in
 108        CicMathView.screenshot status sequents menv subst name;
 109        [status, parsed_text], "", parsed_text_length
 110   | TA.NCheck (_,t) ->
 111       let status = script#status in
 112       let _,_,menv,subst,_ = status#obj in
 113       let ctx =
 114        match Continuationals.Stack.head_goals status#stack with
 115           [] -> []
 116         | g::tl ->
 117            if tl <> [] then
 118             HLog.warn
 119              "Many goals focused. Using the context of the first one\n";
 120            let _, ctx, _ = NCicUtils.lookup_meta g menv in
 121             ctx in
 122       let m, s, status, t =
 123         GrafiteDisambiguate.disambiguate_nterm
 124           status None ctx menv subst (parsed_text,parsed_text_length,
 125             NotationPt.Cast (t,NotationPt.Implicit `JustOne))
 126           (* XXX use the metasenv, if possible *)
 127       in
 128       MatitaMathView.cicBrowser (Some (`NCic (t,ctx,m,s)));
 129       [status, parsed_text], "", parsed_text_length
 130   | TA.NIntroGuess _loc ->
 131       let names_ref = ref [] in
 132       let s = NTactics.intros_tac ~names_ref [] script#status in
 133       let rex = Pcre.regexp ~flags:[`MULTILINE] "\\A([\\n\\t\\r ]*).*\\Z" in
 134       let nl = Pcre.replace ~rex ~templ:"$1" parsed_text in
 135       [s, nl ^ "#" ^ String.concat " " !names_ref ^ ";"], "", parsed_text_length
 136   | TA.NAutoInteractive (_loc, (None,a)) ->
 137       let trace_ref = ref [] in
 138       let s = NnAuto.auto_tac ~params:(None,a) ~trace_ref script#status in
 139       let depth =
 140         try List.assoc "depth" a
 141         with Not_found -> ""
 142       in
 143       let trace = "/"^(if int_of_string depth > 1 then depth else "")^"/ by " in
 144       let thms =
 145         match !trace_ref with
 146         | [] -> "{}"
 147         | thms ->
 148            String.concat ", "
 149              (HExtlib.filter_map (function
 150                | NotationPt.NRef r -> Some (NCicPp.r2s status true r)
 151                | _ -> None)
 152              thms)
 153       in
 154       let rex = Pcre.regexp ~flags:[`MULTILINE] "\\A([\\n\\t\\r ]*).*\\Z" in
 155       let nl = Pcre.replace ~rex ~templ:"$1" parsed_text in
 156       [s, nl ^ trace ^ thms ^ ";"], "", parsed_text_length
 157   | TA.NAutoInteractive (_, (Some _,_)) -> assert false
 158
 159 let rec eval_executable include_paths (buffer : GText.buffer)
 160 status unparsed_text skipped_txt nonskipped_txt script ex loc
 161 =
 162   try
 163    ignore (buffer#move_mark (`NAME "beginning_of_statement")
 164     ~where:((buffer#get_iter_at_mark (`NAME "locked"))#forward_chars
 165        (Glib.Utf8.length skipped_txt))) ;
 166    eval_with_engine include_paths status skipped_txt nonskipped_txt
 167     (TA.Executable (loc, ex))
 168   with
 169      MatitaTypes.Cancel -> [], "", 0
 170    | GrafiteEngine.NMacro (_loc,macro) ->
 171        eval_nmacro include_paths buffer status
 172         unparsed_text (skipped_txt ^ nonskipped_txt) script macro
 173
 174
 175 and eval_statement include_paths (buffer : GText.buffer) status script
 176  statement
 177 =
 178   let st,unparsed_text =
 179     match statement with
 180     | `Raw text ->
 181         if Pcre.pmatch ~rex:only_dust_RE text then raise Margin;
 182         let strm =
 183          GrafiteParser.parsable_statement status
 184           (Ulexing.from_utf8_string text) in
 185         let ast = MatitaEngine.get_ast status include_paths strm in
 186          ast, text
 187     | `Ast (st, text) -> st, text
 188   in
 189   let text_of_loc floc =
 190     let nonskipped_txt,_ = MatitaGtkMisc.utf8_parsed_text unparsed_text floc in
 191     let start, stop = HExtlib.loc_of_floc floc in
 192     let floc = HExtlib.floc_of_loc (0, start) in
 193     let skipped_txt,_ = MatitaGtkMisc.utf8_parsed_text unparsed_text floc in
 194     let floc = HExtlib.floc_of_loc (0, stop) in
 195     let txt,len = MatitaGtkMisc.utf8_parsed_text unparsed_text floc in
 196     txt,nonskipped_txt,skipped_txt,len
 197   in
 198   match st with
 199   | GrafiteAst.Executable (loc, ex) ->
 200      let _, nonskipped, skipped, parsed_text_length = text_of_loc loc in
 201       eval_executable include_paths buffer status unparsed_text
 202        skipped nonskipped script ex loc
 203   | GrafiteAst.Comment (loc, GrafiteAst.Code (_, ex))
 204     when Helm_registry.get_bool "matita.execcomments" ->
 205      let _, nonskipped, skipped, parsed_text_length = text_of_loc loc in
 206       eval_executable include_paths buffer status unparsed_text
 207        skipped nonskipped script ex loc
 208   | GrafiteAst.Comment (loc, _) ->
 209       let parsed_text, _, _, parsed_text_length = text_of_loc loc in
 210       let remain_len = String.length unparsed_text - parsed_text_length in
 211       let s = String.sub unparsed_text parsed_text_length remain_len in
 212       let s,text,len =
 213        try
 214         eval_statement include_paths buffer status script (`Raw s)
 215        with
 216           HExtlib.Localized (floc, exn) ->
 217            HExtlib.raise_localized_exception
 218              ~offset:(MatitaGtkMisc.utf8_string_length parsed_text) floc exn
 219         | MultiPassDisambiguator.DisambiguationError (offset,errorll) ->
 220            raise
 221             (MultiPassDisambiguator.DisambiguationError
 222               (offset+parsed_text_length, errorll))
 223       in
 224       assert (text=""); (* no macros inside comments, please! *)
 225       (match s with
 226       | (statuses,text)::tl ->
 227          (statuses,parsed_text ^ text)::tl,"",parsed_text_length + len
 228       | [] -> [], "", 0)
 229
 230 let fresh_script_id =
 231   let i = ref 0 in
 232   fun () -> incr i; !i
 233
 234 (** Selection handling
 235  * Two clipboards are used: "clipboard" and "primary".
 236  * "primary" is used by X, when you hit the middle button mouse is content is
 237  *    pasted between applications. In Matita this selection always contain the
 238  *    textual version of the selected term.
 239  * "clipboard" is used inside Matita only and support ATM two different targets:
 240  *    "TERM" and "PATTERN", in the future other targets like "MATHMLCONTENT" may
 241  *    be added
 242  *)
 243 class script ~(parent:GBin.scrolled_window) ~tab_label () =
 244 let source_view =
 245   GSourceView2.source_view
 246     ~auto_indent:true
 247     ~insert_spaces_instead_of_tabs:true ~tab_width:2
 248     ~right_margin_position:80 ~show_right_margin:true
 249     ~smart_home_end:`AFTER
 250     ~packing:parent#add
 251     () in
 252 let buffer = source_view#buffer in
 253 let source_buffer = source_view#source_buffer in
 254 let similarsymbols_tag_name = "similarsymbolos" in
 255 let similarsymbols_tag = `NAME similarsymbols_tag_name in
 256 let initial_statuses current baseuri =
 257  let status = new MatitaEngine.status baseuri in
 258  (match current with
 259      Some current ->
 260       NCicLibrary.time_travel status;
 261 (*
 262       (* MATITA 1.0: there is a known bug in invalidation; temporary fix here *)
 263       NCicEnvironment.invalidate () *)
 264    | None -> ());
 265   status
 266 in
 267 let read_include_paths file =
 268  try
 269    let root, _buri, _fname, _tgt =
 270      Librarian.baseuri_of_script ~include_paths:[] file in
 271    let includes =
 272     try
 273      Str.split (Str.regexp " ")
 274       (List.assoc "include_paths" (Librarian.load_root_file (root^"/root")))
 275     with Not_found -> []
 276    in
 277    let rc = root :: includes in
 278     List.iter (HLog.debug) rc; rc
 279  with Librarian.NoRootFor _ | Librarian.FileNotFound _ ->
 280   []
 281 in
 282 let default_buri = "cic:/matita/tests" in
 283 let default_fname = ".unnamed.ma" in
 284 object (self)
 285   val mutable include_paths_ = []
 286   val clipboard = GData.clipboard Gdk.Atom.clipboard
 287   (*val primary = GData.clipboard Gdk.Atom.primary*)
 288   val mutable similarsymbols = []
 289   val mutable similarsymbols_orig = []
 290   val similar_memory = Hashtbl.create 97
 291   val mutable old_used_memory = false
 292
 293   val scriptId = fresh_script_id ()
 294
 295   val mutable filename_ = (None : string option)
 296
 297   method has_name = filename_ <> None
 298
 299   method source_view = source_view
 300
 301   method include_paths =
 302     include_paths_ @
 303     Helm_registry.get_list Helm_registry.string "matita.includes"
 304
 305   method private curdir =
 306     try
 307      let root, _buri, _fname, _tgt =
 308       Librarian.baseuri_of_script ~include_paths:self#include_paths
 309        self#filename
 310      in
 311      root
 312     with Librarian.NoRootFor _ -> Sys.getcwd ()
 313
 314   method buri_of_current_file =
 315     match filename_ with
 316     | None -> default_buri
 317     | Some f ->
 318         try
 319           let _root, buri, _fname, _tgt =
 320             Librarian.baseuri_of_script ~include_paths:self#include_paths f
 321           in
 322           buri
 323         with Librarian.NoRootFor _ | Librarian.FileNotFound _ -> default_buri
 324
 325   method filename = match filename_ with None -> default_fname | Some f -> f
 326
 327   initializer
 328     ignore
 329      (source_view#source_buffer#begin_not_undoable_action ();
 330       self#reset ();
 331       self#template ();
 332       source_view#source_buffer#end_not_undoable_action ());
 333     MatitaMisc.observe_font_size (fun font_size ->
 334      source_view#misc#modify_font_by_name
 335         (sprintf "%s %d" BuildTimeConf.script_font font_size));
 336     source_view#misc#grab_focus ();
 337     ignore(source_view#source_buffer#set_language
 338      (Some MatitaGtkMisc.matita_lang));
 339     ignore(source_view#source_buffer#set_highlight_syntax true);
 340     ignore(source_view#connect#after#paste_clipboard
 341         ~callback:(fun () -> self#clean_dirty_lock));
 342     ignore (GMain.Timeout.add ~ms:300000
 343        ~callback:(fun _ -> self#_saveToBackupFile ();true));
 344     ignore (buffer#connect#modified_changed
 345       (fun _ -> self#set_star buffer#modified));
 346     (* clean_locked is set to true only "during" a PRIMARY paste
 347        operation (i.e. by clicking with the second mouse button) *)
 348     let clean_locked = ref false in
 349     ignore(source_view#event#connect#button_press
 350       ~callback:
 351         (fun button ->
 352           if GdkEvent.Button.button button = 2 then
 353            clean_locked := true;
 354           false
 355         ));
 356     ignore(source_view#event#connect#button_release
 357       ~callback:(fun button -> clean_locked := false; false));
 358     ignore(source_view#buffer#connect#after#apply_tag
 359      ~callback:(
 360        fun tag ~start:_ ~stop:_ ->
 361         if !clean_locked &&
 362            tag#get_oid = self#locked_tag#get_oid
 363         then
 364          begin
 365           clean_locked := false;
 366           self#clean_dirty_lock;
 367           clean_locked := true
 368          end));
 369     ignore(source_view#source_buffer#connect#after#insert_text
 370      ~callback:(fun iter str ->
 371         if (MatitaMisc.get_gui ())#main#menuitemAutoAltL#active && (str = " " || str = "\n") then
 372           ignore(self#expand_virtual_if_any iter str)));
 373     ignore(source_view#connect#after#populate_popup
 374      ~callback:(fun pre_menu ->
 375        let menu = new GMenu.menu pre_menu in
 376        let menuItems = menu#children in
 377        let undoMenuItem, redoMenuItem =
 378         match menuItems with
 379            [undo;redo;sep1;cut;copy;paste;delete;sep2;
 380             selectall;sep3;inputmethod;insertunicodecharacter] ->
 381               List.iter menu#remove [ copy; cut; delete; paste ];
 382               undo,redo
 383          | _ -> assert false in
 384        let add_menu_item =
 385          let i = ref 2 in (* last occupied position *)
 386          fun ?label ?stock () ->
 387            incr i;
 388            GMenu.image_menu_item ?label ?stock ~packing:(menu#insert ~pos:!i)
 389             ()
 390        in
 391        let copy = add_menu_item ~stock:`COPY () in
 392        let cut = add_menu_item ~stock:`CUT () in
 393        let delete = add_menu_item ~stock:`DELETE () in
 394        let paste = add_menu_item ~stock:`PASTE () in
 395        let paste_pattern = add_menu_item ~label:"Paste as pattern" () in
 396        copy#misc#set_sensitive self#canCopy;
 397        cut#misc#set_sensitive self#canCut;
 398        delete#misc#set_sensitive self#canDelete;
 399        paste#misc#set_sensitive self#canPaste;
 400        paste_pattern#misc#set_sensitive self#canPastePattern;
 401        MatitaGtkMisc.connect_menu_item copy self#copy;
 402        MatitaGtkMisc.connect_menu_item cut self#cut;
 403        MatitaGtkMisc.connect_menu_item delete self#delete;
 404        MatitaGtkMisc.connect_menu_item paste self#paste;
 405        MatitaGtkMisc.connect_menu_item paste_pattern self#pastePattern;
 406        let new_undoMenuItem =
 407         GMenu.image_menu_item
 408          ~image:(GMisc.image ~stock:`UNDO ())
 409          ~use_mnemonic:true
 410          ~label:"_Undo"
 411          ~packing:(menu#insert ~pos:0) () in
 412        new_undoMenuItem#misc#set_sensitive
 413         (undoMenuItem#misc#get_flag `SENSITIVE);
 414        menu#remove (undoMenuItem :> GMenu.menu_item);
 415        MatitaGtkMisc.connect_menu_item new_undoMenuItem
 416         (fun () -> self#safe_undo);
 417        let new_redoMenuItem =
 418         GMenu.image_menu_item
 419          ~image:(GMisc.image ~stock:`REDO ())
 420          ~use_mnemonic:true
 421          ~label:"_Redo"
 422          ~packing:(menu#insert ~pos:1) () in
 423        new_redoMenuItem#misc#set_sensitive
 424         (redoMenuItem#misc#get_flag `SENSITIVE);
 425         menu#remove (redoMenuItem :> GMenu.menu_item);
 426         MatitaGtkMisc.connect_menu_item new_redoMenuItem
 427          (fun () -> self#safe_redo)));
 428
 429   val mutable statements = []    (** executed statements *)
 430
 431   val mutable history = [ initial_statuses None default_buri ]
 432     (** list of states before having executed statements. Head element of this
 433       * list is the current state, last element is the state at the beginning of
 434       * the script.
 435       * Invariant: this list length is 1 + length of statements *)
 436
 437   (** text mark and tag representing locked part of a script *)
 438   val locked_mark =
 439     buffer#create_mark ~name:"locked" ~left_gravity:true buffer#start_iter
 440   val beginning_of_statement_mark =
 441     buffer#create_mark ~name:"beginning_of_statement"
 442      ~left_gravity:true buffer#start_iter
 443   val locked_tag = buffer#create_tag [`BACKGROUND "lightblue"; `EDITABLE false]
 444   val error_tag = buffer#create_tag [`UNDERLINE `SINGLE; `FOREGROUND "red"]
 445
 446   (** unicode handling *)
 447   method nextSimilarSymbol =
 448     let write_similarsymbol s =
 449       let s = Glib.Utf8.from_unichar s in
 450       let iter = source_view#source_buffer#get_iter_at_mark `INSERT in
 451       assert(Glib.Utf8.validate s);
 452       source_view#source_buffer#delete ~start:iter ~stop:(iter#copy#backward_chars 1);
 453       source_view#source_buffer#insert ~iter:(source_view#source_buffer#get_iter_at_mark `INSERT) s;
 454       (try source_view#source_buffer#delete_mark similarsymbols_tag
 455        with GText.No_such_mark _ -> ());
 456       ignore(source_view#source_buffer#create_mark ~name:similarsymbols_tag_name
 457         (source_view#source_buffer#get_iter_at_mark `INSERT));
 458     in
 459     let new_similarsymbol =
 460       try
 461         let iter_ins = source_view#source_buffer#get_iter_at_mark `INSERT in
 462         let iter_lig = source_view#source_buffer#get_iter_at_mark similarsymbols_tag in
 463         not (iter_ins#equal iter_lig)
 464       with GText.No_such_mark _ -> true
 465     in
 466     if new_similarsymbol then
 467       (if not(self#expand_virtual_if_any (source_view#source_buffer#get_iter_at_mark `INSERT) "")then
 468         let last_symbol =
 469           let i = source_view#source_buffer#get_iter_at_mark `INSERT in
 470           Glib.Utf8.first_char (i#get_slice ~stop:(i#copy#backward_chars 1))
 471         in
 472         (match Virtuals.similar_symbols last_symbol with
 473         | [] ->  ()
 474         | eqclass ->
 475             similarsymbols_orig <- eqclass;
 476             let is_used =
 477               try Hashtbl.find similar_memory similarsymbols_orig
 478               with Not_found ->
 479                 let is_used = List.map (fun x -> x,false) eqclass in
 480                 Hashtbl.add similar_memory eqclass is_used;
 481                 is_used
 482             in
 483             let hd, next, tl =
 484               let used, unused =
 485                 List.partition (fun s -> List.assoc s is_used) eqclass
 486               in
 487               match used @ unused with a::b::c -> a,b,c | _ -> assert false
 488             in
 489             let hd, tl =
 490               if hd = last_symbol then next, tl @ [hd] else hd, (next::tl)
 491             in
 492             old_used_memory <- List.assoc hd is_used;
 493             let is_used =
 494               (hd,true) :: List.filter (fun (x,_) -> x <> hd) is_used
 495             in
 496             Hashtbl.replace similar_memory similarsymbols_orig is_used;
 497             write_similarsymbol hd;
 498             similarsymbols <- tl @ [ hd ]))
 499     else
 500       match similarsymbols with
 501       | [] -> ()
 502       | hd :: tl ->
 503           let is_used = Hashtbl.find similar_memory similarsymbols_orig in
 504           let last = HExtlib.list_last tl in
 505           let old_used_for_last = old_used_memory in
 506           old_used_memory <- List.assoc hd is_used;
 507           let is_used =
 508             (hd, true) :: (last,old_used_for_last) ::
 509               List.filter (fun (x,_) -> x <> last && x <> hd) is_used
 510           in
 511           Hashtbl.replace similar_memory similarsymbols_orig is_used;
 512           similarsymbols <- tl @ [ hd ];
 513           write_similarsymbol hd
 514
 515   method private reset_similarsymbols =
 516    similarsymbols <- [];
 517    similarsymbols_orig <- [];
 518    try source_view#source_buffer#delete_mark similarsymbols_tag
 519    with GText.No_such_mark _ -> ()
 520
 521   method private expand_virtual_if_any iter tok =
 522     try
 523      let len = MatitaGtkMisc.utf8_string_length tok in
 524      let last_word =
 525       let prev = iter#copy#backward_chars len in
 526        prev#get_slice ~stop:(prev#copy#backward_find_char
 527         (fun x -> Glib.Unichar.isspace x || x = Glib.Utf8.first_char "\\"))
 528      in
 529      let inplaceof, symb = Virtuals.symbol_of_virtual last_word in
 530      self#reset_similarsymbols;
 531      let s = Glib.Utf8.from_unichar symb in
 532      assert(Glib.Utf8.validate s);
 533      source_view#source_buffer#delete ~start:iter
 534        ~stop:(iter#copy#backward_chars
 535          (MatitaGtkMisc.utf8_string_length inplaceof + len));
 536      source_view#source_buffer#insert ~iter
 537        (if inplaceof.[0] = '\\' then s else (s ^ tok));
 538      true
 539     with Virtuals.Not_a_virtual -> false
 540
 541   (** selections / clipboards handling *)
 542
 543   method markupSelected = MatitaMathView.has_selection ()
 544   method private textSelected =
 545     (source_view#source_buffer#get_iter_at_mark `INSERT)#compare
 546       (source_view#source_buffer#get_iter_at_mark `SEL_BOUND) <> 0
 547   method private markupStored = MatitaMathView.has_clipboard ()
 548   method private textStored = clipboard#text <> None
 549   method canCopy = self#textSelected
 550   method canCut = self#textSelected
 551   method canDelete = self#textSelected
 552   (*CSC: WRONG CODE: we should look in the clipboard instead! *)
 553   method canPaste = self#markupStored || self#textStored
 554   method canPastePattern = self#markupStored
 555
 556   method safe_undo =
 557    (* phase 1: we save the actual status of the marks and we undo *)
 558    let locked_mark = `MARK (self#locked_mark) in
 559    let locked_iter = source_view#buffer#get_iter_at_mark locked_mark in
 560    let locked_iter_offset = locked_iter#offset in
 561    let mark2 =
 562     `MARK
 563       (source_view#buffer#create_mark ~name:"lock_point"
 564         ~left_gravity:true locked_iter) in
 565    source_view#source_buffer#undo ();
 566    (* phase 2: we save the cursor position and we redo, restoring
 567       the previous status of all the marks *)
 568    let cursor_iter = source_view#buffer#get_iter_at_mark `INSERT in
 569    let mark =
 570     `MARK
 571       (source_view#buffer#create_mark ~name:"undo_point"
 572         ~left_gravity:true cursor_iter)
 573    in
 574     source_view#source_buffer#redo ();
 575     let mark_iter = source_view#buffer#get_iter_at_mark mark in
 576     let mark2_iter = source_view#buffer#get_iter_at_mark mark2 in
 577     let mark2_iter = mark2_iter#set_offset locked_iter_offset in
 578      source_view#buffer#move_mark locked_mark ~where:mark2_iter;
 579      source_view#buffer#delete_mark mark;
 580      source_view#buffer#delete_mark mark2;
 581      (* phase 3: if after the undo the cursor was in the locked area,
 582         then we move it there again and we perform a goto *)
 583      if mark_iter#offset < locked_iter_offset then
 584       begin
 585        source_view#buffer#move_mark `INSERT ~where:mark_iter;
 586        self#goto `Cursor ();
 587       end;
 588      (* phase 4: we perform again the undo. This time we are sure that
 589         the text to undo is not locked *)
 590      source_view#source_buffer#undo ();
 591      source_view#misc#grab_focus ()
 592
 593   method safe_redo =
 594    (* phase 1: we save the actual status of the marks, we redo and
 595       we undo *)
 596    let locked_mark = `MARK (self#locked_mark) in
 597    let locked_iter = source_view#buffer#get_iter_at_mark locked_mark in
 598    let locked_iter_offset = locked_iter#offset in
 599    let mark2 =
 600     `MARK
 601       (source_view#buffer#create_mark ~name:"lock_point"
 602         ~left_gravity:true locked_iter) in
 603    source_view#source_buffer#redo ();
 604    source_view#source_buffer#undo ();
 605    (* phase 2: we save the cursor position and we restore
 606       the previous status of all the marks *)
 607    let cursor_iter = source_view#buffer#get_iter_at_mark `INSERT in
 608    let mark =
 609     `MARK
 610       (source_view#buffer#create_mark ~name:"undo_point"
 611         ~left_gravity:true cursor_iter)
 612    in
 613     let mark_iter = source_view#buffer#get_iter_at_mark mark in
 614     let mark2_iter = source_view#buffer#get_iter_at_mark mark2 in
 615     let mark2_iter = mark2_iter#set_offset locked_iter_offset in
 616      source_view#buffer#move_mark locked_mark ~where:mark2_iter;
 617      source_view#buffer#delete_mark mark;
 618      source_view#buffer#delete_mark mark2;
 619      (* phase 3: if after the undo the cursor is in the locked area,
 620         then we move it there again and we perform a goto *)
 621      if mark_iter#offset < locked_iter_offset then
 622       begin
 623        source_view#buffer#move_mark `INSERT ~where:mark_iter;
 624        self#goto `Cursor ();
 625       end;
 626      (* phase 4: we perform again the redo. This time we are sure that
 627         the text to redo is not locked *)
 628      source_view#source_buffer#redo ();
 629      source_view#misc#grab_focus ()
 630
 631
 632   method copy () =
 633    if self#textSelected
 634    then begin
 635      MatitaMathView.empty_clipboard ();
 636      source_view#buffer#copy_clipboard clipboard;
 637    end else
 638      MatitaMathView.copy_selection ()
 639
 640   method cut () =
 641    source_view#buffer#cut_clipboard clipboard;
 642    MatitaMathView.empty_clipboard ()
 643
 644   method delete () =
 645    ignore (source_view#buffer#delete_selection ())
 646
 647   method paste () =
 648     if MatitaMathView.has_clipboard ()
 649     then source_view#buffer#insert (MatitaMathView.paste_clipboard `Term)
 650     else source_view#buffer#paste_clipboard clipboard;
 651     self#clean_dirty_lock
 652
 653   method pastePattern () =
 654     source_view#buffer#insert (MatitaMathView.paste_clipboard `Pattern)
 655
 656   method locked_mark = locked_mark
 657   method locked_tag = locked_tag
 658   method error_tag = error_tag
 659
 660     (* history can't be empty, the invariant above grant that it contains at
 661      * least the init grafite_status *)
 662   method status = match history with s::_ -> s | _ -> assert false
 663
 664   method private _advance ?statement () =
 665    let s = match statement with Some s -> s | None -> self#getFuture in
 666    if self#bos then LibraryClean.clean_baseuris [self#buri_of_current_file];
 667    HLog.debug ("evaluating: " ^ first_line s ^ " ...");
 668    let time1 = Unix.gettimeofday () in
 669    let entries, newtext, parsed_len =
 670     try
 671      eval_statement self#include_paths buffer self#status self (`Raw s)
 672     with End_of_file -> raise Margin
 673    in
 674    let time2 = Unix.gettimeofday () in
 675    HLog.debug ("... done in " ^ string_of_float (time2 -. time1) ^ "s");
 676    let new_statuses, new_statements =
 677      let statuses, texts = List.split entries in
 678      statuses, texts
 679    in
 680    history <- new_statuses @ history;
 681    statements <- new_statements @ statements;
 682    let start = buffer#get_iter_at_mark (`MARK locked_mark) in
 683    let new_text = String.concat "" (List.rev new_statements) in
 684    if statement <> None then
 685      buffer#insert ~iter:start new_text
 686    else begin
 687      let parsed_text = String.sub s 0 parsed_len in
 688      if new_text <> parsed_text then begin
 689        let stop = start#copy#forward_chars (Glib.Utf8.length parsed_text) in
 690        buffer#delete ~start ~stop;
 691        buffer#insert ~iter:start new_text;
 692      end;
 693    end;
 694    self#moveMark (Glib.Utf8.length new_text);
 695    buffer#insert ~iter:(buffer#get_iter_at_mark (`MARK locked_mark)) newtext
 696
 697   method private _retract offset status new_statements new_history =
 698     NCicLibrary.time_travel status;
 699     statements <- new_statements;
 700     history <- new_history;
 701     self#moveMark (- offset)
 702
 703   method advance ?statement () =
 704     try
 705       self#_advance ?statement ();
 706       self#notify
 707     with
 708     | Margin -> self#notify
 709     | Not_found -> assert false
 710     | Invalid_argument "Array.make" -> HLog.error "The script is too big!\n"
 711     | exc -> self#notify; raise exc
 712
 713   method retract () =
 714     try
 715       let cmp,new_statements,new_history,status =
 716        match statements,history with
 717           stat::statements, _::(status::_ as history) ->
 718            assert (Glib.Utf8.validate stat);
 719            Glib.Utf8.length stat, statements, history, status
 720        | [],[_] -> raise Margin
 721        | _,_ -> assert false
 722       in
 723        self#_retract cmp status new_statements new_history;
 724        self#notify
 725     with
 726     | Margin -> self#notify
 727     | Invalid_argument "Array.make" -> HLog.error "The script is too big!\n"
 728     | exc -> self#notify; raise exc
 729
 730   method private getFuture =
 731     let lock = buffer#get_iter_at_mark (`MARK locked_mark) in
 732     let text = buffer#get_text ~start:lock ~stop:buffer#end_iter () in
 733     text
 734
 735   method expandAllVirtuals =
 736     let lock = buffer#get_iter_at_mark (`MARK locked_mark) in
 737     let text = buffer#get_text ~start:lock ~stop:buffer#end_iter () in
 738     buffer#delete ~start:lock ~stop:buffer#end_iter;
 739     let text = Pcre.replace ~pat:":=" ~templ:"\\def" text in
 740     let text = Pcre.replace ~pat:"->" ~templ:"\\to" text in
 741     let text = Pcre.replace ~pat:"=>" ~templ:"\\Rightarrow" text in
 742     let text =
 743       Pcre.substitute_substrings
 744         ~subst:(fun str ->
 745            let pristine = Pcre.get_substring str 0 in
 746            let input =
 747              if pristine.[0] = ' ' then
 748                String.sub pristine 1 (String.length pristine -1)
 749              else pristine
 750            in
 751            let input =
 752              if input.[String.length input-1] = ' ' then
 753                String.sub input 0 (String.length input -1)
 754              else input
 755            in
 756            let before, after =
 757              if input = "\\forall" ||
 758                 input = "\\lambda" ||
 759                 input = "\\exists" then "","" else " ", " "
 760            in
 761            try
 762              before ^ Glib.Utf8.from_unichar
 763                (snd (Virtuals.symbol_of_virtual input)) ^ after
 764            with Virtuals.Not_a_virtual -> pristine)
 765         ~pat:" ?\\\\[a-zA-Z]+ ?" text
 766     in
 767     buffer#insert ~iter:lock text
 768
 769   (** @param rel_offset relative offset from current position of locked_mark *)
 770   method private moveMark rel_offset =
 771     let mark = `MARK locked_mark in
 772     let old_insert = buffer#get_iter_at_mark `INSERT in
 773     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 774     let current_mark_pos = buffer#get_iter_at_mark mark in
 775     let new_mark_pos =
 776       match rel_offset with
 777       | 0 -> current_mark_pos
 778       | n when n > 0 -> current_mark_pos#forward_chars n
 779       | n (* when n < 0 *) -> current_mark_pos#backward_chars (abs n)
 780     in
 781     buffer#move_mark mark ~where:new_mark_pos;
 782     buffer#apply_tag locked_tag ~start:buffer#start_iter ~stop:new_mark_pos;
 783     buffer#move_mark `INSERT old_insert;
 784     let mark_position = buffer#get_iter_at_mark mark in
 785     if source_view#move_mark_onscreen mark then
 786      begin
 787       buffer#move_mark mark mark_position;
 788       source_view#scroll_to_mark ~use_align:true ~xalign:1.0 ~yalign:0.1 mark;
 789      end;
 790     while Glib.Main.pending () do ignore(Glib.Main.iteration false); done
 791
 792   method clean_dirty_lock =
 793     let lock_mark_iter = buffer#get_iter_at_mark (`MARK locked_mark) in
 794     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 795     buffer#apply_tag locked_tag ~start:buffer#start_iter ~stop:lock_mark_iter
 796
 797   val mutable observers = []
 798
 799   method addObserver (o: GrafiteTypes.status -> unit) =
 800     observers <- o :: observers
 801
 802   method private notify =
 803     let status = self#status in
 804     List.iter (fun o -> o status) observers
 805
 806   method activate =
 807     self#notify
 808
 809   method loadFromFile f =
 810     buffer#set_text (HExtlib.input_file f);
 811     self#reset_buffer;
 812     buffer#set_modified false
 813
 814   method assignFileName file =
 815    match file with
 816       None ->
 817        tab_label#set_text default_fname;
 818        filename_ <- None;
 819        include_paths_ <- [];
 820        self#reset_buffer
 821     | Some file ->
 822        let f = Librarian.absolutize file in
 823         tab_label#set_text (Filename.basename f);
 824         filename_ <- Some f;
 825         include_paths_ <- read_include_paths f;
 826         self#reset_buffer
 827
 828   method set_star b =
 829    tab_label#set_text ((if b then "*" else "")^Filename.basename self#filename);
 830    tab_label#misc#set_tooltip_text
 831     ("URI: " ^ self#buri_of_current_file ^ "\nPATH: " ^ self#filename);
 832
 833   method saveToFile () =
 834     if self#has_name then
 835       let oc = open_out self#filename in
 836       output_string oc (buffer#get_text ~start:buffer#start_iter
 837                         ~stop:buffer#end_iter ());
 838       close_out oc;
 839       self#set_star false;
 840       buffer#set_modified false
 841     else
 842       HLog.error "Can't save, no filename selected"
 843
 844   method private _saveToBackupFile () =
 845     if buffer#modified then
 846       begin
 847         let f = self#filename in
 848         let oc = open_out f in
 849         output_string oc (buffer#get_text ~start:buffer#start_iter
 850                             ~stop:buffer#end_iter ());
 851         close_out oc;
 852         HLog.debug ("backup " ^ f ^ " saved")
 853       end
 854
 855   method private reset_buffer =
 856     statements <- [];
 857     history <- [ initial_statuses (Some self#status) self#buri_of_current_file ];
 858     self#notify;
 859     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 860     buffer#move_mark (`MARK locked_mark) ~where:buffer#start_iter
 861
 862   method reset () =
 863     self#reset_buffer;
 864     source_buffer#begin_not_undoable_action ();
 865     buffer#delete ~start:buffer#start_iter ~stop:buffer#end_iter;
 866     source_buffer#end_not_undoable_action ();
 867     buffer#set_modified false;
 868
 869   method template () =
 870     let template = HExtlib.input_file BuildTimeConf.script_template in
 871     buffer#insert ~iter:(buffer#get_iter `START) template;
 872     buffer#set_modified false;
 873     self#set_star false;
 874
 875   method goto (pos: [`Top | `Bottom | `Cursor]) () =
 876   try
 877     let old_locked_mark =
 878      `MARK
 879        (buffer#create_mark ~name:"old_locked_mark"
 880          ~left_gravity:true (buffer#get_iter_at_mark (`MARK locked_mark))) in
 881     let getpos _ = buffer#get_iter_at_mark (`MARK locked_mark) in
 882     let getoldpos _ = buffer#get_iter_at_mark old_locked_mark in
 883     let dispose_old_locked_mark () = buffer#delete_mark old_locked_mark in
 884     match pos with
 885     | `Top ->
 886         dispose_old_locked_mark ();
 887         self#reset_buffer;
 888         self#notify
 889     | `Bottom ->
 890         (try
 891           let rec dowhile () =
 892             self#_advance ();
 893             let newpos = getpos () in
 894             if (getoldpos ())#compare newpos < 0 then
 895               begin
 896                 buffer#move_mark old_locked_mark newpos;
 897                 dowhile ()
 898               end
 899           in
 900           dowhile ();
 901           dispose_old_locked_mark ();
 902           self#notify
 903         with
 904         | Margin -> dispose_old_locked_mark (); self#notify
 905         | exc -> dispose_old_locked_mark (); self#notify; raise exc)
 906     | `Cursor ->
 907         let locked_iter () = buffer#get_iter_at_mark (`NAME "locked") in
 908         let cursor_iter () = buffer#get_iter_at_mark `INSERT in
 909         let remember =
 910          `MARK
 911            (buffer#create_mark ~name:"initial_insert"
 912              ~left_gravity:true (cursor_iter ())) in
 913         let dispose_remember () = buffer#delete_mark remember in
 914         let remember_iter () =
 915          buffer#get_iter_at_mark (`NAME "initial_insert") in
 916         let cmp () = (locked_iter ())#offset - (remember_iter ())#offset in
 917         let icmp = cmp () in
 918         let forward_until_cursor () = (* go forward until locked > cursor *)
 919           let rec aux () =
 920             self#_advance ();
 921             if cmp () < 0 && (getoldpos ())#compare (getpos ()) < 0
 922             then
 923              begin
 924               buffer#move_mark old_locked_mark (getpos ());
 925               aux ()
 926              end
 927           in
 928           aux ()
 929         in
 930         let rec back_until_cursor len = (* go backward until locked < cursor *)
 931          function
 932             statements, ((status)::_ as history)
 933             when len <= 0 ->
 934              self#_retract (icmp - len) status statements
 935               history
 936           | statement::tl1, _::tl2 ->
 937              back_until_cursor (len - MatitaGtkMisc.utf8_string_length statement) (tl1,tl2)
 938           | _,_ -> assert false
 939         in
 940         (try
 941           begin
 942            if icmp < 0 then       (* locked < cursor *)
 943              (forward_until_cursor (); self#notify)
 944            else if icmp > 0 then  (* locked > cursor *)
 945              (back_until_cursor icmp (statements,history); self#notify)
 946            else                  (* cursor = locked *)
 947                ()
 948           end ;
 949           dispose_remember ();
 950           dispose_old_locked_mark ();
 951         with
 952         | Margin -> dispose_remember (); dispose_old_locked_mark (); self#notify
 953         | exc -> dispose_remember (); dispose_old_locked_mark ();
 954                  self#notify; raise exc)
 955   with Invalid_argument "Array.make" ->
 956      HLog.error "The script is too big!\n"
 957
 958   method bos =
 959     match history with
 960     | _::[] -> true
 961     | _ -> false
 962
 963   method eos =
 964     let rec is_there_only_comments status s =
 965       if Pcre.pmatch ~rex:only_dust_RE s then raise Margin;
 966       let strm =
 967        GrafiteParser.parsable_statement status
 968         (Ulexing.from_utf8_string s)in
 969       match GrafiteParser.parse_statement status strm with
 970       | GrafiteAst.Comment (loc,_) ->
 971           let _,parsed_text_length = MatitaGtkMisc.utf8_parsed_text s loc in
 972           (* CSC: why +1 in the following lines ???? *)
 973           let parsed_text_length = parsed_text_length + 1 in
 974           let remain_len = String.length s - parsed_text_length in
 975           let next = String.sub s parsed_text_length remain_len in
 976           is_there_only_comments status next
 977       | GrafiteAst.Executable _ -> false
 978     in
 979     try is_there_only_comments self#status self#getFuture
 980     with
 981     | NCicLibrary.IncludedFileNotCompiled _
 982     | HExtlib.Localized _
 983     | CicNotationParser.Parse_error _ -> false
 984     | Margin | End_of_file -> true
 985     | Invalid_argument "Array.make" -> false
 986
 987   (* debug *)
 988   method dump () =
 989     HLog.debug "script status:";
 990     HLog.debug ("history size: " ^ string_of_int (List.length history));
 991     HLog.debug (sprintf "%d statements:" (List.length statements));
 992     List.iter HLog.debug statements;
 993     HLog.debug ("Current file name: " ^ self#filename);
 994
 995   method has_parent (p : GObj.widget) = parent#coerce#misc#get_oid = p#misc#get_oid
 996 end
 997
 998 let _script = ref []
 999
1000 let script ~parent ~tab_label ()
1001 =
1002   let s = new script ~parent ~tab_label () in
1003   _script := s::!_script;
1004   s
1005
1006 let at_page page =
1007  let notebook = (MatitaMisc.get_gui ())#main#scriptNotebook in
1008  let parent = notebook#get_nth_page page in
1009   try
1010    List.find (fun s -> s#has_parent parent) !_script
1011   with
1012    Not_found -> assert false
1013 ;;
1014
1015 let current () =
1016  at_page ((MatitaMisc.get_gui ())#main#scriptNotebook#current_page)
1017
1018 let destroy page =
1019  let s = at_page page in
1020   _script := List.filter ((<>) s) !_script
1021 ;;
1022
1023 let iter_scripts f = List.iter f !_script;;
1024
1025 let _ =
1026  CicMathView.register_matita_script_current (current :> unit -> < advance: ?statement:string -> unit -> unit; status: GrafiteTypes.status >)
1027 ;;