ocaml/num.ml

   1 open Util
   2 open Util.Vars
   3 open Pure
   4
   5 (* debug options *)
   6 let debug_display_arities = false;;
   7
   8 (************ Syntax ************************************)
   9
  10 (* Normal forms*)
  11
  12 (* Var n = n-th De Bruijn index, 0-based *)
  13
  14 (*type nf =
  15   | Lam of nf
  16   | Var of int
  17   | i
  18 and i =
  19   | I of int * nf listx
  20 ;;*)
  21 type var = int * (* arity of variable*) int;;
  22 type 'nf_nob i_var_ = [ `I of var * 'nf_nob Listx.listx | `Var of var ]
  23 type 'nf_nob i_n_var_ = [ `N of int | 'nf_nob i_var_ ]
  24 type ('nf_nob,'nf) i_num_var_ = [
  25   | 'nf_nob i_n_var_
  26   | `Match of ('nf_nob,'nf) i_num_var_ * (* originating var *) var * (*lift*) int * (*branches*)(int * 'nf) list ref * (*args*)'nf_nob list
  27 ]
  28 type 'nf nf_nob_ = [ `Lam of (* was_unpacked *) bool * 'nf | `Pacman | ('nf nf_nob_,'nf) i_num_var_ ]
  29 type nf = [ nf nf_nob_ | `Bottom  ]
  30 type nf_nob = nf nf_nob_
  31 type i_var = nf_nob i_var_;;
  32 type i_n_var = nf_nob i_n_var_;;
  33 type i_num_var = (nf_nob,nf) i_num_var_;;
  34
  35 let hd_of_i_var =
  36  function
  37    `I ((v,_),_)
  38  | `Var (v,_) -> v
  39
  40 let hd_of =
  41  function
  42    `I ((v,_),_)
  43  | `Var(v,_) -> Some v
  44  | `N _ -> None
  45  | `Match _ -> assert false
  46
  47 let arity_of_hd =
  48 function
  49   `I ((_,a),_)
  50 | `Var(_,a) -> a
  51 | _ -> 0 (* FIXME? *)
  52
  53 let lift m (t : nf) =
  54  let aux_var l (n, ar) = (if n < l then n else n+m), ar in
  55  let rec aux_i_num_var l =
  56   function
  57     `I(v,args) -> `I(aux_var l v, Listx.map (aux_nob l) args)
  58    | `Var v -> `Var(aux_var l v)
  59    | `N _ as x -> x
  60    | `Match(t,v,lift,bs,args) ->
  61       `Match(aux_i_num_var l t, v, lift + m, bs, List.map (aux_nob l) args)
  62  and aux_nob l =
  63   function
  64      #i_num_var as x -> (aux_i_num_var l x :> nf_nob)
  65    | `Lam(b,nf) -> `Lam (b, aux (l+1) nf)
  66    | `Pacman -> `Pacman
  67  and aux l =
  68   function
  69      #nf_nob as x -> (aux_nob l x :> nf)
  70    | `Bottom -> `Bottom
  71  in
  72   (aux 0 t : nf)
  73 ;;
  74
  75 (* put t under n lambdas, lifting t accordingtly *)
  76 let rec make_lams t =
  77  function
  78    0 -> t
  79  | n when n > 0 -> `Lam (false, lift 1 (make_lams t (n-1)))
  80  | _ -> assert false
  81
  82 let free_vars' =
  83  let rec aux n = function
  84     `N _ -> []
  85   | `Var(x,ar) -> if x < n then [] else [(x-n,ar)]
  86   | `I((x,ar),args) ->
  87       (if x < n then [] else [(x-n,ar)]) @
  88       List.concat (List.map (aux n) (Listx.to_list args :> nf list))
  89   | `Lam(_,t) -> aux (n+1) t
  90   | `Match(t,_,liftno,bs,args) ->
  91       aux n (t :> nf) @
  92       List.concat (List.map (fun (_,t) -> aux (n-liftno) t) !bs) @
  93       List.concat (List.map (aux n) (args :> nf list))
  94   | `Bottom | `Pacman -> []
  95   in aux 0
  96 ;;
  97 let free_vars = (List.map fst) ++ free_vars';;
  98
  99 module ToScott =
 100 struct
 101
 102 let rec scott_of_nf = function
 103  | `N n -> Scott.mk_n n
 104  | `Var(v,_) -> Pure.V v
 105  | `Match(t,_,liftno,bs,args) ->
 106  let bs = List.map (fun (n,t) -> n, scott_of_nf (lift liftno (t :> nf))) !bs in
 107      let t = scott_of_nf (t :> nf) in
 108      let m = Scott.mk_match t bs in
 109      List.fold_left (fun acc t -> Pure.A(acc,scott_of_nf t)) m (args :> nf list)
 110  | `I((v,_), args) -> Listx.fold_left (fun acc t -> Pure.A(acc,scott_of_nf t)) (Pure.V v) (args :> nf Listx.listx)
 111  | `Lam(_,t) -> Pure.L (scott_of_nf t)
 112  | `Bottom -> Pure.B
 113  | `Pacman -> let f x = Pure.A (x,x) in f (Pure.L (Pure.L (f (Pure.V 0))))
 114 end
 115
 116
 117 (************ Pretty-printing ************************************)
 118
 119 (* let rec string_of_term l  = fun _ -> "";; *)
 120
 121 let rec string_of_term l  =
 122  let rec string_of_term_w_pars l  = function
 123   | `Var(n,ar) -> print_name l n ^ (if debug_display_arities then ":" ^ string_of_int ar else "")
 124   | `N n -> string_of_int n
 125   | `I _ as t -> "(" ^ string_of_term_no_pars_app l t ^ ")"
 126   | `Lam(_,`Bottom) -> "BOMB"
 127   | `Lam _ as t -> "(" ^ string_of_term_no_pars_lam l t ^ ")"
 128   | `Match(t,(v,ar),bs_lift,bs,args) ->
 129      "["^ string_of_var v ^ (if debug_display_arities then ":"^ string_of_int ar else "") ^",match " ^ string_of_term_no_pars l (t :> nf) ^
 130      " with " ^ String.concat " | " (List.map (fun (n,t) -> string_of_int n ^ " => " ^ string_of_term l (lift bs_lift (t :> nf))) !bs) ^ "] " ^
 131      String.concat " " (List.map (string_of_term l) (args :> nf list)) ^ ")"
 132   | `Bottom -> "BOT"
 133   | `Pacman -> "PAC"
 134  and string_of_term_no_pars_app l  = function
 135   | `I((n,ar), args) -> print_name l n ^ (if debug_display_arities then ":" ^ string_of_int ar else "") ^ " " ^ String.concat " " (List.map (string_of_term_w_pars l) (Listx.to_list args :> nf list))
 136   | #nf as t -> string_of_term_w_pars l t
 137  and string_of_term_no_pars_lam l  = function
 138   | `Lam(_,`Bottom) -> "BOMB"
 139   | `Lam(_,t) -> let name = string_of_var (List.length l) in
 140      "λ" ^ name ^ ". " ^ (string_of_term_no_pars_lam (name::l) t)
 141   | _ as t -> string_of_term_no_pars l t
 142  and string_of_term_no_pars l  = function
 143   | `Lam _ as t -> string_of_term_no_pars_lam l t
 144   | #nf as t -> string_of_term_no_pars_app l t
 145  in string_of_term_no_pars l
 146 ;;
 147
 148 let print ?(l=[]) = string_of_term l;;
 149 let string_of_nf t = string_of_term [] (t :> nf);;
 150
 151 (************ Hereditary substitutions ************************************)
 152
 153 let cast_to_i_var =
 154  function
 155     #i_var as y -> (y : i_var)
 156   | t ->
 157     prerr_endline (print (t :> nf));
 158     assert false (* algorithm failed *)
 159
 160 let cast_to_i_n_var =
 161  function
 162     #i_n_var as y -> (y : i_n_var)
 163   | t ->
 164     prerr_endline (print (t :> nf));
 165     assert false (* algorithm failed *)
 166
 167 let cast_to_i_num_var =
 168  function
 169     #i_num_var as y -> (y : i_num_var)
 170   | t ->
 171     prerr_endline (print (t :> nf));
 172     assert false (* algorithm failed *)
 173
 174 let rec set_arity arity = function
 175 (* FIXME because onlt variables should be in branches of matches, one day *)
 176 | `Var(n,_) -> `Var(n,arity)
 177 | `N _ | `Bottom | `Pacman as t -> t
 178 | `Lam(false, t) -> `Lam(false, set_arity arity t)
 179 | `Match(t,(n,_),bs_lift,bs,args) -> `Match(t,(n,arity),bs_lift,bs,args)
 180 | `I _ | `Lam _ -> assert false
 181
 182 let minus1 n = if n = min_int then n else n - 1;;
 183
 184 let rec mk_app (h : nf) (arg : nf) =
 185  match arg with
 186   | `Bottom -> `Bottom
 187   | #nf_nob as arg ->
 188     match h with
 189      | `I(v,args) -> `I(v,Listx.append (Listx.Nil arg) args)
 190      | `Var v -> `I(v, Listx.Nil arg)
 191      | `Lam(truelam,nf) -> subst truelam true 0 arg (nf : nf) (* AC FIXME sanity check on arity *)
 192      | `Match(t,v,lift,bs,args) -> `Match(t,v,lift,bs,List.append args [arg])
 193      | `Bottom | `Pacman as t -> t
 194      | `N _ -> assert false (* Numbers cannot be applied *)
 195 (*in let l = ["v0";"v1";"v2"] in
 196 prerr_endline ("mk_app h:" ^ print ~l h ^ " arg:" ^ print ~l:l arg ^ " res:" ^ print ~l:l res); res*)
 197
 198 and mk_appl h args =
 199  (*prerr_endline ("MK_APPL: " ^ print h ^ " " ^ String.concat " " (List.map print args));*)
 200  List.fold_left mk_app h args
 201
 202 and mk_appx h args = Listx.fold_left mk_app h args
 203
 204 and mk_match t (n,ar) bs_lift bs args =
 205  (*prerr_endline ("MK_MATCH: ([" ^ print t ^ "] " ^ String.concat " " (Listx.to_list (Listx.map (fun (n,t) -> string_of_int n ^ " => " ^ print t) bs)) ^ ") " ^ String.concat " " (List.map print args));*)
 206  let m =
 207   match t with
 208     `N m as t ->
 209       (try
 210         let h = List.assoc m !bs in
 211         let h = set_arity (minus1 ar) h in
 212         let h = lift bs_lift h in
 213          h
 214        with Not_found ->
 215         `Match (t,(n,ar),bs_lift,bs,[]))
 216    (* We are assuming that the econding of matches is s.t.:
 217       - match PAC.. --> PAC
 218       - match BOT.. --> BOT *)
 219    | `Bottom -> `Bottom
 220    | `Pacman -> `Pacman
 221    | `Lam _ -> assert false
 222    | `I _ | `Var _ | `Match _ as t -> `Match(t,(n,ar),bs_lift,bs,[]) in
 223  mk_appl m args
 224
 225 and subst truelam delift_by_one what (with_what : nf(*_nob*)) (where : nf) =
 226  let rec aux_propagate_arity ar = function
 227  | `Lam(false, t) when not delift_by_one -> `Lam(false, aux_propagate_arity ar t)
 228  | `Match(`I(v,args),(x,_),liftno,bs,args') when not delift_by_one ->
 229     `Match(`I(v,args),(x,ar),liftno,bs,args')
 230  | `Var(i,oldar) -> `Var(i, if truelam then (assert (oldar = min_int); ar) else oldar)
 231  | _ as t -> t in
 232  let rec aux_i_num_var l =
 233   function
 234      `I((n,ar),args) ->
 235        if n = what + l then
 236        let args = Listx.map (aux l) (args :> nf Listx.listx) in
 237         mk_appx (lift l (aux_propagate_arity ar (with_what :> nf))) args
 238        else
 239         mk_appl (`Var ((if delift_by_one && n >= l then n-1 else n), ar)) (List.map (aux l) (Listx.to_list (args :> nf Listx.listx)))
 240    | `Var(n,ar) ->
 241        if n = what + l then
 242         lift l (aux_propagate_arity ar (with_what :> nf))
 243        else
 244         `Var((if delift_by_one && n >= l then n-1 else n), ar)
 245    | `N _ as x -> x
 246    | `Match(t,v,bs_lift,bs,args) ->
 247        let bs_lift = bs_lift + if delift_by_one then -1 else 0 in
 248        let l' = l - bs_lift  in
 249        let with_what' = lift l' (with_what :> nf) in
 250        (* The following line should be the identity when delift_by_one = true because we
 251           are assuming the ts to not contain lambda-bound variables. *)
 252        bs := List.map (fun (n,t) -> n,subst truelam false what with_what' t) !bs ;
 253        let body = aux_i_num_var l t in
 254        mk_match body v bs_lift bs (List.map (aux l) (args :> nf list))
 255  and aux l(*lift*) =
 256 (*function iii -> let res = match iii with*)
 257   function
 258    | #i_num_var as x -> aux_i_num_var l x
 259    | `Lam(b, nf) -> `Lam(b, aux (l+1) nf)
 260    | `Bottom -> `Bottom
 261    | `Pacman -> `Pacman
 262 (*in let ll = ["v0";"v1";"v2"] in
 263 prerr_endline ("subst l:" ^ string_of_int l ^ " delift_by_one:" ^ string_of_bool delift_by_one ^ " what:" ^ (List.nth ll what) ^ " with_what:" ^ print ~l:ll with_what ^ " where:" ^ print ~l:ll iii ^ " res:" ^ print ~l:ll res); res*)
 264  in
 265   aux 0 where
 266 ;;
 267
 268 (************ Parsing ************************************)
 269
 270 (************** Algorithm(s) ************************)
 271
 272 let eta_compare x y =
 273  (* let clex a b = let diff = ? a b in if diff = 0 then cont () else 0 in *)
 274  let clex aux1 aux2 (a1,a2) (b1,b2) =
 275   let diff = aux1 a1 b1 in if diff = 0 then aux2 a2 b2 else diff in
 276  let rec lex aux l1 l2 =
 277   match l1,l2 with
 278  | [], [] -> 0
 279  | [], _ -> -1
 280  | _, [] -> 1
 281  | x::xs, y::ys -> clex aux (lex aux) (x,xs) (y,ys) in
 282  let rec aux t1 t2 = match t1, t2 with
 283   | `Var(n,_) , `Var(m,_) -> compare n m
 284   | `I((n1,_), l1), `I((n2,_), l2) ->
 285     clex compare (lex aux) (n1, (Listx.to_list l1 :> nf list)) (n2, (Listx.to_list l2 :> nf list))
 286   | `Bottom, `Bottom
 287   | `Pacman, `Pacman -> 0
 288   | `Lam _, `N _ -> -1
 289   | `N _, `Lam _ -> 1
 290   | `Bottom, `Lam _
 291   | `Lam _, `Bottom -> assert false (* TO BE UNDERSTOOD *)
 292   | `Lam(_,t1), `Lam(_,t2) -> aux t1 t2
 293   | `Lam(_,t1), t2 -> - aux t1 (mk_app (lift 1 t2) (`Var(0,-666)))
 294   | t2, `Lam(_,t1) ->   aux t1 (mk_app (lift 1 t2) (`Var(0,-666)))
 295   | `N n1, `N n2 -> compare n1 n2
 296   | `Match(u,_,bs_lift,bs,args), `Match(u',_,bs_lift',bs',args') ->
 297     let bs = List.sort (fun (n,_) (m,_) -> compare n m) !bs in
 298     let bs' = List.sort (fun (n,_) (m,_) -> compare n m) !bs' in
 299     clex aux (clex (lex (clex compare aux)) (lex aux)) ((u :> nf), (bs, (args :> nf list))) ((u' :> nf), (bs', (args' :> nf list)))
 300   | `Match _, _ -> -1
 301   | _, `Match _ -> 1
 302   | `N _, _ -> -1
 303   | _, `N _ -> 1
 304   | `I _, _ -> -1
 305   | _, `I _ -> 1
 306   | `Bottom, _ -> -1
 307   | _, `Bottom -> 1
 308   | `Pacman, _ -> -1
 309   | _, `Pacman -> 1
 310   in aux x y
 311 ;;
 312
 313 let eta_eq (#nf as x) (#nf as y) = 0 = eta_compare x y ;;
 314
 315 let rec eta_subterm sub t =
 316  if eta_eq sub t then true else
 317   match t with
 318   | `Lam(_,t') -> eta_subterm (lift 1 sub) t'
 319   | `Bottom
 320   | `Pacman  -> false
 321   | `Match(u,ar,liftno,bs,args) ->
 322      eta_subterm sub (u :> nf)
 323      || List.exists (fun (_, t) -> eta_subterm sub (lift liftno t)) !bs
 324      || List.exists (eta_subterm sub) (args :> nf list)
 325   | `I((v,_), args) -> List.exists (eta_subterm sub) ((Listx.to_list args) :> nf list) || (match sub with
 326    | `Var(v',_) -> v = v'
 327    | `I((v',_), args') -> v = v'
 328     && Listx.length args' < Listx.length args
 329     && List.for_all (fun (x,y) -> eta_eq x y) (List.combine (Util.take (Listx.length args') (Listx.to_list args :> nf list)) (Listx.to_list args' :> nf list))
 330    | _ -> false
 331    )
 332   | `N _ | `Var _ -> false
 333 ;;
 334
 335 let eta_subterm (#nf as x) (#nf as y) = eta_subterm x y;;
 336
 337 let max_arity_tms n =
 338  let max a b = match a, b with
 339   | None, None -> None
 340   | None, Some x
 341   | Some x, None -> Some x
 342   | Some x, Some y -> Some (Pervasives.max x y) in
 343  let aux_var l (m,a) = if n + l = m then Some a else None in
 344  let rec aux l = function
 345   | `Var v -> aux_var l v
 346   | `I(v,tms) -> max (aux_var l v) (aux_tms l (Listx.to_list tms :> nf list))
 347   | `Lam(_,t) -> aux (l+1) t
 348   | `Match(u,_,_,bs,args) -> max (max (aux l (u :> nf)) (aux_tms l (args :> nf list))) (aux_tms l (List.map snd !bs))
 349   | `N _ | `Bottom | `Pacman -> None
 350  and aux_tms l =
 351   List.fold_left (fun acc t -> max acc (aux l t)) None in
 352  fun tms -> aux_tms 0 (tms :> nf list)
 353 ;;