(* Copyright (C) 2004, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://helm.cs.unibo.it/
 *)

open Printf

type location = Lexing.position * Lexing.position

let pp_location (loc_begin, loc_end) =
  sprintf "(%d,%d)-(%d,%d)"
    loc_begin.Lexing.pos_lnum
    (loc_begin.Lexing.pos_cnum - loc_begin.Lexing.pos_bol)
    loc_end.Lexing.pos_lnum
    (loc_end.Lexing.pos_cnum - loc_end.Lexing.pos_bol)

let floc_of_loc (loc_begin, loc_end) =
  let floc_begin =
    { Lexing.pos_fname = ""; Lexing.pos_lnum = -1; Lexing.pos_bol = -1;
      Lexing.pos_cnum = loc_begin }
  in
  let floc_end = { floc_begin with Lexing.pos_cnum = loc_end } in
  (floc_begin, floc_end)

let loc_of_floc = function
  | { Lexing.pos_cnum = loc_begin }, { Lexing.pos_cnum = loc_end } ->
      (loc_begin, loc_end)

let dummy_floc = floc_of_loc (-1, -1)

type binder_kind = [ `Lambda | `Pi | `Exists | `Forall ]
type induction_kind = [ `Inductive | `CoInductive ]
type sort_kind = [ `Prop | `Set | `Type | `CProp ]

type term_attribute =
  [ `Loc of location
  | `IdRef of string
  ]

type term =
  | AttributedTerm of term_attribute * term

  | Appl of term list
  | Binder of binder_kind * capture_variable * term
  | Case of term * string option * term option * (case_pattern * term) list
  | LetIn of capture_variable * term * term
  | LetRec of induction_kind * (capture_variable * term * int) list * term
  | Ident of string * subst list option
  | Implicit
  | Meta of int * meta_subst list
  | Num of string * int
  | Sort of sort_kind
  | Symbol of string * int

  | UserInput
  | Uri of string * subst list option

and capture_variable = Cic.name * term option
and meta_subst = term option
and subst = string * term
and case_pattern = string * capture_variable list

let pack asts =
  List.fold_right
    (fun ast acc -> Binder (`Forall, (Cic.Anonymous, Some ast), acc))
    asts (Sort `Type)

let rec unpack = function
  | Binder (`Forall, (Cic.Anonymous, Some ast), Sort `Type) -> [ast]
  | Binder (`Forall, (Cic.Anonymous, Some ast), tgt) -> ast :: unpack tgt
  | _ -> assert false