(* Copyright (C) 2004, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://helm.cs.unibo.it/
 *)

let debug = true
let debug_print s =
  if debug then begin
    prerr_endline "<NEW_TEXTUAL_PARSER>";
    prerr_endline s;
    prerr_endline "</NEW_TEXTUAL_PARSER>"
  end

  (** if set to true each number will have a different insance number and can
  * thus be interpreted differently than others *)
let use_fresh_num_instances = false

open Printf
open DisambiguateTypes

exception Parse_error of string

let fresh_num_instance =
  let n = ref 0 in
  if use_fresh_num_instances then
    (fun () -> incr n; !n)
  else
    (fun () -> 0)

let choice_of_uri (uri: string) =
  let cic = HelmLibraryObjects.term_of_uri (UriManager.uri_of_string uri) in
  (uri, (fun _ _ _ -> cic))

let grammar = Grammar.gcreate CicTextualLexer2.cic_lexer

let term = Grammar.Entry.create grammar "term"
let term0 = Grammar.Entry.create grammar "term0"
let tactic = Grammar.Entry.create grammar "tactic"
let tactical = Grammar.Entry.create grammar "tactical"
let tactical0 = Grammar.Entry.create grammar "tactical0"
let command = Grammar.Entry.create grammar "command"

let return_term loc term = CicAst.AttributedTerm (`Loc loc, term)
let return_tactic loc tactic = TacticAst.LocatedTactic (loc, tactic)
let return_tactical loc tactical = TacticAst.LocatedTactical (loc, tactical)
let return_command loc cmd = cmd

let fail (x, y) msg =
  failwith (Printf.sprintf "Error at characters %d - %d: %s" x y msg)

let name_of_string = function
  | "_" -> Cic.Anonymous
  | s -> Cic.Name s

EXTEND
  GLOBAL: term term0 tactic tactical tactical0 command;
  int: [
    [ num = NUM ->
        try
          int_of_string num
        with Failure _ ->
          let (x, y) = loc in
          raise (Parse_error (sprintf
            "integer literal expected at characters %d-%d" x y))
    ]
  ];
  meta_subst: [
    [ s = SYMBOL "_" -> None
    | t = term -> Some t ]
  ];
  binder: [
    [ SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda
    | SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
    | SYMBOL <:unicode<exists>> (* ∃ *) -> `Exists
    | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall ]
  ];
  sort: [
    [ "Prop" -> `Prop
    | "Set" -> `Set
    | "Type" -> `Type
    | "CProp" -> `CProp ]
  ];
  typed_name: [
    [ PAREN "("; i = IDENT; SYMBOL ":"; typ = term; PAREN ")" ->
        (name_of_string i, Some typ)
    | i = IDENT -> (name_of_string i, None)
    ]
  ];
  substituted_name: [ (* a subs.name is an explicit substitution subject *)
    [ s = [ IDENT | SYMBOL ];
      subst = OPT [
        SYMBOL "\subst";  (* to avoid catching frequent "a [1]" cases *)
        PAREN "[";
        substs = LIST1 [
          i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = term -> (i, t)
        ] SEP SYMBOL ";";
        PAREN "]" ->
          substs
      ] ->
        CicAst.Ident (s, subst)
    ]
  ];
  name: [ (* as substituted_name with no explicit substitution *)
    [ s = [ IDENT | SYMBOL ] -> s ]
  ];
  pattern: [
    [ n = name -> (n, [])
    | PAREN "("; head = name; vars = LIST1 typed_name; PAREN ")" ->
        (head, vars)
    ]
  ];
  term0: [ [ t = term; EOI -> return_term loc t ] ];
  term:
    [ "letin" NONA
        (* actually "in" and "and" are _not_ keywords. Parsing works anyway
         * since applications are required to be bound by parens *)
      [ "let"; var = typed_name;
        SYMBOL "="; (* SYMBOL <:unicode<def>> (* ≝ *); *)
        t1 = term;
        IDENT "in"; t2 = term ->
          return_term loc (CicAst.LetIn (var, t1, t2))
      | "let"; ind_kind = [ "corec" -> `CoInductive | "rec"-> `Inductive ];
          defs = LIST1 [
            var = typed_name;
            index = OPT [ PAREN "("; index = NUM; PAREN ")" ->
              int_of_string index
            ];
            SYMBOL "="; (* SYMBOL <:unicode<def>> (* ≝ *); *)
            t1 = term ->
              (var, t1, (match index with None -> 0 | Some i -> i))
          ] SEP (IDENT "and");
          IDENT "in"; body = term ->
            return_term loc (CicAst.LetRec (ind_kind, defs, body))
      ]
    | "binder" RIGHTA
      [
        b = binder;
        (vars, typ) =
          [ vars = LIST1 IDENT SEP SYMBOL ",";
            typ = OPT [ SYMBOL ":"; t = term -> t ] -> (vars, typ)
          | PAREN "("; vars = LIST1 IDENT SEP SYMBOL ",";
            typ = OPT [ SYMBOL ":"; t = term -> t ]; PAREN ")" -> (vars, typ)
          ];
        SYMBOL "."; body = term ->
          let binder =
            List.fold_right
              (fun var body ->
                let name = name_of_string var in
                CicAst.Binder (b, (name, typ), body))
              vars body
          in
          return_term loc binder
      | t1 = term; SYMBOL <:unicode<to>> (* → *); t2 = term ->
            return_term loc
              (CicAst.Binder (`Pi, (Cic.Anonymous, Some t1), t2))
      ]
    | "logic_add" LEFTA   [ (* nothing here by default *) ]
    | "logic_mult" LEFTA  [ (* nothing here by default *) ]
    | "logic_inv" NONA    [ (* nothing here by default *) ]
    | "relop" LEFTA
      [ t1 = term; SYMBOL "="; t2 = term ->
        return_term loc (CicAst.Appl [CicAst.Symbol ("eq", 0); t1; t2])
      ]
    | "add" LEFTA     [ (* nothing here by default *) ]
    | "mult" LEFTA    [ (* nothing here by default *) ]
    | "power" LEFTA   [ (* nothing here by default *) ]
    | "inv" NONA      [ (* nothing here by default *) ]
    | "simple" NONA
      [ sort = sort -> CicAst.Sort sort
      | n = substituted_name -> return_term loc n
      | PAREN "("; head = term; args = LIST1 term; PAREN ")" ->
          return_term loc (CicAst.Appl (head :: args))
      | i = NUM -> return_term loc (CicAst.Num (i, (fresh_num_instance ())))
      | IMPLICIT -> return_term loc CicAst.Implicit
      | m = META;
        substs = [
          PAREN "["; substs = LIST0 meta_subst SEP SYMBOL ";" ; PAREN "]" ->
            substs
        ] ->
            let index =
              try
                int_of_string (String.sub m 1 (String.length m - 1))
              with Failure "int_of_string" ->
                fail loc ("Invalid meta variable number: " ^ m)
            in
            return_term loc (CicAst.Meta (index, substs))
      | outtyp = OPT [ PAREN "["; typ = term; PAREN "]" -> typ ];
        "match"; t = term;
        indty_ident = OPT [ SYMBOL ":"; id = IDENT -> id ];
        "with";
        PAREN "[";
        patterns = LIST0 [
          lhs = pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *); rhs = term ->
            ((lhs: CicAst.case_pattern), rhs)
        ] SEP SYMBOL "|";
        PAREN "]" ->
          return_term loc
            (CicAst.Case (t, indty_ident, outtyp, patterns))
      | PAREN "("; t1 = term; SYMBOL ":"; t2 = term; PAREN ")" ->
          return_term loc (CicAst.Appl [CicAst.Symbol ("cast", 0); t1; t2])
      | PAREN "("; t = term; PAREN ")" -> return_term loc t
      ]
    ];
  tactic_where: [
    [ where = OPT [ IDENT "in"; ident = IDENT -> ident ] -> where ]
  ];
  tactic_term: [ [ t = term -> t ] ];
  ident_list0: [
    [ PAREN "["; idents = LIST0 IDENT SEP SYMBOL ";"; PAREN "]" -> idents ]
  ];
  ident_list1: [
    [ PAREN "["; idents = LIST1 IDENT SEP SYMBOL ";"; PAREN "]" -> idents ]
  ];
  reduction_kind: [
    [ "reduce" -> `Reduce
    | "simpl" -> `Simpl
    | "whd" -> `Whd ]
  ];
  tactic: [
    [ [ IDENT "absurd" | IDENT "Absurd" ] -> return_tactic loc TacticAst.Absurd
    | [ IDENT "apply" | IDENT "Apply" ];
      t = tactic_term -> return_tactic loc (TacticAst.Apply t)
    | [ IDENT "assumption" | IDENT "Assumption" ] ->
        return_tactic loc TacticAst.Assumption
    | [ IDENT "change" | IDENT "Change" ];
      t1 = tactic_term; "with"; t2 = tactic_term;
      where = tactic_where ->
        return_tactic loc (TacticAst.Change (t1, t2, where))
    (* TODO Change_pattern *)
    | [ IDENT "contradiction" | IDENT "Contradiction" ] ->
        return_tactic loc TacticAst.Contradiction
    | [ IDENT "cut" | IDENT "Cut" ];
      t = tactic_term -> return_tactic loc (TacticAst.Cut t)
    | [ IDENT "decompose" | IDENT "Decompose" ];
      principles = ident_list1; where = IDENT ->
        return_tactic loc (TacticAst.Decompose (where, principles))
    | [ IDENT "discriminate" | IDENT "Discriminate" ];
      hyp = IDENT ->
        return_tactic loc (TacticAst.Discriminate hyp)
    | [ IDENT "elim" | IDENT "Elim" ]; IDENT "type";
      t = tactic_term ->
        return_tactic loc (TacticAst.ElimType t)
    | [ IDENT "elim" | IDENT "Elim" ];
      t1 = tactic_term;
      using = OPT [ "using"; using = tactic_term -> using ] ->
        return_tactic loc (TacticAst.Elim (t1, using))
    | [ IDENT "exact" | IDENT "Exact" ]; t = tactic_term ->
        return_tactic loc (TacticAst.Exact t)
    | [ IDENT "exists" | IDENT "Exists" ] ->
        return_tactic loc TacticAst.Exists
    | [ IDENT "fold" | IDENT "Fold" ];
      kind = reduction_kind; t = tactic_term ->
        return_tactic loc (TacticAst.Fold (kind, t))
    | [ IDENT "fourier" | IDENT "Fourier" ] ->
        return_tactic loc TacticAst.Fourier
    | [ IDENT "injection" | IDENT "Injection" ]; ident = IDENT ->
        return_tactic loc (TacticAst.Injection ident)
    | [ IDENT "intros" | IDENT "Intros" ];
      num = OPT [ num = int -> num ];
      idents = OPT ident_list0 ->
        let idents = match idents with None -> [] | Some idents -> idents in
        return_tactic loc (TacticAst.Intros (num, idents))
    | [ IDENT "left" | IDENT "Left" ] -> return_tactic loc TacticAst.Left
    | [ "let" | "Let" ];
      t = tactic_term; IDENT "in"; where = IDENT ->
        return_tactic loc (TacticAst.LetIn (t, where))
    (* TODO Reduce *)
    | [ IDENT "reflexivity" | IDENT "Reflexivity" ] ->
        return_tactic loc TacticAst.Reflexivity
    | [ IDENT "replace" | IDENT "Replace" ];
      t1 = tactic_term; "with"; t2 = tactic_term ->
        return_tactic loc (TacticAst.Replace (t1, t2))
    (* TODO Rewrite *)
    (* TODO Replace_pattern *)
    | [ IDENT "right" | IDENT "Right" ] -> return_tactic loc TacticAst.Right
    | [ IDENT "ring" | IDENT "Ring" ] -> return_tactic loc TacticAst.Ring
    | [ IDENT "split" | IDENT "Split" ] -> return_tactic loc TacticAst.Split
    | [ IDENT "symmetry" | IDENT "Symmetry" ] ->
        return_tactic loc TacticAst.Symmetry
    | [ IDENT "transitivity" | IDENT "Transitivity" ];
      t = tactic_term ->
        return_tactic loc (TacticAst.Transitivity t)
    ]
  ];
  tactical0: [ [ t = tactical; SYMBOL "." -> t ] ];
  tactical:
    [ "command" NONA
      [ cmd = command -> return_tactical loc (TacticAst.Command cmd) ]
    | "sequence" LEFTA
      [ tactics = LIST1 NEXT SEP SYMBOL ";" ->
          return_tactical loc (TacticAst.Seq tactics)
      ]
    | "then" NONA
      [ tac = tactical;
        PAREN "["; tacs = LIST0 tactical SEP SYMBOL ";"; PAREN "]" ->
          return_tactical loc (TacticAst.Then (tac, tacs))
      ]
    | "loops" RIGHTA
      [ [ IDENT "do" | IDENT "Do" ]; count = int; tac = tactical ->
          return_tactical loc (TacticAst.Do (count, tac))
      | [ IDENT "repeat" | IDENT "Repeat" ]; tac = tactical ->
          return_tactical loc (TacticAst.Repeat tac)
      ]
    | "simple" NONA
      [ [ IDENT "tries" | IDENT "Tries" ];
        PAREN "["; tacs = LIST0 tactical SEP SYMBOL ";"; PAREN "]" ->
          return_tactical loc (TacticAst.Tries tacs)
      | [ IDENT "try" | IDENT "Try" ]; tac = NEXT ->
          return_tactical loc (TacticAst.Try tac)
      | [ IDENT "fail" | IDENT "Fail" ] -> return_tactical loc TacticAst.Fail
      | [ IDENT "id" | IDENT "Id" ] -> return_tactical loc TacticAst.IdTac
      | PAREN "("; tac = tactical; PAREN ")" -> return_tactical loc tac
      | tac = tactic -> return_tactical loc (TacticAst.Tactic tac)
      ]
    ];
  theorem_flavour: [  (* all flavours but Goal *)
    [ [ IDENT "definition"  | IDENT "Definition"  ] -> `Definition
    | [ IDENT "fact"        | IDENT "Fact"        ] -> `Fact
    | [ IDENT "lemma"       | IDENT "Lemma"       ] -> `Lemma
    | [ IDENT "remark"      | IDENT "Remark"      ] -> `Remark
    | [ IDENT "theorem"     | IDENT "Theorem"     ] -> `Theorem
    ]
  ];
  command: [
    [ [ IDENT "abort" | IDENT "Abort" ] -> return_command loc TacticAst.Abort
    | [ IDENT "proof" | IDENT "Proof" ] -> return_command loc TacticAst.Proof
    | [ IDENT "quit"  | IDENT "Quit"  ] -> return_command loc TacticAst.Quit
    | [ IDENT "qed"   | IDENT "Qed"   ] ->
        return_command loc (TacticAst.Qed None)
    | [ IDENT "save"  | IDENT "Save"  ]; name = IDENT ->
        return_command loc (TacticAst.Qed (Some name))
    | flavour = theorem_flavour; name = OPT IDENT; SYMBOL ":"; typ = term;
      body = OPT [ SYMBOL <:unicode<def>> (* ≝ *); body = term -> body ] ->
        return_command loc (TacticAst.Theorem (flavour, name, typ, body))
    | [ IDENT "goal" | IDENT "Goal" ]; typ = term;
      body = OPT [ SYMBOL <:unicode<def>> (* ≝ *); body = term -> body ] ->
        return_command loc (TacticAst.Theorem (`Goal, None, typ, body))
    ]
  ];
END

let exc_located_wrapper f =
  try
    Lazy.force f
  with Stdpp.Exc_located ((x, y), exn) ->
    raise (Parse_error (sprintf "parse error at characters %d-%d: %s" x y
        (Printexc.to_string exn)))

let parse_term stream =
  exc_located_wrapper (lazy (Grammar.Entry.parse term0 stream))
let parse_tactic stream =
  exc_located_wrapper (lazy (Grammar.Entry.parse tactic stream))
let parse_tactical stream =
  exc_located_wrapper (lazy (Grammar.Entry.parse tactical0 stream))

(**/**)

(** {2 Interface for gTopLevel} *)

module EnvironmentP3 =
  struct
    type t = environment

    let empty = ""

    let aliases_grammar = Grammar.gcreate CicTextualLexer2.cic_lexer
    let aliases = Grammar.Entry.create aliases_grammar "aliases"

    let to_string env =
      let aliases =
        Environment.fold
          (fun domain_item (dsc, _) acc ->
            let s =
              match domain_item with
              | Id id -> sprintf "alias id %s = %s" id dsc
              | Symbol (symb, instance) ->
                  sprintf "alias symbol \"%s\" (instance %d) = \"%s\""
                    symb instance dsc
              | Num instance ->
                  sprintf "alias num (instance %d) = \"%s\"" instance dsc
            in
            s :: acc)
          env []
      in
      String.concat "\n" (List.sort compare aliases)

    EXTEND
      GLOBAL: aliases;
      aliases: [  (* build an environment from an aliases list *)
        [ aliases = LIST0 alias; EOI ->
            List.fold_left
              (fun env (domain_item, codomain_item) ->
                Environment.add domain_item codomain_item env)
              Environment.empty aliases
        ]
      ];
      alias: [  (* return a pair <domain_item, codomain_item> from an alias *)
        [ IDENT "alias";
          choice =
            [ IDENT "id"; id = IDENT; SYMBOL "="; uri = URI ->
                (Id id, choice_of_uri uri)
            | IDENT "symbol"; symbol = QSTRING;
              PAREN "("; IDENT "instance"; instance = NUM; PAREN ")";
              SYMBOL "="; dsc = QSTRING ->
                (Symbol (symbol, int_of_string instance),
                 DisambiguateChoices.lookup_symbol_by_dsc symbol dsc)
            | IDENT "num";
              PAREN "("; IDENT "instance"; instance = NUM; PAREN ")";
              SYMBOL "="; dsc = QSTRING ->
                (Num (int_of_string instance),
                 DisambiguateChoices.lookup_num_by_dsc dsc)
            ] -> choice ]
      ];
    END

    let of_string s =
      if s = empty then
        Environment.empty
      else
        try
          Grammar.Entry.parse aliases (Stream.of_string s)
        with Stdpp.Exc_located ((x, y), exn) ->
          raise (Parse_error (sprintf "parse error at characters %d-%d: %s" x y
          (Printexc.to_string exn)))
  end

(* vim:set encoding=utf8: *)