(* Copyright (C) 2004-2005, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://helm.cs.unibo.it/
 *)

open Printf
open MatitaTypes

let debug = true
let debug_print = if  debug then prerr_endline else ignore

  (** raised when one of the script margins (top or bottom) is reached *)
exception Margin

let safe_substring s i j =
  try String.sub s i j with Invalid_argument _ -> assert false

let heading_nl_RE = Pcre.regexp "^\\s*\n\\s*"
let heading_nl_RE' = Pcre.regexp "^(\\s*\n\\s*)((.|\n)*)"
let only_dust_RE = Pcre.regexp "^(\\s|\n|%%[^\n]*\n)*$"
let multiline_RE = Pcre.regexp "^\n[^\n]+$"
let newline_RE = Pcre.regexp "\n"
 
let comment str =
  if Pcre.pmatch ~rex:multiline_RE str then
    "\n(** " ^ (Pcre.replace ~rex:newline_RE str) ^ " **)"
  else
    "\n(**\n" ^ str ^ "\n**)"
                     
let first_line s =
  let s = Pcre.replace ~rex:heading_nl_RE s in
  try
    let nl_pos = String.index s '\n' in
    String.sub s 0 nl_pos
  with Not_found -> s

  (** creates a statement AST for the Goal tactic, e.g. "goal 7" *)
let goal_ast n =
  let module A = GrafiteAst in
  let loc = Disambiguate.dummy_floc in
  A.Executable (loc, A.Tactical (loc, A.Tactic (loc, A.Goal (loc, n))))

type guistuff = {
  mathviewer:MatitaTypes.mathViewer;
  urichooser: UriManager.uri list -> UriManager.uri list;
  ask_confirmation: title:string -> message:string -> [`YES | `NO | `CANCEL];
  develcreator: containing:string option -> unit;
  mutable filenamedata: string option * MatitamakeLib.development option
}

let eval_with_engine guistuff status user_goal parsed_text st =
  let module TA = GrafiteAst in
  let module TAPp = GrafiteAstPp in
  let include_ = 
    match guistuff.filenamedata with
    | None,None -> []
    | None,Some devel -> [MatitamakeLib.root_for_development devel ]
    | Some f,_ -> 
        match MatitamakeLib.development_for_dir (Filename.dirname f) with
        | None -> []
        | Some devel -> [MatitamakeLib.root_for_development devel ]
  in
  let parsed_text_length = String.length parsed_text in
  let loc, ex = 
    match st with TA.Executable (loc,ex) -> loc, ex | _ -> assert false in
  let initial_space,parsed_text =
   try
    let pieces = Pcre.extract ~rex:heading_nl_RE' parsed_text in
     pieces.(1), pieces.(2)
   with
    Not_found -> "", parsed_text in
  (* we add the goal command if needed *)
  let inital_space,new_status,new_status_and_text_list' =
    match status.proof_status with
      | Incomplete_proof (_, goal) when goal <> user_goal ->
         let status =
          MatitaEngine.eval_ast ~include_paths:include_
            ~do_heavy_checks:true status (goal_ast user_goal) in
         let initial_space =
          if initial_space = "" then "\n" else initial_space
         in
          "\n", status,
           [status, initial_space ^ TAPp.pp_tactic (TA.Goal (loc, user_goal))]
      | _ -> initial_space,status,[] in
  let new_status = 
    MatitaEngine.eval_ast 
      ~include_paths:include_ ~do_heavy_checks:true new_status st 
  in
  let new_aliases =
    match ex with
      | TA.Command (_, TA.Alias _)
      | TA.Command (_, TA.Include _) -> DisambiguateTypes.Environment.empty
      | _ -> MatitaSync.alias_diff ~from:status new_status
  in
  (* we remove the defined object since we consider them "automatic aliases" *)
  let initial_space,status,new_status_and_text_list_rev = 
    let module DTE = DisambiguateTypes.Environment in
    let module UM = UriManager in
    DTE.fold (
      fun k ((v,_) as value) (initial_space,status,acc) -> 
        let b = 
          try
            let v = UM.strip_xpointer (UM.uri_of_string v) in
            List.exists (fun (s,_) -> s = v) new_status.objects 
          with UM.IllFormedUri _ -> false
        in
        if b then 
          initial_space,status,acc
        else
         let new_text =
          let initial_space =
           if initial_space = "" then "\n" else initial_space in
            initial_space ^
             DisambiguatePp.pp_environment(DTE.add k value DTE.empty) in
         let new_status =
          {status with aliases = DTE.add k value status.aliases}
         in
          "\n",new_status,((new_status, new_text)::acc)
    ) new_aliases (initial_space,status,[]) in
  let parsed_text = initial_space ^ parsed_text in
  let res =
   List.rev new_status_and_text_list_rev @ new_status_and_text_list' @
    [new_status, parsed_text]
  in
   res,parsed_text_length

let eval_with_engine guistuff status user_goal parsed_text st =
  try
    eval_with_engine guistuff status user_goal parsed_text st
  with
  | MatitaEngine.UnableToInclude what 
  | MatitaEngine.IncludedFileNotCompiled what as exc ->
      let compile_needed_and_go_on d =
        let target = what in
        let refresh_cb () = 
          while Glib.Main.pending () do ignore(Glib.Main.iteration false); done
        in
        if not(MatitamakeLib.build_development_in_bg ~target refresh_cb d) then
          raise exc
        else
          eval_with_engine guistuff status user_goal parsed_text st
      in
      let do_nothing () = [], 0 in
      let handle_with_devel d =
        let name = MatitamakeLib.name_for_development d in
        let title = "Unable to include " ^ what in
        let message = 
          what ^ " is handled by development <b>" ^ name ^ "</b>.\n\n" ^
          "<i>Should I compile it and Its dependencies?</i>"
        in
        (match guistuff.ask_confirmation ~title ~message with
        | `YES -> compile_needed_and_go_on d
        | `NO -> raise exc
        | `CANCEL -> do_nothing ())
      in
      let handle_without_devel filename =
        let title = "Unable to include " ^ what in
        let message = 
         what ^ " is <b>not</b> handled by a development.\n" ^
         "All dependencies are authomatically solved for a development.\n\n" ^
         "<i>Do you want to set up a development?</i>"
        in
        (match guistuff.ask_confirmation ~title ~message with
        | `YES -> 
            (match filename with
            | Some f -> 
                guistuff.develcreator ~containing:(Some (Filename.dirname f))
            | None -> guistuff.develcreator ~containing:None);
            do_nothing ()
        | `NO -> raise exc
        | `CANCEL -> do_nothing())
      in
      match guistuff.filenamedata with
      | None,None -> handle_without_devel None
      | None,Some d -> handle_with_devel d
      | Some f,_ ->
          match MatitamakeLib.development_for_dir (Filename.dirname f) with
          | None -> handle_without_devel (Some f)
          | Some d -> handle_with_devel d
;;

let disambiguate term status =
  let module MD = MatitaDisambiguator in
  let dbd = MatitaDb.instance () in
  let metasenv = MatitaMisc.get_proof_metasenv status in
  let context = MatitaMisc.get_proof_context status in
  let aliases = MatitaMisc.get_proof_aliases status in
  let interps = MD.disambiguate_term dbd context metasenv aliases term in
  match interps with 
  | [_,_,x,_] -> x
  | _ -> assert false
 
let eval_macro guistuff status parsed_text script mac
=
  let module TA = GrafiteAst in
  let module TAPp = GrafiteAstPp in
  let module MQ = MetadataQuery in
  let module MDB = MatitaDb in
  let module CTC = CicTypeChecker in
  let module CU = CicUniv in
  (* no idea why ocaml wants this *)
  let advance ?statement () = script#advance ?statement () in
  let parsed_text_length = String.length parsed_text in
  let dbd = MatitaDb.instance () in
  match mac with
  (* WHELP's stuff *)
  | TA.WMatch (loc, term) -> 
      let term = disambiguate term status in
      let l =  MQ.match_term ~dbd term in
      let entry = `Whelp (TAPp.pp_macro_cic (TA.WMatch (loc, term)), l) in
      guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
      [], parsed_text_length
  | TA.WInstance (loc, term) ->
      let term = disambiguate term status in
      let l = MQ.instance ~dbd term in
      let entry = `Whelp (TAPp.pp_macro_cic (TA.WInstance (loc, term)), l) in
      guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
      [], parsed_text_length
  | TA.WLocate (loc, s) -> 
      let l = MQ.locate ~dbd s in
      let entry = `Whelp (TAPp.pp_macro_cic (TA.WLocate (loc, s)), l) in
      guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
      [], parsed_text_length
  | TA.WElim (loc, term) ->
      let term = disambiguate term status in
      let uri =
        match term with
        | Cic.MutInd (uri,n,_) -> UriManager.uri_of_uriref uri n None 
        | _ -> failwith "Not a MutInd"
      in
      let l = MQ.elim ~dbd uri in
      let entry = `Whelp (TAPp.pp_macro_cic (TA.WElim (loc, term)), l) in
      guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
      [], parsed_text_length
  | TA.WHint (loc, term) ->
      let term = disambiguate term status in
      let s = ((None,[0,[],term], Cic.Meta (0,[]) ,term),0) in
      let l = List.map fst (MQ.experimental_hint ~dbd s) in
      let entry = `Whelp (TAPp.pp_macro_cic (TA.WHint (loc, term)), l) in
      guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
      [], parsed_text_length
  (* REAL macro *)
  | TA.Hint loc -> 
      let s = MatitaMisc.get_proof_status status in
      let l = List.map fst (MQ.experimental_hint ~dbd s) in
      let selected = guistuff.urichooser l in
      (match selected with
      | [] -> [], parsed_text_length
      | [uri] -> 
        let ast = 
         TA.Executable (loc,
          (TA.Tactical (loc, 
            TA.Tactic (loc,
             TA.Apply (loc, CicNotationPt.Uri (UriManager.string_of_uri uri,None))))))
        in
        let new_status = MatitaEngine.eval_ast status ast in
        let extra_text = 
          comment parsed_text ^ 
          "\n" ^ TAPp.pp_statement ast
        in
        [ new_status , extra_text ], parsed_text_length
      | _ -> 
          MatitaLog.error 
            "The result of the urichooser should be only 1 uri, not:\n";
          List.iter (
            fun u -> MatitaLog.error (UriManager.string_of_uri u ^ "\n")
          ) selected;
          assert false)
  | TA.Check (_,term) ->
      let metasenv = MatitaMisc.get_proof_metasenv status in
      let context = MatitaMisc.get_proof_context status in
      let aliases = MatitaMisc.get_proof_aliases status in
      let interps = 
        MatitaDisambiguator.disambiguate_term 
          dbd context metasenv aliases term 
      in
      let _, metasenv , term, ugraph =
        match interps with 
        | [x] -> x
        | _ -> assert false
      in
      let ty,_ = CTC.type_of_aux' metasenv context term ugraph in
      let t_and_ty = Cic.Cast (term,ty) in
      guistuff.mathviewer#show_entry (`Cic (t_and_ty,metasenv));
      [], parsed_text_length
(*   | TA.Abort _ -> 
      let rec go_back () =
        let status = script#status.proof_status in
        match status with
        | No_proof -> ()
        | _ -> script#retract ();go_back()
      in
      [], parsed_text_length, Some go_back
  | TA.Redo (_, Some i) ->  [], parsed_text_length, 
      Some (fun () -> for j = 1 to i do advance () done)
  | TA.Redo (_, None) ->   [], parsed_text_length, 
      Some (fun () -> advance ())
  | TA.Undo (_, Some i) ->  [], parsed_text_length, 
      Some (fun () -> for j = 1 to i do script#retract () done)
  | TA.Undo (_, None) -> [], parsed_text_length, 
      Some (fun () -> script#retract ()) *)
  (* TODO *)
  | TA.Quit _ -> failwith "not implemented"
  | TA.Print (_,kind) -> failwith "not implemented"
  | TA.Search_pat (_, search_kind, str) -> failwith "not implemented"
  | TA.Search_term (_, search_kind, term) -> failwith "not implemented"

                                
let eval_executable guistuff status user_goal parsed_text script ex =
  let module TA = GrafiteAst in
  let module TAPp = GrafiteAstPp in
  let module MD = MatitaDisambiguator in
  let module ML = MatitacleanLib in
  let parsed_text_length = String.length parsed_text in
  match ex with
  | TA.Command (loc, _) | TA.Tactical (loc, _) ->
      (try 
        (match MatitaMisc.baseuri_of_baseuri_decl (TA.Executable (loc,ex)) with
        | None -> ()
        | Some u -> 
            if not (MatitaMisc.is_empty u) then
              match 
                guistuff.ask_confirmation 
                  ~title:"Baseuri redefinition" 
                  ~message:(
                    "Baseuri " ^ u ^ " already exists.\n" ^
                    "Do you want to redefine the corresponding "^
                    "part of the library?")
              with
              | `YES -> MatitacleanLib.clean_baseuris [u]
              | `NO -> ()
              | `CANCEL -> raise MatitaTypes.Cancel);
        eval_with_engine 
          guistuff status user_goal parsed_text (TA.Executable (loc, ex))
      with MatitaTypes.Cancel -> [], 0)
  | TA.Macro (_,mac) ->
      eval_macro guistuff status parsed_text script mac

let rec eval_statement baseoffset parsedlen error_tag (buffer : GText.buffer)
 guistuff status user_goal script s
=
  if Pcre.pmatch ~rex:only_dust_RE s then raise Margin;
  let st =
   try
    GrafiteParser.parse_statement (Stream.of_string s)
   with
    CicNotationParser.Parse_error (floc,err) as exc ->
     let (x, y) = CicNotationPt.loc_of_floc floc in
     let x = parsedlen + x in
     let y = parsedlen + y in
     let x' = baseoffset + x in
     let y' = baseoffset + y in
     let x_iter = buffer#get_iter (`OFFSET x') in
     let y_iter = buffer#get_iter (`OFFSET y') in
      buffer#apply_tag error_tag ~start:x_iter ~stop:y_iter;
     let id = ref None in
      id :=
       Some
        (buffer#connect#changed
          ~callback:(
            fun () ->
             buffer#remove_tag error_tag ~start:buffer#start_iter
              ~stop:buffer#end_iter;
             match !id with
                None -> assert false (* a race condition occurred *)
              | Some id ->
                 (new GObj.gobject_ops buffer#as_buffer)#disconnect id));
      let flocb,floce = floc in
      let floc =
       {flocb with Lexing.pos_cnum = x}, {floce with Lexing.pos_cnum = y } in
      raise (CicNotationParser.Parse_error (floc,err))
  in
  let text_of_loc loc =
    let parsed_text_length = snd (CicNotationPt.loc_of_floc loc) in
    let parsed_text = safe_substring s 0 parsed_text_length in
    parsed_text, parsed_text_length
  in
  match st with
  | GrafiteAst.Comment (loc,_)-> 
      let parsed_text, parsed_text_length = text_of_loc loc in
      let remain_len = String.length s - parsed_text_length in
      let s = String.sub s parsed_text_length remain_len in
      let s,len = 
        eval_statement baseoffset (parsedlen + parsed_text_length) error_tag
         buffer guistuff status user_goal script s 
      in
      (match s with
      | (status, text) :: tl ->
        ((status, parsed_text ^ text)::tl), (parsed_text_length + len)
      | [] -> [], 0)
  | GrafiteAst.Executable (loc, ex) ->
      let parsed_text, parsed_text_length = text_of_loc loc in
      eval_executable guistuff  status user_goal parsed_text script ex 
  
let fresh_script_id =
  let i = ref 0 in
  fun () -> incr i; !i

class script  ~(source_view: GSourceView.source_view)
              ~(init: MatitaTypes.status) 
              ~(mathviewer: MatitaTypes.mathViewer) 
              ~set_star
              ~ask_confirmation
              ~urichooser 
              ~develcreator 
              () =
let buffer = source_view#buffer in
let source_buffer = source_view#source_buffer in
object (self)
  val scriptId = fresh_script_id ()
  
  val guistuff = {
    mathviewer = mathviewer;
    urichooser = urichooser;
    ask_confirmation = ask_confirmation;
    develcreator = develcreator;
    filenamedata = (None, None)} 
  
  method private getFilename =
    match guistuff.filenamedata with Some f,_ -> f | _ -> assert false
    
  method private ppFilename =
    match guistuff.filenamedata with 
    | Some f,_ -> f 
    | None,_ -> sprintf ".unnamed%d.ma" scriptId
  
  initializer 
    ignore(GMain.Timeout.add ~ms:300000 
       ~callback:(fun _ -> self#_saveToBackuptFile ();true));
    ignore(buffer#connect#modified_changed 
       (fun _ -> if buffer#modified then 
          set_star self#ppFilename true 
        else 
          set_star self#ppFilename false))

  val mutable statements = [];    (** executed statements *)
  val mutable history = [ init ];
    (** list of states before having executed statements. Head element of this
      * list is the current state, last element is the state at the beginning of
      * the script.
      * Invariant: this list length is 1 + length of statements *)

  (** goal as seen by the user (i.e. metano corresponding to current tab) *)
  val mutable userGoal = ~-1

  (** text mark and tag representing locked part of a script *)
  val locked_mark =
    buffer#create_mark ~name:"locked" ~left_gravity:true buffer#start_iter
  val locked_tag = buffer#create_tag [`BACKGROUND "lightblue"; `EDITABLE false]
  val error_tag = buffer#create_tag [`UNDERLINE `SINGLE; `FOREGROUND "red"]

  method locked_mark = locked_mark
  method locked_tag = locked_tag

    (* history can't be empty, the invariant above grant that it contains at
     * least the init status *)
  method status = match history with hd :: _ -> hd | _ -> assert false

  method private _advance ?statement () =
    let s = match statement with Some s -> s | None -> self#getFuture in
    MatitaLog.debug ("evaluating: " ^ first_line s ^ " ...");
    let (entries, parsed_len) = 
     eval_statement (buffer#get_iter_at_mark (`MARK locked_mark))#offset 0
      error_tag buffer guistuff self#status userGoal self s
    in
    let (new_statuses, new_statements) = List.split entries in
    history <- List.rev new_statuses @ history;
    statements <- List.rev new_statements @ statements;
    let start = buffer#get_iter_at_mark (`MARK locked_mark) in
    let new_text = String.concat "" new_statements in
    if statement <> None then
     buffer#insert ~iter:start new_text
    else
     if new_text <> String.sub s 0 parsed_len then
      begin
       let stop = start#copy#forward_chars parsed_len in
        buffer#delete ~start ~stop;
        buffer#insert ~iter:start new_text;
      end;
    self#moveMark (String.length new_text)

  method private _retract offset status new_statements new_history =
   let cur_status = match history with s::_ -> s | [] -> assert false in
    MatitaSync.time_travel ~present:cur_status ~past:status;
    statements <- new_statements;
    history <- new_history;
    self#moveMark (- offset)

  method advance ?statement () =
    try
      self#_advance ?statement ();
      self#notify
    with 
    | Margin -> self#notify
    | exc -> self#notify; raise exc

  method retract () =
    try
      let cmp,new_statements,new_history,status =
       match statements,history with
          stat::statements, _::(status::_ as history) ->
           String.length stat, statements, history, status
       | [],[_] -> raise Margin
       | _,_ -> assert false
      in
       self#_retract cmp status new_statements new_history;
       self#notify
    with 
    | Margin -> self#notify
    | exc -> self#notify; raise exc

  method private getFuture =
    buffer#get_text ~start:(buffer#get_iter_at_mark (`MARK locked_mark))
      ~stop:buffer#end_iter ()

      
  (** @param rel_offset relative offset from current position of locked_mark *)
  method private moveMark rel_offset =
    let mark = `MARK locked_mark in
    let old_insert = buffer#get_iter_at_mark `INSERT in
    buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
    let current_mark_pos = buffer#get_iter_at_mark mark in
    let new_mark_pos =
      match rel_offset with
      | 0 -> current_mark_pos
      | n when n > 0 -> current_mark_pos#forward_chars n
      | n (* when n < 0 *) -> current_mark_pos#backward_chars (abs n)
    in
    buffer#move_mark mark ~where:new_mark_pos;
    buffer#apply_tag locked_tag ~start:buffer#start_iter ~stop:new_mark_pos;
    buffer#move_mark `INSERT old_insert;
    begin
     match self#status.proof_status with
        Incomplete_proof (_,goal) -> self#setGoal goal
      | _ -> ()
    end ;
    let mark_position = buffer#get_iter_at_mark mark in
    if source_view#move_mark_onscreen mark then
     begin
      buffer#move_mark mark mark_position;
      source_view#scroll_to_mark ~use_align:true ~xalign:1.0 ~yalign:0.1 mark;
     end;
    while Glib.Main.pending () do ignore(Glib.Main.iteration false); done

  method clean_dirty_lock =
    let lock_mark_iter = buffer#get_iter_at_mark (`MARK locked_mark) in
    buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
    buffer#apply_tag locked_tag ~start:buffer#start_iter ~stop:lock_mark_iter

  val mutable observers = []

  method addObserver (o: MatitaTypes.status -> unit) =
    observers <- o :: observers

  method private notify =
    let status = self#status in
    List.iter (fun o -> o status) observers

  method loadFromFile f =
    buffer#set_text (MatitaMisc.input_file f);
    self#goto_top;
    buffer#set_modified false
    
  method assignFileName file =
    let abspath = MatitaMisc.absolute_path file in
    let devel = MatitamakeLib.development_for_dir (Filename.dirname abspath) in
    guistuff.filenamedata <- Some abspath, devel
    
  method saveToFile () =
    let oc = open_out self#getFilename in
    output_string oc (buffer#get_text ~start:buffer#start_iter
                        ~stop:buffer#end_iter ());
    close_out oc;
    buffer#set_modified false
  
  method private _saveToBackuptFile () =
    if buffer#modified then
      begin
        let f = self#ppFilename ^ "~" in
        let oc = open_out f in
        output_string oc (buffer#get_text ~start:buffer#start_iter
                            ~stop:buffer#end_iter ());
        close_out oc;
        MatitaLog.debug ("backup " ^ f ^ " saved")                    
      end
  
  method private goto_top =
    MatitaSync.time_travel ~present:self#status ~past:init;
    statements <- [];
    history <- [ init ];
    userGoal <- ~-1;
    buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
    buffer#move_mark (`MARK locked_mark) ~where:buffer#start_iter

  method reset () =
    self#goto_top;
    source_buffer#begin_not_undoable_action ();
    buffer#delete ~start:buffer#start_iter ~stop:buffer#end_iter;
    source_buffer#end_not_undoable_action ();
    self#notify;
    buffer#set_modified false

  method template () =
    let template = MatitaMisc.input_file BuildTimeConf.script_template in 
    buffer#insert ~iter:(buffer#get_iter `START) template;
    guistuff.filenamedata <- 
      (None,MatitamakeLib.development_for_dir (Unix.getcwd ()));
    buffer#set_modified false;
    set_star self#ppFilename false

  method goto (pos: [`Top | `Bottom | `Cursor]) () =
    let old_locked_mark =
     `MARK
       (buffer#create_mark ~name:"old_locked_mark"
         ~left_gravity:true (buffer#get_iter_at_mark (`MARK locked_mark))) in
    let getpos _ = buffer#get_iter_at_mark (`MARK locked_mark) in 
    let getoldpos _ = buffer#get_iter_at_mark old_locked_mark in 
    let dispose_old_locked_mark () = buffer#delete_mark old_locked_mark in
    match pos with
    | `Top -> dispose_old_locked_mark (); self#goto_top; self#notify
    | `Bottom ->
        (try 
          let rec dowhile () =
            self#_advance ();
            let newpos = getpos () in
            if (getoldpos ())#compare newpos < 0 then
              begin
                buffer#move_mark old_locked_mark newpos;
                dowhile ()
              end
          in
          dowhile ();
          dispose_old_locked_mark ();
          self#notify 
        with 
        | Margin -> dispose_old_locked_mark (); self#notify
        | exc -> dispose_old_locked_mark (); self#notify; raise exc)
    | `Cursor ->
        let locked_iter () = buffer#get_iter_at_mark (`NAME "locked") in
        let cursor_iter () = buffer#get_iter_at_mark `INSERT in
        let remember =
         `MARK
           (buffer#create_mark ~name:"initial_insert"
             ~left_gravity:true (cursor_iter ())) in
        let dispose_remember () = buffer#delete_mark remember in
        let remember_iter () =
         buffer#get_iter_at_mark (`NAME "initial_insert") in
        let cmp () = (locked_iter ())#offset - (remember_iter ())#offset in
        let icmp = cmp () in
        let forward_until_cursor () = (* go forward until locked > cursor *)
          let rec aux () =
            self#_advance ();
            if cmp () < 0 && (getoldpos ())#compare (getpos ()) < 0 
            then
             begin
              buffer#move_mark old_locked_mark (getpos ());
              aux ()
             end
          in
          aux ()
        in
        let rec back_until_cursor len = (* go backward until locked < cursor *)
         function
            statements, (status::_ as history) when len <= 0 ->
             self#_retract (icmp - len) status statements history
          | statement::tl1, _::tl2 ->
             back_until_cursor (len - String.length statement) (tl1,tl2)
          | _,_ -> assert false
        in
        (try
          begin
           if icmp < 0 then       (* locked < cursor *)
             (forward_until_cursor (); self#notify)
           else if icmp > 0 then  (* locked > cursor *)
             (back_until_cursor icmp (statements,history); self#notify)
           else                  (* cursor = locked *)
               ()
          end ;
          dispose_remember ();
          dispose_old_locked_mark ();
        with 
        | Margin -> dispose_remember (); dispose_old_locked_mark (); self#notify
        | exc -> dispose_remember (); dispose_old_locked_mark ();
                 self#notify; raise exc)
              
  method onGoingProof () =
    match self#status.proof_status with
    | No_proof | Proof _ -> false
    | Incomplete_proof _ -> true
    | Intermediate _ -> assert false

  method proofStatus = MatitaMisc.get_proof_status self#status
  method proofMetasenv = MatitaMisc.get_proof_metasenv self#status
  method proofContext = MatitaMisc.get_proof_context self#status
  method proofConclusion = MatitaMisc.get_proof_conclusion self#status
  method setGoal n = userGoal <- n

  method eos = 
    let s = self#getFuture in
    let rec is_there_and_executable s = 
      if Pcre.pmatch ~rex:only_dust_RE s then raise Margin;
      let st = GrafiteParser.parse_statement (Stream.of_string s) in
      match st with
      | GrafiteAst.Comment (loc,_)-> 
          let parsed_text_length = snd (CicNotationPt.loc_of_floc loc) in
          let remain_len = String.length s - parsed_text_length in
          let next = String.sub s parsed_text_length remain_len in
          is_there_and_executable next
      | GrafiteAst.Executable (loc, ex) -> false
    in
    try
      is_there_and_executable s
    with 
    | CicNotationParser.Parse_error _ -> false
    | Margin -> true
      
    
    
  (* debug *)
  method dump () =
    MatitaLog.debug "script status:";
    MatitaLog.debug ("history size: " ^ string_of_int (List.length history));
    MatitaLog.debug (sprintf "%d statements:" (List.length statements));
    List.iter MatitaLog.debug statements;
    MatitaLog.debug ("Current file name: " ^
      (match guistuff.filenamedata with 
      |None,_ -> "[ no name ]" 
      | Some f,_ -> f));

end

let _script = ref None

let script ~source_view ~init ~mathviewer ~urichooser ~develcreator ~ask_confirmation ~set_star ()
=
  let s = new script 
    ~source_view ~init ~mathviewer ~ask_confirmation ~urichooser ~develcreator ~set_star () 
  in
  _script := Some s;
  s

let instance () = match !_script with None -> assert false | Some s -> s