tps.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic-2/substitution/drop.ma".
  16
  17 (* PARTIAL SUBSTITUTION ON TERMS ********************************************)
  18
  19 inductive tps: lenv → term → nat → nat → term → Prop ≝
  20 | tps_sort : ∀L,k,d,e. tps L (⋆k) d e (⋆k)
  21 | tps_lref : ∀L,i,d,e. tps L (#i) d e (#i)
  22 | tps_subst: ∀L,K,V,U1,U2,i,d,e.
  23              d ≤ i → i < d + e →
  24              ↓[0, i] L ≡ K. 𝕓{Abbr} V → tps K V 0 (d + e - i - 1) U1 →
  25              ↑[0, i + 1] U1 ≡ U2 → tps L (#i) d e U2
  26 | tps_bind : ∀L,I,V1,V2,T1,T2,d,e.
  27              tps L V1 d e V2 → tps (L. 𝕓{I} V1) T1 (d + 1) e T2 →
  28              tps L (𝕓{I} V1. T1) d e (𝕓{I} V2. T2)
  29 | tps_flat : ∀L,I,V1,V2,T1,T2,d,e.
  30              tps L V1 d e V2 → tps L T1 d e T2 →
  31              tps L (𝕗{I} V1. T1) d e (𝕗{I} V2. T2)
  32 .
  33
  34 interpretation "partial telescopic substritution"
  35    'PSubst L T1 d e T2 = (tps L T1 d e T2).
  36
  37 (* Basic properties *********************************************************)
  38
  39 lemma tps_leq_repl: ∀L1,T1,T2,d,e. L1 ⊢ T1 [d, e] ≫ T2 →
  40                     ∀L2. L1 [d, e] ≈ L2 → L2 ⊢ T1 [d, e] ≫ T2.
  41 #L1 #T1 #T2 #d #e #H elim H -H L1 T1 T2 d e
  42 [ //
  43 | //
  44 | #L1 #K1 #V #V1 #V2 #i #d #e #Hdi #Hide #HLK1 #_ #HV12 #IHV12 #L2 #HL12
  45   elim (drop_leq_drop1 … HL12 … HLK1 ? ?) -HL12 HLK1 // #K2 #HK12 #HLK2
  46   @tps_subst [4,5,6,8: // |1,2,3: skip | /2/ ] (**) (* /3 width=6/ is too slow *)
  47 | /4/
  48 | /3/
  49 ]
  50 qed.
  51
  52 lemma tps_refl: ∀T,L,d,e. L ⊢ T [d, e] ≫ T.
  53 #T elim T -T //
  54 #I elim I -I /2/
  55 qed.
  56
  57 lemma tps_weak: ∀L,T1,T2,d1,e1. L ⊢ T1 [d1, e1] ≫ T2 →
  58                 ∀d2,e2. d2 ≤ d1 → d1 + e1 ≤ d2 + e2 →
  59                 L ⊢ T1 [d2, e2] ≫ T2.
  60 #L #T1 #T #d1 #e1 #H elim H -L T1 T d1 e1
  61 [ //
  62 | //
  63 | #L #K #V #V1 #V2 #i #d1 #e1 #Hid1 #Hide1 #HLK #_ #HV12 #IHV12 #d2 #e2 #Hd12 #Hde12
  64   lapply (transitive_le … Hd12 … Hid1) -Hd12 Hid1 #Hid2
  65   lapply (lt_to_le_to_lt … Hide1 … Hde12) -Hide1 #Hide2
  66   @tps_subst [4,5,6,8: // |1,2,3: skip | @IHV12 /2/ ] (**) (* /4 width=6/ is too slow *)
  67 | /4/
  68 | /4/
  69 ]
  70 qed.
  71
  72 lemma tps_weak_top: ∀L,T1,T2,d,e.
  73                     L ⊢ T1 [d, e] ≫ T2 → L ⊢ T1 [d, |L| - d] ≫ T2.
  74 #L #T1 #T #d #e #H elim H -L T1 T d e
  75 [ //
  76 | //
  77 | #L #K #V #V1 #V2 #i #d #e #Hdi #_ #HLK #_ #HV12 #IHV12
  78   lapply (drop_fwd_drop2_length … HLK) #Hi
  79   lapply (le_to_lt_to_lt … Hdi Hi) #Hd
  80   lapply (plus_minus_m_m_comm (|L|) d ?) [ /2/ ] -Hd #Hd
  81   lapply (drop_fwd_O1_length … HLK) normalize #HKL
  82   lapply (tps_weak … IHV12 0 (|L| - i - 1) ? ?) -IHV12 // -HKL /2 width=6/
  83 | normalize /2/
  84 | /2/
  85 ]
  86 qed.
  87
  88 lemma tps_weak_all: ∀L,T1,T2,d,e.
  89                     L ⊢ T1 [d, e] ≫ T2 → L ⊢ T1 [0, |L|] ≫ T2.
  90 #L #T1 #T #d #e #HT12
  91 lapply (tps_weak … HT12 0 (d + e) ? ?) -HT12 // #HT12
  92 lapply (tps_weak_top … HT12) //
  93 qed.
  94
  95 (* Basic inversion lemmas ***************************************************)
  96
  97 lemma tps_inv_lref1_aux: ∀L,T1,T2,d,e. L ⊢ T1 [d, e] ≫ T2 → ∀i. T1 = #i →
  98                          T2 = #i ∨
  99                          ∃∃K,V1,V2,i. d ≤ i & i < d + e &
 100                                       ↓[O, i] L ≡ K. 𝕓{Abbr} V1 &
 101                                       K ⊢ V1 [O, d + e - i - 1] ≫ V2 &
 102                                       ↑[O, i + 1] V2 ≡ T2.
 103 #L #T1 #T2 #d #e * -L T1 T2 d e
 104 [ #L #k #d #e #i #H destruct
 105 | /2/
 106 | #L #K #V1 #V2 #T2 #i #d #e #Hdi #Hide #HLK #HV12 #HVT2 #j #H destruct -i /3 width=9/
 107 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 108 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 109 ]
 110 qed.
 111
 112 lemma tps_inv_lref1: ∀L,T2,i,d,e. L ⊢ #i [d, e] ≫ T2 →
 113                      T2 = #i ∨
 114                      ∃∃K,V1,V2,i. d ≤ i & i < d + e &
 115                                   ↓[O, i] L ≡ K. 𝕓{Abbr} V1 &
 116                                   K ⊢ V1 [O, d + e - i - 1] ≫ V2 &
 117                                   ↑[O, i + 1] V2 ≡ T2.
 118 /2/ qed.
 119
 120 lemma tps_inv_bind1_aux: ∀d,e,L,U1,U2. L ⊢ U1 [d, e] ≫ U2 →
 121                          ∀I,V1,T1. U1 = 𝕓{I} V1. T1 →
 122                          ∃∃V2,T2. L ⊢ V1 [d, e] ≫ V2 &
 123                                   L. 𝕓{I} V1 ⊢ T1 [d + 1, e] ≫ T2 &
 124                                   U2 =  𝕓{I} V2. T2.
 125 #d #e #L #U1 #U2 * -d e L U1 U2
 126 [ #L #k #d #e #I #V1 #T1 #H destruct
 127 | #L #i #d #e #I #V1 #T1 #H destruct
 128 | #L #K #V #U1 #U2 #i #d #e #_ #_ #_ #_ #_ #I #V1 #T1 #H destruct
 129 | #L #J #V1 #V2 #T1 #T2 #d #e #HV12 #HT12 #I #V #T #H destruct /2 width=5/
 130 | #L #J #V1 #V2 #T1 #T2 #d #e #_ #_ #I #V #T #H destruct
 131 ]
 132 qed.
 133
 134 lemma tps_inv_bind1: ∀d,e,L,I,V1,T1,U2. L ⊢ 𝕓{I} V1. T1 [d, e] ≫ U2 →
 135                      ∃∃V2,T2. L ⊢ V1 [d, e] ≫ V2 &
 136                               L. 𝕓{I} V1 ⊢ T1 [d + 1, e] ≫ T2 &
 137                               U2 =  𝕓{I} V2. T2.
 138 /2/ qed.
 139
 140 lemma tps_inv_flat1_aux: ∀d,e,L,U1,U2. L ⊢ U1 [d, e] ≫ U2 →
 141                          ∀I,V1,T1. U1 = 𝕗{I} V1. T1 →
 142                          ∃∃V2,T2. L ⊢ V1 [d, e] ≫ V2 & L ⊢ T1 [d, e] ≫ T2 &
 143                                   U2 =  𝕗{I} V2. T2.
 144 #d #e #L #U1 #U2 * -d e L U1 U2
 145 [ #L #k #d #e #I #V1 #T1 #H destruct
 146 | #L #i #d #e #I #V1 #T1 #H destruct
 147 | #L #K #V #U1 #U2 #i #d #e #_ #_ #_ #_ #_ #I #V1 #T1 #H destruct
 148 | #L #J #V1 #V2 #T1 #T2 #d #e #_ #_ #I #V #T #H destruct
 149 | #L #J #V1 #V2 #T1 #T2 #d #e #HV12 #HT12 #I #V #T #H destruct /2 width=5/
 150 ]
 151 qed.
 152
 153 lemma tps_inv_flat1: ∀d,e,L,I,V1,T1,U2. L ⊢ 𝕗{I} V1. T1 [d, e] ≫ U2 →
 154                      ∃∃V2,T2. L ⊢ V1 [d, e] ≫ V2 & L ⊢ T1 [d, e] ≫ T2 &
 155                               U2 =  𝕗{I} V2. T2.
 156 /2/ qed.