(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.      
     \ /   This software is distributed as is, NO WARRANTY.     
      V_______________________________________________________________ *)

(* $Id: orderings.ml 9869 2009-06-11 22:52:38Z denes $ *)

 (*let debug s = prerr_endline s ;;*)
 let debug _ = ();;
    
let max_nb_iter = max_int ;;
let amount_of_time = 300.0 ;;

module Paramod (B : Terms.Blob) = struct
  exception Failure of string * B.t Terms.bag * int * int
  type bag = B.t Terms.bag * int
  module Pp = Pp.Pp (B) 
  module FU = FoUnif.Founif(B) 
  module IDX = Index.Index(B) 
  module Sup = Superposition.Superposition(B) 
  module Utils = FoUtils.Utils(B) 
  module WeightOrderedPassives =
      struct
	type t = B.t Terms.passive_clause
	let compare = Utils.compare_passive_clauses_weight
      end

  module AgeOrderedPassives =
      struct
	type t = B.t Terms.passive_clause
	let compare = Utils.compare_passive_clauses_age
      end
  
  module WeightPassiveSet = Set.Make(WeightOrderedPassives)
  module AgePassiveSet = Set.Make(AgeOrderedPassives)

  let add_passive_clause ?(no_weight=false) (passives_w,passives_a) cl =
    let cl = if no_weight then (0,cl)
    else Utils.mk_passive_clause cl in
    WeightPassiveSet.add cl passives_w, AgePassiveSet.add cl passives_a
  ;;

  let remove_passive_clause (passives_w,passives_a) cl =
    let passives_w = WeightPassiveSet.remove cl passives_w in
    let passives_a = AgePassiveSet.remove cl passives_a in
      passives_w,passives_a
  ;;

  let add_passive_clauses (passives_w,passives_a) new_clauses =
    let new_clauses_w,new_clauses_a = List.fold_left add_passive_clause
      (WeightPassiveSet.empty,AgePassiveSet.empty) new_clauses
    in
      (WeightPassiveSet.union new_clauses_w passives_w,
       AgePassiveSet.union new_clauses_a passives_a)
  ;;

  let is_passive_set_empty (passives_w,passives_a) =
    if (WeightPassiveSet.is_empty passives_w) then begin
      assert (AgePassiveSet.is_empty passives_a); true
    end else begin
      assert (not (AgePassiveSet.is_empty passives_a)); false
    end
  ;;

  let passive_set_cardinal (passives_w,_) = WeightPassiveSet.cardinal passives_w
  
  let passive_empty_set =
    (WeightPassiveSet.empty,AgePassiveSet.empty)
  ;;

  let pick_min_passive ~use_age (passives_w,passives_a) =
    if use_age then AgePassiveSet.min_elt passives_a
    else WeightPassiveSet.min_elt passives_w
  ;;

  let mk_clause bag maxvar (t,ty) =
    let (proof,ty) = B.saturate t ty in
    let c, maxvar = Utils.mk_unit_clause maxvar ty proof in
    let bag, c = Utils.add_to_bag bag c in
    (bag, maxvar), c
  ;;
  
  let mk_passive (bag,maxvar) = mk_clause bag maxvar;;
  let mk_goal (bag,maxvar) = mk_clause bag maxvar;;

  (* TODO : global age over facts and goals (without comparing weights) *)
  let select ~use_age passives g_passives =
    if is_passive_set_empty passives then begin
      assert (not (is_passive_set_empty g_passives));
      let g_cl = pick_min_passive ~use_age:use_age g_passives in
	(true,snd g_cl,passives,remove_passive_clause g_passives g_cl)
    end
    else let cl = pick_min_passive ~use_age:use_age passives in
      if is_passive_set_empty g_passives then
	(false,snd cl,remove_passive_clause passives cl,g_passives)
      else
	let g_cl = pick_min_passive ~use_age:use_age g_passives in
	  if (fst cl <= fst g_cl) then
	    (false,snd cl,remove_passive_clause passives cl,g_passives)
	  else
	    (true,snd g_cl,passives,remove_passive_clause g_passives g_cl)
  ;;

  let backward_infer_step bag maxvar actives passives
                          g_actives g_passives g_current =
    (* superposition left, simplifications on goals *)
      debug "infer_left step...";
      let bag, maxvar, new_goals = 
        Sup.infer_left bag maxvar g_current actives 
      in
	debug "Performed infer_left step";
        bag, maxvar, actives, passives, g_current::g_actives,
    (add_passive_clauses g_passives new_goals)
  ;;

  let forward_infer_step bag maxvar actives passives g_actives
                         g_passives current =
    (* forward step *)
    
    (* e = select P           *
     * e' = demod A e         *
     * A' = demod [e'] A      *
     * A'' = A' + e'          *
     * e'' = fresh e'         *
     * new = supright e'' A'' *
     * new'= demod A'' new    *
     * P' = P + new'          *)
    debug "Forward infer step...";
    let bag, maxvar, actives, new_clauses = 
      Sup.infer_right bag maxvar current actives 
    in
      debug "Demodulating goals with actives...";
      (* keep goals demodulated w.r.t. actives and check if solved *)
      let bag, g_actives = 
	List.fold_left 
          (fun (bag,acc) c -> 
	     match Sup.simplify_goal maxvar (snd actives) bag acc c with
	       | None -> bag, acc
	       | Some (bag,c) -> bag,c::acc)
          (bag,[]) g_actives 
      in
      let ctable = IDX.index_unit_clause IDX.DT.empty current in
      let bag, maxvar, new_goals = 
	List.fold_left 
	  (fun (bag,m,acc) g -> 
	     let bag, m, ng = Sup.infer_left bag m g
	       ([current],ctable) in
	       bag,m,ng@acc) 
	  (bag,maxvar,[]) g_actives 
      in
	bag, maxvar, actives,
    add_passive_clauses passives new_clauses, g_actives,
    add_passive_clauses g_passives new_goals
  ;;
 
  let rec given_clause bag maxvar nb_iter timeout actives passives g_actives g_passives =
    (* prerr_endline "Bag :"; prerr_endline (Pp.pp_bag bag);
      prerr_endline "Active table :"; 
       (List.iter (fun x -> prerr_endline (Pp.pp_unit_clause x))
	  (fst actives)); *)
    let nb_iter = nb_iter + 1 in
    if nb_iter = max_nb_iter then       
      raise (Failure ("No iterations left !",bag,maxvar,nb_iter));
    if Unix.gettimeofday () > timeout then
      raise (Failure ("Timeout !",bag,maxvar,nb_iter));

    let use_age = nb_iter mod 10 = 0 in

    let rec aux_select passives g_passives =
      let backward,current,passives,g_passives =
	select ~use_age:false passives g_passives
      in
	if backward then
	 match Sup.simplify_goal maxvar (snd actives) bag g_actives current with
	    | None -> aux_select passives g_passives
	    | Some x -> let bag,g_current = x in
		backward_infer_step bag maxvar actives passives
	          g_actives g_passives g_current
	else
	  (* debug ("Selected fact : " ^ Pp.pp_unit_clause current); *)
          match Sup.keep_simplified current actives bag maxvar with
	(*  match Sup.one_pass_simplification current actives bag maxvar with*)
	      | None -> aux_select passives g_passives
	      | Some x -> let (current, bag, actives) = x in
		  forward_infer_step bag maxvar actives passives
		                     g_actives g_passives current
    in

    let bag,maxvar,actives,passives,g_actives,g_passives =      
      aux_select passives g_passives
    in
      debug
	(Printf.sprintf "Number of active goals : %d"
	   (List.length g_actives));
      debug
	(Printf.sprintf "Number of passive goals : %d"
	   (passive_set_cardinal g_passives));
      debug
	(Printf.sprintf "Number of actives : %d" (List.length (fst actives)));
      debug
	(Printf.sprintf "Number of passives : %d"
	   (passive_set_cardinal passives));
      given_clause 
        bag maxvar nb_iter timeout actives passives g_actives g_passives
  ;;

  let paramod (bag,maxvar) ~g_passives ~passives =
    let timeout = Unix.gettimeofday () +. amount_of_time in 
    let passives = add_passive_clauses passive_empty_set passives in
    let g_passives = add_passive_clauses passive_empty_set g_passives in
    let g_actives = [] in
    let actives = [], IDX.DT.empty in
    try 
     given_clause 
      bag maxvar 0 timeout actives passives g_actives g_passives
    with 
    | Sup.Success (bag, _, (i,_,_,_)) ->
        let l =
          let rec traverse ongoal (accg,acce) i =
            match Terms.M.find i bag with
              | (id,_,_,Terms.Exact _),_ ->
          	if ongoal then [i],acce else
          	  if (List.mem i acce) then accg,acce else accg,acce@[i]
              | (_,_,_,Terms.Step (_,i1,i2,_,_,_)),_ ->
          	if (not ongoal) && (List.mem i acce) then accg,acce
          	else
                    let accg,acce = 
          	    traverse false (traverse ongoal (accg,acce) i1) i2
          	  in
          	    if ongoal then i::accg,acce else accg,i::acce
          in
          let gsteps,esteps = traverse true ([],[]) i in
            (List.rev esteps)@gsteps
        in
        prerr_endline 
          (Printf.sprintf "Found proof, %fs" 
            (Unix.gettimeofday() -. timeout +. amount_of_time));
        (* prerr_endline "Proof:"; 
        List.iter (fun x -> prerr_endline (string_of_int x);
                prerr_endline (Pp.pp_unit_clause (fst (Terms.M.find x bag)))) l;*)
        [ bag, i, l ]
    | Failure (msg,_bag,_maxvar,nb_iter) -> 
        prerr_endline msg;
        prerr_endline (Printf.sprintf "FAILURE in %d iterations" nb_iter); 
        []
  ;;

end