[fireball-separation.git] / ocaml / lambda4.ml

open Util
open Util.Vars
open Pure
open Num

(* exceptions *)
exception Pacman
exception Bottom
exception Lambda
exception Backtrack of string

(* verbosity *)
let _very_verbose = false;;
(** Display measure of every term when printing problem *)
let _measure_of_terms = false;;

let verbose s =
 if _very_verbose then prerr_endline s
;;

let convergent_dummy = `N(-1);;

type discriminating_set = (int * nf) list;;

type problem =
 { freshno: int
 ; div: i_var option (* None = bomb *)
 ; conv: i_n_var list (* the inerts that must converge *)
 ; ps: i_n_var list (* the n-th inert must become n *)
 ; sigma: (int * nf) list (* the computed substitution *)
 ; deltas: discriminating_set ref list (* collection of all branches *)
 ; initialSpecialK: int
 ; label : string
 ; var_names : string list (* names of the original free variables *)

 ; trail: discriminating_set list list
};;

let label_of_problem {label} = label;;

let string_of_var l x =
 try
  List.nth l x
 with Failure "nth" -> "`" ^ string_of_int x
;;
let string_of_term p t = print ~l:p.var_names (t :> nf);;

let first bound p var f =
 let p = {p with trail = (List.map (!) p.deltas)::p.trail} in
 let rec aux i =
  if i > bound then
   raise (Backtrack ("no more alternatives for " ^ string_of_var p.var_names var))
  else
   try
    f p i
   with Backtrack s ->
prerr_endline (">>>>>> BACKTRACK (reason: " ^ s ^") measure=$ ");
     List.iter (fun (r,l) -> r := l) (List.combine p.deltas (List.hd p.trail)) ;
prerr_endline("Now trying var="^string_of_var p.var_names var^" i="^string_of_int (i+1));
     aux (i+1)
 in
  aux 1


let all_terms p =
 (match p.div with None -> [] | Some t -> [(t :> i_n_var)])
 @ p.conv
 @ p.ps
;;

let measure_of_term, measure_of_terms =
 let rec aux = function
 | `N _ | `Bottom | `Pacman -> 0
 | `Var(_,ar) -> if ar = min_int then 0 else max 0 ar (*assert (ar >= 0); ar*)
 | `Lam(_,t) -> aux t
 | `I(v,args) -> aux (`Var v) + aux_many (Listx.to_list args :> nf list)
 | `Match(u,(_,ar),_,_,args) -> aux (u :> nf) + (if ar <= 0 then 0 else ar - 1) + aux_many (args :> nf list)
 and aux_many tms = List.fold_right ((+) ++ aux) tms 0 in
 (fun t -> aux (t :> nf)), (fun l -> aux_many (l :> nf list))
;;

let sum_arities p = measure_of_terms (all_terms p)

let problem_measure p = sum_arities p;;
let string_of_measure = string_of_int;;

let string_of_problem label ({freshno; div; conv; ps; deltas} as p) =
 let aux_measure_terms t = if _measure_of_terms then "(" ^ string_of_int (measure_of_term t) ^ ") " else "" in
 let deltas = String.concat ("\n#  ") (List.map (fun r -> String.concat " <> " (List.map (fun (i,_) -> string_of_int i) !r)) deltas) in
 let l = p.var_names in
 String.concat "\n" ([
  "";
  "# DISPLAY PROBLEM (" ^ label ^ ") " ^ "measure=" ^ string_of_measure (problem_measure p);
  if List.length p.deltas > 1 then (
   "# Discriminating sets (deltas):\n" ^
   "#  " ^ deltas
   ) else "# ";
  "#";
  "$" ^ p.label;
  (match div with None -> "# D" | Some div -> "D " ^ aux_measure_terms div ^ print ~l (div :> nf));
  ]
  @ List.map (fun t -> if t = convergent_dummy then "# C" else "C " ^ aux_measure_terms t ^ print ~l (t :> nf)) conv
  @ List.mapi (fun i t -> string_of_int i ^ " " ^ aux_measure_terms t ^ print ~l (t :> nf)) ps
  @ [""])
;;


let failwithProblem p reason =
 print_endline (string_of_problem "FAIL" p);
 failwith reason
;;

let make_fresh_var p arity =
 let freshno = p.freshno + 1 in
 {p with freshno}, `Var(freshno,arity)
;;

let make_fresh_vars p arities =
 List.fold_right
  (fun arity (p, vars) -> let p, var = make_fresh_var p arity in p, var::vars)
  arities
  (p, [])
;;

let simple_expand_match ps =
 let rec aux_nob level = function
  | #i_num_var as t -> (aux_i_num_var level t :> nf)
  | `Lam(b,t) -> `Lam(b,aux (level+1) t)
  | `Pacman as t -> t
 and aux level = function
  | `Bottom as t -> t
  | #nf_nob as t -> aux_nob level t
 and aux_i_num_var level = function
  | `Match(u,v,bs_lift,bs,args) as torig ->
    let (u : i_num_var) = aux_i_num_var level u in
    bs := List.map (fun (n, x) -> n, aux 0 x) !bs;
    (try
       (match u with
         | #i_n_var as u ->
            let i = index_of ~eq:eta_eq (lift (-level) u) (ps :> nf list) in (* can raise Not_found *)
            let t = cast_to_i_num_var (mk_match (`N i) v bs_lift bs (args :> nf list)) in
            if t <> torig then
             aux_i_num_var level t
            else raise Not_found
         | _ -> raise Not_found)
      with Not_found ->
       cast_to_i_num_var (mk_appl (`Match(u,v,bs_lift,bs,[])) (List.map (aux_nob level) args)))
  | `I(v,args) -> cast_to_i_num_var (mk_appl (`Var v) (List.map (aux_nob level) (Listx.to_list args)))
  | `N _ | `Var _ as t -> t
 in aux_i_num_var 0
;;

let fixpoint f =
 let rec aux x = let x' = f x in if x <> x' then aux x' else x in aux
;;

let rec super_simplify_ps ps =
 fixpoint (List.map (fun x -> cast_to_i_n_var (simple_expand_match ps (x :> i_num_var))))
;;

let rec super_simplify_ps_with_match ps =
 fixpoint (List.map (cast_to_i_num_var ++ (simple_expand_match ps)))
;;

let super_simplify ({div; ps; conv} as p) =
  let ps = super_simplify_ps p.ps p.ps in
  let conv = super_simplify_ps ps p.conv in
  let div = option_map (fun div ->
   let divs = super_simplify_ps p.ps ([div] :> i_n_var list) in
    List.hd divs) div in
  {p with div=option_map cast_to_i_var div; ps; conv}

let cast_to_ps_with_match =
 function
    #i_num_var as y -> (y : i_num_var)
  | `Bottom | `Pacman -> raise (Backtrack "BOT/PAC in ps")
  | t ->
    prerr_endline (print (t :> nf));
    assert false (* algorithm failed *)

let subst_in_problem x inst ({freshno; div; conv; ps; sigma} as p) =
 let len_ps = List.length ps in
(*(let l = Array.to_list (Array.init (freshno + 1) string_of_var) in
prerr_endline ("# INST0: " ^ string_of_var x ^ " := " ^ print ~l inst));*)
 let rec aux_ps ((freshno,acc_ps,acc_new_ps) as acc) =
  function
  | [] -> acc
  | t::todo_ps ->
(*prerr_endline ("EXPAND t:" ^ print (t :> nf));*)
     let t = subst false false x inst (t :> nf) in
(*prerr_endline ("SUBSTITUTED t:" ^ print (t :> nf));*)
     let freshno,new_t,acc_new_ps =
      try
       expand_match (freshno,acc_ps@`Var(max_int/3,-666)::todo_ps,acc_new_ps) t
      with Pacman | Bottom -> raise (Backtrack "Pacman/Bottom in ps")
     in
      aux_ps (freshno,acc_ps@[new_t],acc_new_ps) todo_ps

  (* cut&paste from aux above *)
  and aux_conv ps ((freshno,acc_conv,acc_new_ps) as acc) =
   function
   | [] -> acc
   | t::todo_conv ->
   (*prerr_endline ("EXPAND t:" ^ print (t :> nf));*)
      let t = subst false false x inst (t :> nf) in
(*prerr_endline ("SUBSTITUTED t:" ^ print (t :> nf));*)
      let freshno,new_t,acc_new_ps =
       try
        expand_match (freshno,ps,acc_new_ps) t
       with Pacman | Lambda -> freshno,convergent_dummy,acc_new_ps
          | Bottom -> raise (Backtrack "Bottom in conv") in
      aux_conv ps (freshno,acc_conv@[new_t],acc_new_ps) todo_conv

  (* cut&paste from aux' above *)
  and aux_div ps (freshno,acc_new_ps) =
   function
   | None -> freshno, None, acc_new_ps
   | Some t ->
      let t = subst false false x inst (t :> nf) in
      try
       let freshno,new_t,acc_new_ps = expand_match (freshno,ps,acc_new_ps) t in
        (* backtrack if it is a number or a variable *)
        match new_t with
         | `N _   -> raise (Backtrack "div=`N")
         | `Var _
         | `I _ as new_t -> freshno, Some(new_t), acc_new_ps
      with
       | Bottom -> freshno, None, acc_new_ps
       | Pacman -> raise (Backtrack "div=PAC")

  and expand_match ((freshno,acc_ps,acc_new_ps) as acc) t =
   match t with
   | `Match(u',orig,bs_lift,bs,args) ->
        let freshno,u,acc_new_ps = expand_match acc (u' :> nf) in
        let acc_new_ps,i =
         match u with
         | `N i -> acc_new_ps,i
         | _ ->
            let ps = List.map (fun t -> cast_to_ps_with_match (subst false false x inst (t:> nf))) (acc_ps@acc_new_ps) in
            let super_simplified_ps = super_simplify_ps_with_match ps ps in
(*prerr_endline ("CERCO u:" ^ print (fst u :> nf));
List.iter (fun x -> prerr_endline ("IN: " ^ print (fst x :> nf))) ps;
List.iter (fun x -> prerr_endline ("IN2: " ^ print (fst x :> nf))) super_simplified_ps;*)
            match index_of_opt ~eq:eta_eq super_simplified_ps (u :> i_num_var) with
               Some i -> acc_new_ps, i
             | None -> acc_new_ps@[u], len_ps + List.length acc_new_ps
        in
         let freshno=
          if List.exists (fun (j,_) -> i=j) !bs then
           freshno
          else
           let freshno,v = freshno+1, `Var (freshno+1, -666) in (* make_fresh_var freshno in *)
           bs := !bs @ [i, v] ;
           freshno in
(*prerr_endlie ("t DA RIDURRE:" ^ print (`Match(`N i,arity,bs_lift,bs,args) :> nf) ^ " more_args=" ^ string_of_int more_args);*)
         let t = mk_match (`N i) orig bs_lift bs (args :> nf list) in
(*prerr_endline ("NUOVO t:" ^ print (fst t :> nf) ^ " more_args=" ^ string_of_int (snd t));*)
          expand_match (freshno,acc_ps,acc_new_ps) t
   | `Lam _ -> raise Lambda (* assert false (* algorithm invariant/loose typing *) *)
   | `Bottom -> raise Bottom
   | `Pacman -> raise Pacman
   | #i_n_var as x ->
      let x = simple_expand_match (acc_ps@acc_new_ps) x in
      freshno,cast_to_i_n_var x,acc_new_ps in

 let freshno,old_ps,new_ps = aux_ps (freshno,[],[]) ps in
 let freshno,conv,new_ps = aux_conv old_ps (freshno,[],new_ps) conv in
 let freshno,div,new_ps = aux_div old_ps (freshno,new_ps) (div :> i_num_var option) in

 let ps = List.map cast_to_i_n_var (old_ps @ new_ps) in
 let conv = List.map cast_to_i_n_var conv in
 let p = {p with freshno; div; conv; ps} in
 prerr_endline ("# INST: " ^ string_of_var p.var_names x ^ " := " ^ string_of_term p inst);
 ( (* check if double substituting a variable *)
  if List.exists (fun (x',_) -> x = x') sigma
   then failwithProblem p ("Variable "^ string_of_var p.var_names x ^"replaced twice")
 );
 let p = {p with sigma = sigma@[x,inst]} in
 let p = super_simplify p in
 p
;;

exception TriggerMatchReduction of int;;
exception Dangerous;;

let arity_of arities hd =
 let pos,_,nargs = List.find (fun (_,hd',_) -> hd=hd') arities in
 nargs + if pos = -1 then - 1 else 0
;;

let rec dangerous arities showstoppers =
 function
    `N _
  | `Var _
  | `Lam _
  | `Pacman -> ()
  | `Match(t,_,liftno,bs,args) ->
      (* CSC: XXX partial dependency on the encoding *)
      (match t with
          `N _ -> List.iter (dangerous arities showstoppers) args
        | `Match _ as t -> dangerous arities showstoppers t ; List.iter (dangerous arities showstoppers) args
        | `Var(x,_) -> dangerous_inert arities showstoppers x args 2
        | `I((x,_),args') -> dangerous_inert arities showstoppers x (Listx.to_list args' @ args) 2
      )
  | `I((k,_),args) -> dangerous_inert arities showstoppers k (Listx.to_list args) 0

and dangerous_inert arities showstoppers k args more_args =
 List.iter (dangerous arities showstoppers) args ;
 if List.mem k showstoppers then raise Dangerous else
 try
  let arity = arity_of arities k in
  if List.length args + more_args > arity then raise Dangerous else ()
 with
  Not_found -> ()

(* cut & paste from above *)
let rec dangerous_conv p arities showstoppers =
 function
  | `N _
  | `Var _
  | `Lam _
  | `Pacman -> ()
  | `Match(t,_,liftno,bs,args) -> (
      (* CSC: XXX partial dependency on the encoding *)
       try (match t with
        | `N _ -> List.iter (dangerous_conv p arities showstoppers) args
        | `Match _ as t -> dangerous_conv p arities showstoppers t; List.iter (dangerous_conv p arities showstoppers) args
        | `Var(x,_) -> dangerous_inert_conv p arities showstoppers x [] args 2
        | `I((x,_),args') -> dangerous_inert_conv p arities showstoppers x (Listx.to_list args') args 2
        ) with TriggerMatchReduction x -> (
           match Util.find_opt (fun (n, t) -> if hd_of (List.nth p.ps n) = Some x then Some t else None) !bs with
            | None -> ()
            | Some t -> (
               match t with
                | `Bottom -> raise Dangerous
                | #nf_nob as t -> dangerous_conv p arities showstoppers t
               )
           )
       )
  | `I((k,_),args) -> dangerous_inert_conv p arities showstoppers k (Listx.to_list args) [] 0

and dangerous_inert_conv p arities showstoppers k args match_args more_args =
 let all_args = args @ match_args in
 List.iter (dangerous_conv p arities showstoppers) all_args;
 let all_args = (all_args :> nf list) in
 if List.mem k showstoppers then raise Dangerous else
  try
   let arity = arity_of arities k in
prerr_endline ("dangerous_inert_conv: ar=" ^ string_of_int arity ^ " k="^string_of_var p.var_names k ^ " listlenargs=" ^ (string_of_int (List.length args)) ^ " more_args=" ^ string_of_int more_args);
   if more_args > 0 (* match argument*) && List.length args = arity then raise (TriggerMatchReduction k)
    else if List.length all_args + more_args > arity then raise Dangerous else ()
  with
   Not_found -> ()

(* inefficient algorithm *)
let rec edible p arities showstoppers =
 let rec aux f showstoppers tms = function
   | [] -> showstoppers
   | x::xs when List.exists (fun y -> hd_of x = Some y) showstoppers ->
      (* se la testa di x e' uno show-stopper *)
      let new_showstoppers = sort_uniq (showstoppers @ free_vars (x :> nf)) in
      (* aggiungi tutte le variabili libere di x *)
      if List.length showstoppers <> List.length new_showstoppers then
       aux f new_showstoppers tms tms
      else
       aux f showstoppers tms xs
   | x::xs ->
      match hd_of x with
         None -> aux f showstoppers tms xs
       | Some h ->
          try
           f showstoppers (x :> nf_nob) ;
           aux f showstoppers tms xs
          with
           Dangerous ->
            aux f (sort_uniq (h::showstoppers)) tms tms
  in
   let showstoppers = sort_uniq (aux (dangerous arities) showstoppers p.ps p.ps) in
   let dangerous_conv = sort_uniq (aux (dangerous_conv p arities) showstoppers p.conv p.conv) in

prerr_endline ("dangerous_conv lenght:" ^ string_of_int (List.length dangerous_conv));
prerr_endline (String.concat " " (List.map (string_of_var p.var_names) dangerous_conv));

    let showstoppers' = showstoppers @ dangerous_conv in
    let showstoppers' = sort_uniq (match p.div with
     | None -> showstoppers'
     | Some div ->
       if List.exists ((=) (hd_of_i_var div)) showstoppers'
       then showstoppers' @ free_vars (div :> nf) else showstoppers') in
    if showstoppers <> showstoppers' then edible p arities showstoppers' else showstoppers'
;;

let precompute_edible_data {ps; div} xs =
 let aux t = match t with `Var _ -> 0 | `I(_, args) -> Listx.length args | `N _ -> assert false in
 (fun l -> match div with
  | None -> l
  | Some div -> (-1, hd_of_i_var div, aux div) :: l)
  (List.map (fun hd ->
   let i, tm = Util.findi (fun y -> hd_of y = Some hd) ps in
    i, hd, aux tm
   ) xs)
;;

(** Returns (p, showstoppers_step, showstoppers_eat) where:
    - showstoppers_step are the heads occurring twice
      in the same discriminating set
    - showstoppers_eat are the heads in ps having different number
      of arguments *)
let critical_showstoppers p =
  let p = super_simplify p in
  let hd_of_div = match p.div with None -> [] | Some t -> [hd_of_i_var t] in
  let showstoppers_step =
  concat_map (fun bs ->
    let heads = List.map (fun (i,_) -> List.nth p.ps i) !bs in
    let heads = List.sort compare (hd_of_div @ filter_map hd_of heads) in
    snd (split_duplicates heads)
    ) p.deltas @
     if List.exists (fun t -> [hd_of t] = List.map (fun x -> Some x) hd_of_div) p.conv
     then hd_of_div else [] in
  let showstoppers_step = sort_uniq showstoppers_step in
  let showstoppers_eat =
   let heads_and_arities =
    List.sort (fun (k,_) (h,_) -> compare k h)
     (filter_map (function `Var(k,_) -> Some (k,0) | `I((k,_),args) -> Some (k,Listx.length args) | _ -> None ) p.ps) in
   let rec multiple_arities =
    function
       []
     | [_] -> []
     | (x,i)::(y,j)::tl when x = y && i <> j ->
         x::multiple_arities tl
     | _::tl -> multiple_arities tl in
   multiple_arities heads_and_arities in

  let showstoppers_eat = sort_uniq showstoppers_eat in
  let showstoppers_eat = List.filter
    (fun x -> not (List.mem x showstoppers_step))
    showstoppers_eat in
  List.iter (fun v -> prerr_endline ("DANGEROUS STEP: " ^ (string_of_var p.var_names) v)) showstoppers_step;
  List.iter (fun v -> prerr_endline ("DANGEROUS EAT: " ^ (string_of_var p.var_names) v)) showstoppers_eat;
  p, showstoppers_step, showstoppers_eat
  ;;

let eat p =
  let ({ps} as p), showstoppers_step, showstoppers_eat = critical_showstoppers p in
  let showstoppers = showstoppers_step @ showstoppers_eat in
  let heads = List.sort compare (filter_map hd_of ps) in
  let arities = precompute_edible_data p (uniq heads) in
  let inedible = edible p arities showstoppers in
  prerr_endline ("showstoppers (in eat)" ^ String.concat " " (List.map (string_of_var p.var_names) (inedible)));
  let l = List.filter (fun (_,hd,_) -> not (List.mem hd inedible)) arities in
  let new_sigma = List.map (fun (pos,hd,nargs) ->
   let v = if pos = -1 then `Bottom else `N pos in
   let inst = make_lams v nargs in
prerr_endline ("# [INST_IN_EAT] eating: " ^ string_of_var p.var_names hd ^ " := " ^ string_of_term p inst);
    hd,inst
   ) l in
  (* to avoid applied numbers in safe positions that
     trigger assert failures subst_in_problem x inst p*)
 let ps =
  List.map (fun t ->
   try
    let j,_,_ = List.find (fun (_,hd,_) -> hd_of t = Some hd) l in
    `N j
   with Not_found -> t
  ) ps in
(*let dangerous_conv = showstoppers_conv in
prerr_endline ("dangerous_conv lenght:" ^ string_of_int (List.length dangerous_conv));
List.iter (fun l -> prerr_endline (String.concat " " (List.map (string_of_var p.var_names) l))) dangerous_conv; *)
 let conv =
   List.map (function t ->
    try
     (match t with | `Var _ -> raise Not_found | _ -> ());
     let _ = List.find (fun h -> hd_of t = Some h) inedible in t
    with Not_found -> (
     (match hd_of t with
      | None -> assert (t = convergent_dummy)
      | Some h -> prerr_endline ("FREEZING " ^ string_of_var p.var_names h));
     convergent_dummy)
   ) p.conv in
 List.iter
  (fun bs ->
    bs :=
     List.map
      (fun (n,t as res) ->
        match List.nth ps n with
           `N m -> m,t
         | _ -> res
      ) !bs
  ) p.deltas ;
 let old_conv = p.conv in
 let p = { p with ps; conv } in
 (* In case (match x ... with ...) and we are eating x,
    so we need to substitute *)
 let p = List.fold_left (fun p (x,inst) -> subst_in_problem x inst p) p new_sigma in
 if l <> [] || old_conv <> conv
  then prerr_endline (string_of_problem "eat" p);
 if List.for_all (function `N _ -> true | _ -> false) ps && p.div = None then
  `Finished p
 else
  `Continue p


let safe_arity_of_var p x =
 (* Compute the minimum number of arguments when x is in head
    position at p.div or p.ps *)
 let aux = function
 | `Var(y,_) -> if x = y then 0 else max_int
 | `I((y,_),args) -> if x = y then Listx.length args else max_int
 | _ -> max_int in
 let tms = ((match p.div with None -> [] | Some t -> [(t :> i_n_var)]) @ p.ps) in
 List.fold_left (fun acc t -> Pervasives.min acc (aux t)) max_int tms
;;

let instantiate p x perm =
 let n = (prerr_endline ("WARNING: using constant initialSpecialK=" ^ string_of_int p.initialSpecialK)); p.initialSpecialK in
 let arities = Array.to_list (Array.make (n+1) min_int) in
 let p,vars = make_fresh_vars p arities in
 (* manual lifting of vars by perm in next line *)
 let vars = List.map (function `Var (n,ar) -> `Var (n+perm,ar)) vars in
 let args = Listx.from_list vars in
 let bs = ref [] in
 (* other_vars are the variables which are delayed and re-applied to the match *)
 let other_vars = Array.mapi (fun n () -> `Var(n+1,min_int)) (Array.make (perm-1) ()) in
 let other_vars = Array.to_list other_vars in
 (* 666, since it will be replaced anyway during subst: *)
 let inst = `Match(`I((0,min_int),args),(x,-666),perm,bs,other_vars) in
 (* Add a number of 'perm' leading lambdas *)
 let inst = Array.fold_left (fun t () -> `Lam(false, t)) inst (Array.make perm ()) in
 let p = {p with deltas=bs::p.deltas} in
 subst_in_problem x inst p
;;

let compute_special_k tms =
 let rec aux k (t: nf) = Pervasives.max k (match t with
 | `Lam(b,t) -> aux (k + if b then 1 else 0) t
 | `I(n, tms) -> Listx.max (Listx.map (aux 0) (tms :> nf Listx.listx))
 | `Match(t, _, liftno, bs, args) ->
     List.fold_left max 0 (List.map (aux 0) ((t :> nf)::(args :> nf list)@List.map snd !bs))
 | `N _
 | `Bottom
 | `Pacman
 | `Var _ -> 0
 ) in
 let rec aux' top t = match t with
 | `Lam(_,t) -> aux' false t
 | `I((_,ar), tms) -> max ar
     (Listx.max (Listx.map (aux' false) (tms :> nf Listx.listx)))
 | `Match(t, _, liftno, bs, args) ->
     List.fold_left max 0 (List.map (aux' false) ((t :> nf)::(args :> nf list)@List.map snd !bs))
 | `N _
 | `Bottom
 | `Pacman
 | `Var _ -> 0 in
 Listx.max (Listx.map (aux 0) tms) + Listx.max (Listx.map (aux' true) tms)
;;

let choose_step p =
 let p, showstoppers_step, showstoppers_eat = critical_showstoppers p in
 let x =
  match showstoppers_step, showstoppers_eat with
  | [], y::_ ->
     prerr_endline ("INSTANTIATING (critical eat) : " ^ string_of_var p.var_names y); y
  | x::_, _ ->
     prerr_endline ("INSTANTIATING (critical step): " ^ string_of_var p.var_names x); x
  | [], [] ->
     let heads =
      (* Choose only variables still alive (with arity > 0) *)
      List.sort compare (filter_map (
       fun t -> match t with `Var _ -> None | x -> if arity_of_hd x <= 0 then None else hd_of x
      ) ((match p.div with Some t -> [(t :> i_n_var)] | _ -> []) @ p.ps)) in
     (match heads with
      | [] ->
         (try
           fst (List.find (((<) 0) ++ snd) (concat_map free_vars' (p.conv :> nf list)))
          with
           Not_found -> assert false)
      | x::_ ->
         prerr_endline ("INSTANTIATING TO EAT " ^ string_of_var p.var_names x);
         x) in
 let arity_of_x = Util.option_get (max_arity_tms x (all_terms p)) in
 let safe_arity_of_x = safe_arity_of_var p x in
 x, min arity_of_x safe_arity_of_x
;;

let rec auto_eat p =
(* prerr_endline "{{{{{{{{ Computing measure before auto_instantiate }}}}}}"; *)
 let m = problem_measure p in
 let x, arity_of = choose_step p in
 first arity_of p x (fun p j ->
  let p' = instantiate p x j in
  prerr_endline (string_of_problem "after instantiate" p');
  match eat p' with
  | `Finished p -> p
  | `Continue p ->
(* prerr_endline "{{{{{{{{ Computing measure inafter auto_instantiate }}}}}}"; *)
      let delta = problem_measure p - m in
      if delta >= 0
       then
        (failwith
        ("Measure did not decrease (+=" ^ string_of_int delta ^ ")"))
       else prerr_endline ("$ Measure decreased: " ^ string_of_int delta);
      auto_eat p)
;;

let auto p n =
prerr_endline ("@@@@ FIRST INSTANTIATE PHASE (" ^ string_of_int n ^ ") @@@@");
 match eat p with
 | `Finished p -> p
 | `Continue p -> auto_eat p
;;


(******************************************************************************)

let optimize_numerals p =
  let replace_in_sigma perm =
    let rec aux = function
    | `N n -> `N (List.nth perm n)
    | `Pacman
    | `I _ -> assert false
    | `Var _ as t -> t
    | `Lam(v,t) -> `Lam(v, aux t)
    | `Match(_,_,_,bs,_) as t -> (bs := List.map (fun (n,t) -> (List.nth perm n, t)) !bs); t
    | `Bottom as t -> t
    in List.map (fun (n,t) -> (n,aux t))
  in
  let deltas' = List.mapi (fun n d -> (n, List.map fst !d)) p.deltas in
  let maxs = Array.to_list (Array.init (List.length deltas') (fun _ -> 0)) in
  let max = List.fold_left max 0 (concat_map snd deltas') in
  let perm,_ = List.fold_left (fun (perm, maxs) (curr_n:int) ->
      let containing = filter_map (fun (i, bs) -> if List.mem curr_n bs then Some i else None) deltas' in
      (* (prerr_endline (string_of_int curr_n ^ " occurs in: " ^ (String.concat " " (List.map string_of_int containing)))); *)
      let neww = List.fold_left Pervasives.max 0 (List.mapi (fun n max -> if List.mem n containing then max else 0) maxs) in
      let maxs = List.mapi (fun i m -> if List.mem i containing then neww+1 else m) maxs in
      (neww::perm, maxs)
    ) ([],maxs) (Array.to_list (Array.init (max+1) (fun x -> x))) in
  replace_in_sigma (List.rev perm) p.sigma
;;

let env_of_sigma freshno sigma =
 let rec aux n =
  if n > freshno then
   []
  else
   let e = aux (n+1) in
   (try
    e,Pure.lift (-n-1) (snd (List.find (fun (i,_) -> i = n) sigma)),[]
   with
    Not_found -> ([],Pure.V n,[]))::e
 in aux 0
;;
(* ************************************************************************** *)

type response = [
 | `CompleteSeparable of string
 | `CompleteUnseparable of string
 | `Uncomplete
]

type result = [
 `Complete | `Uncomplete
] * [
 | `Separable of (int * Num.nf) list
 | `Unseparable of string
]

let run p =
 Console.print_hline();
 prerr_endline (string_of_problem "main" p);
 let p_finale = auto p p.initialSpecialK in
 let freshno,sigma = p_finale.freshno, p_finale.sigma in
 prerr_endline ("------- <DONE> ------ measure=. \n ");
 List.iter (fun (x,inst) -> prerr_endline (string_of_var p_finale.var_names x ^ " := " ^ string_of_term p_finale inst)) sigma;

 prerr_endline "---------<OPT>----------";
 let sigma = optimize_numerals p_finale in (* optimize numerals *)
 List.iter (fun (x,inst) -> prerr_endline (string_of_var p_finale.var_names x ^ " := " ^ string_of_term p_finale inst)) sigma;

 prerr_endline "---------<PURE>---------";
 let scott_of_nf t = ToScott.scott_of_nf (t :> nf) in
 let div = option_map scott_of_nf p.div in
 let conv = List.map scott_of_nf p.conv in
 let ps = List.map scott_of_nf p.ps in

 let sigma' = List.map (fun (x,inst) -> x, ToScott.scott_of_nf inst) sigma in
 let e' = env_of_sigma freshno sigma' in

 prerr_endline "--------<REDUCE>---------";
 (function Some div ->
  print_endline (Pure.print div);
  let t = Pure.mwhd (e',div,[]) in
  prerr_endline ("*:: " ^ (Pure.print t));
  assert (t = Pure.B)
 | None -> ()) div;
 List.iter (fun n ->
   verbose ("_::: " ^ (Pure.print n));
   let t = Pure.mwhd (e',n,[]) in
   verbose ("_:: " ^ (Pure.print t));
   assert (t <> Pure.B)
 ) conv ;
 List.iteri (fun i n ->
   verbose ((string_of_int i) ^ "::: " ^ (Pure.print n));
   let t = Pure.mwhd (e',n,[]) in
   verbose ((string_of_int i) ^ ":: " ^ (Pure.print t));
   assert (t = Scott.mk_n i)
 ) ps ;
 prerr_endline "-------- </DONE> --------";
 p_finale.sigma
;;

let solve (p, todo) =
 let completeness, to_run =
  match todo with
   | `CompleteUnseparable s -> `Complete, `False s
   | `CompleteSeparable _ -> `Complete, `True
   | `Uncomplete -> `Uncomplete, `True in
 completeness, match to_run with
  | `False s -> `Unseparable s
  | `True ->
      try
       `Separable (run p)
      with
       Backtrack _ -> `Unseparable "backtrack"
;;

let no_bombs_pacmans p =
    not (List.exists (eta_subterm `Bottom) (p.ps@p.conv))
 && not (List.exists (eta_subterm `Pacman) p.ps)
 && Util.option_map (eta_subterm `Pacman) p.div <> Some true
;;

let check p =
 if (let rec f = function
     | [] -> false
     | hd::tl -> List.exists (eta_eq hd) tl || f tl in
   f p.ps) (* FIXME what about initial fragments of numbers? *)
  then `CompleteUnseparable "ps contains duplicates"
 (* check if div occurs somewhere in ps@conv *)
 else if (match p.div with
  | None -> true
  | Some div -> not (List.exists (eta_subterm div) (p.ps@p.conv))
  ) && no_bombs_pacmans p
  then `CompleteSeparable "no bombs, pacmans and div"
  (* il check seguente e' spostato nel parser e lancia un ParsingError *)
 (* else if false (* TODO bombs or div fuori da lambda in ps@conv *)
  then `CompleteUnseparable "bombs or div fuori da lambda in ps@conv" *)
 else if p.div = None
  then `CompleteSeparable "no div"
 else `Uncomplete
;;

let problem_of (label, div, conv, ps, var_names) =
 (* TODO: replace div with bottom in problem??? *)
 let all_tms = (match div with None -> [] | Some div -> [(div :> i_n_var)]) @ ps @ conv in
 if all_tms = [] then failwith "problem_of: empty problem";
 let initialSpecialK = compute_special_k (Listx.from_list (all_tms :> nf list)) in
 let freshno = List.length var_names in
 let deltas =
  let dummy = `Var (max_int / 2, -666) in
   [ ref (Array.to_list (Array.init (List.length ps) (fun i -> i, dummy))) ] in
 let trail = [] in
 let sigma = [] in
 let p = {freshno; div; conv; ps; sigma; deltas; initialSpecialK; trail; var_names; label} in
 p, check p
;;