(* Copyright (C) 2003-2005, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://cs.unibo.it/helm/.
 *)

module C = Cic
module R = CicReduction
module D = Deannotate
module Int = struct
   type t = int
   let compare = compare 
end
module S = Set.Make (Int) 

type conclusion = (int * int) option

(* debugging ****************************************************************)

let string_of_entry inverse =
   if S.mem 0 inverse then "C" else
   if S.is_empty inverse then "I" else "P"

let to_string (classes, rc) =
   let linearize = String.concat " " (List.map string_of_entry classes) in
   match rc with
      | None        -> linearize
      | Some (i, j) -> Printf.sprintf "%s %u %u" linearize i j

let out_table b =
   let map i (_, inverse) =
      let map i tl = Printf.sprintf "%2u" i :: tl in 
      let iset = String.concat " " (S.fold map inverse []) in
      Printf.eprintf "%2u|%s\n" i iset
   in
   Array.iteri map b;
   prerr_newline ()
   
(****************************************************************************)

let id x = x

let rec list_fold_left g map = function
  | []       -> g
  | hd :: tl -> map (list_fold_left g map tl) hd

let get_rels h t = 
   let rec aux d g = function
      | C.Sort _
      | C.Implicit _       -> g
      | C.Rel i            -> 
         if i < d then g else fun a -> g (S.add (i - d + h + 1) a)
      | C.Appl ss          -> list_fold_left g (aux d) ss
      | C.Const (_, ss)
      | C.MutInd (_, _, ss)
      | C.MutConstruct (_, _, _, ss)
      | C.Var (_, ss)      -> 
         let map g (_, t) = aux d g t in 
	 list_fold_left g map ss
      | C.Meta (_, ss)     ->
         let map g = function 
	    | None   -> g
	    | Some t -> aux d g t
	 in
	 list_fold_left g map ss
      | C.Cast (t1, t2)    -> aux d (aux d g t2) t1
      | C.LetIn (_, t1, t2)
      | C.Lambda (_, t1, t2)
      | C.Prod (_, t1, t2) -> aux d (aux (succ d) g t2) t1
      | C.MutCase (_, _, t1, t2, ss) ->
	 aux d (aux d (list_fold_left g (aux d) ss) t2) t1
      | C.Fix (_, ss) ->
         let k = List.length ss in
	 let map g (_, _, t1, t2) = aux d (aux (d + k) g t2) t1 in
	 list_fold_left g map ss
      | C.CoFix (_, ss) ->
         let k = List.length ss in
	 let map g (_, t1, t2) = aux d (aux (d + k) g t2) t1 in
	 list_fold_left g map ss
   in
   let g a = a in
   aux 1 g t S.empty

let split c t =
   let add s v c = Some (s, C.Decl v) :: c in
   let rec aux whd a n c = function
      | C.Prod (s, v, t)  -> aux false (v :: a) (succ n) (add s v c) t
      | v when whd        -> v :: a, n
      | v                 -> aux true a n c (R.whd ~delta:true c v)
    in
    aux false [] 0 c t

let classify_conclusion = function
   | C.Rel i                -> Some (i, 0)
   | C.Appl (C.Rel i :: tl) -> Some (i, List.length tl)
   | _                      -> None

let classify c t =
try   
   let vs, h = split c t in
   let rc = classify_conclusion (List.hd vs) in
   let map (b, h) v = (get_rels h v, S.empty) :: b, succ h in
   let l, h = List.fold_left map ([], 0) vs in
   let b = Array.of_list (List.rev l) in
   let mk_closure b h =
      let map j = if j < h then S.union (fst b.(j)) else id in 
      for i = pred h downto 0 do
         let direct, unused = b.(i) in
	 b.(i) <- S.fold map direct direct, unused 
      done; b
   in
   let b = mk_closure b h in
   let rec mk_inverse i direct =
      if S.is_empty direct then () else
      let j = S.choose direct in
      if j < h then
         let unused, inverse = b.(j) in 
         b.(j) <- unused, S.add i inverse
       else ();
       mk_inverse i (S.remove j direct)
   in
   let map i (direct, _) = mk_inverse i direct in
   Array.iteri map b;
(*   out_table b; *)
   List.rev_map snd (List.tl (Array.to_list b)), rc
with Invalid_argument _ -> failwith "Classify.classify"

let overlaps s1 s2 =
   let predicate x = S.mem x s1 in
   S.exists predicate s2