(* Copyright (C) 2005, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://helm.cs.unibo.it/
 *)

let compose_tac ?howmany ?mk_fresh_name_callback t1 t2 (proof, goal) =
  let _,metasenv,_subst,_,_,_ = proof in
  let _,context,_ = CicUtil.lookup_meta goal metasenv in
  let ty1,_ = 
    CicTypeChecker.type_of_aux' metasenv context t1 CicUniv.oblivion_ugraph 
  in
  let rec count_pi = function Cic.Prod (_,_,t) -> count_pi t + 1 | _ -> 0 in
  let rec generate arity menv acc =
    if arity < 0 then acc, menv
    else
      try
        let t, menv, _ =
          CloseCoercionGraph.generate_composite t1 t2 context menv
            CicUniv.oblivion_ugraph arity false
        in
        generate (arity - 1) menv (t::acc)
      with 
      | CloseCoercionGraph.UnableToCompose -> generate (arity - 1) menv acc
  in
  let terms, metasenv = generate (count_pi ty1) metasenv [] in
  let proof = 
    let uri, _, _subst, bo, ty, attrs = proof in
    uri, metasenv, _subst, bo, ty, attrs
  in
  let proof, goal =
    List.fold_left 
      (fun (proof,goal) t ->
        let lazy_of t =
          ProofEngineTypes.const_lazy_term t
        in
        let proof, gl = 
          ProofEngineTypes.apply_tactic
            (VariousTactics.generalize_tac (Some (lazy_of t), [], None))
            (proof,goal)
        in
        assert(List.length gl = 1);
        proof,List.hd gl)
      (proof,goal) terms
  in
  ProofEngineTypes.apply_tactic 
    (PrimitiveTactics.intros_tac ?howmany ?mk_fresh_name_callback ())
    (proof,goal)
;;

let compose_tac ?howmany ?mk_fresh_name_callback t1 t2 =
  ProofEngineTypes.mk_tactic 
    (compose_tac ?howmany ?mk_fresh_name_callback t1 t2)
;;