(* Copyright (C) 2003-2005, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://cs.unibo.it/helm/.
 *)

module C    = Cic
module L    = CicClassify
module P    = ProceduralTypes
module D    = Deannotate
module DTI  = DoubleTypeInference
module TC   = CicTypeChecker 
module U    = CicUniv
module UM   = UriManager
module Obj  = LibraryObjects
module HObj = HelmLibraryObjects
module A    = Cic2acic
module T    = CicUtil

type status = {
   sorts : (C.id, Cic2acic.sort_kind) Hashtbl.t;
   types : (C.id, A.anntypes) Hashtbl.t;
   prefix: string;
   max_depth: int option;
   depth: int;
   entries: C.context;
   intros: string list
}

(* helpers ******************************************************************)

let cic = D.deannotate_term

let split2_last l1 l2 =
try
   let n = pred (List.length l1) in
   let before1, after1 = P.list_split n l1 in
   let before2, after2 = P.list_split n l2 in
   before1, before2, List.hd after1, List.hd after2
with Invalid_argument _ -> failwith "A2P.split2_last"

let string_of_head = function
   | C.ASort _         -> "sort"
   | C.AConst _        -> "const"
   | C.AMutInd _       -> "mutind"
   | C.AMutConstruct _ -> "mutconstruct"
   | C.AVar _          -> "var"
   | C.ARel _          -> "rel"
   | C.AProd _         -> "prod"
   | C.ALambda _       -> "lambda"
   | C.ALetIn _        -> "letin"
   | C.AFix _          -> "fix"
   | C.ACoFix _        -> "cofix"
   | C.AAppl _         -> "appl"
   | C.ACast _         -> "cast"
   | C.AMutCase _      -> "mutcase"
   | C.AMeta _         -> "meta"
   | C.AImplicit _     -> "implict"

let next st = {st with depth = succ st.depth; intros = []}

let add st entry intro = 
   {st with entries = entry :: st.entries; intros = intro :: st.intros}

let test_depth st =
try   
   let msg = Printf.sprintf "Depth %u: " st.depth in
   match st.max_depth with
      | None   -> true, "" 
      | Some d -> 
         if st.depth < d then true, msg else false, "DEPTH EXCEDED"
with Invalid_argument _ -> failwith "A2P.test_depth"

let get_itype st v =
try
   let id = T.id_of_annterm v in
   try Some ((Hashtbl.find st.types id).A.annsynthesized)
   with Not_found -> None
with Invalid_argument _ -> failwith "A2P.get_itype"

(* proof construction *******************************************************)

let unused_premise = "UNUSED"

let get_intro name t = 
try
match name with 
   | C.Anonymous -> unused_premise
   | C.Name s    -> 
      if DTI.does_not_occur 1 (cic t) then unused_premise else s
with Invalid_argument _ -> failwith "A2P.get_intro"

let mk_intros st script =
try
   if st.intros = [] then script else
   let count = List.length st.intros in
   P.Intros (Some count, List.rev st.intros, "") :: script
with Invalid_argument _ -> failwith "A2P.mk_intros"

let is_rewrite_right = function
   | C.AConst (_, uri, []) ->
      UM.eq uri HObj.Logic.eq_ind_r_URI || Obj.is_eq_ind_r_URI uri
   | _                     -> false

let is_rewrite_left = function
   | C.AConst (_, uri, []) ->
      UM.eq uri HObj.Logic.eq_ind_URI || Obj.is_eq_ind_URI uri
   | _                     -> false

let mk_premise = function
   | C.ARel (_, _, _, binder) -> binder
   | C.AVar (_, uri, _)
   | C.AConst (_, uri, _)                  -> UM.name_of_uri uri
   | C.ASort (_, sort)                     -> assert false
   | C.AMutInd (_, uri, tno, _)            -> assert false
   | C.AMutConstruct (_, uri, tno, cno, _) -> assert false
   | _                                     -> assert false

let rec mk_fwd_proof st dtext name = function
   | C.AAppl (_, hd :: tl) as v -> 
      if is_rewrite_right hd then
         let what, where = List.nth tl 5, List.nth tl 3 in
	 let premise = mk_premise where in
	 [P.Rewrite (true, what, Some (premise, name), dtext)] 
      else if is_rewrite_left hd then
         let what, where = List.nth tl 5, List.nth tl 3 in
	 let premise = mk_premise where in
	 [P.Rewrite (false, what, Some (premise, name), dtext)]
      else begin match get_itype st v with
         | Some ty ->
	    let qs = [[P.Id ""]; mk_proof (next st) v] in
	    [P.Branch (qs, ""); P.Cut (name, ty, dtext)]
         | None    ->         
            let ty, _ = TC.type_of_aux' [] st.entries (cic hd) U.empty_ugraph in
            let (classes, rc) as h = L.classify ty in
            let text = Printf.sprintf "%u %s" (List.length classes) (L.to_string h) in
            [P.LetIn (name, v, dtext ^ text)]
      end
   | v                          -> 
      [P.LetIn (name, v, dtext)] 

and mk_proof st = function
   | C.ALambda (_, name, v, t) -> 
      let entry = Some (name, C.Decl (cic v)) in
      let intro = get_intro name t in
      mk_proof (add st entry intro) t
   | C.ALetIn (_, name, v, t) as what ->
      let proceed, dtext = test_depth st in
      let script = if proceed then 
         let entry = Some (name, C.Def (cic v, None)) in
         let intro = get_intro name t in
         let q = mk_proof (next (add st entry intro)) t in
         List.rev_append (mk_fwd_proof st dtext intro v) q
      else
	 [P.Apply (what, dtext)]
      in
      mk_intros st script
   | C.ARel _ as what           ->
      let _, dtext = test_depth st in
      let script = [P.Apply (what, dtext)] in 
      mk_intros st script
   | C.AAppl (_, hd :: tl) as t  ->
      let proceed, dtext = test_depth st in
      let script = if proceed then
         let ty, _ = TC.type_of_aux' [] st.entries (cic hd) U.empty_ugraph in
         let (classes, rc) as h = L.classify ty in
         let synth = L.S.singleton 0 in
         let text = Printf.sprintf "%u %s" (List.length classes) (L.to_string h) in
         match rc with
            | Some (i, j) when i > 1 ->
	       let classes, tl, _, what = split2_last classes tl in
	       let synth = L.S.add 1 synth in
	       let qs = mk_bkd_proofs (next st) synth classes tl in
               if is_rewrite_right hd then 
	          [P.Rewrite (false, what, None, dtext); P.Branch (qs, "")]
	       else if is_rewrite_left hd then 
	          [P.Rewrite (true, what, None, dtext); P.Branch (qs, "")]
	       else   
	          let using = Some hd in
	          [P.Elim (what, using, dtext ^ text); P.Branch (qs, "")]
	    | _                                             ->
	       let qs = mk_bkd_proofs (next st) synth classes tl in
               [P.Apply (hd, dtext ^ text); P.Branch (qs, "")]
      else
         [P.Apply (t, dtext)]
      in
      mk_intros st script
   | t ->
      let text = Printf.sprintf "%s: %s" "UNEXPANDED" (string_of_head t) in
      let script = [P.Note text] in
      mk_intros st script

and mk_bkd_proofs st synth classes ts =
try 
   let _, dtext = test_depth st in   
   let aux inv v =
      if L.overlaps synth inv then None else
      if L.S.is_empty inv then Some (mk_proof st v) else
      Some [P.Apply (v, dtext ^ "dependent")]
   in
   let l1, l2 = List.length classes, List.length ts in
   if l1 > l2 then failwith "partial application" else
   if l1 < l2 then failwith "too many arguments" else
   P.list_map2_filter aux classes ts
with Invalid_argument _ -> failwith "A2P.mk_bkd_proofs"

(* object costruction *******************************************************)

let is_theorem pars =   
   List.mem (`Flavour `Theorem) pars || List.mem (`Flavour `Fact) pars || 
   List.mem (`Flavour `Remark) pars || List.mem (`Flavour `Lemma) pars

let mk_obj st = function
   | C.AConstant (_, _, s, Some v, t, [], pars) when is_theorem pars ->
      let ast = mk_proof st v in
      let count = P.count_steps 0 ast in
      let text = Printf.sprintf "tactics: %u" count in
      P.Theorem (s, t, text) :: ast @ [P.Qed ""]
   | _                                                               ->
      failwith "not a theorem"

(* interface functions ******************************************************)

let acic2procedural ~ids_to_inner_sorts ~ids_to_inner_types prefix aobj = 
   let st = {
      sorts     = ids_to_inner_sorts;
      types     = ids_to_inner_types;
      prefix    = prefix;
      max_depth = None;
      depth     = 0;
      entries   = [];
      intros    = []
   } in
   prerr_endline "Level 2 transformation";
   let steps = mk_obj st aobj in
   prerr_endline "grafite rendering";
   List.rev (P.render_steps [] steps)