(* Copyright (C) 2004, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://helm.cs.unibo.it/
 *)

(* $Id$ *)

open Printf

open GrafiteAst

let tactical_terminator = ""
let tactic_terminator = tactical_terminator
let command_terminator = tactical_terminator

let pp_idents idents = "[" ^ String.concat "; " idents ^ "]"

let pp_reduction_kind ~term_pp = function
  | `Normalize -> "normalize"
  | `Reduce -> "reduce"
  | `Simpl -> "simplify"
  | `Unfold (Some t) -> "unfold " ^ term_pp t
  | `Unfold None -> "unfold"
  | `Whd -> "whd"
 
let pp_tactic_pattern ~term_pp ~lazy_term_pp (what, hyp, goal) = 
  let what_text =
    match what with
    | None -> ""
    | Some t -> sprintf "in match (%s) " (lazy_term_pp t) in
  let hyp_text =
    String.concat " "
      (List.map (fun (name, p) -> sprintf "%s:(%s)" name (term_pp p)) hyp) in
  let goal_text =
    match goal with
    | None -> ""
    | Some t -> sprintf "\\vdash (%s)" (term_pp t) in
  sprintf "%sin %s%s" what_text hyp_text goal_text

let pp_intros_specs = function
   | None, []         -> ""
   | Some num, []     -> Printf.sprintf " names %i" num
   | None, idents     -> Printf.sprintf " names %s" (pp_idents idents)
   | Some num, idents -> Printf.sprintf " names %i %s" num (pp_idents idents)

let terms_pp ~term_pp terms = String.concat ", " (List.map term_pp terms)

let opt_string_pp = function
   | None -> ""
   | Some what -> what ^ " "

let rec pp_tactic ~term_pp ~lazy_term_pp =
  let pp_reduction_kind = pp_reduction_kind ~term_pp in
  let pp_tactic_pattern = pp_tactic_pattern ~lazy_term_pp ~term_pp in
  function
  | Absurd (_, term) -> "absurd" ^ term_pp term
  | Apply (_, term) -> "apply " ^ term_pp term
  | ApplyS (_, term, params) ->
     "applyS " ^ term_pp term ^
      String.concat " " 
        (List.map (fun (k,v) -> if v <> "" then k ^ "=" ^ v else k) params)
  | Auto (_,params) -> "auto " ^ 
      String.concat " " 
        (List.map (fun (k,v) -> if v <> "" then k ^ "=" ^ v else k) params)
  | Assumption _ -> "assumption"
  | Change (_, where, with_what) ->
      sprintf "change %s with %s" (pp_tactic_pattern where) (lazy_term_pp with_what)
  | Clear (_,ids) -> sprintf "clear %s" (pp_idents ids)
  | ClearBody (_,id) -> sprintf "clearbody %s" id
  | Constructor (_,n) -> "constructor " ^ string_of_int n
  | Contradiction _ -> "contradiction"
  | Cut (_, ident, term) ->
     "cut " ^ term_pp term ^
      (match ident with None -> "" | Some id -> " as " ^ id)
  | Decompose (_, [], what, names) ->
      sprintf "decompose %s%s" (opt_string_pp what) (pp_intros_specs (None, names)) 
  | Decompose (_, types, what, names) ->
      let to_ident = function
         | Ident id -> id
	 | Type _   -> assert false 
      in
      let types = List.rev_map to_ident types in
      sprintf "decompose %s %s%s" (pp_idents types) (opt_string_pp what) (pp_intros_specs (None, names)) 
  | Demodulate _ -> "demodulate"
  | Destruct (_, term) -> "destruct " ^ term_pp term
  | Elim (_, term, using, num, idents) ->
      sprintf "elim " ^ term_pp term ^
      (match using with None -> "" | Some term -> " using " ^ term_pp term)
      ^ pp_intros_specs (num, idents) 
  | ElimType (_, term, using, num, idents) ->
      sprintf "elim type " ^ term_pp term ^
      (match using with None -> "" | Some term -> " using " ^ term_pp term)
      ^ pp_intros_specs (num, idents)
  | Exact (_, term) -> "exact " ^ term_pp term
  | Exists _ -> "exists"
  | Fold (_, kind, term, pattern) ->
      sprintf "fold %s %s %s" (pp_reduction_kind kind)
       (lazy_term_pp term) (pp_tactic_pattern pattern)
  | FwdSimpl (_, hyp, idents) -> 
      sprintf "fwd %s%s" hyp 
        (match idents with [] -> "" | idents -> " as " ^ pp_idents idents)
  | Generalize (_, pattern, ident) ->
     sprintf "generalize %s%s" (pp_tactic_pattern pattern)
      (match ident with None -> "" | Some id -> " as " ^ id)
  | Goal (_, n) -> "goal " ^ string_of_int n
  | Fail _ -> "fail"
  | Fourier _ -> "fourier"
  | IdTac _ -> "id"
  | Intros (_, None, []) -> "intros"
  | Inversion (_, term) -> "inversion " ^ term_pp term
  | Intros (_, num, idents) ->
      sprintf "intros%s%s"
        (match num with None -> "" | Some num -> " " ^ string_of_int num)
        (match idents with [] -> "" | idents -> " " ^ pp_idents idents)
  | LApply (_, linear, level_opt, terms, term, ident_opt) -> 
      sprintf "lapply %s%s%s%s%s" 
        (if linear then " linear " else "")
	(match level_opt with None -> "" | Some i -> " depth = " ^ string_of_int i ^ " ")  
        (term_pp term) 
        (match terms with [] -> "" | _ -> " to " ^ terms_pp ~term_pp terms)
        (match ident_opt with None -> "" | Some ident -> " as " ^ ident)
  | Left _ -> "left"
  | LetIn (_, term, ident) -> sprintf "let %s in %s" (term_pp term) ident
  | Reduce (_, kind, pat) ->
      sprintf "%s %s" (pp_reduction_kind kind) (pp_tactic_pattern pat)
  | Reflexivity _ -> "reflexivity"
  | Replace (_, pattern, t) ->
      sprintf "replace %s with %s" (pp_tactic_pattern pattern) (lazy_term_pp t)
  | Rewrite (_, pos, t, pattern) -> 
      sprintf "rewrite %s %s %s" 
        (if pos = `LeftToRight then ">" else "<")
        (term_pp t)
        (pp_tactic_pattern pattern)
  | Right _ -> "right"
  | Ring _ -> "ring"
  | Split _ -> "split"
  | Subst _ -> "subst"
  | Symmetry _ -> "symmetry"
  | Transitivity (_, term) -> "transitivity " ^ term_pp term
  (* Tattiche Aggiunte *)
  | Assume (_, ident , term) -> "assume" ^ ident ^ ":" ^ term_pp term 
  | Suppose (_, term, ident,term1) -> "suppose" ^ term_pp term ^ "("  ^ ident ^ ")" ^ (match term1 with None -> " " | Some term1 -> term_pp term1)
  | Bydone (_, term) -> "by" ^ (match term with None -> "_" | Some term -> term_pp term) ^ "done"
  | By_term_we_proved (_, term, term1, ident, term2) -> "by" ^ (match term with None -> "_" | Some term -> term_pp term)  ^ "we proved" ^ term_pp term1 ^ (match ident with None -> "" | Some ident -> "(" ^ident^ ")") ^
       (match term2 with  None -> " " | Some term2 -> term_pp term2)
  | We_need_to_prove (_, term, ident, term1) -> "we need to prove" ^ term_pp term ^ (match ident with None -> "" | Some ident -> "(" ^ ident ^ ")") ^ (match term1 with None -> " " | Some term1 -> term_pp term1)
  | We_proceed_by_induction_on (_, term, term1) -> "we proceed by induction on" ^ term_pp term ^ "to prove" ^ term_pp term1
  | Byinduction (_, term, ident) -> "by induction hypothesis we know" ^ term_pp term ^ "(" ^ ident ^ ")"
  | Thesisbecomes (_, term) -> "the thesis becomes " ^ term_pp term
  | ExistsElim (_, term0, ident, term, ident1, term1) -> "by " ^ term_pp term0 ^ "let " ^ ident ^ ":" ^ term_pp term ^ "such that " ^ term_pp term1 ^ "(" ^ ident1 ^ ")"
  | AndElim (_, term, ident1, term1, ident2, term2) -> "by " ^ term_pp term ^ "we have " ^ term_pp term1 ^ " (" ^ ident1 ^ ") " ^ "and " ^ term_pp term2 ^ " (" ^ ident2 ^ ")" 
  | RewritingStep (_, term, term1, term2, cont) -> (match term with None -> " " | Some term -> "obtain " ^ term_pp term) ^ "=" ^ term_pp term1 ^ (match term2 with None -> "_" | Some term2 -> term_pp term2) ^ (match cont with None -> " done" | Some Cic.Anonymous -> "" | Some (Cic.Name id) -> " we proved " ^ id)
  | Case (_, id, args) ->
     "case" ^ id ^
       String.concat " "
        (List.map (function (id,term) -> "(" ^ id ^ ": " ^ term_pp term ^  ")")
	  args)

 let pp_search_kind = function
  | `Locate -> "locate"
  | `Hint -> "hint"
  | `Match -> "match"
  | `Elim -> "elim"
  | `Instance -> "instance"

let pp_arg ~term_pp arg = 
  let s = term_pp arg in
   if s = "" || (s.[0] = '(' && s.[String.length s - 1] = ')') then
     (* _nice_ heuristic *)
     s
   else
     "(" ^ s ^ ")"
  
let pp_macro ~term_pp = 
  let term_pp = pp_arg ~term_pp in
  function 
  (* Whelp *)
  | WInstance (_, term) -> "whelp instance " ^ term_pp term
  | WHint (_, t) -> "whelp hint " ^ term_pp t
  | WLocate (_, s) -> "whelp locate \"" ^ s ^ "\""
  | WElim (_, t) -> "whelp elim " ^ term_pp t
  | WMatch (_, term) -> "whelp match " ^ term_pp term
  (* real macros *)
  | Check (_, term) -> sprintf "check %s" (term_pp term)
  | Hint _ -> "hint"
  | Inline (_,suri) -> sprintf "inline \"%s\"" suri

let pp_associativity = function
  | Gramext.LeftA -> "left associative"
  | Gramext.RightA -> "right associative"
  | Gramext.NonA -> "non associative"

let pp_precedence i = sprintf "with precedence %d" i

let pp_dir_opt = function
  | None -> ""
  | Some `LeftToRight -> "> "
  | Some `RightToLeft -> "< "

let pp_default what uris = 
  sprintf "default \"%s\" %s" what
    (String.concat " " (List.map UriManager.string_of_uri uris))

let pp_coercion uri do_composites arity =
   sprintf "coercion %s %d (* %s *)" (UriManager.string_of_uri uri) arity
     (if do_composites then "compounds" else "no compounds")
    
let pp_command ~term_pp ~obj_pp = function
  | Coercion (_, uri, do_composites, i) -> pp_coercion uri do_composites i
  | Default (_,what,uris) -> pp_default what uris
  | Drop _ -> "drop"
  | Include (_,path) -> "include \"" ^ path ^ "\""
  | Obj (_,obj) -> obj_pp obj
  | Qed _ -> "qed"
  | Relation (_,id,a,aeq,refl,sym,trans) ->
     "relation " ^ term_pp aeq ^ " on " ^ term_pp a ^
     (match refl with
         Some r -> " reflexivity proved by " ^ term_pp r
       | None -> "") ^
     (match sym with
         Some r -> " symmetry proved by " ^ term_pp r
       | None -> "") ^
     (match trans with
         Some r -> " transitivity proved by " ^ term_pp r
       | None -> "")
  | Print (_,s) -> "print " ^ s
  | Set (_, name, value) -> sprintf "set \"%s\" \"%s\"" name value

let rec pp_tactical ~term_pp ~lazy_term_pp =
  let pp_tactic = pp_tactic ~lazy_term_pp ~term_pp in
  let pp_tacticals = pp_tacticals ~lazy_term_pp ~term_pp in
  function
  | Tactic (_, tac) -> pp_tactic tac
  | Do (_, count, tac) ->
      sprintf "do %d %s" count (pp_tactical ~term_pp ~lazy_term_pp tac)
  | Repeat (_, tac) -> "repeat " ^ pp_tactical ~term_pp ~lazy_term_pp tac
  | Seq (_, tacs) -> pp_tacticals ~sep:"; " tacs
  | Then (_, tac, tacs) ->
      sprintf "%s; [%s]" (pp_tactical ~term_pp ~lazy_term_pp tac)
        (pp_tacticals ~sep:" | " tacs)
  | First (_, tacs) -> sprintf "tries [%s]" (pp_tacticals ~sep:" | " tacs)
  | Try (_, tac) -> "try " ^ pp_tactical ~term_pp ~lazy_term_pp tac
  | Solve (_, tac) -> sprintf "solve [%s]" (pp_tacticals ~sep:" | " tac)
  | Progress (_, tac) -> "progress " ^ pp_tactical ~term_pp ~lazy_term_pp tac

  | Dot _ -> "."
  | Semicolon _ -> ";"
  | Branch _ -> "["
  | Shift _ -> "|"
  | Pos (_, i) -> sprintf "%s:" (String.concat "," (List.map string_of_int i))
  | Wildcard _ -> "*:"
  | Merge _ -> "]"
  | Focus (_, goals) ->
      sprintf "focus %s" (String.concat " " (List.map string_of_int goals))
  | Unfocus _ -> "unfocus"
  | Skip _ -> "skip"

and pp_tacticals ~term_pp ~lazy_term_pp ~sep tacs =
  String.concat sep (List.map (pp_tactical~lazy_term_pp ~term_pp) tacs)

let pp_executable ~term_pp ~lazy_term_pp ~obj_pp =
  function
  | Macro (_, macro) -> pp_macro ~term_pp macro ^ "."
  | Tactical (_, tac, Some punct) ->
      pp_tactical ~lazy_term_pp ~term_pp tac
      ^ pp_tactical ~lazy_term_pp ~term_pp punct
  | Tactical (_, tac, None) -> pp_tactical ~lazy_term_pp ~term_pp tac
  | Command (_, cmd) -> pp_command ~term_pp ~obj_pp cmd ^ "."
                      
let pp_comment ~term_pp ~lazy_term_pp ~obj_pp =
  function
  | Note (_,str) -> sprintf "(* %s *)" str
  | Code (_,code) ->
      sprintf "(** %s. **)" (pp_executable ~term_pp ~lazy_term_pp ~obj_pp code)

let pp_statement ~term_pp ~lazy_term_pp ~obj_pp =
  function
  | Executable (_, ex) -> pp_executable ~lazy_term_pp ~term_pp ~obj_pp ex 
  | Comment (_, c) -> pp_comment ~term_pp ~lazy_term_pp ~obj_pp c