(* Copyright (C) 2004, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://helm.cs.unibo.it/
 *)

let debug = false
let debug_print s =
  if debug then begin
    prerr_endline "<NEW_TEXTUAL_PARSER>";
    prerr_endline s;
    prerr_endline "</NEW_TEXTUAL_PARSER>"
  end

  (** if set to true each number will have a different insance number and can
  * thus be interpreted differently than others *)
let use_fresh_num_instances = false

  (** does the lexer return COMMENT tokens? *)
let return_comments = false

open Printf

open DisambiguateTypes

exception Parse_error of Token.flocation * string

let cic_lexer = CicTextualLexer2.cic_lexer ~comments:return_comments ()

let fresh_num_instance =
  let n = ref 0 in
  if use_fresh_num_instances then
    (fun () -> incr n; !n)
  else
    (fun () -> 0)

let choice_of_uri uri =
  let term = CicUtil.term_of_uri uri in
  (uri, (fun _ _ _ -> term))

let grammar = Grammar.gcreate cic_lexer

let term = Grammar.Entry.create grammar "term"
let term0 = Grammar.Entry.create grammar "term0"
let tactic = Grammar.Entry.create grammar "tactic"
let tactical = Grammar.Entry.create grammar "tactical"
let tactical0 = Grammar.Entry.create grammar "tactical0"
let command = Grammar.Entry.create grammar "command"
let script = Grammar.Entry.create grammar "script"

let return_term loc term = CicAst.AttributedTerm (`Loc loc, term)
let return_tactic loc tactic = TacticAst.LocatedTactic (loc, tactic)
let return_tactical loc tactical = TacticAst.LocatedTactical (loc, tactical)
let return_command loc cmd = cmd  (* TODO ZACK FIXME uhm ... why we drop loc? *)

let fail floc msg =
  let (x, y) = CicAst.loc_of_floc floc in
  failwith (Printf.sprintf "Error at characters %d - %d: %s" x y msg)

let name_of_string = function
  | "_" -> Cic.Anonymous
  | s -> Cic.Name s

let string_of_name = function
  | Cic.Anonymous -> "_"
  | Cic.Name s -> s
  
let int_opt = function
  | None -> None
  | Some lexeme -> Some (int_of_string lexeme)

  (** the uri of an inductive type (a ".ind" uri) is not meaningful without an
  * xpointer. Still, it's likely that an user who wrote "cic:/blabla/foo.ind"
  * actually meant "cic:/blabla/foo.ind#xpointer(1/1)", i.e. the first inductive
  * type in a block of mutual inductive types.
  *
  * This function performs the expansion foo.ind -> foo#xpointer..., if needed
  *)
let ind_expansion uri =
  let len = String.length uri in
  if len >= 4 && String.sub uri (len - 4) 4 = ".ind" then
    uri ^ "#xpointer(1/1)"
  else
    uri

EXTEND
  GLOBAL: term term0 tactic tactical tactical0 command script;
  int: [
    [ num = NUM ->
        try
          int_of_string num
        with Failure _ -> raise (Parse_error (loc, "integer literal expected"))
    ]
  ];
  meta_subst: [
    [ s = SYMBOL "_" -> None
    | t = term -> Some t ]
  ];
  binder: [
    [ SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda
    | SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
    | SYMBOL <:unicode<exists>> (* ∃ *) -> `Exists
    | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall ]
  ];
  sort: [
    [ "Prop" -> `Prop
    | "Set" -> `Set
    | "Type" -> `Type
    | "CProp" -> `CProp ]
  ];
  typed_name: [
    [ PAREN "("; i = IDENT; SYMBOL ":"; typ = term; PAREN ")" ->
        (Cic.Name i, Some typ)
    | i = IDENT -> (Cic.Name i, None)
    ]
  ];
  subst: [
    [ subst = OPT [
        SYMBOL "\\subst";  (* to avoid catching frequent "a [1]" cases *)
        PAREN "[";
        substs = LIST1 [
          i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = term -> (i, t)
        ] SEP SYMBOL ";";
        PAREN "]" ->
          substs
      ] -> subst
    ]
  ];
  substituted_name: [ (* a subs.name is an explicit substitution subject *)
    [ s = IDENT; subst = subst -> CicAst.Ident (s, subst)
    | s = URI; subst = subst -> CicAst.Uri (ind_expansion s, subst)
    ]
  ];
  name: [ (* as substituted_name with no explicit substitution *)
    [ s = [ IDENT | SYMBOL ] -> s ]
  ];
  pattern: [
    [ n = name -> (n, [])
    | PAREN "("; head = name; vars = LIST1 typed_name; PAREN ")" ->
        (head, vars)
    ]
  ];
  let_defs:[
    [ defs = LIST1 [
        name = IDENT;
        args = LIST1 [
          PAREN "(" ; names = LIST1 IDENT SEP SYMBOL ","; SYMBOL ":";
          ty = term; PAREN ")" ->
            (names, ty)
        ];
        index_name = OPT [ IDENT "on"; idx = IDENT -> idx ];
        ty = OPT [ SYMBOL ":" ; t = term -> t ];
        SYMBOL <:unicode<def>> (* ≝ *);
        t1 = term ->
          let rec list_of_binder binder ty final_term = function
            | [] -> final_term
            | name::tl -> 
                CicAst.Binder (binder, (Cic.Name name, Some ty), 
                  list_of_binder binder ty final_term tl)
          in
          let rec binder_of_arg_list binder final_term = function
            | [] -> final_term
            | (l,ty)::tl ->  
                list_of_binder binder ty 
                  (binder_of_arg_list binder final_term tl) l
          in
          let t1' = binder_of_arg_list `Lambda t1 args in
          let ty' = 
            match ty with 
            | None -> None
            | Some ty -> Some (binder_of_arg_list `Pi ty args)
          in
          let rec get_position_of name n = function 
            | [] -> (None,n)
            | nam::tl -> 
                if nam = name then 
                  (Some n,n) 
                else 
                  (get_position_of name (n+1) tl)
          in
          let rec find_arg name n = function 
            | [] -> (fail loc (sprintf "Argument %s not found" name))
            | (l,_)::tl -> 
                let (got,len) = get_position_of name 0 l in
                (match got with 
                | None -> (find_arg name (n+len) tl)
                | Some where -> n + where)
          in
          let index = 
            (match index_name with 
             | None -> 0 
             | (Some name) -> find_arg name 0 args)
          in
          ((Cic.Name name,ty'), t1', index)
      ] SEP "and" -> defs
    ]];
  constructor: [ [ name = IDENT; SYMBOL ":"; typ = term -> (name, typ) ] ];
  term0: [ [ t = term; EOI -> return_term loc t ] ];
  term:
    [ "letin" NONA
      [ "let"; var = typed_name;
        SYMBOL <:unicode<def>> (* ≝ *);
        t1 = term; "in"; t2 = term ->
          return_term loc (CicAst.LetIn (var, t1, t2))
      | "let"; ind_kind = [ "corec" -> `CoInductive | "rec"-> `Inductive ];
        defs = let_defs; "in"; body = term ->
            return_term loc (CicAst.LetRec (ind_kind, defs, body))
      ]
    | "binder" RIGHTA
      [
        b = binder;
        (vars, typ) =
          [ vars = LIST1 IDENT SEP SYMBOL ",";
            typ = OPT [ SYMBOL ":"; t = term -> t ] -> (vars, typ)
          | PAREN "("; vars = LIST1 IDENT SEP SYMBOL ",";
            typ = OPT [ SYMBOL ":"; t = term -> t ]; PAREN ")" -> (vars, typ)
          ];
        SYMBOL "."; body = term ->
          let binder =
            List.fold_right
              (fun var body ->
                let name = name_of_string var in
                CicAst.Binder (b, (name, typ), body))
              vars body
          in
          return_term loc binder
      | t1 = term; SYMBOL <:unicode<to>> (* → *); t2 = term ->
            return_term loc
              (CicAst.Binder (`Pi, (Cic.Anonymous, Some t1), t2))
      ]
    | "logic_add" LEFTA   [ (* nothing here by default *) ]
    | "logic_mult" LEFTA  [ (* nothing here by default *) ]
    | "logic_inv" NONA    [ (* nothing here by default *) ]
    | "relop" LEFTA
      [ t1 = term; SYMBOL "="; t2 = term ->
        return_term loc (CicAst.Appl [CicAst.Symbol ("eq", 0); t1; t2])
      ]
    | "add" LEFTA     [ (* nothing here by default *) ]
    | "mult" LEFTA    [ (* nothing here by default *) ]
    | "power" LEFTA   [ (* nothing here by default *) ]
    | "inv" NONA      [ (* nothing here by default *) ]
    | "apply" LEFTA
      [ t1 = term; t2 = term ->
        let rec aux = function
          | CicAst.Appl (hd :: tl) -> aux hd @ tl
          | term -> [term]
        in
        CicAst.Appl (aux t1 @ [t2])
      ]
    | "simple" NONA
      [ sort = sort -> CicAst.Sort sort
      | n = substituted_name -> return_term loc n
      | i = NUM -> return_term loc (CicAst.Num (i, (fresh_num_instance ())))
      | IMPLICIT -> return_term loc CicAst.Implicit
      | m = META;
        substs = [
          PAREN "["; substs = LIST0 meta_subst SEP SYMBOL ";" ; PAREN "]" ->
            substs
        ] ->
            let index =
              try
                int_of_string (String.sub m 1 (String.length m - 1))
              with Failure "int_of_string" ->
                fail loc ("Invalid meta variable number: " ^ m)
            in
            return_term loc (CicAst.Meta (index, substs))
      | outtyp = OPT [ PAREN "["; typ = term; PAREN "]" -> typ ];
        "match"; t = term;
        indty_ident = OPT [ SYMBOL ":"; id = IDENT -> id ];
        "with";
        PAREN "[";
        patterns = LIST0 [
          lhs = pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *); rhs = term
          ->
            ((lhs: CicAst.case_pattern), rhs)
        ] SEP SYMBOL "|";
        PAREN "]" ->
          return_term loc
            (CicAst.Case (t, indty_ident, outtyp, patterns))
      | PAREN "("; t1 = term; SYMBOL ":"; t2 = term; PAREN ")" ->
          return_term loc (CicAst.Appl [CicAst.Symbol ("cast", 0); t1; t2])
      | PAREN "("; t = term; PAREN ")" -> return_term loc t
      ]
    ];
  tactic_where: [
    [ where = OPT [ "in"; ident = IDENT -> ident ] -> where ]
  ];
  tactic_term: [ [ t = term -> t ] ];
  ident_list0: [
    [ PAREN "["; idents = LIST0 IDENT SEP SYMBOL ";"; PAREN "]" -> idents ]
  ];
  ident_list1: [
    [ PAREN "["; idents = LIST1 IDENT SEP SYMBOL ";"; PAREN "]" -> idents ]
  ];
  reduction_kind: [
    [ [ IDENT "reduce" | IDENT "Reduce" ] -> `Reduce
    | [ IDENT "simplify" | IDENT "Simplify" ] -> `Simpl
    | [ IDENT "whd" | IDENT "Whd" ] -> `Whd ]
  ];
  tactic: [
    [ [ IDENT "absurd" | IDENT "Absurd" ]; t = tactic_term ->
        return_tactic loc (TacticAst.Absurd t)
    | [ IDENT "apply" | IDENT "Apply" ]; t = tactic_term ->
        return_tactic loc (TacticAst.Apply t)
    | [ IDENT "assumption" | IDENT "Assumption" ] ->
        return_tactic loc TacticAst.Assumption
    | [ IDENT "auto" | IDENT "Auto" ] -> return_tactic loc TacticAst.Auto
    | [ IDENT "change" | IDENT "Change" ];
      t1 = tactic_term; "with"; t2 = tactic_term;
      where = tactic_where ->
        return_tactic loc (TacticAst.Change (t1, t2, where))
    (* TODO Change_pattern *)
    | [ IDENT "contradiction" | IDENT "Contradiction" ] ->
        return_tactic loc TacticAst.Contradiction
    | [ IDENT "cut" | IDENT "Cut" ];
      t = tactic_term -> return_tactic loc (TacticAst.Cut t)
    | [ IDENT "decompose" | IDENT "Decompose" ];
      principles = ident_list1; where = IDENT ->
        return_tactic loc (TacticAst.Decompose (where, principles))
    | [ IDENT "discriminate" | IDENT "Discriminate" ];
      hyp = IDENT ->
        return_tactic loc (TacticAst.Discriminate hyp)
    | [ IDENT "elimType" | IDENT "ElimType" ]; t = tactic_term ->
        return_tactic loc (TacticAst.ElimType t)
    | [ IDENT "elim" | IDENT "Elim" ];
      t1 = tactic_term;
      using = OPT [ "using"; using = tactic_term -> using ] ->
        return_tactic loc (TacticAst.Elim (t1, using))
    | [ IDENT "exact" | IDENT "Exact" ]; t = tactic_term ->
        return_tactic loc (TacticAst.Exact t)
    | [ IDENT "exists" | IDENT "Exists" ] ->
        return_tactic loc TacticAst.Exists
    | [ IDENT "fold" | IDENT "Fold" ];
      kind = reduction_kind; t = tactic_term ->
        return_tactic loc (TacticAst.Fold (kind, t))
    | [ IDENT "fourier" | IDENT "Fourier" ] ->
        return_tactic loc TacticAst.Fourier
    | [ IDENT "hint" | IDENT "Hint" ] -> return_tactic loc TacticAst.Hint
    | [ IDENT "injection" | IDENT "Injection" ]; ident = IDENT ->
        return_tactic loc (TacticAst.Injection ident)
    | [ IDENT "intros" | IDENT "Intros" ];
      num = OPT [ num = int -> num ];
      idents = OPT ident_list0 ->
        let idents = match idents with None -> [] | Some idents -> idents in
        return_tactic loc (TacticAst.Intros (num, idents))
    | [ IDENT "intro" | IDENT "Intro" ] ->
        return_tactic loc (TacticAst.Intros (Some 1, []))
    | [ IDENT "left" | IDENT "Left" ] -> return_tactic loc TacticAst.Left
    | [ "let" | "Let" ];
      t = tactic_term; "in"; where = IDENT ->
        return_tactic loc (TacticAst.LetIn (t, where))
    | kind = reduction_kind;
      pat = OPT [
        "in"; pat = [ IDENT "goal" -> `Goal | IDENT "hyp" -> `Everywhere ] ->
          pat
      ];
      terms = LIST0 term SEP SYMBOL "," ->
        let tac =
          (match (pat, terms) with
          | None, [] -> TacticAst.Reduce (kind, None)
          | None, terms -> TacticAst.Reduce (kind, Some (terms, `Goal))
          | Some pat, [] -> TacticAst.Reduce (kind, Some ([], pat))
          | Some pat, terms -> TacticAst.Reduce (kind, Some (terms, pat)))
        in
        return_tactic loc tac
    | [ IDENT "reflexivity" | IDENT "Reflexivity" ] ->
        return_tactic loc TacticAst.Reflexivity
    | [ IDENT "replace" | IDENT "Replace" ];
      t1 = tactic_term; "with"; t2 = tactic_term ->
        return_tactic loc (TacticAst.Replace (t1, t2))
    (* TODO Rewrite *)
    (* TODO Replace_pattern *)
    | [ IDENT "right" | IDENT "Right" ] -> return_tactic loc TacticAst.Right
    | [ IDENT "ring" | IDENT "Ring" ] -> return_tactic loc TacticAst.Ring
    | [ IDENT "split" | IDENT "Split" ] -> return_tactic loc TacticAst.Split
    | [ IDENT "symmetry" | IDENT "Symmetry" ] ->
        return_tactic loc TacticAst.Symmetry
    | [ IDENT "transitivity" | IDENT "Transitivity" ];
      t = tactic_term ->
        return_tactic loc (TacticAst.Transitivity t)
    ]
  ];
  tactical0: [ [ t = tactical; SYMBOL "." -> return_tactical loc t ] ];
  tactical:
    [ "command" NONA
      [ cmd = command -> return_tactical loc (TacticAst.Command cmd) ]
    | "sequence" LEFTA
      [ tactics = LIST1 NEXT SEP SYMBOL ";" ->
          return_tactical loc (TacticAst.Seq tactics)
      ]
    | "then" NONA
      [ tac = tactical;
        PAREN "["; tacs = LIST0 tactical SEP SYMBOL ";"; PAREN "]" ->
          return_tactical loc (TacticAst.Then (tac, tacs))
      ]
    | "loops" RIGHTA
      [ [ IDENT "do" | IDENT "Do" ]; count = int; tac = tactical ->
          return_tactical loc (TacticAst.Do (count, tac))
      | [ IDENT "repeat" | IDENT "Repeat" ]; tac = tactical ->
          return_tactical loc (TacticAst.Repeat tac)
      ]
    | "simple" NONA
      [ [ IDENT "tries" | IDENT "Tries" ];
        PAREN "["; tacs = LIST0 tactical SEP SYMBOL ";"; PAREN "]" ->
          return_tactical loc (TacticAst.Tries tacs)
      | [ IDENT "try" | IDENT "Try" ]; tac = NEXT ->
          return_tactical loc (TacticAst.Try tac)
      | [ IDENT "fail" | IDENT "Fail" ] -> return_tactical loc TacticAst.Fail
      | [ IDENT "id" | IDENT "Id" ] -> return_tactical loc TacticAst.IdTac
      | PAREN "("; tac = tactical; PAREN ")" -> return_tactical loc tac
      | tac = tactic -> return_tactical loc (TacticAst.Tactic tac)
      ]
    ];
  theorem_flavour: [  (* all flavours but Goal *)
    [ [ IDENT "definition"  | IDENT "Definition"  ] -> `Definition
    | [ IDENT "fact"        | IDENT "Fact"        ] -> `Fact
    | [ IDENT "lemma"       | IDENT "Lemma"       ] -> `Lemma
    | [ IDENT "remark"      | IDENT "Remark"      ] -> `Remark
    | [ IDENT "theorem"     | IDENT "Theorem"     ] -> `Theorem
    ]
  ];
  inductive_spec: [ [
    fst_name = IDENT; params = LIST0 [
      PAREN "("; names = LIST1 IDENT SEP SYMBOL ","; SYMBOL ":";
      typ = term; PAREN ")" -> (names, typ) ];
    SYMBOL ":"; fst_typ = term; SYMBOL <:unicode<def>>; OPT SYMBOL "|";
    fst_constructors = LIST0 constructor SEP SYMBOL "|";
    tl = OPT [ "with";
      types = LIST1 [
        name = IDENT; SYMBOL ":"; typ = term; SYMBOL <:unicode<def>>;
       OPT SYMBOL "|"; constructors = LIST0 constructor SEP SYMBOL "|" ->
          (name, true, typ, constructors) ] SEP "with" -> types
    ] ->
      let params =
        List.fold_right
          (fun (names, typ) acc ->
            (List.map (fun name -> (name, typ)) names) @ acc)
          params []
      in
      let fst_ind_type = (fst_name, true, fst_typ, fst_constructors) in
      let tl_ind_types = match tl with None -> [] | Some types -> types in
      let ind_types = fst_ind_type :: tl_ind_types in
      (params, ind_types)
  ] ];
  print_kind: [
    [ [ IDENT "Env" | IDENT "env" | IDENT "Environment" | IDENT "environment" ]
      -> `Env
    | [ IDENT "Coer" | IDENT "coer" | IDENT "Coercions" | IDENT "coercions" ]
      -> `Coer
  ] ];

  command: [
    [ [ IDENT "abort" | IDENT "Abort" ] -> return_command loc TacticAst.Abort
    | [ IDENT "proof" | IDENT "Proof" ] -> return_command loc TacticAst.Proof
    | [ IDENT "quit"  | IDENT "Quit"  ] -> return_command loc TacticAst.Quit
    | [ IDENT "qed"   | IDENT "Qed"   ] ->
        return_command loc (TacticAst.Qed None)
    | [ IDENT "print"   | IDENT "Print" ];
      print_kind = print_kind ->
            return_command loc (TacticAst.Print print_kind)
    | [ IDENT "save"  | IDENT "Save"  ]; name = IDENT ->
        return_command loc (TacticAst.Qed (Some name))
    | flavour = theorem_flavour; name = OPT IDENT; SYMBOL ":"; typ = term;
      body = OPT [ SYMBOL <:unicode<def>> (* ≝ *); body = term -> body ] ->
        return_command loc (TacticAst.Theorem (flavour, name, typ, body))
    | "let"; ind_kind = [ "corec" -> `CoInductive | "rec"-> `Inductive ];
        defs = let_defs -> 
          let name,ty = 
            match defs with
            | ((Cic.Name name,Some ty),_,_) :: _ -> name,ty
            | ((Cic.Name name,None),_,_) :: _ -> 
                fail loc ("No type given for " ^ name)
            | _ -> assert false 
          in
          let body = CicAst.Ident (name,None) in
          TacticAst.Theorem(`Definition, Some name, ty,
            Some (CicAst.LetRec (ind_kind, defs, body)))
          
    | [ IDENT "inductive" | IDENT "Inductive" ]; spec = inductive_spec ->
        let (params, ind_types) = spec in
        return_command loc (TacticAst.Inductive (params, ind_types))
    | [ IDENT "coinductive" | IDENT "CoInductive" ]; spec = inductive_spec ->
        let (params, ind_types) = spec in
        let ind_types = (* set inductive flags to false (coinductive) *)
          List.map (fun (name, _, term, ctors) -> (name, false, term, ctors))
            ind_types
        in
        return_command loc (TacticAst.Inductive (params, ind_types))
    | [ IDENT "coercion" | IDENT "Coercion" ] ; name = IDENT -> 
        return_command loc (TacticAst.Coercion (CicAst.Ident (name,Some [])))
    | [ IDENT "coercion" | IDENT "Coercion" ] ; name = URI -> 
        return_command loc (TacticAst.Coercion (CicAst.Uri (name,Some [])))
    | [ IDENT "goal" | IDENT "Goal" ]; typ = term;
      body = OPT [ SYMBOL <:unicode<def>> (* ≝ *); body = term -> body ] ->
        return_command loc (TacticAst.Theorem (`Goal, None, typ, body))
    | [ IDENT "undo"   | IDENT "Undo" ]; steps = OPT NUM ->
        return_command loc (TacticAst.Undo (int_opt steps))
    | [ IDENT "redo"   | IDENT "Redo" ]; steps = OPT NUM ->
        return_command loc (TacticAst.Redo (int_opt steps))
    | [ IDENT "baseuri"   | IDENT "Baseuri" ]; uri = OPT QSTRING ->
        return_command loc (TacticAst.Baseuri uri)
    | [ IDENT "basedir"   | IDENT "Basedir" ]; uri = OPT QSTRING ->
        return_command loc (TacticAst.Basedir uri)
    | [ IDENT "check"   | IDENT "Check" ]; t = term ->
        return_command loc (TacticAst.Check t)
(*
    | [ IDENT "alias"   | IDENT "Alias" ]; spec = alias_spec ->
        return_command loc (TacticAst.Alias spec)
*)
    ]
  ];
  script_entry: [
    [ cmd = tactical0 -> Command cmd
(*     | s = COMMENT -> Comment (loc, s) *)
    ]
  ];
  script: [ [ entries = LIST0 script_entry; EOI -> (loc, entries) ] ];
END

let exc_located_wrapper f =
  try
    f ()
  with
  | Stdpp.Exc_located (floc, Stream.Error msg) ->
      raise (Parse_error (floc, msg))
  | Stdpp.Exc_located (floc, exn) ->
      raise (Parse_error (floc, (Printexc.to_string exn)))

let parse_term stream =
  exc_located_wrapper (fun () -> (Grammar.Entry.parse term0 stream))
let parse_tactic stream =
  exc_located_wrapper (fun () -> (Grammar.Entry.parse tactic stream))
let parse_tactical stream =
  exc_located_wrapper (fun () -> (Grammar.Entry.parse tactical0 stream))
let parse_script stream =
  exc_located_wrapper (fun () -> (Grammar.Entry.parse script stream))

(**/**)

(** {2 Interface for gTopLevel} *)

module EnvironmentP3 =
  struct
    type t = environment

    let empty = ""

    let aliases_grammar = Grammar.gcreate cic_lexer
    let aliases = Grammar.Entry.create aliases_grammar "aliases"

    let to_string env =
      let aliases =
        Environment.fold
          (fun domain_item (dsc, _) acc ->
            let s =
              match domain_item with
              | Id id -> sprintf "alias id %s = %s" id dsc
              | Symbol (symb, instance) ->
                  sprintf "alias symbol \"%s\" (instance %d) = \"%s\""
                    symb instance dsc
              | Num instance ->
                  sprintf "alias num (instance %d) = \"%s\"" instance dsc
            in
            s :: acc)
          env []
      in
      String.concat "\n" (List.sort compare aliases)

    EXTEND
      GLOBAL: aliases;
      aliases: [  (* build an environment from an aliases list *)
        [ aliases = LIST0 alias; EOI ->
            List.fold_left
              (fun env (domain_item, codomain_item) ->
                Environment.add domain_item codomain_item env)
              Environment.empty aliases
        ]
      ];
      alias: [  (* return a pair <domain_item, codomain_item> from an alias *)
        [ IDENT "alias";
          choice =
            [ IDENT "id"; id = IDENT; SYMBOL "="; uri = URI ->
                (Id id, choice_of_uri uri)
            | IDENT "symbol"; symbol = QSTRING;
              PAREN "("; IDENT "instance"; instance = NUM; PAREN ")";
              SYMBOL "="; dsc = QSTRING ->
                (Symbol (symbol, int_of_string instance),
                 DisambiguateChoices.lookup_symbol_by_dsc symbol dsc)
            | IDENT "num";
              PAREN "("; IDENT "instance"; instance = NUM; PAREN ")";
              SYMBOL "="; dsc = QSTRING ->
                (Num (int_of_string instance),
                 DisambiguateChoices.lookup_num_by_dsc dsc)
            ] -> choice ]
      ];
    END

    let of_string s =
      if s = empty then
        Environment.empty
      else
        exc_located_wrapper
          (fun () -> Grammar.Entry.parse aliases (Stream.of_string s))
  end

(* vim:set encoding=utf8: *)