(* Copyright (C) 2004-2005, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://helm.cs.unibo.it/
 *)

open Printf

open MatitaTypes

let alias_diff ~from status = 
  let module Map = DisambiguateTypes.Environment in
  Map.fold
    (fun domain_item (description1,_ as codomain_item) acc ->
      try
       let description2,_ = Map.find domain_item from.aliases in
        if description1 <> description2 then
         (domain_item,codomain_item)::acc
        else
          acc
      with
       Not_found ->
         (domain_item,codomain_item)::acc)
    status.aliases []

let alias_diff =
 let profiler = HExtlib.profile "alias_diff (conteggiato anche in include)" in
 fun ~from status -> profiler.HExtlib.profile (alias_diff ~from) status

let set_proof_aliases status new_aliases =
 let commands_of_aliases =
   List.map
    (fun alias -> GrafiteAst.Alias (DisambiguateTypes.dummy_floc, alias))
 in
 let deps_of_aliases =
   HExtlib.filter_map
    (function
    | GrafiteAst.Ident_alias (_, suri) ->
        let buri = UriManager.buri_of_uri (UriManager.uri_of_string suri) in
        Some (GrafiteAst.Dependency buri)
    | _ -> None)
 in
 let aliases =
  List.fold_left (fun acc (d,c) -> DisambiguateTypes.Environment.add d c acc)
   status.aliases new_aliases in
 let multi_aliases =
  List.fold_left (fun acc (d,c) -> DisambiguateTypes.Environment.cons d c acc)
   status.multi_aliases new_aliases in
 let new_status =
   { status with multi_aliases = multi_aliases ; aliases = aliases}
 in
 if new_aliases = [] then
   new_status
 else
   let aliases = 
     DisambiguatePp.aliases_of_domain_and_codomain_items_list new_aliases
   in
   let status = add_moo_content (commands_of_aliases aliases) new_status in
   let status = add_moo_metadata (deps_of_aliases aliases) status in
   status

(** given a uri and a type list (the contructors types) builds a list of pairs
 *  (name,uri) that is used to generate automatic aliases **)
let extract_alias types uri = 
  fst(List.fold_left (
    fun (acc,i) (name, _, _, cl) -> 
      (name, UriManager.uri_of_uriref uri i None) ::
      (fst(List.fold_left (
        fun (acc,j) (name,_) ->
          (((name,UriManager.uri_of_uriref uri i
          (Some j)) :: acc) , j+1)
        ) (acc,1) cl)),i+1
  ) ([],0) types)

let build_aliases =
 List.map
  (fun (name,uri) ->
    DisambiguateTypes.Id name,
     (UriManager.string_of_uri uri, fun _ _ _ -> CicUtil.term_of_uri uri))

let add_aliases_for_inductive_def status types uri = 
  let aliases = build_aliases (extract_alias types uri) in
   set_proof_aliases status aliases

let add_alias_for_constant status uri =
 let name = UriManager.name_of_uri uri in
 let new_env = build_aliases [(name,uri)] in
 set_proof_aliases status new_env

let add_aliases_for_object status uri =
 function
    Cic.InductiveDefinition (types,_,_,_) ->
     add_aliases_for_inductive_def status types uri
  | Cic.Constant _ -> add_alias_for_constant status uri
  | Cic.Variable _
  | Cic.CurrentProof _ -> assert false
  
let add_obj uri obj status =
 let basedir = Helm_registry.get "matita.basedir" in
 let lemmas = LibrarySync.add_obj uri obj basedir in
  List.fold_left add_alias_for_constant
   (add_aliases_for_object status uri obj) lemmas

let add_obj =
 let profiler = HExtlib.profile "add_obj" in
  fun uri obj status -> profiler.HExtlib.profile (add_obj uri obj) status
   
module OrderedUri =
struct
  type t = UriManager.uri * string
  let compare (u1, _) (u2, _) = UriManager.compare u1 u2
end

module OrderedId = 
struct
  type t = CicNotation.notation_id
  let compare = Pervasives.compare
end

module UriSet = Set.Make (OrderedUri)
module IdSet  = Set.Make (OrderedId)

  (** @return l2 \ l1 *)
let urixstring_list_diff l2 l1 =
  let module S = UriSet in
  let s1 = List.fold_left (fun set uri -> S.add uri set) S.empty l1 in
  let s2 = List.fold_left (fun set uri -> S.add uri set) S.empty l2 in
  let diff = S.diff s2 s1 in
  S.fold (fun uri uris -> uri :: uris) diff []

let uri_list_diff l2 l1 =
  let module S = UriManager.UriSet in
  let s1 = List.fold_left (fun set uri -> S.add uri set) S.empty l1 in
  let s2 = List.fold_left (fun set uri -> S.add uri set) S.empty l2 in
  let diff = S.diff s2 s1 in
  S.fold (fun uri uris -> uri :: uris) diff []

  (** @return l2 \ l1 *)
let id_list_diff l2 l1 =
  let module S = IdSet in
  let s1 = List.fold_left (fun set uri -> S.add uri set) S.empty l1 in
  let s2 = List.fold_left (fun set uri -> S.add uri set) S.empty l2 in
  let diff = S.diff s2 s1 in
  S.fold (fun uri uris -> uri :: uris) diff []

let time_travel ~present ~past =
  let objs_to_remove = urixstring_list_diff present.objects past.objects in
  let coercions_to_remove = uri_list_diff present.coercions past.coercions in
  let notation_to_remove =
    id_list_diff present.notation_ids past.notation_ids
  in
  let debug_list = ref [] in
  List.iter
   (fun uri -> CoercDb.remove_coercion (fun (_,_,u) -> UriManager.eq u uri))
   coercions_to_remove;
  List.iter
    (fun (uri,p) -> 
      HExtlib.safe_remove p;
      (try 
        CicEnvironment.remove_obj uri
      with CicEnvironment.Object_not_found _ -> 
        HLog.debug
          (sprintf "time_travel removes from cache %s that is not in" 
            (UriManager.string_of_uri uri)));
      let l = LibraryDb.remove_uri uri in
      debug_list := UriManager.string_of_uri uri :: !debug_list @ l) 
    objs_to_remove;
  List.iter CicNotation.remove_notation notation_to_remove
  (*
  (* this is debug code
  * idea: debug_list is the list of objects to be removed as computed from the
  * db, while list_of_objs_to_remove is the same list but computer from the
  * differences between statuses *)
  let l1 = List.sort Pervasives.compare !debug_list in
  let l2 = List.sort Pervasives.compare 
    (List.map (fun (x,_) -> UriManager.string_of_uri x) list_of_objs_to_remove)
  in
  let rec uniq = function 
    | [] -> []
    | h::[] -> [h]
    | h1::h2::tl when h1 = h2 -> uniq (h2 :: tl)
    | h1::tl (* when h1 <> h2 *) -> h1 :: uniq tl
  in
  let l1 =  uniq l1 in
  let l2 =  uniq l2 in
  try
    List.iter2 (fun x y -> if x <> y then raise Exit) l1 l2
  with
  | Invalid_argument _ | Exit -> 
      HLog.debug "It seems you garbaged something...";
      HLog.debug "l1:";
      List.iter HLog.debug l1;
      HLog.debug "l2:";
      List.iter HLog.debug l2
      *)