(*
 * Copyright (C) 2003-2004:
 *    Stefano Zacchiroli <zack@cs.unibo.it>
 *    for the HELM Team http://helm.cs.unibo.it/
 *
 *  This file is part of HELM, an Hypertextual, Electronic
 *  Library of Mathematics, developed at the Computer Science
 *  Department, University of Bologna, Italy.
 *
 *  HELM is free software; you can redistribute it and/or
 *  modify it under the terms of the GNU General Public License
 *  as published by the Free Software Foundation; either version 2
 *  of the License, or (at your option) any later version.
 *
 *  HELM is distributed in the hope that it will be useful,
 *  but WITHOUT ANY WARRANTY; without even the implied warranty of
 *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 *  GNU General Public License for more details.
 *
 *  You should have received a copy of the GNU General Public License
 *  along with HELM; if not, write to the Free Software
 *  Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 *  MA  02111-1307, USA.
 *
 *  For details, see the HELM World-Wide-Web page,
 *  http://helm.cs.unibo.it/
 *)

open Printf

open Http_getter_common
open Http_getter_misc
open Http_getter_debugger
open Http_getter_types

let (index_line_sep_RE, index_sep_RE, trailing_types_RE,
    heading_cic_RE, heading_theory_RE, heading_nuprl_RE,
    heading_rdf_cic_RE, heading_rdf_theory_RE) =
  (Pcre.regexp "[ \t]+", Pcre.regexp "\r\n|\r|\n",
  Pcre.regexp "\\.types$",
  Pcre.regexp "^cic:", Pcre.regexp "^theory:", Pcre.regexp "^nuprl:",
  Pcre.regexp "^helm:rdf.*//cic:", Pcre.regexp "^helm:rdf.*//theory:")

  (* global maps, shared by all threads *)

let cic_map = new Http_getter_map.map Http_getter_env.cic_dbm
let nuprl_map = new Http_getter_map.map Http_getter_env.nuprl_dbm
let rdf_map = new Http_getter_map.map Http_getter_env.rdf_dbm
let xsl_map = new Http_getter_map.map Http_getter_env.xsl_dbm

let maps = [ cic_map; nuprl_map; rdf_map; xsl_map ]
let close_maps () = List.iter (fun m -> m#close) maps
let clear_maps () = List.iter (fun m -> m#clear) maps
let sync_maps () = List.iter (fun m -> m#sync) maps

let map_of_uri = function
  | uri when is_cic_uri uri -> cic_map
  | uri when is_nuprl_uri uri -> nuprl_map
  | uri when is_rdf_uri uri -> rdf_map
  | uri when is_xsl_uri uri -> xsl_map
  | uri -> raise (Unresolvable_URI uri)

let update_from_server logmsg server_url = (* use global maps *)
  debug_print ("Updating information from " ^ server_url);
  let xml_url_of_uri = function
      (* TODO missing sanity checks on server_url, e.g. it can contains $1 *)
    | uri when (Pcre.pmatch ~rex:heading_cic_RE uri) ->
        Pcre.replace ~rex:heading_cic_RE ~templ:server_url uri
    | uri when (Pcre.pmatch ~rex:heading_theory_RE uri) ->
        Pcre.replace ~rex:heading_theory_RE ~templ:server_url uri
    | uri when (Pcre.pmatch ~rex:heading_nuprl_RE uri) ->
        Pcre.replace ~rex:heading_nuprl_RE ~templ:server_url uri
    | uri -> raise (Invalid_URI uri)
  in
  let rdf_url_of_uri = function (* TODO as above *)
    | uri when (Pcre.pmatch ~rex:heading_rdf_cic_RE uri) ->
        Pcre.replace ~rex:heading_rdf_cic_RE ~templ:server_url uri
    | uri when (Pcre.pmatch ~rex:heading_rdf_theory_RE uri) ->
        Pcre.replace ~rex:heading_rdf_theory_RE ~templ:server_url uri
    | uri -> raise (Invalid_URI uri)
  in
  let log = ref (`T ("Processing server: " ^ server_url) :: logmsg) in
  let (xml_index, rdf_index, xsl_index) =
    (* TODO keeps index in memory, is better to keep them on temp files? *)
    (http_get (server_url ^ "/" ^ Http_getter_env.xml_index),
     http_get (server_url ^ "/" ^ Http_getter_env.rdf_index),
     http_get (server_url ^ "/" ^ Http_getter_env.xsl_index))
  in
  if (xml_index = None && rdf_index = None && xsl_index = None) then
    debug_print (sprintf "Warning: useless server %s" server_url);
  (match xml_index with
  | Some xml_index ->
      (log := `T "Updating XML db ...<br />" :: !log;
      List.iter
        (function
          | l when is_blank_line l -> ()  (* skip blank and commented lines *)
          | l ->
              (try
                (match Pcre.split ~rex:index_line_sep_RE l with
                | [uri; "gz"] ->
                   assert (is_cic_uri uri || is_nuprl_uri uri) ;
                   (map_of_uri uri)#replace
                    uri ((xml_url_of_uri uri) ^ ".xml.gz")
                | [uri] ->
                   assert (is_cic_uri uri || is_nuprl_uri uri) ;
                   (map_of_uri uri)#replace
                    uri ((xml_url_of_uri uri) ^ ".xml")
                | _ -> log := `T ("Ignoring invalid line: '" ^ l) :: !log)
              with Invalid_URI uri ->
                log := `T ("Ignoring invalid XML URI: '" ^ l) :: !log))
        (Pcre.split ~rex:index_sep_RE xml_index); (* xml_index lines *)
      log := `T "All done" :: !log)
  | None -> ());
  (match rdf_index with
  | Some rdf_index ->
      (log := `T "Updating RDF db ..." :: !log;
      List.iter
        (fun l ->
          try
            (match Pcre.split ~rex:index_line_sep_RE l with
            | [uri; "gz"] ->
                rdf_map#replace uri
                  ((rdf_url_of_uri uri) ^ ".xml.gz")
            | [uri] ->
                rdf_map#replace uri ((rdf_url_of_uri uri) ^ ".xml")
            | _ -> log := `T ("Ignoring invalid line: '" ^ l) :: !log)
          with Invalid_URI uri ->
            log := `T ("Ignoring invalid RDF URI: '" ^ l) :: !log)
        (Pcre.split ~rex:index_sep_RE rdf_index); (* rdf_index lines *)
      log := `T "All done" :: !log)
  | None -> ());
  (match xsl_index with
  | Some xsl_index ->
      (log := `T "Updating XSLT db ..." :: !log;
      List.iter
        (fun l -> xsl_map#replace l (server_url ^ "/" ^ l))
        (Pcre.split ~rex:index_sep_RE xsl_index);
      log := `T "All done" :: !log)
  | None -> ());
  debug_print "done with this server";
  !log

let update_from_all_servers () =  (* use global maps *)
  clear_maps ();
  let log =
    List.fold_left
      update_from_server
      []  (* initial logmsg: empty *)
        (* reverse order: 1st server is the most important one *)
      (List.map snd (List.rev (Http_getter_env.servers ())))
  in
  sync_maps ();
  `Msg (`L (List.rev log))

let update_from_one_server server_url =
  let log = update_from_server [] server_url in
  `Msg (`L (List.rev log))

let temp_file_of_uri uri =
  let flat_string s s' c =
    let cs = String.copy s in
    for i = 0 to (String.length s) - 1 do
      if String.contains s' s.[i] then cs.[i] <- c
    done;
    cs
  in
  let user = try Unix.getlogin () with _ -> "" in
  Filename.open_temp_file (user ^ flat_string uri ".-=:;!?/&" '_') ""
  
(* API *)

let help () = Http_getter_const.usage_string (Http_getter_env.env_to_string ())

let resolve uri =
  try
    (map_of_uri uri)#resolve uri
  with Http_getter_map.Key_not_found _ -> raise (Unresolvable_URI uri)

  (* Warning: this fail if uri is already registered *)
let register ~uri ~url = (map_of_uri uri)#add uri url

let update () = update_from_all_servers ()

let getxml ?(format = Enc_normal) ?(patch_dtd = true) uri =
  let url = resolve uri in
  let (fname, outchan) = temp_file_of_uri uri in
  Http_getter_cache.respond_xml ~uri ~url ~enc:format ~patch:patch_dtd outchan;
  close_out outchan;
  fname

let getxslt ?(patch_dtd = true) uri =
  let url = resolve uri in
  let (fname, outchan) = temp_file_of_uri uri in
  Http_getter_cache.respond_xsl ~url ~patch:patch_dtd outchan;
  close_out outchan;
  fname

let getdtd ?(patch_dtd = true) uri =
  let url = Http_getter_env.dtd_dir ^ "/" ^ uri in
  let (fname, outchan) = temp_file_of_uri uri in
  Http_getter_cache.respond_dtd ~url ~patch:patch_dtd outchan;
  close_out outchan;
  fname

let clean_cache () = Http_getter_cache.clean ()

let list_servers () = Http_getter_env.servers ()

let add_server ?(position = 0) name =
  if position = 0 then begin
    Http_getter_env.add_server ~position:0 name;
    update_from_one_server name (* quick update (new server only) *)
  end else if position > 0 then begin
    Http_getter_env.add_server ~position name;
    update ()
  end else  (* already checked bt parse_position *)
    assert false

let remove_server position =
  let server_name =
    try
      List.assoc position (Http_getter_env.servers ())
    with Not_found ->
      raise (Invalid_argument (sprintf "no server with position %d" position))
  in
  Http_getter_env.remove_server position;
  update ()

let return_uris map filter =
  let uris = ref [] in
  map#iter (fun uri _ -> if filter uri then uris := uri :: !uris);
  List.rev !uris

let getalluris () =
  let filter uri =
    (Pcre.pmatch ~rex:heading_cic_RE uri) &&
    not (Pcre.pmatch ~rex:trailing_types_RE uri)
  in
  return_uris cic_map filter

let getallrdfuris classs =
  let filter =
    let base = "^helm:rdf:www\\.cs\\.unibo\\.it/helm/rdf/" in
    match classs with
    | `Forward -> (fun uri -> Pcre.pmatch ~pat:(base ^ "forward") uri)
    | `Backward -> (fun uri -> Pcre.pmatch ~pat:(base ^ "backward") uri)
  in
  return_uris rdf_map filter

let ls =
  let (++) (oldann, oldtypes, oldbody, oldtree)
           (newann, newtypes, newbody, newtree) =
    ((if newann   > oldann    then newann   else oldann),
     (if newtypes > oldtypes  then newtypes else oldtypes),
     (if newbody  > oldbody   then newbody  else oldbody),
     (if newtree  > oldtree   then newtree  else oldtree))
  in
  let basepart_RE =
    Pcre.regexp
      "^([^.]*\\.[^.]*)((\\.body)|(\\.proof_tree)|(\\.types))?(\\.ann)?$"
  in
  let (types_RE, types_ann_RE, body_RE, body_ann_RE,
       proof_tree_RE, proof_tree_ann_RE) =
    (Pcre.regexp "\\.types$", Pcre.regexp "\\.types\\.ann$",
     Pcre.regexp "\\.body$", Pcre.regexp "\\.body\\.ann$",
     Pcre.regexp "\\.proof_tree$", Pcre.regexp "\\.proof_tree\\.ann$")
  in
  let (slash_RE, til_slash_RE, no_slashes_RE) =
    (Pcre.regexp "/", Pcre.regexp "^.*/", Pcre.regexp "^[^/]*$")
  in
  fun lsuri ->
    let pat =
      "^" ^
      (match lsuri with Cic p -> ("cic:" ^ p) | Theory p -> ("theory:" ^ p))
    in
    let (dir_RE, obj_RE) =
      (Pcre.regexp (pat ^ "/"), Pcre.regexp (pat ^ "(\\.|$)"))
    in
    let dirs = ref StringSet.empty in
    let objs = Hashtbl.create 17 in
    let store_dir d =
      dirs := StringSet.add (List.hd (Pcre.split ~rex:slash_RE d)) !dirs
    in
    let store_obj o =
      let basepart = Pcre.replace ~rex:basepart_RE ~templ:"$1" o in
      let no_flags = false, No, No, No in
      let oldflags =
        try
          Hashtbl.find objs basepart
        with Not_found -> (* no ann, no types, no body, no proof tree *)
          no_flags
      in
      let newflags =
        match o with
        | s when Pcre.pmatch ~rex:types_RE s          -> (false, Yes, No, No)
        | s when Pcre.pmatch ~rex:types_ann_RE s      -> (true,  Ann, No, No)
        | s when Pcre.pmatch ~rex:body_RE s           -> (false, No, Yes, No)
        | s when Pcre.pmatch ~rex:body_ann_RE s       -> (true,  No, Ann, No)
        | s when Pcre.pmatch ~rex:proof_tree_RE s     -> (false, No, No, Yes)
        | s when Pcre.pmatch ~rex:proof_tree_ann_RE s -> (true,  No, No, Ann)
        | s -> no_flags
      in
      Hashtbl.replace objs basepart (oldflags ++ newflags)
    in
    cic_map#iter
      (* BLEARGH Dbm module lacks support for fold-like functions *)
      (fun key _ ->
        match key with
        | uri when Pcre.pmatch ~rex:dir_RE uri ->  (* directory hit *)
            let localpart = Pcre.replace ~rex:dir_RE uri in
            if Pcre.pmatch ~rex:no_slashes_RE localpart then
              store_obj localpart
            else
              store_dir localpart
        | uri when Pcre.pmatch ~rex:obj_RE  uri ->  (* file hit *)
            store_obj (Pcre.replace ~rex:til_slash_RE uri)
        | uri -> () (* miss *));
    let ls_items = ref [] in
    StringSet.iter (fun dir -> ls_items := Ls_section dir :: !ls_items) !dirs;
    Http_getter_misc.hashtbl_sorted_iter
      (fun uri (annflag, typesflag, bodyflag, treeflag) ->
        ls_items :=
          Ls_object {
            uri = uri; ann = annflag;
            types = typesflag; body = typesflag; proof_tree = treeflag
          } :: !ls_items)
      objs;
    List.rev !ls_items