ocaml/num.ml

   1 open Util
   2 open Util.Vars
   3 open Pure
   4
   5 (* debug options *)
   6 let debug_display_arities = false;;
   7
   8 (************ Syntax ************************************)
   9
  10 (* Normal forms*)
  11
  12 (* Var n = n-th De Bruijn index, 0-based *)
  13
  14 (*type nf =
  15   | Lam of nf
  16   | Var of int
  17   | i
  18 and i =
  19   | I of int * nf listx
  20 ;;*)
  21 type var = int * (* arity of variable*) int;;
  22 type 'nf i_var_ = [ `I of var * 'nf Listx.listx | `Var of var ]
  23 type 'nf i_n_var_ = [ `N of int | 'nf i_var_ ]
  24 type 'nf i_num_var_ = [
  25   | 'nf i_n_var_
  26   | `Match of 'nf i_num_var_ * (* originating var *) var * (*lift*) int * (*branches*)(int * 'nf) list ref * (*args*)'nf list
  27 ]
  28 type 'nf nf_ = [ `Lam of (* was_unpacked *) bool * 'nf nf_ | 'nf i_num_var_ ]
  29 type nf = nf nf_
  30 type i_var = nf i_var_;;
  31 type i_n_var = nf i_n_var_;;
  32 type i_num_var = nf i_num_var_;;
  33
  34 let hd_of_i_var =
  35  function
  36    `I ((v,_),_)
  37  | `Var (v,_) -> v
  38
  39 let hd_of =
  40  function
  41    `I ((v,_),_)
  42  | `Var(v,_) -> Some v
  43  | `N _ -> None
  44  | `Match _ -> assert false
  45
  46 let arity_of_hd =
  47 function
  48   `I ((_,a),_)
  49 | `Var(_,a) -> a
  50 | _ -> 0 (* FIXME? *)
  51
  52 let lift m (t : nf) =
  53  let aux_var l (n, ar) = (if n < l then n else n+m), ar in
  54  let rec aux_i_num_var l =
  55   function
  56     `I(v,args) -> `I(aux_var l v, Listx.map (aux l) args)
  57    | `Var v -> `Var(aux_var l v)
  58    | `N _ as x -> x
  59    | `Match(t,v,lift,bs,args) ->
  60       `Match(aux_i_num_var l t, v, lift + m, bs, List.map (aux l) args)
  61  and aux l =
  62   function
  63      #i_num_var as x -> (aux_i_num_var l x :> nf)
  64    | `Lam(b,nf) -> `Lam (b, aux (l+1) nf)
  65  in
  66   (aux 0 t : nf)
  67 ;;
  68
  69 (* put t under n lambdas, lifting t accordingtly *)
  70 let rec make_lams t =
  71  function
  72    0 -> t
  73  | n when n > 0 -> `Lam (false, lift 1 (make_lams t (n-1)))
  74  | _ -> assert false
  75
  76 let free_vars' =
  77  let rec aux n = function
  78     `N _ -> []
  79   | `Var(x,ar) -> if x < n then [] else [(x-n,ar)]
  80   | `I((x,ar),args) ->
  81       (if x < n then [] else [(x-n,ar)]) @
  82       List.concat (List.map (aux n) (Listx.to_list args))
  83   | `Lam(_,t) -> aux (n+1) t
  84   | `Match(t,_,liftno,bs,args) ->
  85       aux n (t :> nf) @
  86       List.concat (List.map (fun (_,t) -> aux (n-liftno) t) !bs) @
  87       List.concat (List.map (aux n) args)
  88   in aux 0
  89 ;;
  90 let free_vars = (List.map fst) ++ free_vars';;
  91
  92 module ToScott =
  93 struct
  94
  95 let rec t_of_i_num_var =
  96  function
  97   | `N n -> Scott.mk_n n
  98   | `Var(v,_) -> Pure.V v
  99   | `Match(t,_,liftno,bs,args) ->
 100       let bs = List.map (fun (n,t) -> n, t_of_nf (lift liftno t)) !bs in
 101       let t = t_of_i_num_var t in
 102       let m = Scott.mk_match t bs in
 103       List.fold_left (fun acc t -> Pure.A(acc,t_of_nf t)) m args
 104   | `I((v,_), args) -> Listx.fold_left (fun acc t -> Pure.A(acc,t_of_nf t)) (Pure.V v) args
 105 and t_of_nf =
 106  function
 107   | #i_num_var as x -> t_of_i_num_var x
 108   | `Lam(b,f) -> Pure.L (t_of_nf f)
 109
 110 end
 111
 112
 113 (************ Pretty-printing ************************************)
 114
 115 let rec string_of_term l =
 116  let rec string_of_term_w_pars l = function
 117   | `Var(n,ar) -> print_name l n ^ ":" ^ string_of_int ar
 118   | `N n -> string_of_int n
 119   | `I _ as t -> "(" ^ string_of_term_no_pars_app l (t :> nf) ^ ")"
 120   | `Lam _ as t -> "(" ^ string_of_term_no_pars_lam l t ^ ")"
 121   | `Match(t,(v,ar),bs_lift,bs,args) ->
 122      "["^ string_of_var v ^ (if debug_display_arities then ":"^ string_of_int ar else "") ^",match " ^ string_of_term_no_pars l (t :> nf) ^
 123      " with " ^ String.concat " | " (List.map (fun (n,t) -> string_of_int n ^ " => " ^ string_of_term l (lift bs_lift (t :> nf))) !bs) ^ "] " ^
 124      String.concat " " (List.map (string_of_term l) (args :> nf list)) ^ ")"
 125  and string_of_term_no_pars_app l  = function
 126   | `I((n,ar), args) -> print_name l n ^ (if debug_display_arities then ":" ^ string_of_int ar else "") ^ " " ^ String.concat " " (List.map (string_of_term_w_pars l) (Listx.to_list args :> nf list))
 127   | #nf as t -> string_of_term_w_pars l t
 128  and string_of_term_no_pars_lam l  = function
 129   | `Lam(_,t) -> let name = string_of_var (List.length l) in
 130      "λ" ^ name ^ ". " ^ (string_of_term_no_pars_lam (name::l) t)
 131   | _ as t -> string_of_term_no_pars l t
 132  and string_of_term_no_pars l : nf -> string = function
 133   | `Lam _ as t -> string_of_term_no_pars_lam l t
 134   | #nf as t -> string_of_term_no_pars_app l t
 135  in string_of_term_no_pars l
 136 ;;
 137
 138 let print ?(l=[]) = string_of_term l;;
 139 let string_of_nf t = string_of_term [] (t:>nf);;
 140
 141 (************ Hereditary substitutions ************************************)
 142
 143 let cast_to_i_var =
 144  function
 145     #i_var as y -> (y : i_var)
 146   | t ->
 147     prerr_endline (print (t :> nf));
 148     assert false (* algorithm failed *)
 149
 150 let cast_to_i_n_var =
 151  function
 152     #i_n_var as y -> (y : i_n_var)
 153   | t ->
 154     prerr_endline (print (t :> nf));
 155     assert false (* algorithm failed *)
 156
 157 let cast_to_i_num_var =
 158  function
 159     #i_num_var as y -> (y : i_num_var)
 160   | t ->
 161     prerr_endline (print (t :> nf));
 162     assert false (* algorithm failed *)
 163
 164 let rec set_arity arity = function
 165 | `Var(n,_) -> `Var(n,arity)
 166 | `N _ as t -> t
 167 | `Lam(false, t) -> `Lam(false, set_arity arity t)
 168 | `Match(t,(n,_),bs_lift,bs,args) -> `Match(t,(n,arity),bs_lift,bs,args)
 169 | `I _ | `Lam _ -> assert false
 170
 171 let minus1 n = if n = min_int then n else n - 1;;
 172
 173 let rec mk_app (h : nf) (arg : nf) =
 174 (*let res =*)
 175  match h with
 176     `I(v,args) -> `I(v,Listx.append (Listx.Nil arg) args)
 177   | `Var v -> `I(v, Listx.Nil arg)
 178   | `Lam(truelam,nf) -> subst truelam true 0 arg (nf : nf) (* AC FIXME sanity check on arity *)
 179   | `Match(t,v,lift,bs,args) -> `Match(t,v,lift,bs,List.append args [arg])
 180   | `N _ -> assert false (* Numbers cannot be applied *)
 181 (*in let l = ["v0";"v1";"v2"] in
 182 prerr_endline ("mk_app h:" ^ print ~l h ^ " arg:" ^ print ~l:l arg ^ " res:" ^ print ~l:l res); res*)
 183
 184 and mk_appl h args =
 185  (*prerr_endline ("MK_APPL: " ^ print h ^ " " ^ String.concat " " (List.map print args));*)
 186  List.fold_left mk_app h args
 187
 188 and mk_appx h args = Listx.fold_left mk_app h args
 189
 190 and mk_match t (n,ar) bs_lift bs args =
 191  (*prerr_endline ("MK_MATCH: ([" ^ print t ^ "] " ^ String.concat " " (Listx.to_list (Listx.map (fun (n,t) -> string_of_int n ^ " => " ^ print t) bs)) ^ ") " ^ String.concat " " (List.map print args));*)
 192  match t with
 193     `N m ->
 194       (try
 195         let h = List.assoc m !bs in
 196         let h = set_arity (minus1 ar) h in
 197         let h = lift bs_lift h in
 198         mk_appl h args
 199        with Not_found ->
 200         `Match (t,(n,ar),bs_lift,bs,args))
 201   | `I _ | `Var _ | `Match _ -> `Match(t,(n,ar),bs_lift,bs,args)
 202
 203 and subst truelam delift_by_one what (with_what : nf) (where : nf) =
 204  let rec aux_propagate_arity ar = function
 205  | `Lam(false, t) when not delift_by_one -> `Lam(false, aux_propagate_arity ar t)
 206  | `Match(`I(v,args),(x,_),liftno,bs,args') when not delift_by_one ->
 207     `Match(`I(v,args),(x,ar),liftno,bs,args')
 208  | `Var(i,oldar) -> `Var(i, if truelam then (assert (oldar = min_int); ar) else oldar)
 209  | _ as t -> t in
 210  let rec aux_i_num_var l =
 211   function
 212      `I((n,ar),args) ->
 213        if n = what + l then
 214         mk_appx (lift l (aux_propagate_arity ar with_what)) (Listx.map (aux l) args)
 215        else
 216         `I (((if delift_by_one && n >= l then n-1 else n), ar), Listx.map (aux l) args)
 217    | `Var(n,ar) ->
 218        if n = what + l then
 219         lift l (aux_propagate_arity ar with_what)
 220        else
 221         `Var((if delift_by_one && n >= l then n-1 else n), ar)
 222    | `N _ as x -> x
 223    | `Match(t,v,bs_lift,bs,args) ->
 224        let bs_lift = bs_lift + if delift_by_one then -1 else 0 in
 225        let l' = l - bs_lift  in
 226        let with_what' = lift l' with_what in
 227        (* The following line should be the identity when delift_by_one = true because we
 228           are assuming the ts to not contain lambda-bound variables. *)
 229        bs := List.map (fun (n,t) -> n,subst truelam false what with_what' t) !bs ;
 230        mk_match (cast_to_i_num_var (aux_i_num_var l t)) v bs_lift bs (List.map (aux l) args)
 231  and aux l(*lift*) =
 232 (*function iii -> let res = match iii with*)
 233   function
 234    | #i_num_var as x -> aux_i_num_var l x
 235    | `Lam(b, nf) -> `Lam(b, aux (l+1) nf)
 236 (*in let ll = ["v0";"v1";"v2"] in
 237 prerr_endline ("subst l:" ^ string_of_int l ^ " delift_by_one:" ^ string_of_bool delift_by_one ^ " what:" ^ (List.nth ll what) ^ " with_what:" ^ print ~l:ll with_what ^ " where:" ^ print ~l:ll iii ^ " res:" ^ print ~l:ll res); res*)
 238  in
 239   aux 0 where
 240 ;;
 241
 242 (************** Algorithm(s) ************************)
 243
 244 let eta_compare x y =
 245  (* let clex a b = let diff = ? a b in if diff = 0 then cont () else 0 in *)
 246  let clex aux1 aux2 (a1,a2) (b1,b2) =
 247   let diff = aux1 a1 b1 in if diff = 0 then aux2 a2 b2 else diff in
 248  let rec lex aux l1 l2 =
 249   match l1,l2 with
 250  | [], [] -> 0
 251  | [], _ -> -1
 252  | _, [] -> 1
 253  | x::xs, y::ys -> clex aux (lex aux) (x,xs) (y,ys) in
 254  let rec aux t1 t2 = match t1, t2 with
 255   | `Var(n,_) , `Var(m,_) -> compare n m
 256   | `I((n1,_), l1), `I((n2,_), l2) ->
 257     clex compare (lex aux) (n1, Listx.to_list l1) (n2, Listx.to_list l2)
 258   | `Lam _, `N _ -> -1
 259   | `N _, `Lam _ -> 1
 260   | `Lam(_,t1), `Lam(_,t2) -> aux t1 t2
 261   | `Lam(_,t1), t2 -> - aux t1 (mk_app (lift 1 t2) (`Var(0,-666)))
 262   | t2, `Lam(_,t1) ->   aux t1 (mk_app (lift 1 t2) (`Var(0,-666)))
 263   | `N n1, `N n2 -> compare n1 n2
 264   | `Match(u,_,bs_lift,bs,args), `Match(u',_,bs_lift',bs',args') ->
 265     let bs = List.sort (fun (n,_) (m,_) -> compare n m) !bs in
 266     let bs' = List.sort (fun (n,_) (m,_) -> compare n m) !bs' in
 267     clex aux (clex (lex (clex compare aux)) (lex aux)) ((u :> nf), (bs, args)) ((u' :> nf), (bs', args'))
 268   | `Match _, _ -> -1
 269   | _, `Match _ -> 1
 270   | `N _, _ -> -1
 271   | _, `N _ -> 1
 272   | `I _, _ -> -1
 273   | _, `I _ -> 1
 274   in aux x y
 275 ;;
 276
 277 let eta_eq (#nf as x) (#nf as y) = 0 = eta_compare x y ;;
 278
 279 let rec eta_subterm sub t =
 280  if eta_eq sub t then true else
 281   match t with
 282   | `Lam(_,t') -> eta_subterm (lift 1 sub) t'
 283   | `Match(u,ar,liftno,bs,args) ->
 284      eta_subterm sub (u :> nf)
 285      || List.exists (fun (_, t) -> eta_subterm sub (lift liftno t)) !bs
 286      || List.exists (eta_subterm sub) (args :> nf list)
 287   | `I((v,_), args) -> List.exists (eta_subterm sub) ((Listx.to_list args) :> nf list) || (match sub with
 288    | `Var(v',_) -> v = v'
 289    | `I((v',_), args') -> v = v'
 290     && Listx.length args' < Listx.length args
 291     && List.for_all (fun (x,y) -> eta_eq x y) (List.combine (Util.take (Listx.length args') (Listx.to_list args)) (Listx.to_list args'))
 292    | _ -> false
 293    )
 294   | `N _ | `Var _ -> false
 295 ;;
 296
 297 let eta_subterm (#nf as x) (#nf as y) = eta_subterm x y;;
 298
 299
 300 let max_arity_tms n =
 301  let max a b = match a, b with
 302   | None, None -> None
 303   | None, Some x
 304   | Some x, None -> Some x
 305   | Some x, Some y -> Some (Pervasives.max x y) in
 306  let aux_var l (m,a) = if n + l = m then Some a else None in
 307  let rec aux l = function
 308   | `Var v -> aux_var l v
 309   | `I(v,tms) -> max (aux_var l v) (aux_tms l (Listx.to_list tms))
 310   | `Lam(_,t) -> aux (l+1) t
 311   | `Match(u,_,_,bs,args) -> max (max (aux l (u :> nf)) (aux_tms l args)) (aux_tms l (List.map snd !bs))
 312   | `N _ -> None
 313  and aux_tms l =
 314   List.fold_left (fun acc t -> max acc (aux l t)) None in
 315  fun tms -> aux_tms 0 (tms :> nf list)
 316 ;;
 317
 318 let get_first_args var =
 319 let rec aux l = function
 320 | `Lam(_,t) -> aux (l+1) t
 321 | `Match(u,orig,liftno,bs,args) -> Util.concat_map (aux l) args
 322 | `I((n,_), args) -> if n = var + l then [Listx.last args] else []
 323 | `N _
 324 | `Var _ -> []
 325 in aux 0
 326 ;;
 327
 328 let compute_arities m =
 329  let rec aux n tms =
 330   if n = 0
 331    then []
 332    else
 333     let tms = Util.filter_map (function `Lam(_,t) -> Some t | _ -> None ) tms in
 334     let arity = match max_arity_tms (m-n) tms with None -> -666 | Some x -> x in
 335      arity :: (aux (n-1) tms)
 336  in fun tms -> List.rev (aux m tms)
 337 ;;
 338
 339 let compute_arities var special_k all_tms =
 340  let tms = List.fold_left (fun acc t -> acc @ (get_first_args var t)) [] all_tms in
 341  compute_arities special_k tms
 342 ;;