let debug s =
  () (* prerr_endline s *)
;;

let nparamod rdb metasenv subst context t table =
  let nb_iter = ref 200 in
  let amount_of_time = 20.0 in
  let module C = struct
    let metasenv = metasenv
    let subst = subst
    let context = context
  end
  in
  let module B = NCicBlob.NCicBlob(C) in
  let module Pp = Pp.Pp (B) in
  let module FU = FoUnif.Founif(B) in
  let module IDX = Index.Index(B) in
  let module Sup = Superposition.Superposition(B) in
  let module Utils = FoUtils.Utils(B) in
    
  let module OrderedPassives =
      struct
	type t = B.t Terms.passive_clause
	    
	let compare = Utils.compare_passive_clauses
      end
  in
  let module PassiveSet = Set.Make(OrderedPassives)
  in
  let add_passive_clause passives cl =
    PassiveSet.add (Utils.mk_passive_clause cl) passives
  in
  let timeout = Unix.gettimeofday () +. amount_of_time in 
    (* TODO : fairness condition *)
  let select passives =
    if PassiveSet.is_empty passives then None
    else let cl = PassiveSet.min_elt passives in
      Some (snd cl,PassiveSet.remove cl passives)
  in
  let rec given_clause bag maxvar actives      
      passives g_actives g_passives =
    
    decr nb_iter; if !nb_iter = 0 then 
      (*(prerr_endline "Bag :"; prerr_endline (Pp.pp_bag bag);
      prerr_endline "Active table :"; 
       (List.iter (fun x -> prerr_endline (Pp.pp_unit_clause x))
	  (fst actives));*)
      raise (Failure "No iterations left !");
    if Unix.gettimeofday () > timeout then
      raise (Failure "Timeout !");


      
    (* superposition left, simplifications on goals *)
      debug "infer_left step...";
      let bag, maxvar, g_actives, g_passives =
	match select g_passives with
      | None -> bag, maxvar, g_actives, g_passives
      | Some (g_current, g_passives) -> 
	  debug ("Selected goal : " ^ Pp.pp_unit_clause g_current);
          let bag, g_current = 
            Sup.simplify_goal maxvar (snd actives) bag g_current
          in
          let bag, maxvar, new_goals = 
            Sup.infer_left bag maxvar g_current actives 
          in
	  let new_goals = List.fold_left add_passive_clause
	    PassiveSet.empty new_goals
	  in
          bag, maxvar, g_current::g_actives,
	  (PassiveSet.union new_goals g_passives)
    in
      debug
	(Printf.sprintf "Number of active goals : %d"
	   (List.length g_actives));
      debug
	(Printf.sprintf "Number of passive goals : %d"
	   (PassiveSet.cardinal g_passives));
  
      (* forward step *)
 
      (* e = select P           *
       * e' = demod A e         *
       * A' = demod [e'] A      *
       * A'' = A' + e'          *
       * e'' = fresh e'         *
       * new = supright e'' A'' *
       * new'= demod A'' new    *
       * P' = P + new'          *)
      debug "Forward infer step...";
    let bag, maxvar, actives, passives, g_passives =
      let rec aux_simplify passives =
	match select passives with
	  | None -> assert false
	  | Some (current, passives) -> 
	      debug ("Selected fact : " ^ Pp.pp_unit_clause current);
(*               match Sup.keep_simplified current actives bag maxvar with *)
               match Sup.one_pass_simplification current actives bag maxvar with 
		| None -> aux_simplify passives
		| Some x -> x,passives
      in
      let (current, bag, actives),passives = aux_simplify passives
      in		    
	debug ("Fact after simplification :"
	       ^ Pp.pp_unit_clause current);
	let bag, maxvar, actives, new_clauses = 
          Sup.infer_right bag maxvar current actives 
	in
  debug "Demodulating goals with actives...";
	  (* keep goals demodulated w.r.t. actives and check if solved *)
	let bag, g_actives = 
	  List.fold_left 
            (fun (bag,acc) c -> 
               let bag, c = Sup.simplify_goal maxvar (snd actives) bag c in
		 bag, c::acc) 
            (bag,[]) g_actives 
	in
	let ctable = IDX.index_unit_clause IDX.DT.empty current in
	let bag, maxvar, new_goals = 
	  List.fold_left 
	    (fun (bag,m,acc) g -> 
	       let bag, m, ng = Sup.infer_left bag maxvar g
		 ([current],ctable) in
		 bag,m,ng@acc) 
	    (bag,maxvar,[]) g_actives 
	in
	let new_clauses = List.fold_left add_passive_clause
	  PassiveSet.empty new_clauses in
	let new_goals = List.fold_left add_passive_clause
	  PassiveSet.empty new_goals in
	  bag, maxvar, actives,
      PassiveSet.union new_clauses passives,
      PassiveSet.union new_goals g_passives
    in
      debug
	(Printf.sprintf "Number of actives : %d" (List.length (fst actives)));
      debug
	(Printf.sprintf "Number of passives : %d"
	   (PassiveSet.cardinal passives));
      given_clause bag maxvar actives passives g_actives g_passives
  in

  let mk_clause bag maxvar (t,ty) =
    let (proof,ty) = B.saturate t ty in
    let c, maxvar = Utils.mk_unit_clause maxvar ty proof in
    let bag, c = Utils.add_to_bag bag c in
    bag, maxvar, c
  in
  let bag, maxvar, goal = mk_clause Terms.M.empty 0 t in
  let g_actives = [] in
  let g_passives = PassiveSet.singleton (Utils.mk_passive_clause goal) in
  let passives, bag, maxvar = 
    List.fold_left
      (fun (cl, bag, maxvar) t -> 
         let bag, maxvar, c = mk_clause bag maxvar t in
         (add_passive_clause cl c), bag, maxvar)
      (PassiveSet.empty, bag, maxvar) table 
  in
  let actives = [], IDX.DT.empty in
  try given_clause bag maxvar actives passives g_actives g_passives
  with 
  | Sup.Success (bag, _, (i,_,_,_)) ->
      let l =
        let module S  = 
          HTopoSort.Make(struct type t=int let compare=Pervasives.compare end)
        in
        let module C : Set.S with type elt = int = 
          Set.Make(struct type t=int let compare=Pervasives.compare end)
        in
        let all id = 
          let rec traverse ongoal (accg,acce) i =
            match Terms.M.find i bag with
            | (_,_,_,Terms.Exact _) -> accg, acce
            | (_,_,_,Terms.Step (_,i1,i2,_,_,_)) -> 
               let accg, acce = 
                 if ongoal then C.add i1 accg, acce
                 else accg, C.add i1 acce
               in
               let acce = C.add i2 acce in
                 traverse false (traverse ongoal (accg,acce) i1) i2    
          in
            traverse true (C.empty,C.empty) id
        in
        let esteps = 
          S.topological_sort (C.elements (snd (all i))) 
           (fun i -> C.elements (C.union (snd (all i)) (fst (all i)) ))
        in
        let gsteps = 
          S.topological_sort (C.elements (fst (all i))) 
           (fun i -> C.elements (fst (all i)))
        in
        let gsteps = List.rev gsteps in
        esteps@(i::gsteps)
      in
      prerr_endline "YES!";
      prerr_endline ("Meeting point : " ^ (string_of_int i));
      prerr_endline "Proof:"; 
      List.iter (fun x -> prerr_endline (string_of_int x);
              prerr_endline (Pp.pp_unit_clause (Terms.M.find x bag))) l;
      let proofterm = B.mk_proof bag i l in
      let metasenv, proofterm = 
        let rec aux k metasenv = function
          | NCic.Meta _ as t -> metasenv, t
          | NCic.Implicit _ -> 
              let metasenv,i,_,_=NCicMetaSubst.mk_meta metasenv context `Term in
              metasenv, NCic.Meta (i,(k,NCic.Irl (List.length context)))
          | t -> NCicUntrusted.map_term_fold_a 
                  (fun _ k -> k+1) k aux metasenv t                 
        in
         aux 0 metasenv proofterm
      in
      prerr_endline
        ("prova generata: " ^ NCicPp.ppterm 
           ~metasenv ~subst ~context proofterm);
      let metasenv, subst, proofterm, _prooftype = 
        NCicRefiner.typeof 
          (rdb#set_coerc_db NCicCoercion.empty_db) 
          metasenv subst context proofterm None
      in
      prerr_endline "prova raffinata";
      proofterm, metasenv, subst
  | Failure _ -> prerr_endline "FAILURE"; assert false
;;