#!@PERL_BINARY@

# Copyright (C) 2000, HELM Team.
# 
# This file is part of HELM, an Hypertextual, Electronic
# Library of Mathematics, developed at the Computer Science
# Department, University of Bologna, Italy.
# 
# HELM is free software; you can redistribute it and/or
# modify it under the terms of the GNU General Public License
# as published by the Free Software Foundation; either version 2
# of the License, or (at your option) any later version.
# 
# HELM is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
# 
# You should have received a copy of the GNU General Public License
# along with HELM; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
# 
# For details, see the HELM World-Wide-Web page,
# http://cs.unibo.it/helm/.

#use strict;

my $VERSION = "@VERSION@";

# various variables
my ($HELM_LIB_PATH);
my $cgi_dir = "@HELM_CGI_DIR@";
my (%map, %rdf_map);

# First of all, let's load HELM configuration
use Env;
my $HELM_LIB_DIR = $ENV{"HELM_LIB_DIR"};
# this should be the only fixed constant
my $DEFAULT_HELM_LIB_DIR = "@HELM_LIB_DIR@";
if (defined ($HELM_LIB_DIR)) {
   $HELM_LIB_PATH = $HELM_LIB_DIR."/configuration.pl";
} else {
   $HELM_LIB_PATH = $DEFAULT_HELM_LIB_DIR."/configuration.pl";
}

# next require defines: $helm_dir, $html_link, $dtd_dir, $uris_dbm, $indexname
require $HELM_LIB_PATH;

# TEMP: TODO put these vars in configuration file configuration.xml
# <move_to_conf_file>
my $cachemode = $ENV{'HTTP_GETTER_CACHE_MODE'} ||
    'gzipped';
if (($cachemode ne 'gzipped') and ($cachemode ne 'normal')) {
 die "Invalid HTTP_GETTER_CACHE_MODE environment variable, must be".
 "'normal' or 'gzipped'\n";
}
my $helm_rdf_dir = $ENV{'HTTP_GETTER_RDF_DIR'} ||
    "/usr/local/helm/rdf_library";
my $rdf_dbm = $ENV{'HTTP_GETTER_RDF_DBM'} ||
    "/usr/local/helm/rdf_urls_of_uris";
my $rdf_indexname = $ENV{'HTTP_GETTER_RDF_INDEXNAME'} ||
    "rdf_index.txt";
# </move_to_conf_file>

# Let's override the configuration file
$style_dir = $ENV{"HELM_STYLE_DIR"} if (defined ($ENV{"HELM_STYLE_DIR"}));
$dtd_dir = $ENV{"HELM_DTD_DIR"} if (defined ($ENV{"HELM_DTD_DIR"}));

use HTTP::Daemon;
use HTTP::Status;
use HTTP::Request;
use LWP::UserAgent;
use DB_File;
use Compress::Zlib;
use CGI;
use URI::Escape;

#CSC: mancano i controlli sulle condizioni di errore di molte funzioni
#CSC: ==> non e' robusto
#CSC: altra roba da sistemare segnata con CSC

my $d = new HTTP::Daemon LocalPort => 8081;
my $myownurl = $d->url;

# Let's patch the returned URL
$myownurl =~ s/\/$//; # chop the final slash
my $myownport = $myownurl;
$myownport =~ s/http:\/\/(.*):(.*)/$2/;
$myownurl  =~ s/http:\/\/(.*):(.*)/$1/;
($myownurl) = gethostbyname($myownurl);
$myownurl = "http://".$myownurl.":".$myownport;

tie(%map, 'DB_File', $uris_dbm.".db", O_RDWR, 0664); # open dbs
tie(%rdf_map, 'DB_File', $rdf_dbm.".db", O_RDWR, 0664);

print "\n";
print "HTTP Getter $VERSION\n"; # print hello information
print "Please contact me at: <URL:", $myownurl."/", ">\n";
print "\n";
print "helm_dir: $helm_dir\n";
print "helm_rdf_dir: $helm_rdf_dir\n";
print "style_dir: $style_dir\n";
print "dtd_dir: $dtd_dir\n";
print "urls_of_uris db: $uris_dbm.db\n";
print "rdf db: $rdf_dbm.db\n";
print "cache mode: $cachemode\n";
print "indexname: $indexname\n";
print "rdf_indexname: $rdf_indexname\n";
print "\n";

$SIG{CHLD} = "IGNORE"; # do not accumulate defunct processes
$SIG{USR1} = \&update; # sent by the child to make the parent update

while (my $c = $d->accept) {
 if (fork() == 0) {
    while (my $r = $c->get_request) {
        #CSC: mancano i controlli di sicurezza
        
        my $http_method = $r->method;
        my $http_path = $r->url->path;
        my $http_query = uri_unescape($r->url->query);
        my $cgi = new CGI("$http_query");
        my $inputuri = $cgi->param('uri');
        print "\nRequest: ".$r->url."\n\n";

        print "\nUnescaped query: ".$http_query."\n";

         # "getxml" works with rdf uris
        if ($http_method eq 'GET' and $http_path eq "/getxml") {
            # finds the uri, url and filename

            my $answerformat = $cgi->param('format');
            my $patch_dtd = $cgi->param('patch_dtd');
            $answerformat = "" if (not defined($answerformat));
            $patch_dtd = "yes" if (not defined($patch_dtd));
            if (($answerformat ne "gz") and ($answerformat ne "normal")
               and ($answerformat ne "")) {
             die "Wrong output format: $answerformat, must be 'normal' ".
                 "or 'gz'\n";
            }
            if (($patch_dtd ne "yes") and ($patch_dtd ne "no")
               and ($patch_dtd ne "")) {
             die "Wrong param, patch_dtd must be 'yes' or 'no'\n";
            }

            my $filename = $inputuri;
            my $prefix;
            if (not isRdfUri($inputuri)) { # standad cic: or theory: uri
             $filename =~ s/^cic:(.*)/$1/;
             $filename =~ s/^theory:(.*)/$1/;
            } else { # rdf uri
             # The "helm:rdf/<<...>>//cic:" prefix is kept, but quoted
             # (so that a "helm:rdf/<<...>>//cic:" dir is created
             $prefix = $filename;
             $filename =~ s/^(.*)\/\/cic:(.*)/$2/;
             $filename =~ s/^(.*)\/\/theory:(.*)/$2/;
             $prefix =~ s/\Q$filename\E//;
             $prefix =~ s/_/__/g;
             $prefix =~ s/\//_/g;
             $filename = $prefix.$filename;
            }

            my $url = resolve ($inputuri); # resolve uri in url
            if (not defined($url)) { # uri not found in uri2url map
             die "NOT FOUND: uri \"$inputuri\" can't be resolved\n";
             $c->send_error(RC_NOT_FOUND)
            } else { # uri found and mapped to url
              my $extension; # file extension
              if ($url =~ /\.xml$/) { # non gzipped file
                $extension = ".xml";
              } elsif ($url =~ /\.xml\.gz$/) { # gzipped file
                $extension = ".xml.gz";
              } else { # error: unknown extension
               die "unexpected extension in url: $url, might be '.xml'".
                "or '.xml.gz'";
              }

              if (not isRdfUri ($inputuri)) { # save in uri std cache dir
               $filename = $helm_dir.$filename.$extension;
              } else { # save in rdf metadata cache dir
               $filename = $helm_rdf_dir."/".$filename.$extension;
              }

              print_request($inputuri,$url,$filename);

              # Retrieves the file
              my $ciccontent = download($patch_dtd,$url,$filename,$answerformat);

              if ($answerformat eq "normal") { # answer the client in text/xml
               answer($c,$ciccontent,"text/xml","");
              } else { # answer the client in text/xml, gzip encoding
               answer($c,$ciccontent,"text/xml","x-gzip");
              }
            }
            
                           # "/register" does not work with rdf uris
        } elsif ($http_method eq 'GET' and $http_path eq "/register") {
          my $inputurl = $cgi->param('url');
          print "Register requested...\n";
          $map{$inputuri}=$inputurl;

          # Now let's clean the cache
          my $cicfilename = $inputuri;
          $cicfilename =~ s/cic:(.*)/$1/;
          $cicfilename =~ s/theory:(.*)/$1/;

          print "Unlinking ".$helm_dir.$cicfilename.".xml[.gz]\n";
          unlink ($helm_dir.$cicfilename.".xml");
          unlink ($helm_dir.$cicfilename.".xml.gz");

          kill(USR1,getppid()); # signal changes to parent
          untie %map;
          print "done.\n";
          html_nice_answer($c,"Register done");

                                  # "/resolve" works with rdf uri
        } elsif ($http_method eq 'GET' and $http_path eq "/resolve") {
          #my $outputurl = $map{$inputuri};
          my $outputurl = resolve($inputuri);
          $outputurl = "" if (not defined($outputurl));
          $cont = "<?xml version=\"1.0\" ?>\n\n";
          if ($outputurl eq "") {
           $cont .= "<unresolved />\n";
          } else {
           $cont .= "<url value=\"$outputurl\" />\n";
          }
          answer($c,$cont,"text/xml","");

        } elsif ($http_method eq 'GET' and $http_path eq "/getdtd") {
            my $filename = $inputuri;
            $filename = $dtd_dir."/".$filename;
            print "DTD: $inputuri ==> ($filename)\n";
            if (stat($filename)) {
               print "Using local copy\n";
               open(FD, $filename) or die "Cannot open $filename\n";
               $cont = "";
               while(<FD>) {
                # Vary bad heuristic for substituion of absolute URLs
                # for relative ones
		s/ENTITY (.*) SYSTEM\s+"/ENTITY $1 SYSTEM "$myownurl\/getdtd?uri=/g;
	        $cont .= $_;
	       }
               close(FD);
               answer($c,$cont,"text/xml","");
            } else {
               die "Could not find DTD!";
            }

        } elsif ($http_method eq 'GET' and $http_path eq "/getstyleconf") {
            my $filename = $inputuri;
            $filename = $style_dir."/config/".$filename;
            if (stat($filename)) {
               open(FD, $filename) or die "Cannot open $filename\n";
               $cont = "";
               while(<FD>) {
	        s/DOCTYPE (.*) SYSTEM\s+"/DOCTYPE $1 SYSTEM "$myownurl\/getstyleconf?uri=/g;
	        $cont .= $_;
	       }
               close(FD);
               answer($c,$cont,"text/plain","");
            } else {
               die "Could not find Style Configuration File!";
            }

        } elsif ($http_method eq 'GET' and $http_path eq "/getxslt") {
            my $filename = $inputuri;
            $filename = $style_dir."/".$filename;
            print "XSLT: $inputuri ==> ($filename)\n";
            if (stat($filename)) {
               print "Using local copy\n";
               open(FD, $filename) or die "Cannot open $filename\n";
               $cont = "";
               while(<FD>) {
                # Vary bad heuristic for substituion of absolute URLs
                # for relative ones
                s/xsl:import\s+href="/xsl:import href="$myownurl\/getxslt?uri=/g ;
                s/xsl:include\s+href="/xsl:include href="$myownurl\/getxslt?uri=/g ;
                $cont .= $_;
               }
               close(FD);
               answer($c,$cont,"text/xml","");
            } else {
               die "Could not find XSLT!";
            }

                                    # "/update" works with rdf uri
        } elsif ($http_method eq 'GET' and $http_path eq "/update") {
            # rebuild urls_of_uris db and rdf uris db
           print "Update requested...\n";
           update_dbs();
           kill(USR1,getppid()); # signal changes to parent
           print " done\n";
           html_nice_answer($c,"Update done");

                                 # "/ls" does not work with rdf uris
        } elsif ($http_method eq 'GET' and $http_path eq "/ls") {
            # send back keys that begin with a given uri
           my ($uritype,$uripattern,$uriprefix);
           my $baseuri = $cgi->param('baseuri');
           chop $baseuri if ($baseuri =~ /.*\/$/); # remove trailing "/"
                         # output type, might be 'txt' or 'xml':
           my $outype = $cgi->param('format');
           $uripattern = $baseuri;
           $uripattern =~ s/^.*:(.*)/$1/;
           if ($baseuri =~ /^cic:/) {
            $uritype = "cic";
           } elsif ($baseuri =~ /^theory:/) {
            $uritype = "theory";
           } else {
            $uritype = "invalid";
           }
           if ($uritype ne "invalid") { # uri is valid
            if (($outype ne 'txt') and ($outype ne 'xml')) { # invalid out type
             print "Invalid output type specified: $outype\n";
             html_nice_answer($c,"Invalid output type, must be ".
              "'txt' or 'xml'");
            } else { # valid output
             print "BASEURI $baseuri, FORMAT $outype\n";
             $cont = finduris($uritype,$uripattern,$outype);
             if ($outype eq 'txt') {
              answer($c,$cont,"text/plain","");
             } elsif ($outype eq 'xml') {
              answer($c,$cont,"text/xml","");
             } else {
              die "Internal error, exiting!";
             }
            }
           } else { # invalid uri
            print "Invalid uri: $baseuri, may begin with 'cic:', ".
             "'theory:' or '*:'\n";
            html_nice_answer($c,"Invalid uri , must begin with ".
             "'cic:' or 'theory:'");
           }

        } elsif ($http_method eq 'GET' and $http_path eq "/help") {
          # help request
           print "Help requested!\n";
           html_nice_answer($c,"HTTP Getter Version: $VERSION");

        } elsif ($http_method eq 'GET' and $http_path =~ /\.cgi$/) {
          # cgi handling
           print "CGI requested!\n";
           if ($http_path !~ /^\/[^\/]*\.cgi$/) {
            html_nice_answer($c,"Invalid CGI name: $http_path, ".
            "you can't request CGI that contain a slash in the name\n");
           } elsif (stat "$cgi_dir"."$http_path") {
            if (not -x "$cgi_dir/$http_path") {
             html_nice_answer($c,"CGI $http_path found but not ".
              "executable\n");
            } else { # exec CGI and anser back its output
             my %old_ENV = %ENV;
             %ENV = ();
             $ENV{'QUERY_STRING'} = $http_query;
             my $cgi_output = `$cgi_dir/$http_path`;
             answer($c,$cgi_output,"","");
             %ENV = %old_ENV;
            }
           } else {
            html_nice_answer($c,"CGI '$http_path' not found ".
             "in CGI dir '$cgi_dir'");
           }

        } else { # unsupported request
            print "\n";
            print "INVALID REQUEST!!!!!\n";
            print "(PATH: ",$http_path,", ";
            print "QUERY: ",$http_query,")\n";
            $c->send_error(RC_FORBIDDEN)
        }

        print "\nRequest solved: ".$r->url."\n\n";
    }

    $c->close;
    undef($c);
    print "\nCONNECTION CLOSED\n\n";
    exit;
  } # fork
}

#================================

sub isRdfUri { # return true if the uri is an rdf uri, false otherwise
# typycal rdf uri:
# helm:rdf/cic:www.cs.unibo.it/helm/rdf/foo_schema//cic:\
#  /Coq/Init/Logic/True_rec.con.types
#
# the format is "helm:rdf/<metadata_tree>:<metadata_scheme>//<xml_file_uri>"
#
 my ($uri) = @_;
 if ($uri =~ /^helm:rdf(.*):(.*)\/\/(.*)/) {
  return 1;
 } else {
  return 0;
 }
}

sub resolve { # resolve an uri in a url, work both with standard cic: or theory:
              # uris and rdf uris
 print "RESOLVE subroutine\n";
 my ($uri) = @_;
 print "GIVEN URI: \"$uri\"\n";
 if (isRdfUri ($uri)) { # rdf uri, resolve using rdf db
  print "IS A RDF URI\n";
  print "I WILL RETURN '$rdf_map{$uri}'\n";
  return ($rdf_map{$uri});
 } else { # standard cic: or theory: uri, resolve using std uri db
  print "IS NOT A RDF URI\n";
  print "I WILL RETURN '$map{$uri}'\n";
  return ($map{$uri});
 }
}

sub finduris { # find uris for cic and theory trees generation
 my ($uritype,$uripattern,$format) = @_;
 my $content = "";
 my ($uri,$localpart,$basepart,$dirname,$suffix,$flags,$key);
 my (@itemz,@already_pushed_dir);
 my (%objects,%dirs); # map uris to suffixes' flags
 my $debug=1; # for debug

 print "FINDURIS, uritype: $uritype, uripattern: $uripattern, ".
  "format: $format\n\n" if defined($debug);
 
 if (($uritype eq "cic") or ($uritype eq "theory")) {
   # get info only of one type: cic or theory
  foreach (keys(%map)) { # select matching uris
   $uri = $_;
   if ($uri =~ /^$uritype:$uripattern(\/|$|\.)/) {
    if ($uri =~ /^$uritype:$uripattern\//) { # directory match
     $localpart = $uri;
     $localpart =~ s/^$uritype:$uripattern\/(.*)/$1/;
    } elsif ($uri =~ /^$uritype:$uripattern($|\.)/) { # file match
     $localpart = $uri;
     $localpart =~ s/^.*\/([^\/]*)/$1/;
    } else {
     die "Internal error, seems that requested match is none of ".
      "directory match or file match";
    }
    print "LOCALPART: $localpart\n" if defined($debug);

    if ($localpart =~ /^[^\/]*$/) { # no slash, an OBJECT
     $basepart = $localpart;
     $basepart =~ s/^([^.]*\.[^.]*)(\.types)?(\.ann)?/$1/;
                                              # remove exts .types or
                                              # .types.ann
     $flags = $objects{$basepart}; # get old flags
     if ($localpart =~ /\.ann$/) {
      $flags = add_flag("ann","YES",$flags);
     } else {
      $flags = add_flag("ann","NO",$flags);
     }
     if ($localpart =~ /\.types$/) {
      $flags = add_flag("types","YES",$flags);
     } elsif ($localpart =~ /\.types\.ann$/) {
      $flags = add_flag("types","ANN",$flags);
     } else {
      $flags = add_flag("types","NO",$flags);
     }
     $objects{$basepart} = $flags; # save new flags
    } else { # exists at least one slash, a DIR
     ($dirname) = split (/\//, $localpart);
     $dirs{$dirname} = ""; # no flags requirement for dir
    }
   }
  }
 } else {
  die "getter internal error: unsupported uritype: \"$uritype\"";
 }
                            # now generate OUTPUT:
                            # output will be saved in $content
 if ($format eq "txt") { # TXT output
  foreach $key (sort(keys %dirs)) {
   $content .= "dir, " . $key . "\n";
  }
  foreach $key (sort(keys %objects)) {
   $content .= "object, $key, " . $objects{$key} . "\n";
  }
 } elsif ($format eq "xml") { # XML output
  $content .= '<?xml version="1.0" encoding="ISO-8859-1"?>' . "\n";
  $content .= "<!DOCTYPE ls SYSTEM ";
  $content .= "\"$myownurl/getdtd?uri=ls.dtd\">" . "\n\n";
  $content .= "<ls>\n";
  foreach $key (sort(keys %dirs)) {
   $content .= "\t<section>$key</section>\n";
  }
  foreach $key (sort(keys %objects)) {
   $content .= "\t<object name=\"$key\">\n";
   $flags = $objects{$key};
   $flags =~ s/^<(.*)>$/$1/;
   my ($annflag,$typesflag) = split /,/,$flags;
   $content .= "\t\t<ann value=\"$annflag\" />\n";
   $content .= "\t\t<types value=\"$typesflag\" />\n";
   $content .= "\t</object>\n";
  }
  $content .= "</ls>\n";
 } else { # may not enter this branch
  die "Getter internal error: invalid format received by finduris sub";
 }
 return $content;
}

sub add_flag {
# manage string like: "<ann_flag,type_flag>"
# "ann_flag" may be one of "ann_YES", "ann_NO"
# "type_flag" may be one of "types_NO", "types_YES", "types_ANN"
# when adding a flag the max between the current flag and the new flag
# is taken, the orders are ann_NO < ann_YES and types_NO < types_YES <
# types_ANN
 my ($flagtype,$newflag,$str) = @_;
 $str = "<,>" if ($str eq "");
 ($str =~ s/^<(.*,.*)>$/$1/) or die "Internal error: ".
   "wrong string format for flag adding in $str";
 my ($annflag,$typeflag) = split /,/,$str;
 if ($flagtype eq "ann") { # ANN flag handling
  if ($newflag eq "YES") {
   $annflag = "YES";
  } elsif ($newflag eq "NO") {
   $annflag = "NO" unless ($annflag eq "YES");
  } else {
   die "Internal error: annflag must be \"YES\" or \"NO\"";
  }
 } elsif ($flagtype eq "types") { # TYPES flag handling
  if ($newflag eq "ANN") {
   $typeflag = "ANN";
  } elsif ($newflag eq "YES") {
   $typeflag = "YES" unless ($typeflag eq "ANN");
  } elsif ($newflag eq "NO") {
   $typeflag = "NO"
     unless (($typeflag eq "ANN") or ($typeflag eq "YES"));
  } else {
   die "Internal error: typeflag must be \"YES\", \"NO\" or \"ANN\"";
  }
 } else {
  die "Internal error: unsupported flagtype \"$flagtype\"";
 }
 $str = "<$annflag,$typeflag>";
}

#CSC: Too much powerful: creates even /home, /home/users/, ...
#CSC: Does not raise errors if could not create dirs/files
sub mkdirs
{
 my ($pathname) = @_;
 my @dirs = split /\//,$pathname;
 my $tmp;
 foreach $dir (@dirs) {
  $tmp = ((defined($tmp)) ?  $tmp."\/".$dir : "");
  mkdir($tmp,0777);
 }
 rmdir($tmp);
}

sub print_request
{
 my ($uri,$url,$filename) = @_;
 print "<download_request>\n";
 print "uri: $uri\n";
 print "url: $url\n";
 print "filename: $filename\n\n";
 print "</download_request>\n";
}

sub callback
{
 my ($data) = @_;
 $cont .= $data;
}

sub gunzip { # gunzip a file and return the deflated content
	my ($filename) = @_;

	my ($gz, $buffer, $cont);

	print "deflating $filename ...\n";
	$gz = gzopen($filename, "r")
		or die "Cannot open gzip'ed file $filename: $gzerrno";
	$cont = "";
	while ( $gz->gzread($buffer) > 0 ) {
		$cont .= $buffer;
	}
	die "Error while reading : $gzerrno\n" if $gzerrno != Z_STREAM_END ;
	$gz->gzclose();

	return $cont;
}

sub gzip {	# gzip the content argument and save it to filename argument
	my ($cont, $filename) = @_;
 #my $debug=1; # debug only

 print "gzopening $filename ...\n" if (defined($debug));
	my $gz = gzopen($filename, "w")
		or die "Cannot gzopen for writing file $filename: $gzerrno";
 print "gzwriting ...\n" if (defined($debug));
	$gz->gzwrite($cont) or die "error writing: $gzerrno, exiting!\n";
 print "gzclosing ...\n" if (defined($debug));
	$gz->gzclose();
}

sub download {
 my ($patch_dtd,$url,$filename,$format) = @_;
 my ($gz, $buffer);

# print "DOWNLOAD subs receives url: \"$url\"\n";
# print "DOWNLOAD subs receives filename: \"$filename\"\n";

 my $resourcetype;	# retrieve mode: "normal" (.xml) or "gzipped" (.xml.gz)
 if ($filename =~ /\.xml$/) {	# set retrieve mode
	 $resourcetype = "normal";
 } elsif ($filename =~ /\.xml\.gz$/) {
	 $resourcetype = "gzipped";
 } else {
	 die "Unsupported download extension, might be '.gz' or '.xml'\n";
 }
 my $basefname = $filename;
 $basefname =~ s/\.gz$//;	# get base resource name removing trailing .gz
 $cont = ""; # modified by side-effect by the callback function

 my $localfname="";
 if (stat($basefname)) {
 	$localfname=$basefname;
 } elsif (stat($basefname.".gz")) {
 	$localfname=$basefname.".gz";
 }
 if ($localfname ne "") { # we already have local copy of requested file
      # check both possible cache entry: gzipped or normal
  print "Using local copy.\n";
  if ($localfname =~ /\.xml\.gz$/) { # deflating cached file and return it
   $cont = gunzip($localfname);
  } elsif ($localfname =~ /\.xml$/) { # just return cached file
   open(FD, $localfname) or die "Cannot open $localfname";
   while(<FD>) { $cont .= $_; }
   close(FD);
  } else { # error
   die "Internal error: unexpected file name $localfname,"
   ."must end with '.gz' or '.xml.gz'\n";
  }
 } else { # download file from net
   print "Downloading file ...\n"; # download file
   my $ua = LWP::UserAgent->new;
   my $request = HTTP::Request->new(GET => "$url");
   my $response = $ua->request($request, \&callback);
   
   # cache retrieved file to disk
   # <ZACK/> TODO: inefficent, I haven't yet undestood how to deflate
   #    in memory gzipped file, without call "gzopen"
   print "Storing file ...\n";
#   print "Making dirs ...\n";
   mkdirs($filename);
#   print "Opening tmp file for writing ...\n";
   open(FD, ">".$filename.".tmp") or die "Cannot open $filename.tmp\n";
#   print "Writing on tmp file ...\n";
   print FD $cont;
#   print "Closing tmp file ...\n";
   close(FD);

   # handle cache conversion normal->gzipped or gzipped->normal as user choice
   print "cachemode:$cachemode, resourcetype:$resourcetype\n"
    if (defined($debug));
   if (($cachemode eq 'normal') and ($resourcetype eq 'normal')) {
     # cache the file as is
    rename "$filename.tmp", $filename; 
   } elsif (($cachemode eq 'gzipped') and ($resourcetype eq 'gzipped')) {
     # cache the file as is
     # and update the $cont variabile with deflated content
    rename "$filename.tmp", $filename; 
    $cont = gunzip($filename);
   } elsif (($cachemode eq 'normal') and ($resourcetype eq 'gzipped')) {
     # deflate cache entry
     # and update $cont
    open(FD, "> $basefname") or die "cannot open $basefname\n";
    $cont = gunzip($filename.".tmp");
    print FD $cont;
    close(FD);
    unlink "$filename.tmp"; # delete old gzipped file
   } elsif (($cachemode eq 'gzipped') and ($resourcetype eq 'normal')) {
     # compress cache entry
    print "gzipping ...\n" if (defined($debug));
    gzip($cont, $basefname.".gz");
    unlink "$filename.tmp"; # delete old uncompressed file
   } else {
    die "Internal error, unsopported cachemode, resourcetype couple\n";
   }
   # $cont now contained uncompressed data
 }
 if ($patch_dtd eq "yes") {
    $cont =~ s/DOCTYPE (.*) SYSTEM\s+"http:\/\/www.cs.unibo.it\/helm\/dtd\//DOCTYPE $1 SYSTEM "$myownurl\/getdtd?uri=/g;
 }
 if ($format eq "gz") {
  gzip($cont,"$basefname.tmp");
  open (TMP, "< $basefname.tmp")
   or die "Can't open tempfile: $filename.tmp, exiting!\n";
  $cont = "";
  while(<TMP>) {
   $cont .= $_;
  }
  close TMP;
  unlink ($basefname . ".tmp") or
   die "cannot unlink temporary file: $basefname.tmp\n";
 }

 return $cont;
}

sub answer {
# answer the client setting content, Content-Type and Content-Enconding
# of the answer
 my ($c,$cont,$contype,$contenc) = @_;
 my $res = new HTTP::Response;
 $res->content($cont);
 $res->push_header("Content-Type" => $contype)
   unless ($contype eq "");
 $res->push_header("Content-Encoding" => $contenc)
   unless ($contenc eq "");
 $res->push_header("Cache-Control" => "no-cache");
 $res->push_header("Pragma" => "no-cache");
 $res->push_header("Expires" => "0");
 $c->send_response($res);
}

sub html_nice_answer {
# answer the client whith a nice html document
 my ($c,$content) = @_;
 $content = "<html><body><h1>$content</h1></body></html>";
 answer($c,$content,"text/html","");
}

sub helm_wget {
#retrieve a file from an url and write it to a temp dir
#used for retrieve resource index from servers
 $cont = "";
 my ($prefix, $URL) = @_;
 my $ua = LWP::UserAgent->new;
 my $request = HTTP::Request->new(GET => "$URL");
 my $response = $ua->request($request, \&callback);
 my ($filename) = reverse (split "/", $URL); # get filename part of the URL
 open (TEMP, "> $prefix/$filename")
  || die "Cannot open temporary file: $prefix/$filename\n";
 print TEMP $cont;
 close TEMP;
}

sub update {
# retie dbs
 untie %map;
 tie(%map, 'DB_File', $uris_dbm.".db", O_RDWR, 0664);
 untie %rdf_map;
 tie(%rdf_map, 'DB_File', $rdf_dbm.".db", O_RDWR, 0664);
}

sub update_dbs {
# rebuild dbs fetching resource indexes from servers.
# Rebuild urls_of_uris db (1) and rdf db (2)
 my (
  $server, $idxfile, $rdf_idxfile, $uri, $url, $comp, $line,
  @servers,
  %urls_of_uris, %rdf # local proxy of $map and $rdf_map
 );

 untie %map;
 untie %rdf_map;
 foreach my $file ($uris_dbm, $rdf_dbm) { # remove old db file
  if (stat $file.".db") { # remove if exists
   unlink ($file.".db") or die "can't unlink old db file: $file.db\n";
  }
 }
 tie(%urls_of_uris, 'DB_File', $uris_dbm.".db", O_RDWR|O_CREAT, 0664);
 tie(%rdf, 'DB_File', $rdf_dbm.".db", O_RDWR|O_CREAT, 0664);

 open (SRVS, "< $servers_file") or
  die "cannot open servers file: $servers_file\n";
 @servers = <SRVS>; # read all servers
 close (SRVS);

 while ($server = pop @servers) { # cicle on servers in _reverse_ order
  print "processing server: $server ...\n";
  chomp $server;
  helm_wget($tmp_dir, $server."/".$indexname); # get index
  helm_wget($tmp_dir, $server."/".$rdf_indexname); # get rdf index
  $idxfile = $tmp_dir."/".$indexname;
  $rdf_idxfile = $tmp_dir."/".$rdf_indexname;

  open (INDEX, "< $idxfile") or # (1) REBUILD URLS_OF_URIS DB
   die "cannot open temporary index file: $idxfile\n";
  while ($line = <INDEX>) {  # parse index and add entry to urls_of_uris db
   chomp $line;
   ($uri,$comp) = split /[ \t]+/, $line;
             # build url:
   if ($comp =~ /gz/) { 
    $url = $uri . ".xml" . ".gz";
   } else {
    $url = $uri . ".xml";
   }
   $url =~ s/cic:/$server/;
   $url =~ s/theory:/$server/;
   $urls_of_uris{$uri} = $url;
  }

  open (RDF_INDEX, "< $rdf_idxfile") or # (2) REBUILD RDF DB
   die "cannot open temporary rdf index file: $rdf_idxfile\n";
  while ($line = <RDF_INDEX>) {  # parse index and add entry to rdf db
   chomp $line;
   ($uri,$comp) = split /[ \t]+/, $line; # comp is "gz" or nothing
             # build url:
   if ($comp =~ /gz/) { 
    $url = $uri . ".xml" . ".gz";
   } else {
    $url = $uri . ".xml";
   }
   $url =~ s/^helm:rdf(.*)\/\/cic:/$server/;
   $url =~ s/^helm:rdf(.*)\/\/theory:/$server/;
   $rdf{$uri} = $url;
  }

  close INDEX;  # close indexes
  close RDF_INDEX;
  die "cannot unlink temporary file: $idxfile\n"  # remove temp files
   if (unlink $idxfile) != 1;
  die "cannot unlink temporary file: $rdf_idxfile\n"
   if (unlink $rdf_idxfile) != 1;

 }

 untie(%urls_of_uris); # untie local proxies
 untie(%rdf);
 tie(%map, 'DB_File', $uris_dbm.".db", O_RDWR, 0664); # retie global ones
 tie(%rdf_map, 'DB_File', $rdf_dbm.".db", O_RDWR, 0664);
} # update_dbs

# vim modline: do not remove!
# vim: set ft=perl: