(* Copyright (C) 2003-2005, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://cs.unibo.it/helm/.
 *)

module C    = Cic
module I    = CicInspect
module D    = Deannotate
module DTI  = DoubleTypeInference
module TC   = CicTypeChecker 
module Un   = CicUniv
module UM   = UriManager
module Obj  = LibraryObjects
module HObj = HelmLibraryObjects
module A    = Cic2acic
module Ut   = CicUtil
module E    = CicEnvironment
module PER  = ProofEngineReduction

module Cl   = ProceduralClassify
module M    = ProceduralMode
module T    = ProceduralTypes
module Cn   = ProceduralConversion

type status = {
   sorts : (C.id, A.sort_kind) Hashtbl.t;
   types : (C.id, A.anntypes) Hashtbl.t;
   prefix: string;
   max_depth: int option;
   depth: int;
   context: C.context;
   intros: string list
}

(* helpers ******************************************************************)

let identity x = x

let comp f g x = f (g x)

let cic = D.deannotate_term

let split2_last l1 l2 =
try
   let n = pred (List.length l1) in
   let before1, after1 = T.list_split n l1 in
   let before2, after2 = T.list_split n l2 in
   before1, before2, List.hd after1, List.hd after2
with Invalid_argument _ -> failwith "A2P.split2_last"

let string_of_head = function
   | C.ASort _         -> "sort"
   | C.AConst _        -> "const"
   | C.AMutInd _       -> "mutind"
   | C.AMutConstruct _ -> "mutconstruct"
   | C.AVar _          -> "var"
   | C.ARel _          -> "rel"
   | C.AProd _         -> "prod"
   | C.ALambda _       -> "lambda"
   | C.ALetIn _        -> "letin"
   | C.AFix _          -> "fix"
   | C.ACoFix _        -> "cofix"
   | C.AAppl _         -> "appl"
   | C.ACast _         -> "cast"
   | C.AMutCase _      -> "mutcase"
   | C.AMeta _         -> "meta"
   | C.AImplicit _     -> "implict"

let clear st = {st with intros = []}

let next st = {(clear st) with depth = succ st.depth}

let add st entry intro =
   {st with context = entry :: st.context; intros = intro :: st.intros}

let test_depth st =
try   
   let msg = Printf.sprintf "Depth %u: " st.depth in
   match st.max_depth with
      | None   -> true, "" 
      | Some d -> if st.depth < d then true, msg else false, "DEPTH EXCEDED: "
with Invalid_argument _ -> failwith "A2P.test_depth"

let is_rewrite_right = function
   | C.AConst (_, uri, []) ->
      UM.eq uri HObj.Logic.eq_ind_r_URI || Obj.is_eq_ind_r_URI uri
   | _                     -> false

let is_rewrite_left = function
   | C.AConst (_, uri, []) ->
      UM.eq uri HObj.Logic.eq_ind_URI || Obj.is_eq_ind_URI uri
   | _                     -> false

let is_fwd_rewrite_right hd tl =
   if is_rewrite_right hd then match List.nth tl 3 with
      | C.ARel _ -> true
      | _        -> false
   else false

let is_fwd_rewrite_left hd tl =
   if is_rewrite_left hd then match List.nth tl 3 with
      | C.ARel _ -> true
      | _        -> false
   else false
(*
let get_ind_name uri tno xcno =
try   
   let ts = match E.get_obj Un.empty_ugraph uri with
      | C.InductiveDefinition (ts, _, _,_), _ -> ts 
      | _                                     -> assert false
   in
   let tname, cs = match List.nth ts tno with
      | (name, _, _, cs) -> name, cs
   in
   match xcno with
      | None     -> tname
      | Some cno -> fst (List.nth cs (pred cno))
with Invalid_argument _ -> failwith "A2P.get_ind_name"
*)
let get_inner_types st v =
try
   let id = Ut.id_of_annterm v in
   try match Hashtbl.find st.types id with
      | {A.annsynthesized = st; A.annexpected = Some et} -> Some (st, et)
      | {A.annsynthesized = st; A.annexpected = None}    -> Some (st, st)
   with Not_found -> None
with Invalid_argument _ -> failwith "A2P.get_inner_types"

let get_inner_sort st v =
try
   let id = Ut.id_of_annterm v in
   try Hashtbl.find st.sorts id
   with Not_found -> `Type (CicUniv.fresh())
with Invalid_argument _ -> failwith "A2P.get_sort"

(* proof construction *******************************************************)

let unused_premise = "UNUSED"

let defined_premise = "DEFINED"

let expanded_premise = "EXPANDED"

let convert st ?name v = 
   match get_inner_types st v with
      | None          -> []
      | Some (st, et) ->
         let cst, cet = cic st, cic et in
	 if PER.alpha_equivalence cst cet then [] else 
	 let e = Cn.mk_pattern [] (T.mk_arel 1 "") in
	 match name with
	    | None    -> [T.Change (st, et, None, e, "")]
	    | Some id -> [T.Change (st, et, Some (id, id), e, ""); T.ClearBody (id, "")]

let eta_expand n t =
   let id = Ut.id_of_annterm t in
   let ty = C.AImplicit ("", None) in
   let name i = Printf.sprintf "%s%u" expanded_premise i in 
   let lambda i t = C.ALambda (id, C.Name (name i), ty, t) in
   let arg i n = T.mk_arel (n - i) (name (n - i - 1)) in
   let rec aux i f a =
      if i >= n then f, a else aux (succ i) (comp f (lambda i)) (arg i n :: a)
   in
   let absts, args = aux 0 identity [] in
   match Cn.lift 1 n t with
      | C.AAppl (id, ts) -> absts (C.AAppl (id, ts @ args))
      | t                -> absts (C.AAppl ("", t :: args))  

let appl_expand n = function
   | C.AAppl (id, ts) -> 
      let before, after = T.list_split (List.length ts + n) ts in
      C.AAppl (id, C.AAppl ("", before) :: after)
   | _                -> assert false

let get_intro name t = 
try
match name with 
   | C.Anonymous -> unused_premise
   | C.Name s    -> 
      if DTI.does_not_occur 1 (cic t) then unused_premise else s
with Invalid_argument _ -> failwith "A2P.get_intro"

let mk_intros st script =
try
   if st.intros = [] then script else
   let count = List.length st.intros in
   T.Intros (Some count, List.rev st.intros, "") :: script
with Invalid_argument _ -> failwith "A2P.mk_intros"

let rec mk_atomic st dtext what =
   if T.is_atomic what then 
      match what with 
      | C.ARel (_, _, _, name) -> convert st ~name what, what
      | _                      -> [], what
   else
      let name = defined_premise in
      let script = convert st ~name what in  
      script @ mk_fwd_proof st dtext name what, T.mk_arel 0 name

and mk_fwd_rewrite st dtext name tl direction =
   let what, where = List.nth tl 5, List.nth tl 3 in
   let rps, predicate = [List.nth tl 4], List.nth tl 2 in
   let e = Cn.mk_pattern rps predicate in
   match where with
      | C.ARel (_, _, _, premise) ->
         let script, what = mk_atomic st dtext what in
         T.Rewrite (direction, what, Some (premise, name), e, dtext) :: script
      | _                         -> assert false

and mk_fwd_proof st dtext name = function
   | C.ALetIn (_, n, v, t)                           ->
      let entry = Some (n, C.Def (cic v, None)) in
      let intro = get_intro n t in
      let qt = mk_fwd_proof (add st entry intro) dtext name t in
      let qv = mk_fwd_proof st "" intro v in
      List.append qt qv
   | C.AAppl (_, hd :: tl) as v                         -> 
      if is_fwd_rewrite_right hd tl then mk_fwd_rewrite st dtext name tl true else
      if is_fwd_rewrite_left hd tl then mk_fwd_rewrite st dtext name tl false else
      let ty, _ = TC.type_of_aux' [] st.context (cic hd) Un.empty_ugraph in
      begin match get_inner_types st v with
         | Some (ity, _) when M.bkd st.context ty ->
	    let qs = [[T.Id ""]; mk_proof (next st) v] in
	    [T.Branch (qs, ""); T.Cut (name, ity, dtext)]
         | _                                      ->
            let (classes, rc) as h = Cl.classify st.context ty in
            let text = Printf.sprintf "%u %s" (List.length classes) (Cl.to_string h) in
	    [T.LetIn (name, v, dtext ^ text)]
      end
   | C.AMutCase (id, uri, tyno, outty, arg, cases) as v ->
      begin match Cn.mk_ind st.context id uri tyno outty arg cases with 
         | None   -> [T.LetIn (name, v, dtext)] 
         | Some v -> mk_fwd_proof st dtext name v
      end
   | C.ACast (_, v, _)                                  ->
      mk_fwd_proof st dtext name v
   | v                                                  ->
      match get_inner_types st v with
         | Some (ity, _) ->
	    let qs = [[T.Id ""]; mk_proof (next st) v] in
	    [T.Branch (qs, ""); T.Cut (name, ity, dtext)]
         | _             ->
            [T.LetIn (name, v, dtext)]

and mk_proof st = function
   | C.ALambda (_, name, v, t)                     ->
      let entry = Some (name, C.Decl (cic v)) in
      let intro = get_intro name t in
      mk_proof (add st entry intro) t
   | C.ALetIn (_, name, v, t) as what              ->
      let proceed, dtext = test_depth st in
      let script = if proceed then 
         let entry = Some (name, C.Def (cic v, None)) in
         let intro = get_intro name t in
         let q = mk_proof (next (add st entry intro)) t in
         List.rev_append (mk_fwd_proof st dtext intro v) q
      else
	 [T.Apply (what, dtext)]
      in
      mk_intros st script
   | C.ARel _ as what                              ->
      let _, dtext = test_depth st in
      let text = "assumption" in
      let script = [T.Apply (what, dtext ^ text)] in 
      mk_intros st script
   | C.AMutConstruct _ as what                     ->
      let _, dtext = test_depth st in
      let script = [T.Apply (what, dtext)] in 
      mk_intros st script   
   | C.AAppl (_, hd :: tl) as t                    ->
      let proceed, dtext = test_depth st in
      let script = if proceed then
         let ty, _ = TC.type_of_aux' [] st.context (cic hd) Un.empty_ugraph in
         let (classes, rc) as h = Cl.classify st.context ty in
         let premises, _ = Cl.split st.context ty in
	 let decurry = List.length classes - List.length tl in
         if decurry < 0 then mk_proof (clear st) (appl_expand decurry t) else
         if decurry > 0 then mk_proof (clear st) (eta_expand decurry t) else
	 let synth = I.S.singleton 0 in
         let text = Printf.sprintf "%u %s" (List.length classes) (Cl.to_string h) in
         match rc with
            | Some (i, j) when i > 1 && i <= List.length classes && M.is_eliminator premises ->
	       let classes, tl, _, what = split2_last classes tl in
	       let script, what = mk_atomic st dtext what in
	       let synth = I.S.add 1 synth in
	       let qs = mk_bkd_proofs (next st) synth classes tl in
               if is_rewrite_right hd then 
                  let rps, predicate = [List.nth tl 4], List.nth tl 2 in
                  let e = Cn.mk_pattern rps predicate in
		  List.rev script @ convert st t @
		  [T.Rewrite (false, what, None, e, dtext); T.Branch (qs, "")]
	       else if is_rewrite_left hd then 
	          let rps, predicate = [List.nth tl 4], List.nth tl 2 in
                  let e = Cn.mk_pattern rps predicate in
		  List.rev script @ convert st t @
		  [T.Rewrite (true, what, None, e, dtext); T.Branch (qs, "")]
	       else   
	          let using = Some hd in
		  List.rev script @ convert st t @
	          [T.Elim (what, using, dtext ^ text); T.Branch (qs, "")]
	    | _                                                  ->
	       let qs = mk_bkd_proofs (next st) synth classes tl in
	       let script, hd = mk_atomic st dtext hd in               
	       List.rev script @ convert st t @	       
	       [T.Apply (hd, dtext ^ text); T.Branch (qs, "")]
      else
         [T.Apply (t, dtext)]
      in
      mk_intros st script
   | C.AMutCase (id, uri, tyno, outty, arg, cases) ->
      begin match Cn.mk_ind st.context id uri tyno outty arg cases with 
         | _ (* None *)  -> 
            let text = Printf.sprintf "%s" "UNEXPANDED: mutcase" in
            let script = [T.Note text] in
            mk_intros st script
(*         | Some t -> mk_proof st t *)
      end
   | C.ACast (_, t, _)                             ->
      mk_proof st t
   | t                                             ->
      let text = Printf.sprintf "%s: %s" "UNEXPANDED" (string_of_head t) in
      let script = [T.Note text] in
      mk_intros st script

and mk_bkd_proofs st synth classes ts =
try 
   let _, dtext = test_depth st in   
   let aux inv v =
      if I.overlaps synth inv then None else
      if I.S.is_empty inv then Some (mk_proof st v) else
      Some [T.Apply (v, dtext ^ "dependent")]
   in
   T.list_map2_filter aux classes ts
with Invalid_argument _ -> failwith "A2P.mk_bkd_proofs"

(* object costruction *******************************************************)

let is_theorem pars =   
   List.mem (`Flavour `Theorem) pars || List.mem (`Flavour `Fact) pars || 
   List.mem (`Flavour `Remark) pars || List.mem (`Flavour `Lemma) pars

let mk_obj st = function
   | C.AConstant (_, _, s, Some v, t, [], pars) when is_theorem pars ->
      let ast = mk_proof st v in
      let count = T.count_steps 0 ast in
      let text = Printf.sprintf "tactics: %u" count in
      T.Theorem (s, t, text) :: ast @ [T.Qed ""]
   | _                                                               ->
      failwith "not a theorem"

(* interface functions ******************************************************)

let acic2procedural ~ids_to_inner_sorts ~ids_to_inner_types ?depth prefix aobj = 
   let st = {
      sorts     = ids_to_inner_sorts;
      types     = ids_to_inner_types;
      prefix    = prefix;
      max_depth = depth;
      depth     = 0;
      context   = [];
      intros    = []
   } in
   HLog.debug "Level 2 transformation";
   let steps = mk_obj st aobj in
   HLog.debug "grafite rendering";
   List.rev (T.render_steps [] steps)