(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.      
     \ /   This software is distributed as is, NO WARRANTY.     
      V_______________________________________________________________ *)

(* $Id: index.mli 9822 2009-06-03 15:37:06Z tassi $ *)

module Superposition (B : Terms.Blob) = 
  struct
    module IDX = Index.Index(B)
    module Unif = FoUnif.Founif(B)
    module Subst = FoSubst.Subst(B)
    module Order = Orderings.Orderings(B)
    module Utils = FoUtils.Utils(B)
    module Pp = Pp.Pp(B)

    let rec list_first f = function
      | [] -> None
      | x::tl -> match f x with Some _ as x -> x | _ -> list_first f tl
    ;;

    let first_position pos ctx t f =
      let rec aux pos ctx = function
      | Terms.Leaf _ as t -> f t pos ctx 
      | Terms.Var _ -> None
      | Terms.Node l as t-> 
          match f t pos ctx with
          | Some _ as x -> x
          | None ->
              let rec first pre post = function
                | [] -> None
                | t :: tl -> 
                     let newctx = fun x -> ctx (Terms.Node (pre@[x]@post)) in
                     match aux (List.length pre :: pos) newctx t with
                     | Some _ as x -> x
                     | None -> 
                         if post = [] then None (* tl is also empty *)
                         else first (pre @ [t]) (List.tl post) tl
              in
                first [] (List.tl l) l 
      in
        aux pos ctx t
    ;;
                                     
    let all_positions pos ctx t f =
      let rec aux pos ctx = function
      | Terms.Leaf _ as t -> f t pos ctx 
      | Terms.Var _ -> []
      | Terms.Node l as t-> 
          let acc, _, _ = 
            List.fold_left
            (fun (acc,pre,post) t -> (* Invariant: pre @ [t] @ post = l *)
                let newctx = fun x -> ctx (Terms.Node (pre@[x]@post)) in
                let acc = aux (List.length pre :: pos) newctx t @ acc in
                if post = [] then acc, l, []
                else acc, pre @ [t], List.tl post)
             (f t pos ctx, [], List.tl l) l
          in
           acc
      in
        aux pos ctx t
    ;;
    
    let build_clause bag filter rule t subst vl id id2 pos dir =
      let proof = Terms.Step(rule,id,id2,dir,pos,subst) in
      let t = Subst.apply_subst subst t in
      if filter t then
        let literal = 
          match t with
          | Terms.Node [ Terms.Leaf eq ; ty; l; r ] when B.eq B.eqP eq ->
               let o = Order.compare_terms l r in
               Terms.Equation (l, r, ty, o)
          | t -> Terms.Predicate t
        in
        let bag, uc = 
          Utils.add_to_bag bag (0, literal, vl, proof)
        in
        Some (bag, uc)
      else
        ((*prerr_endline ("Filtering: " ^ Pp.pp_foterm t);*)None)
    ;;
      
    
    (* ============ simplification ================= *)

    let demod table varlist subterm pos context =
      let cands = IDX.DT.retrieve_generalizations table subterm in
      list_first
        (fun (dir, (id,lit,vl,_)) ->
           match lit with
           | Terms.Predicate _ -> assert false
           | Terms.Equation (l,r,_,o) ->
               let side, newside = if dir=Terms.Left2Right then l,r else r,l in
               try 
                 let subst, varlist = 
                   Unif.unification (varlist@vl) varlist subterm side 
                 in
                 if o = Terms.Incomparable then
                   let side = Subst.apply_subst subst side in
                   let newside = Subst.apply_subst subst newside in
                   let o = Order.compare_terms side newside in
                   (* Riazanov, pp. 45 (ii) *)
                   if o = Terms.Lt then  
                     Some (context newside, subst, varlist, id, pos, dir)
                   else 
                     ((*prerr_endline ("Filtering: " ^ 
                        Pp.pp_foterm side ^ " =(< || =)" ^ 
                        Pp.pp_foterm newside ^ " coming from " ^ 
                        Pp.pp_unit_clause uc );*)None)
                 else
                   Some (context newside, subst, varlist, id, pos, dir)
               with FoUnif.UnificationFailure _ -> None)
        (IDX.ClauseSet.elements cands)
    ;;

    (* XXX: possible optimization, if the literal has a "side" already
     * in normal form we should not traverse it again *)
    let demodulate_once bag (id, literal, vl, _) table =
      let t = 
        match literal with
        | Terms.Predicate t -> t
        | Terms.Equation (l,r,ty,_) -> Terms.Node [ Terms.Leaf B.eqP; ty; l; r ]
      in
      match first_position [] (fun x -> x) t (demod table vl) with
      | None -> None
      | Some (newt, subst, varlist, id2, pos, dir) ->
          build_clause bag (fun _ -> true) Terms.Demodulation 
            newt subst varlist id id2 pos dir
    ;;

    let rec demodulate bag clause table =
      match demodulate_once bag clause table with
      | None -> bag, clause
      | Some (bag, clause) -> demodulate bag clause table
    ;;

    (* move away *)
    let is_identity_clause = function
      | _, Terms.Equation (_,_,_,Terms.Eq), _, _ -> true
      | _, Terms.Predicate _, _, _ -> assert false
      | _ -> false
    ;;

    let is_subsumed (id, lit, vl, _) table =
      match lit with
      | Terms.Predicate _ -> assert false
      | Terms.Equation (l,r,ty,_) -> 
          let lcands = IDX.DT.retrieve_generalizations table l in
          let rcands = IDX.DT.retrieve_generalizations table l in
          let f b c = 
            let dir, l, r, vl = 
              match c with
              | (d, (_,Terms.Equation (l,r,ty,_),vl,_))-> d, l, r, vl
              |_ -> assert false 
            in 
            let l, r = if (dir = Terms.Left2Right) = b then l,r else r,l in
            Terms.Node [ Terms.Leaf B.eqP; ty; l; r ], vl
          in
          let cands1 = List.map (f true) (IDX.ClauseSet.elements lcands) in
          let cands2 = List.map (f false) (IDX.ClauseSet.elements rcands) in
          let t = Terms.Node [ Terms.Leaf B.eqP; ty; l; r ] in
          List.exists 
            (fun (c, vl1) ->
               try ignore(Unif.unification (vl@vl1) vl c t); true
               with FoUnif.UnificationFailure _ -> false)
            (cands1 @ cands2)
    ;;

    (* demodulate and check for subsumption *)
    let forward_simplify table bag clause = 
      let bag, clause = demodulate bag clause table in
      if is_identity_clause clause then None
      else
        if is_subsumed clause table then None
        else Some (bag, clause)
    ;;

    (* =================== inference ===================== *)

    let superposition_right table varlist subterm pos context =
      let cands = IDX.DT.retrieve_unifiables table subterm in
      HExtlib.filter_map
        (fun (dir, (id,lit,vl,_ (*as uc*))) ->
           match lit with
           | Terms.Predicate _ -> assert false
           | Terms.Equation (l,r,_,o) ->
               let side, newside = if dir=Terms.Left2Right then l,r else r,l in
               try 
                 let subst, varlist = 
                   Unif.unification (varlist@vl) [] subterm side 
                 in
                 if o = Terms.Incomparable then
                   let side = Subst.apply_subst subst side in
                   let newside = Subst.apply_subst subst newside in
                   let o = Order.compare_terms side newside in
                   (* XXX: check Riazanov p. 33 (iii) *)
                   if o <> Terms.Lt && o <> Terms.Eq then  
                     Some (context newside, subst, varlist, id, pos, dir)
                   else 
                     ((*prerr_endline ("Filtering: " ^ 
                        Pp.pp_foterm side ^ " =(< || =)" ^ 
                        Pp.pp_foterm newside ^ " coming from " ^ 
                        Pp.pp_unit_clause uc );*)None)
                 else
                   Some (context newside, subst, varlist, id, pos, dir)
               with FoUnif.UnificationFailure _ -> None)
        (IDX.ClauseSet.elements cands)
    ;;

    let build_new_clause bag maxvar filter rule t subst vl id id2 pos dir =
      let maxvar, vl, relocsubst = Utils.relocate maxvar vl in
      let subst = Subst.concat relocsubst subst in
      match build_clause bag filter rule t subst vl id id2 pos dir with
      | Some (bag, c) -> Some ((bag, maxvar), c)
      | None -> None
    ;;


    let fold_build_new_clause bag maxvar id rule filter res =
      let (bag, maxvar), res =
       HExtlib.filter_map_acc 
         (fun (bag, maxvar) (t,subst,vl,id2,pos,dir) ->
            build_new_clause bag maxvar filter rule t subst vl id id2 pos dir)
         (bag, maxvar) res
      in
       bag, maxvar, res
    ;;

    let superposition_right_with_table bag maxvar (id,selected,vl,_) table =
      match selected with 
      | Terms.Predicate _ -> assert false
      | Terms.Equation (l,r,ty,Terms.Lt) ->
          fold_build_new_clause bag maxvar id Terms.SuperpositionRight 
            (fun _ -> true)
            (all_positions [3] 
              (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; l; x ])
              r (superposition_right table vl))          
      | Terms.Equation (l,r,ty,Terms.Gt) ->
          fold_build_new_clause bag maxvar id Terms.SuperpositionRight
            (fun _ -> true)
            (all_positions [2] 
              (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; x; r ])
              l (superposition_right table vl))
      | Terms.Equation (l,r,ty,Terms.Incomparable) -> 
          fold_build_new_clause bag maxvar id Terms.SuperpositionRight
            (function (* Riazanov: p.33 condition (iv) *)
              | Terms.Node [Terms.Leaf eq; ty; l; r ] when B.eq B.eqP eq -> 
                  Order.compare_terms l r <> Terms.Eq
              | _ -> assert false)
            ((all_positions [3] 
               (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; l; x ])
               r (superposition_right table vl)) @         
             (all_positions [2] 
               (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; x; r ])
               l (superposition_right table vl)))
      | _ -> assert false
    ;;

    (* the current equation is normal w.r.t. demodulation with atable
     * (and is not the identity) *)
    let infer_right bag maxvar current (alist,atable) = 
      let ctable = IDX.index_unit_clause IDX.DT.empty current in
      let bag, maxvar, new_clauses =
        List.fold_left 
          (fun (bag, maxvar, acc) active ->
             let bag, maxvar, newc = 
               superposition_right_with_table bag maxvar active ctable 
             in
             bag, maxvar, newc @ acc)
          (bag, maxvar, []) alist
      in
      let alist, atable = 
        current :: alist, IDX.index_unit_clause atable current
      in
      let fresh_current, maxvar = Utils.fresh_unit_clause maxvar current in
      let bag, maxvar, additional_new_clauses =
        superposition_right_with_table bag maxvar fresh_current atable 
      in
      let new_clauses = new_clauses @ additional_new_clauses in
      let bag, new_clauses = 
        HExtlib.filter_map_acc (forward_simplify atable) bag new_clauses
      in
      bag, maxvar, (alist, atable), new_clauses
    ;;

  end