(* Copyright (C) 2000, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://cs.unibo.it/helm/.
 *)

exception CicReductionInternalError;;
exception WrongUriToInductiveDefinition;;

let fdebug = ref 1;;
let debug t env s =
 let rec debug_aux t i =
  let module C = Cic in
  let module U = UriManager in
   CicPp.ppobj (C.Variable ("DEBUG", None, t)) ^ "\n" ^ i
 in
  if !fdebug = 0 then
   begin
    print_endline (s ^ "\n" ^ List.fold_right debug_aux (t::env) "") ;
    flush stdout
   end
;;

exception Impossible of int;;
exception ReferenceToDefinition;;
exception ReferenceToAxiom;;
exception ReferenceToVariable;;
exception ReferenceToCurrentProof;;
exception ReferenceToInductiveDefinition;;

(* takes a well-typed term *)
let whd context =
 let rec whdaux l =
  let module C = Cic in
  let module S = CicSubstitution in
   function
      C.Rel n as t ->
       (match List.nth context (n-1) with
           C.Decl _ -> if l = [] then t else C.Appl (t::l)
         | C.Def bo -> whdaux l (S.lift n bo)
       )
    | C.Var uri as t ->
       (match CicEnvironment.get_cooked_obj uri 0 with
           C.Definition _ -> raise ReferenceToDefinition
         | C.Axiom _ -> raise ReferenceToAxiom
         | C.CurrentProof _ -> raise ReferenceToCurrentProof
         | C.InductiveDefinition _ -> raise ReferenceToInductiveDefinition
         | C.Variable (_,None,_) -> if l = [] then t else C.Appl (t::l)
         | C.Variable (_,Some body,_) -> whdaux l body
       )
    | C.Meta _ as t -> if l = [] then t else C.Appl (t::l)
    | C.Sort _ as t -> t (* l should be empty *)
    | C.Implicit as t -> t
    | C.Cast (te,ty) -> whdaux l te  (*CSC E' GIUSTO BUTTARE IL CAST? *)
    | C.Prod _ as t -> t (* l should be empty *)
    | C.Lambda (name,s,t) as t' ->
       (match l with
           [] -> t'
         | he::tl -> whdaux tl (S.subst he t)
           (* when name is Anonimous the substitution should be superfluous *)
       )
    | C.LetIn (n,s,t) -> whdaux l (S.subst (whdaux [] s) t)
    | C.Appl (he::tl) -> whdaux (tl@l) he
    | C.Appl [] -> raise (Impossible 1)
    | C.Const (uri,cookingsno) as t ->
       (match CicEnvironment.get_cooked_obj uri cookingsno with
           C.Definition (_,body,_,_) -> whdaux l body
         | C.Axiom _ -> if l = [] then t else C.Appl (t::l)
         | C.Variable _ -> raise ReferenceToVariable
         | C.CurrentProof (_,_,body,_) -> whdaux l body
         | C.InductiveDefinition _ -> raise ReferenceToInductiveDefinition
       )
    | C.Abst _ as t -> t (*CSC l should be empty ????? *)
    | C.MutInd (uri,_,_) as t -> if l = [] then t else C.Appl (t::l)
    | C.MutConstruct (uri,_,_,_) as t -> if l = [] then t else C.Appl (t::l)
    | C.MutCase (mutind,cookingsno,i,_,term,pl) as t->
       let decofix =
        function
           C.CoFix (i,fl) as t ->
            let (_,_,body) = List.nth fl i in
             let body' =
              let counter = ref (List.length fl) in
               List.fold_right
                (fun _ -> decr counter ; S.subst (C.CoFix (!counter,fl)))
                fl
                body
             in
              whdaux [] body'
         | C.Appl (C.CoFix (i,fl) :: tl) ->
            let (_,_,body) = List.nth fl i in
             let body' =
              let counter = ref (List.length fl) in
               List.fold_right
                (fun _ -> decr counter ; S.subst (C.CoFix (!counter,fl)))
                fl
                body
             in
              whdaux tl body'
         | t -> t
       in
        (match decofix (whdaux [] term) with
            C.MutConstruct (_,_,_,j) -> whdaux l (List.nth pl (j-1))
          | C.Appl (C.MutConstruct (_,_,_,j) :: tl) ->
             let (arity, r, num_ingredients) =
              match CicEnvironment.get_obj mutind with
                 C.InductiveDefinition (tl,ingredients,r) ->
                   let (_,_,arity,_) = List.nth tl i
                   and num_ingredients =
                    List.fold_right
                     (fun (k,l) i ->
                       if k < cookingsno then i + List.length l else i
                     ) ingredients 0
                   in
                    (arity,r,num_ingredients)
               | _ -> raise WrongUriToInductiveDefinition
             in
              let ts =
               let num_to_eat = r + num_ingredients in
                let rec eat_first =
                 function
                    (0,l) -> l
                  | (n,he::tl) when n > 0 -> eat_first (n - 1, tl)
                  | _ -> raise (Impossible 5)
                in
                 eat_first (num_to_eat,tl)
              in
               whdaux (ts@l) (List.nth pl (j-1))
         | C.Abst _| C.Cast _ | C.Implicit ->
            raise (Impossible 2) (* we don't trust our whd ;-) *)
         | _ -> if l = [] then t else C.Appl (t::l)
       )
    | C.Fix (i,fl) as t ->
       let (_,recindex,_,body) = List.nth fl i in
        let recparam =
         try
          Some (List.nth l recindex)
         with
          _ -> None
        in
         (match recparam with
             Some recparam ->
              (match whdaux [] recparam with
                  C.MutConstruct _
                | C.Appl ((C.MutConstruct _)::_) ->
                   let body' =
                    let counter = ref (List.length fl) in
                     List.fold_right
                      (fun _ -> decr counter ; S.subst (C.Fix (!counter,fl)))
                      fl
                      body
                   in
                    (* Possible optimization: substituting whd recparam in l *)
                    whdaux l body'
               | _ -> if l = [] then t else C.Appl (t::l)
             )
          | None -> if l = [] then t else C.Appl (t::l)
         )
    | C.CoFix (i,fl) as t ->
       if l = [] then t else C.Appl (t::l)
 in
(*CSC
function t ->
prerr_endline ("PRIMA WHD" ^ CicPp.ppterm t) ; flush stderr ;
List.iter (function (Cic.Decl t) -> prerr_endline ("Context: " ^ CicPp.ppterm t) | (Cic.Def t) -> prerr_endline ("Context:= " ^ CicPp.ppterm t)) context ; flush stderr ; prerr_endline "<PRIMA WHD" ; flush stderr ;
let res =
*)
  whdaux []
(*CSC
t in prerr_endline "DOPO WHD" ; flush stderr ; res
*)
;;

(* t1, t2 must be well-typed *)
let are_convertible =
 let module U = UriManager in
 let rec aux context t1 t2 =
  let aux2 t1 t2 =
   (* this trivial euristic cuts down the total time of about five times ;-) *)
   (* this because most of the time t1 and t2 are "sintactically" the same   *)
   if t1 = t2 then
    true
   else
    begin
     let module C = Cic in
       match (t1,t2) with
          (C.Rel n1, C.Rel n2) -> n1 = n2
        | (C.Var uri1, C.Var uri2) -> U.eq uri1 uri2
        | (C.Meta n1, C.Meta n2) -> n1 = n2
        | (C.Sort s1, C.Sort s2) -> true (*CSC da finire con gli universi *)
        | (C.Prod (_,s1,t1), C.Prod(_,s2,t2)) ->
           aux context s1 s2 && aux ((C.Decl s1)::context) t1 t2
        | (C.Lambda (_,s1,t1), C.Lambda(_,s2,t2)) ->
           aux context s1 s2 && aux ((C.Decl s1)::context) t1 t2
        | (C.LetIn (_,s1,t1), C.LetIn(_,s2,t2)) ->
           aux context s1 s2 && aux ((C.Def s1)::context) t1 t2
        | (C.Appl l1, C.Appl l2) ->
           (try
             List.fold_right2 (fun  x y b -> aux context x y && b) l1 l2 true 
            with
             Invalid_argument _ -> false
           )
        | (C.Const (uri1,_), C.Const (uri2,_)) ->
            (*CSC: questo commento e' chiaro o delirante? Io lo sto scrivendo *)
            (*CSC: mentre sono delirante, quindi ...                          *)
            (* WARNING: it is really important that the two cookingsno are not*)
            (* checked for equality. This allows not to cook an object with no*)
            (* ingredients only to update the cookingsno. E.g: if a term t has*)
            (* a reference to a term t1 which does not depend on any variable *)
            (* and t1 depends on a term t2 (that can't depend on any variable *)
            (* because of t1), then t1 cooked at every level could be the same*)
            (* as t1 cooked at level 0. Doing so, t2 will be extended in t    *)
            (* with cookingsno 0 and not 2. But this will not cause any       *)
            (* trouble if here we don't check that the two cookingsno are     *)
            (* equal.                                                         *)
            U.eq uri1 uri2
        | (C.MutInd (uri1,k1,i1), C.MutInd (uri2,k2,i2)) ->
            (* WARNIG: see the previous warning *)
            U.eq uri1 uri2 && i1 = i2
        | (C.MutConstruct (uri1,_,i1,j1), C.MutConstruct (uri2,_,i2,j2)) ->
            (* WARNIG: see the previous warning *)
            U.eq uri1 uri2 && i1 = i2 && j1 = j2
        | (C.MutCase (uri1,_,i1,outtype1,term1,pl1),
           C.MutCase (uri2,_,i2,outtype2,term2,pl2)) -> 
            (* WARNIG: see the previous warning *)
            (* aux context outtype1 outtype2 should be true if *)
            (* aux context pl1 pl2 *)
            U.eq uri1 uri2 && i1 = i2 && aux context outtype1 outtype2 &&
             aux context term1 term2 &&
             List.fold_right2 (fun x y b -> b && aux context x y) pl1 pl2 true
        | (C.Fix (i1,fl1), C.Fix (i2,fl2)) ->
(*CSC: C.Decl e' giusto? *)
           let tys = List.map (function (_,_,ty,_) -> C.Decl ty) fl1 in
            i1 = i2 &&
             List.fold_right2
              (fun (_,recindex1,ty1,bo1) (_,recindex2,ty2,bo2) b ->
                b && recindex1 = recindex2 && aux context ty1 ty2 &&
                 aux (tys@context) bo1 bo2)
              fl1 fl2 true
        | (C.CoFix (i1,fl1), C.CoFix (i2,fl2)) ->
(*CSC: C.Decl e' giusto? *)
           let tys = List.map (function (_,ty,_) -> C.Decl ty) fl1 in
            i1 = i2 &&
             List.fold_right2
              (fun (_,ty1,bo1) (_,ty2,bo2) b ->
                b && aux context ty1 ty2 && aux (tys@context) bo1 bo2)
              fl1 fl2 true
        | (C.Abst _, _) | (_, C.Abst _) | (C.Cast _, _) | (_, C.Cast _)
        | (C.Implicit, _) | (_, C.Implicit) ->
           raise (Impossible 3) (* we don't trust our whd ;-) *)
        | (_,_) -> false
    end
  in
   if aux2 t1 t2 then true
   else
    begin
     debug t1 [t2] "PREWHD";
     let t1' = whd context t1 
     and t2' = whd context t2 in
      debug t1' [t2'] "POSTWHD";
      aux2 t1' t2'
    end
 in
  aux
;;