(* Copyright (C) 2000, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://cs.unibo.it/helm/.
 *)

(* $Id$ *)

open Printf;;

type coercion_search_result = 
  | SomeCoercion of Cic.term
  | NoCoercion
  | NotMetaClosed
  | NotHandled of string Lazy.t

let debug = false
let debug_print s = if debug then prerr_endline (Lazy.force s) else ()

(* searches a coercion fron src to tgt in the !coercions list *)
let look_for_coercion src tgt =
  let arity_of con =
    try
      let ty,_ = CicTypeChecker.type_of_aux' [] [] con CicUniv.empty_ugraph in
      let rec count_pi = function
        | Cic.Prod (_,_,t) -> 1 + count_pi t
        | _ -> 0
      in
      count_pi ty
    with Invalid_argument _ -> assert false (* all coercions have an uri *)
  in
  let rec mk_implicits = function
    | 0 -> [] 
    | n -> Cic.Implicit None :: mk_implicits (n-1)
  in
  try 
    let l = 
      CoercDb.find_coercion 
        (fun (s,t) -> CoercDb.eq_carr s src && CoercDb.eq_carr t tgt) in
    let uri =
     match l with
     | [] -> 
         debug_print 
           (lazy 
             (sprintf ":-( coercion non trovata da %s a %s" 
               (CoercDb.name_of_carr src) 
               (CoercDb.name_of_carr tgt)));
         None
     | [u] -> 
         debug_print (lazy (
           sprintf ":-) TROVATA 1 coercion da %s a %s: %s" 
             (CoercDb.name_of_carr src) 
             (CoercDb.name_of_carr tgt)
             (UriManager.name_of_uri u)));
         Some u
     | u::_ -> 
         debug_print (lazy (
           sprintf ":-/ TROVATE %d coercion(s) da %s a %s, prendo la prima: %s" 
             (List.length l)
             (CoercDb.name_of_carr src) 
             (CoercDb.name_of_carr tgt)
             (UriManager.name_of_uri u)));
         Some u
    in
     (match uri with
         None -> NoCoercion
       | Some u ->
          let c = CicUtil.term_of_uri u in
          let arity = arity_of c in
          let args = mk_implicits (arity - 1) in
          let newt =
           match args with
              [] -> c
            | _ -> Cic.Appl (c::args)
          in
           SomeCoercion newt)
  with
    | CoercDb.EqCarrNotImplemented s -> NotHandled s
    | CoercDb.EqCarrOnNonMetaClosed -> NotMetaClosed
;;

let look_for_coercion src tgt = 
  let src_uri = CoercDb.coerc_carr_of_term src in
  let tgt_uri = CoercDb.coerc_carr_of_term tgt in
  look_for_coercion src_uri tgt_uri

let is_a_coercion t = 
  try
    let uri = CicUtil.uri_of_term t in
    CoercDb.is_a_coercion uri
  with Invalid_argument _ -> false

let source_of t = 
  try
    let uri = CicUtil.uri_of_term t in
    CoercDb.term_of_carr (fst (CoercDb.get_carr uri))
  with Invalid_argument _ -> assert false (* t must be a coercion *)
  
let target_of t =
  try
    let uri = CicUtil.uri_of_term t in
    CoercDb.term_of_carr (snd (CoercDb.get_carr uri))
  with Invalid_argument _ -> assert false (* t must be a coercion *)
    
let generate_dot_file () =
  let l = CoercDb.to_list () in
  let preamble = "
    digraph pippo {
      node [fontsize=9, width=.4, height=.4];
      edge [fontsize=10]; 
      \n" 
  in
  let conclusion = " } \n" in
  let data = List.fold_left 
    (fun acc (src,tgt,c) -> 
      acc ^ CoercDb.name_of_carr src ^ " -> " ^ 
      CoercDb.name_of_carr tgt ^ "[label=\"" ^ UriManager.name_of_uri c ^ 
      "\"];\n") "" l 
  in
  preamble ^ data ^ conclusion
  
(* EOF *)