(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.      
     \ /   This software is distributed as is, NO WARRANTY.     
      V_______________________________________________________________ *)

(* $Id: orderings.ml 9869 2009-06-11 22:52:38Z denes $ *)

module OT = struct type t = string  let compare = Pervasives.compare end 
module HC = Map.Make(OT)

type leaf = int * string

let cache = ref HC.empty 
let num = ref 100

let hash s = 
  try HC.find s !cache
  with Not_found ->
          cache := HC.add s (!num,s) !cache;
          decr num;
          HC.find s !cache
;;

hash "==";;
hash "_";;

let problem_file = ref "no-file-given";;
let tptppath = ref "/";;
let seconds = ref 300;;

let fail_msg () =
      print_endline ("% SZS status Timeout for " ^ 
        Filename.basename !problem_file)
;;
  
module type LeafComparer =
  sig
    val cmp : leaf -> leaf -> int
  end
;;

module MakeBlob(C:LeafComparer) : Terms.Blob 
  with type t = leaf and type input = Ast.term = struct
        type t = leaf
        let eq a b = a == b
        let compare a b = C.cmp a b
        let eqP = hash "=="
        let pp (_,a) =  a 
        type input = Ast.term
        let rec embed m = function
            | Ast.Variable name ->
                (try m, List.assoc name m
                 with Not_found -> 
                    let t = Terms.Var ~-(List.length m) in
                    (name,t)::m, t)
            | Ast.Constant name -> m, Terms.Leaf (hash name)
            | Ast.Function (name,args) -> 
                let m, args = 
                  HExtlib.list_mapi_acc 
                    (fun x _ m -> embed m x) m args
                in
                m, Terms.Node (Terms.Leaf (hash name):: args) 
        ;;
        let saturate bo ty = 
          let vars, ty = embed [] ty in
          let _, bo = embed vars bo in
          let bo = Terms.Node (bo :: List.map snd (List.rev vars)) in
          bo, ty
        ;;
        let embed t = snd(embed [] t);;

  end
;;

let success_msg bag l (pp : ?margin:int -> leaf Terms.unit_clause -> string) =
  print_endline ("% SZS status Unsatisfiable for " ^ 
    Filename.basename !problem_file);
  print_endline ("% SZS output start CNFRefutation for " ^ 
    Filename.basename !problem_file);
  flush stdout;
  List.iter (fun x ->
    print_endline (pp ~margin:max_int 
      (fst(Terms.M.find x bag)))) l;
  print_endline ("% SZS output end CNFRefutation for " ^ 
    Filename.basename !problem_file)
;;

let start_msg passives g_passives (pp : leaf Terms.unit_clause -> string) =
        prerr_endline (string_of_int (Unix.getpid ()));
(*
  prerr_endline "Facts";
  List.iter (fun x -> prerr_endline (" " ^ pp x)) passives;
  prerr_endline "Goal";
  prerr_endline (" " ^ pp g_passives)
*)
;;

module Main(C:LeafComparer) = struct
 let main goal hypotheses =
   let module B = MakeBlob(C) in
   let module Pp = Pp.Pp(B) in
   let module P = Paramod.Paramod(B) in
   let bag = Terms.M.empty, 0 in
   let bag, g_passives = P.mk_goal bag goal in
   let bag, passives = 
     HExtlib.list_mapi_acc (fun x _ b -> P.mk_passive b x) bag hypotheses 
   in
   start_msg passives g_passives Pp.pp_unit_clause;
   match 
     P.paramod 
      ~max_steps:max_int bag ~g_passives:[g_passives] ~passives 
   with
   | [] -> ()
   | (bag,_,l)::_ -> success_msg bag l Pp.pp_unit_clause
 ;;
end

let killall l = 
  List.iter (fun pid -> try Unix.kill pid 9 with _ -> ()) l
;;

let main () =
  let childs = ref [] in
  let _ =
    Sys.signal 24 (Sys.Signal_handle 
      (fun _ -> fail_msg (); killall !childs; exit 1)) 
  in
  let _ =
    Sys.signal Sys.sigalrm 
      (Sys.Signal_handle (fun _ -> fail_msg (); killall !childs; exit 1)) 
  in
  Arg.parse [
   "--tptppath", Arg.String (fun p -> tptppath := p), 
     ("[path]  TPTP lib root, default " ^ !tptppath);
   "--timeout", Arg.Int (fun p -> seconds := p), 
     ("[seconds]  timeout, default " ^ string_of_int !seconds);
   ] (fun x -> problem_file := x) "
Matitaprover is the first order automatic prover that equips the 
Matita interactive theorem prover (http://matita.cs.unibo.it).

Developed by A.Asperti, M.Denes and E.Tassi, released under GPL-2.1

If --tptppath is given, instead of the problem file you can just give the 
problem name with the .p suffix (e.g. BOO001-1.p)

If --tptppath is not given, included files (i.e. axiom sets) are searched 
in the current directory only.

usage: matitaprover [options] problemfile";
  let hypotheses, goals = Tptp_cnf.parse ~tptppath:!tptppath !problem_file in
  let goal = match goals with [x] -> x | _ -> assert false in
  let _ = Unix.alarm !seconds in
  childs := 
    List.map 
      (fun f -> 
         let pid = Unix.fork () in 
         if pid = 0 then (f ();exit 0) else pid)
    [ 
      (fun () ->     
        let module M = Main(struct let cmp (a,_) (b,_) = compare a b end) in
        M.main goal hypotheses)
    ;
      (fun () ->     
        let module M = Main(struct let cmp (a,_) (b,_) = compare b a end) in
        M.main goal hypotheses)
    ];
  let _ = Unix.wait () in
  killall !childs;
  exit 0;
;;

main ()