(* cOpyright (C) 2005, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://cs.unibo.it/helm/.
 *)

(* $Id: inference.ml 6245 2006-04-05 12:07:51Z tassi $ *)

type rule = SuperpositionRight | SuperpositionLeft | Demodulation
type uncomparable = int -> int 
type equality =
    uncomparable *       (* trick to break structural equality *)
    int  *               (* weight *)
    proof * 
    (Cic.term *          (* type *)
     Cic.term *          (* left side *)
     Cic.term *          (* right side *)
     Utils.comparison) * (* ordering *)  
    Cic.metasenv  *      (* environment for metas *)
    int                  (* id *)
and proof = 
  | Exact of Cic.term
  | Step of Subst.substitution * (rule * int*(Utils.pos*int)* Cic.term) 
            (* subst, (rule,eq1, eq2,predicate) *)  
and goal_proof = (Utils.pos * int * Subst.substitution * Cic.term) list
;;

(* globals *)
let maxid = ref 0;;
let id_to_eq = Hashtbl.create 1024;;

let freshid () =
  incr maxid; !maxid
;;

let reset () = 
  maxid := 0;
  Hashtbl.clear  id_to_eq
;;

let uncomparable = fun _ -> 0

let mk_equality (weight,p,(ty,l,r,o),m) =
  let id = freshid () in
  let eq = (uncomparable,weight,p,(ty,l,r,o),m,id) in
  Hashtbl.add id_to_eq id eq;
  eq
;;

let mk_tmp_equality (weight,(ty,l,r,o),m) =
  let id = -1 in
  uncomparable,weight,Exact (Cic.Implicit None),(ty,l,r,o),m,id
;;


let open_equality (_,weight,proof,(ty,l,r,o),m,id) = 
  (weight,proof,(ty,l,r,o),m,id)

let string_of_equality ?env eq =
  match env with
  | None ->
      let w, _, (ty, left, right, o), _ , id = open_equality eq in
      Printf.sprintf "Id: %d, Weight: %d, {%s}: %s =(%s) %s" 
              id w (CicPp.ppterm ty)
              (CicPp.ppterm left) 
              (Utils.string_of_comparison o) (CicPp.ppterm right)
  | Some (_, context, _) -> 
      let names = Utils.names_of_context context in
      let w, _, (ty, left, right, o), _ , id = open_equality eq in
      Printf.sprintf "Id: %d, Weight: %d, {%s}: %s =(%s) %s" 
              id w (CicPp.pp ty names)
              (CicPp.pp left names) (Utils.string_of_comparison o)
              (CicPp.pp right names)
;;

let compare (_,_,_,s1,_,_) (_,_,_,s2,_,_) =
  Pervasives.compare s1 s2
;;

let proof_of_id id =
  try
    let (_,p,(_,l,r,_),_,_) = open_equality (Hashtbl.find id_to_eq id) in
      p,l,r
  with
      Not_found -> assert false


let string_of_proof ?(names=[]) p gp = 
  let str_of_rule = function
    | SuperpositionRight -> "SupR"
    | SuperpositionLeft -> "SupL"
    | Demodulation -> "Demod"
  in
  let str_of_pos = function
    | Utils.Left -> "left"
    | Utils.Right -> "right"
  in
  let fst3 (x,_,_) = x in
  let rec aux margin name = 
    let prefix = String.make margin ' ' ^ name ^ ": " in function 
    | Exact t -> 
        Printf.sprintf "%sExact (%s)\n" 
          prefix (CicPp.pp t names)
    | Step (subst,(rule,eq1,(pos,eq2),pred)) -> 
        Printf.sprintf "%s%s(%s|%d with %d dir %s pred %s))\n"
          prefix (str_of_rule rule) (Subst.ppsubst ~names subst) eq1 eq2 (str_of_pos pos) 
          (CicPp.pp pred names)^ 
        aux (margin+1) (Printf.sprintf "%d" eq1) (fst3 (proof_of_id eq1)) ^ 
        aux (margin+1) (Printf.sprintf "%d" eq2) (fst3 (proof_of_id eq2)) 
  in
  aux 0 "" p ^ 
  String.concat "\n" 
    (List.map 
      (fun (pos,i,s,t) -> 
        (Printf.sprintf 
          "GOAL: %s %d %s %s\n" 
            (str_of_pos pos) i (Subst.ppsubst ~names s) (CicPp.pp t names)) ^ 
        aux 1 (Printf.sprintf "%d " i) (fst3 (proof_of_id i)))
      gp)
;;

let rec depend eq id =
  let (_,p,(_,_,_,_),_,ideq) = open_equality eq in
  if id = ideq then true else  
  match p with
      Exact _ -> false
    | Step (_,(_,id1,(_,id2),_)) ->
        let eq1 = Hashtbl.find id_to_eq id1 in
        let eq2 = Hashtbl.find id_to_eq id2 in  
        depend eq1 id || depend eq2 id
;;

let ppsubst = Subst.ppsubst ~names:[];;

(* returns an explicit named subst and a list of arguments for sym_eq_URI *)
let build_ens uri termlist =
  let obj, _ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
  match obj with
  | Cic.Constant (_, _, _, uris, _) ->
      assert (List.length uris <= List.length termlist);
      let rec aux = function
        | [], tl -> [], tl
        | (uri::uris), (term::tl) ->
            let ens, args = aux (uris, tl) in
            (uri, term)::ens, args
        | _, _ -> assert false
      in
      aux (uris, termlist)
  | _ -> assert false
;;

let mk_sym uri ty t1 t2 p =
  let ens, args =  build_ens uri [ty;t1;t2;p] in
    Cic.Appl (Cic.Const(uri, ens) :: args)
;;

let mk_trans uri ty t1 t2 t3 p12 p23 =
  let ens, args = build_ens uri [ty;t1;t2;t3;p12;p23] in
    Cic.Appl (Cic.Const (uri, ens) :: args)
;;

let mk_eq_ind uri ty what pred p1 other p2 =
 Cic.Appl [Cic.Const (uri, []); ty; what; pred; p1; other; p2]
;;

let p_of_sym ens tl =
  let args = List.map snd ens @ tl in
  match args with 
    | [_;_;_;p] -> p 
    | _ -> assert false 
;;

let open_trans ens tl =
  let args = List.map snd ens @ tl in
  match args with 
    | [ty;l;m;r;p1;p2] -> ty,l,m,r,p1,p2
    | _ -> assert false   
;;

let open_eq_ind args =
  match args with 
  | [ty;l;pred;pl;r;pleqr] -> ty,l,pred,pl,r,pleqr
  | _ -> assert false   
;;

let open_pred pred =
  match pred with 
  | Cic.Lambda (_,ty,(Cic.Appl [Cic.MutInd (uri, 0,_);_;l;r])) 
     when LibraryObjects.is_eq_URI uri -> ty,uri,l,r
  | _ -> prerr_endline (CicPp.ppterm pred); assert false   
;;

let is_not_fixed t =
   CicSubstitution.subst (Cic.Implicit None) t <>
   CicSubstitution.subst (Cic.Rel 1) t
;;


let canonical t = 
  let rec remove_refl t =
    match t with
    | Cic.Appl (((Cic.Const(uri_trans,ens))::tl) as args)
          when LibraryObjects.is_trans_eq_URI uri_trans ->
          let ty,l,m,r,p1,p2 = open_trans ens tl in
            (match p1,p2 with
              | Cic.Appl [Cic.MutConstruct (uri, 0, 1,_);_;_],p2 -> 
                  remove_refl p2
              | p1,Cic.Appl [Cic.MutConstruct (uri, 0, 1,_);_;_] -> 
                  remove_refl p1
              | _ -> Cic.Appl (List.map remove_refl args))
    | Cic.Appl l -> Cic.Appl (List.map remove_refl l)
    | _ -> t
  in
  let rec canonical t =
    match t with
      | Cic.Appl (((Cic.Const(uri_sym,ens))::tl) as args)
          when LibraryObjects.is_sym_eq_URI uri_sym ->
          (match p_of_sym ens tl with
             | Cic.Appl ((Cic.Const(uri,ens))::tl)
                 when LibraryObjects.is_sym_eq_URI uri -> 
                   canonical (p_of_sym ens tl)
             | Cic.Appl ((Cic.Const(uri_trans,ens))::tl)
                 when LibraryObjects.is_trans_eq_URI uri_trans ->
                 let ty,l,m,r,p1,p2 = open_trans ens tl in
                   mk_trans uri_trans ty r m l 
                     (canonical (mk_sym uri_sym ty m r p2)) 
                     (canonical (mk_sym uri_sym ty l m p1))
             | Cic.Appl (((Cic.Const(uri_ind,ens)) as he)::tl) 
                 when LibraryObjects.is_eq_ind_URI uri_ind || 
                      LibraryObjects.is_eq_ind_r_URI uri_ind ->
                 let ty, what, pred, p1, other, p2 =
                   match tl with
                   | [ty;what;pred;p1;other;p2] -> ty, what, pred, p1, other, p2
                   | _ -> assert false
                 in
                 let pred,l,r = 
                   match pred with
                   | Cic.Lambda (name,s,Cic.Appl [Cic.MutInd(uri,0,ens);ty;l;r])
                       when LibraryObjects.is_eq_URI uri ->
                         Cic.Lambda 
                           (name,s,Cic.Appl [Cic.MutInd(uri,0,ens);ty;r;l]),l,r
                   | _ -> 
                       prerr_endline (CicPp.ppterm pred);
                       assert false
                 in
                 let l = CicSubstitution.subst what l in
                 let r = CicSubstitution.subst what r in
                 Cic.Appl 
                   [he;ty;what;pred;
                    canonical (mk_sym uri_sym ty l r p1);other;canonical p2]
             | Cic.Appl [Cic.MutConstruct (uri, 0, 1,_);_;_] as t
                 when LibraryObjects.is_eq_URI uri -> t
             | _ -> Cic.Appl (List.map canonical args))
      | Cic.Appl l -> Cic.Appl (List.map canonical l)
      | _ -> t
  in
  remove_refl (canonical t)
;;
  
let ty_of_lambda = function
  | Cic.Lambda (_,ty,_) -> ty
  | _ -> assert false 
;;

let compose_contexts ctx1 ctx2 = 
  ProofEngineReduction.replace_lifting 
    ~equality:(=) ~what:[Cic.Rel 1] ~with_what:[ctx2] ~where:ctx1
;;

let put_in_ctx ctx t = 
  ProofEngineReduction.replace_lifting
    ~equality:(=) ~what:[Cic.Rel 1] ~with_what:[t] ~where:ctx
;;

let mk_eq uri ty l r =
  Cic.Appl [Cic.MutInd(uri,0,[]);ty;l;r]
;;

let mk_refl uri ty t = 
  Cic.Appl [Cic.MutConstruct(uri,0,1,[]);ty;t]
;;

let open_eq = function 
  | Cic.Appl [Cic.MutInd(uri,0,[]);ty;l;r] when LibraryObjects.is_eq_URI uri ->
      uri, ty, l ,r
  | _ -> assert false
;;

let contextualize uri ty left right t = 
  (* aux [uri] [ty] [left] [right] [ctx] [t] 
   * 
   * the parameters validate this invariant  
   *   t: eq(uri) ty left right
   * that is used only by the base case
   *
   * ctx is a term with an open (Rel 1). (Rel 1) is the empty context
   *)
    let rec aux uri ty left right ctx_d = function
      | Cic.Appl ((Cic.Const(uri_ind,ens))::tl)
        when LibraryObjects.is_eq_ind_URI uri_ind || 
             LibraryObjects.is_eq_ind_r_URI uri_ind ->
          let ty1,what,pred,p1,other,p2 = open_eq_ind tl in
          let ty2,eq,lp,rp = open_pred pred in 
          let uri_trans = LibraryObjects.trans_eq_URI ~eq:uri in
          let uri_sym = LibraryObjects.sym_eq_URI ~eq:uri in
          let is_not_fixed_lp = is_not_fixed lp in
          let avoid_eq_ind = LibraryObjects.is_eq_ind_URI uri_ind in
          (* extract the context and the fixed term from the predicate *)
          let m, ctx_c = 
            let m, ctx_c = if is_not_fixed_lp then rp,lp else lp,rp in
            (* they were under a lambda *)
            let m =  CicSubstitution.subst (Cic.Implicit None) m in
            let ctx_c = CicSubstitution.subst (Cic.Rel 1) ctx_c in
            m, ctx_c          
          in
          (* create the compound context and put the terms under it *)
          let ctx_dc = compose_contexts ctx_d ctx_c in
          let dc_what = put_in_ctx ctx_dc what in
          let dc_other = put_in_ctx ctx_dc other in
          (* m is already in ctx_c so it is put in ctx_d only *)
          let d_m = put_in_ctx ctx_d m in
          (* we also need what in ctx_c *)
          let c_what = put_in_ctx ctx_c what in
          (* now put the proofs in the compound context *)
          let p1 = (* p1: dc_what = d_m *)
            if is_not_fixed_lp then 
              aux uri ty1 c_what m ctx_d p1 
            else
              mk_sym uri_sym ty d_m dc_what
                (aux uri ty1 m c_what ctx_d p1)
          in
          let p2 = (* p2: dc_other = dc_what *)
            if avoid_eq_ind then
              mk_sym uri_sym ty dc_what dc_other
                (aux uri ty1 what other ctx_dc p2)
            else
              aux uri ty1 other what ctx_dc p2
          in
          (* if pred = \x.C[x]=m --> t : C[other]=m --> trans other what m
             if pred = \x.m=C[x] --> t : m=C[other] --> trans m what other *)
          let a,b,c,paeqb,pbeqc =
            if is_not_fixed_lp then
              dc_other,dc_what,d_m,p2,p1
            else
              d_m,dc_what,dc_other,
                (mk_sym uri_sym ty dc_what d_m p1),
                (mk_sym uri_sym ty dc_other dc_what p2)
          in
          mk_trans uri_trans ty a b c paeqb pbeqc
    | t -> 
        let uri_sym = LibraryObjects.sym_eq_URI ~eq:uri in
        let uri_ind = LibraryObjects.eq_ind_URI ~eq:uri in
        let pred = 
          (* ctx_d will go under a lambda, but put_in_ctx substitutes Rel 1 *)
          let ctx_d = CicSubstitution.lift_from 2 1 ctx_d in (* bleah *)
          let r = put_in_ctx ctx_d (CicSubstitution.lift 1 left) in
          let l = ctx_d in
          let lty = CicSubstitution.lift 1 ty in 
          Cic.Lambda (Cic.Name "foo",ty,(mk_eq uri lty l r))
        in
        let d_left = put_in_ctx ctx_d left in
        let d_right = put_in_ctx ctx_d right in
        let refl_eq = mk_refl uri ty d_left in
        mk_sym uri_sym ty d_right d_left
          (mk_eq_ind uri_ind ty left pred refl_eq right t)
  in
  let empty_context = Cic.Rel 1 in
  aux uri ty left right empty_context t
;;

let contextualize_rewrites t ty = 
  let eq,ty,l,r = open_eq ty in
  contextualize eq ty l r t
;;
  
let build_proof_step subst p1 p2 pos l r pred =
  let p1 = Subst.apply_subst subst p1 in
  let p2 = Subst.apply_subst subst p2 in
  let l  = Subst.apply_subst subst l in
  let r  = Subst.apply_subst subst r in
  let pred = Subst.apply_subst subst pred in
  let ty,body = 
    match pred with
      | Cic.Lambda (_,ty,body) -> ty,body 
      | _ -> assert false
  in
  let what, other = 
    if pos = Utils.Left then l,r else r,l
  in
    match pos with
      | Utils.Left ->
        mk_eq_ind (Utils.eq_ind_URI ()) ty what pred p1 other p2
      | Utils.Right ->
        mk_eq_ind (Utils.eq_ind_r_URI ()) ty what pred p1 other p2
;;

let build_proof_term proof =
  let rec aux = function
     | Exact term -> term
     | Step (subst,(_, id1, (pos,id2), pred)) ->
         let p,_,_ = proof_of_id id1 in
         let p1 = aux p in
         let p,l,r = proof_of_id id2 in
         let p2 = aux p in
           build_proof_step subst p1 p2 pos l r pred
  in
   aux proof
;;

let wfo goalproof proof =
  let rec aux acc id =
    let p,_,_ = proof_of_id id in
    match p with
    | Exact _ -> if (List.mem id acc) then acc else id :: acc
    | Step (_,(_,id1, (_,id2), _)) -> 
        let acc = if not (List.mem id1 acc) then aux acc id1 else acc in
        let acc = if not (List.mem id2 acc) then aux acc id2 else acc in
        id :: acc
  in
  let acc = 
    match proof with
      | Exact _ -> []
      | Step (_,(_,id1, (_,id2), _)) -> aux (aux [] id1) id2
  in 
  List.fold_left (fun acc (_,id,_,_) -> aux acc id) acc goalproof
;;

let string_of_id names id = 
  try
    let (_,p,(_,l,r,_),_,_) = open_equality (Hashtbl.find id_to_eq id) in
    match p with
    | Exact t -> 
        Printf.sprintf "%d = %s: %s = %s" id
          (CicPp.pp t names) (CicPp.pp l names) (CicPp.pp r names)
    | Step (_,(step,id1, (_,id2), _) ) ->
        Printf.sprintf "%6d: %s %6d %6d   %s = %s" id
          (if step = SuperpositionRight then "SupR" else "Demo") 
          id1 id2 (CicPp.pp l names) (CicPp.pp r names)
  with
      Not_found -> assert false

let pp_proof names goalproof proof =
  String.concat "\n" (List.map (string_of_id names) (wfo goalproof proof)) ^ 
  "\ngoal is demodulated with " ^ 
    (String.concat " " 
      ((List.map (fun (_,i,_,_) -> string_of_int i) goalproof)))
;;

let build_goal_proof l initial ty se =
  let se = List.map (fun i -> Cic.Meta (i,[])) se in 
  let proof,se = 
   List.fold_left 
   (fun (current_proof,se) (pos,id,subst,pred) -> 
      let p,l,r = proof_of_id id in
      let p = build_proof_term p in
      let pos = if pos = Utils.Left then Utils.Right else Utils.Left in
        build_proof_step subst current_proof p pos l r pred,
        List.map (fun x -> Subst.apply_subst subst x) se)
   (initial,se) l
  in
  canonical (contextualize_rewrites proof ty), se
;;

let refl_proof ty term = 
  Cic.Appl 
    [Cic.MutConstruct 
       (LibraryObjects.eq_URI (), 0, 1, []);
       ty; term]
;;

let metas_of_proof p =
  let p = build_proof_term p in
  Utils.metas_of_term p
;;

let relocate newmeta menv =
  let subst, metasenv, newmeta = 
    List.fold_right 
      (fun (i, context, ty) (subst, menv, maxmeta) ->         
        let irl = [] (*
         CicMkImplicit.identity_relocation_list_for_metavariable context *)
        in
        let newsubst = Subst.buildsubst i context (Cic.Meta(maxmeta,irl)) ty subst in
        let newmeta = maxmeta, context, ty in
        newsubst, newmeta::menv, maxmeta+1) 
      menv (Subst.empty_subst, [], newmeta+1)
  in
  let metasenv = Subst.apply_subst_metasenv subst metasenv in
  let subst = Subst.flatten_subst subst in
  subst, metasenv, newmeta


let fix_metas newmeta eq = 
  let w, p, (ty, left, right, o), menv,_ = open_equality eq in
  (* debug 
  let _ , eq = 
    fix_metas_old newmeta (w, p, (ty, left, right, o), menv, args) in
  prerr_endline (string_of_equality eq); *)
  let subst, metasenv, newmeta = relocate newmeta menv in
  let ty = Subst.apply_subst subst ty in
  let left = Subst.apply_subst subst left in
  let right = Subst.apply_subst subst right in
  let fix_proof = function
    | Exact p -> Exact (Subst.apply_subst subst p)
    | Step (s,(r,id1,(pos,id2),pred)) -> 
        Step (Subst.concat s subst,(r,id1,(pos,id2), pred))
  in
  let p = fix_proof p in
  let eq = mk_equality (w, p, (ty, left, right, o), metasenv) in
  (* debug prerr_endline (string_of_equality eq); *)
  newmeta+1, eq  

exception NotMetaConvertible;;

let meta_convertibility_aux table t1 t2 =
  let module C = Cic in
  let rec aux ((table_l, table_r) as table) t1 t2 =
    match t1, t2 with
    | C.Meta (m1, tl1), C.Meta (m2, tl2) ->
        let m1_binding, table_l =
          try List.assoc m1 table_l, table_l
          with Not_found -> m2, (m1, m2)::table_l
        and m2_binding, table_r =
          try List.assoc m2 table_r, table_r
          with Not_found -> m1, (m2, m1)::table_r
        in
        if (m1_binding <> m2) || (m2_binding <> m1) then
          raise NotMetaConvertible
        else (
          try
            List.fold_left2
              (fun res t1 t2 ->
                 match t1, t2 with
                 | None, Some _ | Some _, None -> raise NotMetaConvertible
                 | None, None -> res
                 | Some t1, Some t2 -> (aux res t1 t2))
              (table_l, table_r) tl1 tl2
          with Invalid_argument _ ->
            raise NotMetaConvertible
        )
    | C.Var (u1, ens1), C.Var (u2, ens2)
    | C.Const (u1, ens1), C.Const (u2, ens2) when (UriManager.eq u1 u2) ->
        aux_ens table ens1 ens2
    | C.Cast (s1, t1), C.Cast (s2, t2)
    | C.Prod (_, s1, t1), C.Prod (_, s2, t2)
    | C.Lambda (_, s1, t1), C.Lambda (_, s2, t2)
    | C.LetIn (_, s1, t1), C.LetIn (_, s2, t2) ->
        let table = aux table s1 s2 in
        aux table t1 t2
    | C.Appl l1, C.Appl l2 -> (
        try List.fold_left2 (fun res t1 t2 -> (aux res t1 t2)) table l1 l2
        with Invalid_argument _ -> raise NotMetaConvertible
      )
    | C.MutInd (u1, i1, ens1), C.MutInd (u2, i2, ens2)
        when (UriManager.eq u1 u2) && i1 = i2 -> aux_ens table ens1 ens2
    | C.MutConstruct (u1, i1, j1, ens1), C.MutConstruct (u2, i2, j2, ens2)
        when (UriManager.eq u1 u2) && i1 = i2 && j1 = j2 ->
        aux_ens table ens1 ens2
    | C.MutCase (u1, i1, s1, t1, l1), C.MutCase (u2, i2, s2, t2, l2)
        when (UriManager.eq u1 u2) && i1 = i2 ->
        let table = aux table s1 s2 in
        let table = aux table t1 t2 in (
          try List.fold_left2 (fun res t1 t2 -> (aux res t1 t2)) table l1 l2
          with Invalid_argument _ -> raise NotMetaConvertible
        )
    | C.Fix (i1, il1), C.Fix (i2, il2) when i1 = i2 -> (
        try
          List.fold_left2
            (fun res (n1, i1, s1, t1) (n2, i2, s2, t2) ->
               if i1 <> i2 then raise NotMetaConvertible
               else
                 let res = (aux res s1 s2) in aux res t1 t2)
            table il1 il2
        with Invalid_argument _ -> raise NotMetaConvertible
      )
    | C.CoFix (i1, il1), C.CoFix (i2, il2) when i1 = i2 -> (
        try
          List.fold_left2
            (fun res (n1, s1, t1) (n2, s2, t2) ->
               let res = aux res s1 s2 in aux res t1 t2)
            table il1 il2
        with Invalid_argument _ -> raise NotMetaConvertible
      )
    | t1, t2 when t1 = t2 -> table
    | _, _ -> raise NotMetaConvertible
        
  and aux_ens table ens1 ens2 =
    let cmp (u1, t1) (u2, t2) =
      Pervasives.compare (UriManager.string_of_uri u1) (UriManager.string_of_uri u2)
    in
    let ens1 = List.sort cmp ens1
    and ens2 = List.sort cmp ens2 in
    try
      List.fold_left2
        (fun res (u1, t1) (u2, t2) ->
           if not (UriManager.eq u1 u2) then raise NotMetaConvertible
           else aux res t1 t2)
        table ens1 ens2
    with Invalid_argument _ -> raise NotMetaConvertible
  in
  aux table t1 t2
;;


let meta_convertibility_eq eq1 eq2 =
  let _, _, (ty, left, right, _), _,_ = open_equality eq1 in
  let _, _, (ty', left', right', _), _,_ = open_equality eq2 in
  if ty <> ty' then
    false
  else if (left = left') && (right = right') then
    true
  else if (left = right') && (right = left') then
    true
  else
    try
      let table = meta_convertibility_aux ([], []) left left' in
      let _ = meta_convertibility_aux table right right' in
      true
    with NotMetaConvertible ->
      try
        let table = meta_convertibility_aux ([], []) left right' in
        let _ = meta_convertibility_aux table right left' in
        true
      with NotMetaConvertible ->
        false
;;


let meta_convertibility t1 t2 =
  if t1 = t2 then
    true
  else
    try
      ignore(meta_convertibility_aux ([], []) t1 t2);
      true
    with NotMetaConvertible ->
      false
;;

exception TermIsNotAnEquality;;

let term_is_equality term =
  let iseq uri = UriManager.eq uri (LibraryObjects.eq_URI ()) in
  match term with
  | Cic.Appl [Cic.MutInd (uri, _, _); _; _; _] when iseq uri -> true
  | _ -> false
;;

let equality_of_term proof term =
  let eq_uri = LibraryObjects.eq_URI () in
  let iseq uri = UriManager.eq uri eq_uri in
  match term with
  | Cic.Appl [Cic.MutInd (uri, _, _); ty; t1; t2] when iseq uri ->
      let o = !Utils.compare_terms t1 t2 in
      let stat = (ty,t1,t2,o) in
      let w = Utils.compute_equality_weight stat in
      let e = mk_equality (w, Exact proof, stat,[]) in
      e
  | _ ->
      raise TermIsNotAnEquality
;;

let is_weak_identity eq = 
  let _,_,(_,left, right,_),_,_ = open_equality eq in
  left = right || meta_convertibility left right 
;;

let is_identity (_, context, ugraph) eq = 
  let _,_,(ty,left,right,_),menv,_ = open_equality eq in
  left = right ||
  (* (meta_convertibility left right)) *)
  fst (CicReduction.are_convertible ~metasenv:menv context left right ugraph)
;;


let term_of_equality equality =
  let _, _, (ty, left, right, _), menv, _= open_equality equality in
  let eq i = function Cic.Meta (j, _) -> i = j | _ -> false in
  let argsno = List.length menv in
  let t =
    CicSubstitution.lift argsno
      (Cic.Appl [Cic.MutInd (LibraryObjects.eq_URI (), 0, []); ty; left; right])
  in
  snd (
    List.fold_right
      (fun (i,_,ty) (n, t) ->
         let name = Cic.Name ("X" ^ (string_of_int n)) in
         let ty = CicSubstitution.lift (n-1) ty in
         let t = 
           ProofEngineReduction.replace
             ~equality:eq ~what:[i]
             ~with_what:[Cic.Rel (argsno - (n - 1))] ~where:t
         in
           (n-1, Cic.Prod (name, ty, t)))
      menv (argsno, t))
;;