(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.      
     \ /   This software is distributed as is, NO WARRANTY.     
      V_______________________________________________________________ *)

(* $Id: index.mli 9822 2009-06-03 15:37:06Z tassi $ *)

module Superposition (B : Terms.Blob) = 
  struct
    module IDX = Index.Index(B)
    module Unif = FoUnif.Founif(B)
    module Subst = FoSubst.Subst(B)
    module Order = Orderings.Orderings(B)
    module Utils = FoUtils.Utils(B)
    module Pp = Pp.Pp(B)
    
    exception Success of B.t Terms.bag * int * B.t Terms.unit_clause

    let debug s =
      ()(* prerr_endline s *)
    ;;

    let rec list_first f = function
      | [] -> None
      | x::tl -> match f x with Some _ as x -> x | _ -> list_first f tl
    ;;

    let first_position pos ctx t f =
      let rec aux pos ctx = function
      | Terms.Leaf _ as t -> f t pos ctx 
      | Terms.Var _ -> None
      | Terms.Node l as t-> 
          match f t pos ctx with
          | Some _ as x -> x
          | None ->
              let rec first pre post = function
                | [] -> None
                | t :: tl -> 
                     let newctx = fun x -> ctx (Terms.Node (pre@[x]@post)) in
                     match aux (List.length pre :: pos) newctx t with
                     | Some _ as x -> x
                     | None -> 
                         if post = [] then None (* tl is also empty *)
                         else first (pre @ [t]) (List.tl post) tl
              in
                first [] (List.tl l) l 
      in
        aux pos ctx t
    ;;
                                     
    let all_positions pos ctx t f =
      let rec aux pos ctx = function
      | Terms.Leaf _ as t -> f t pos ctx 
      | Terms.Var _ -> []
      | Terms.Node l as t-> 
          let acc, _, _ = 
            List.fold_left
            (fun (acc,pre,post) t -> (* Invariant: pre @ [t] @ post = l *)
                let newctx = fun x -> ctx (Terms.Node (pre@[x]@post)) in
                let acc = aux (List.length pre :: pos) newctx t @ acc in
                if post = [] then acc, l, []
                else acc, pre @ [t], List.tl post)
             (f t pos ctx, [], List.tl l) l
          in
           acc
      in
        aux pos ctx t
    ;;
    
    let build_clause bag filter rule t subst vl id id2 pos dir =
      let proof = Terms.Step(rule,id,id2,dir,pos,subst) in
      let t = Subst.apply_subst subst t in
      if filter t then
        let literal = 
          match t with
          | Terms.Node [ Terms.Leaf eq ; ty; l; r ] when B.eq B.eqP eq ->
               let o = Order.compare_terms l r in
               Terms.Equation (l, r, ty, o)
          | t -> Terms.Predicate t
        in
        let bag, uc = 
          Utils.add_to_bag bag (0, literal, vl, proof)
        in
        Some (bag, uc)
      else
        ((*prerr_endline ("Filtering: " ^ Pp.pp_foterm t);*)None)
    ;;
      
    
    (* ============ simplification ================= *)

    let demod table varlist subterm pos context =
      let cands = IDX.DT.retrieve_generalizations table subterm in
      list_first
        (fun (dir, (id,lit,vl,_)) ->
           match lit with
           | Terms.Predicate _ -> assert false
           | Terms.Equation (l,r,_,o) ->
               let side, newside = if dir=Terms.Left2Right then l,r else r,l in
               try 
                 let subst, varlist = 
                   Unif.unification (varlist@vl) varlist subterm side 
                 in
                 if o = Terms.Incomparable then
                   let side = Subst.apply_subst subst side in
                   let newside = Subst.apply_subst subst newside in
                   let o = Order.compare_terms newside side in
                   (* Riazanov, pp. 45 (ii) *)
                   if o = Terms.Lt then  
                     Some (context newside, subst, varlist, id, pos, dir)
                   else 
                     ((*prerr_endline ("Filtering: " ^ 
                        Pp.pp_foterm side ^ " =(< || =)" ^ 
                        Pp.pp_foterm newside ^ " coming from " ^ 
                        Pp.pp_unit_clause uc );*)None)
                 else
                   Some (context newside, subst, varlist, id, pos, dir)
               with FoUnif.UnificationFailure _ -> None)
        (IDX.ClauseSet.elements cands)
    ;;

    (* XXX: possible optimization, if the literal has a "side" already
     * in normal form we should not traverse it again *)
    let demodulate_once bag (id, literal, vl, pr) table =
      debug ("Demodulating : " ^ (Pp.pp_unit_clause (id, literal, vl, pr)));
      let t = 
        match literal with
        | Terms.Predicate t -> t
        | Terms.Equation (l,r,ty,_) -> Terms.Node [ Terms.Leaf B.eqP; ty; l; r ]
      in
      match first_position [] (fun x -> x) t (demod table vl) with
      | None -> None
      | Some (newt, subst, varlist, id2, pos, dir) ->
          build_clause bag (fun _ -> true) Terms.Demodulation 
            newt subst varlist id id2 pos dir
    ;;

    let rec demodulate bag clause table =
      match demodulate_once bag clause table with
      | None -> bag, clause
      | Some (bag, clause) -> demodulate bag clause table
    ;;

    (* move away *)
    let is_identity_clause = function
      | _, Terms.Equation (_,_,_,Terms.Eq), _, _ -> true
      | _, Terms.Predicate _, _, _ -> assert false
      | _ -> false
    ;;

    let is_subsumed ~unify (id, lit, vl, _) table =
      match lit with
      | Terms.Predicate _ -> assert false
      | Terms.Equation (l,r,ty,_) -> 
	  let retrieve = if unify then IDX.DT.retrieve_unifiables
	  else IDX.DT.retrieve_generalizations in
          let lcands = retrieve table l in
          let rcands = retrieve table r in
          let f b c = 
            let dir, l, r, vl = 
              match c with
              | (d, (_,Terms.Equation (l,r,ty,_),vl,_))-> d, l, r, vl
              |_ -> assert false 
            in 
            let l, r = if (dir = Terms.Left2Right) = b then l,r else r,l in
            Terms.Node [ Terms.Leaf B.eqP; ty; l; r ], vl
          in
          let cands1 = List.map (f true) (IDX.ClauseSet.elements lcands) in
          let cands2 = List.map (f false) (IDX.ClauseSet.elements rcands) in
          let t = Terms.Node [ Terms.Leaf B.eqP; ty; l; r ] in
	  let locked_vars = if unify then [] else vl in
            List.exists 
              (fun (c, vl1) ->
		 try ignore(Unif.unification (vl@vl1) locked_vars c t); true
		 with FoUnif.UnificationFailure _ -> false)
              (cands1 @ cands2)
    ;;

    (* demodulate and check for subsumption *)
    let simplify table bag clause = 
      let bag, clause = demodulate bag clause table in
      if is_identity_clause clause then None
      else
        if is_subsumed ~unify:false clause table then None
        else Some (bag, clause)
    ;;

    let simplification_step ~new_cl cl (alist,atable) bag new_clause =
      let atable1 =
	if new_cl then atable else
	IDX.index_unit_clause atable cl
      in
	match simplify atable1 bag new_clause with
	  | None -> (Some cl, None)
	  | Some (bag, clause) ->
              let ctable = IDX.index_unit_clause IDX.DT.empty clause in
	      let bag, newa, alist, atable = 
		List.fold_left 
		  (fun (bag, newa, alist, atable as acc) c ->
		     match simplify ctable bag c with
		       |None -> acc
		       |Some (bag, c1) ->
			    if (c1 == c) then 
			      bag, newa, c :: alist,
			    IDX.index_unit_clause atable c
			    else
			      bag, c1 :: newa, alist, atable)		  
		  (bag,[],[],IDX.DT.empty) alist
	      in
		if new_cl then
		  (Some cl, Some (clause, (alist,atable), newa, bag))
		else
		  match simplify ctable bag cl with
		    | None ->
			(None, Some (clause, (alist,atable), newa, bag))
		    | Some (bag,cl1) ->
			(Some cl1, Some (clause, (alist,atable), newa, bag))
    ;;

    let keep_simplified cl (alist,atable) bag =
      let rec keep_simplified_aux ~new_cl cl (alist,atable) bag newc =
	if new_cl then
	  match simplification_step ~new_cl cl (alist,atable) bag cl with
	    | (None, _) -> assert false
	    | (Some _, None) -> None
	    | (Some _, Some (clause, (alist,atable), newa, bag)) ->
		keep_simplified_aux ~new_cl:(cl!=clause) clause (alist,atable)
		  bag (newa@newc)
	else
	  match newc with
	    | [] -> Some (cl, bag, (alist,atable))
	    | hd::tl ->
		match simplification_step ~new_cl cl
		  (alist,atable) bag hd with
		  | (None,None) -> assert false
		  | (Some _,None) ->
		      keep_simplified_aux ~new_cl cl (alist,atable) bag tl
		  | (None, Some _) -> None
		  | (Some cl1, Some (clause, (alist,atable), newa, bag)) ->
		      let alist,atable =
			(clause::alist, IDX.index_unit_clause atable clause)
		      in
			keep_simplified_aux ~new_cl:(cl!=cl1) cl1 (alist,atable)
			  bag (newa@tl)
      in
	keep_simplified_aux ~new_cl:true cl (alist,atable) bag []
    ;;			
	  
    (* this is like simplify but raises Success *)
    let simplify_goal maxvar table bag clause = 
      let bag, clause = demodulate bag clause table in
      if (is_identity_clause clause) || (is_subsumed ~unify:true clause table)
      then raise (Success (bag, maxvar, clause))
      else bag, clause
    ;;

    (* =================== inference ===================== *)

    (* this is OK for both the sup_left and sup_right inference steps *)
    let superposition table varlist subterm pos context =
      let cands = IDX.DT.retrieve_unifiables table subterm in
      HExtlib.filter_map
        (fun (dir, (id,lit,vl,_ (*as uc*))) ->
           match lit with
           | Terms.Predicate _ -> assert false
           | Terms.Equation (l,r,_,o) ->
               let side, newside = if dir=Terms.Left2Right then l,r else r,l in
               try 
                 let subst, varlist = 
                   Unif.unification (varlist@vl) [] subterm side 
                 in
                 if o = Terms.Incomparable then
                   let side = Subst.apply_subst subst side in
                   let newside = Subst.apply_subst subst newside in
                   let o = Order.compare_terms side newside in
                   (* XXX: check Riazanov p. 33 (iii) *)
                   if o <> Terms.Lt && o <> Terms.Eq then  
                     Some (context newside, subst, varlist, id, pos, dir)
                   else 
                     ((*prerr_endline ("Filtering: " ^ 
                        Pp.pp_foterm side ^ " =(< || =)" ^ 
                        Pp.pp_foterm newside ^ " coming from " ^ 
                        Pp.pp_unit_clause uc );*)None)
                 else
                   Some (context newside, subst, varlist, id, pos, dir)
               with FoUnif.UnificationFailure _ -> None)
        (IDX.ClauseSet.elements cands)
    ;;

    let build_new_clause bag maxvar filter rule t subst vl id id2 pos dir =
      let maxvar, vl, relocsubst = Utils.relocate maxvar vl in
      let subst = Subst.concat relocsubst subst in
      match build_clause bag filter rule t subst vl id id2 pos dir with
      | Some (bag, c) -> Some ((bag, maxvar), c)
      | None -> None
    ;;


    let fold_build_new_clause bag maxvar id rule filter res =
      let (bag, maxvar), res =
       HExtlib.filter_map_acc 
         (fun (bag, maxvar) (t,subst,vl,id2,pos,dir) ->
            build_new_clause bag maxvar filter rule t subst vl id id2 pos dir)
         (bag, maxvar) res
      in
       bag, maxvar, res
    ;;

    (* Superposes selected equation with equalities in table *)
    let superposition_with_table bag maxvar (id,selected,vl,_) table =
      match selected with 
      | Terms.Predicate _ -> assert false
      | Terms.Equation (l,r,ty,Terms.Lt) ->
          fold_build_new_clause bag maxvar id Terms.Superposition
            (fun _ -> true)
            (all_positions [3] 
              (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; l; x ])
              r (superposition table vl))          
      | Terms.Equation (l,r,ty,Terms.Gt) ->
          fold_build_new_clause bag maxvar id Terms.Superposition
            (fun _ -> true)
            (all_positions [2] 
              (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; x; r ])
              l (superposition table vl))
      | Terms.Equation (l,r,ty,Terms.Incomparable) -> 
          fold_build_new_clause bag maxvar id Terms.Superposition
            (function (* Riazanov: p.33 condition (iv) *)
              | Terms.Node [Terms.Leaf eq; ty; l; r ] when B.eq B.eqP eq -> 
                  Order.compare_terms l r <> Terms.Eq
              | _ -> assert false)
            ((all_positions [3] 
               (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; l; x ])
               r (superposition table vl)) @         
             (all_positions [2] 
               (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; x; r ])
               l (superposition table vl)))
      | _ -> assert false
    ;;

    (* the current equation is normal w.r.t. demodulation with atable
     * (and is not the identity) *)
    let infer_right bag maxvar current (alist,atable) = 
      (* We demodulate actives clause with current until all *
       * active clauses are reduced w.r.t each other         *)
      (* let bag, (alist,atable) = keep_simplified (alist,atable) bag [current] in *)
      let ctable = IDX.index_unit_clause IDX.DT.empty current in
      (* let bag, (alist, atable) = 
        let bag, alist = 
          HExtlib.filter_map_acc (simplify ctable) bag alist
        in
        bag, (alist, List.fold_left IDX.index_unit_clause IDX.DT.empty alist)
      in*)
	debug "Simplified active clauses with fact";
      (* We superpose active clauses with current *)
      let bag, maxvar, new_clauses =
        List.fold_left 
          (fun (bag, maxvar, acc) active ->
             let bag, maxvar, newc = 
               superposition_with_table bag maxvar active ctable 
             in
             bag, maxvar, newc @ acc)
          (bag, maxvar, []) alist
      in
	debug "First superpositions";
	(* We add current to active clauses so that it can be *
	 * superposed with itself                             *)
      let alist, atable = 
        current :: alist, IDX.index_unit_clause atable current
      in
	debug "Indexed";
      let fresh_current, maxvar = Utils.fresh_unit_clause maxvar current in
	(* We need to put fresh_current into the bag so that all *
	 * variables clauses refer to are known.                 *)
      let bag, fresh_current = Utils.add_to_bag bag fresh_current in
	(* We superpose current with active clauses *)
      let bag, maxvar, additional_new_clauses =
        superposition_with_table bag maxvar fresh_current atable 
      in
	debug "Another superposition";
      let new_clauses = new_clauses @ additional_new_clauses in
      let bag, new_clauses = 
        HExtlib.filter_map_acc (simplify atable) bag new_clauses
      in
	debug "Demodulated new clauses";
      bag, maxvar, (alist, atable), new_clauses
    ;;

    let infer_left bag maxvar goal (_alist, atable) =
	(* We superpose the goal with active clauses *)
      let bag, maxvar, new_goals =
        superposition_with_table bag maxvar goal atable 
      in
	(* We demodulate the goal with active clauses *)
      let bag, new_goals = 
        List.fold_left
         (fun (bag, acc) g -> 
            let bag, g = demodulate bag g atable in
            bag, g :: acc) 
         (bag, []) new_goals
      in
      bag, maxvar, List.rev new_goals
    ;;

  end