(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.      
     \ /   This software is distributed as is, NO WARRANTY.     
      V_______________________________________________________________ *)

(* $Id$ *)

type 'a foterm = 
  | Leaf of 'a
  | Var of int
  | Node of ('a foterm) list

type 'a substitution = (int * 'a foterm) list

type comparison = Lt | Eq | Gt | Incomparable

type rule = SuperpositionRight | SuperpositionLeft | Demodulation
type direction = Left2Right | Right2Left | Nodir
type position = int list

type 'a proof =
  | Exact of 'a
  | Step of rule * int * int * direction * position * 'a substitution
         (* rule, eq1, eq2, direction of eq2, position, substitution *)

type 'a literal = 
 | Equation of    'a foterm  (* lhs *)
                * 'a foterm  (* rhs *)
                * 'a foterm  (* type *)
                * comparison (* orientation *)
 | Predicate of   'a foterm 

type varlist = int list

type 'a unit_clause =
   int        (* ID *)
 * 'a literal
 * varlist       (* variable list *)
 * 'a proof      (* proof *)

type 'a passive_clause = int * 'a unit_clause (* weight * equation *)


module OT =
 struct
   type t = int 
   let compare = Pervasives.compare
 end

module M : Map.S with type key = int 
  = Map.Make(OT) 

type 'a bag = 'a unit_clause M.t

module type Blob =
  sig
    type t
    val eq : t -> t -> bool
    val compare : t -> t -> int
    val pp : t -> string
  end

module Utils (B : Blob) = struct
  let rec eq_foterm x y =
    x == y ||
    match x, y with
    | Leaf t1, Leaf t2 -> B.eq t1 t2
    | Var i, Var j -> i = j
    | Node l1, Node l2 -> List.for_all2 eq_foterm l1 l2
    | _ -> false
  ;;

  let rec lexicograph f l1 l2 =
    match l1, l2 with
    | [], [] -> 0
    | x::xs, y::ys ->
       let c = f x y in
       if c <> 0 then c else lexicograph f xs ys
    | [],_ -> ~-1
    | _,[] -> 1
  ;;

  let rec compare_foterm x y =
    match x, y with
    | Leaf t1, Leaf t2 -> B.compare t1 t2
    | Var i, Var j -> i - j
    | Node l1, Node l2 -> lexicograph compare_foterm l1 l2
    | Leaf _, ( Node _ | Var _ ) -> ~-1
    | Node _, Leaf _ -> 1
    | Node _, Var _ -> ~-1
    | Var _, _ ->  1
  ;;

  let eq_literal l1 l2 =
    match l1, l2 with
    | Predicate p1, Predicate p2 -> eq_foterm p1 p2
    | Equation (l1,r1,ty1,o1), Equation (l2,r2,ty2,o2) ->
        o1 = o2 && eq_foterm l1 l2 && eq_foterm r1 r2 && eq_foterm ty1 ty2
    | _ -> false
  ;;

  let compare_literal l1 l2 =
    match l1, l2 with
    | Predicate p1, Predicate p2 -> compare_foterm p1 p2
    | Equation (l1,r1,ty1,o1), Equation (l2,r2,ty2,o2) ->
        let c = Pervasives.compare o1 o2 in
        if c <> 0 then c else
          let c = compare_foterm l1 l2 in
          if c <> 0 then c else
            let c = compare_foterm r1 r2 in
            if c <> 0 then c else
              compare_foterm ty1 ty2
    | Predicate _, Equation _ -> ~-1
    | Equation _, Predicate _ -> 1
  ;;

  let eq_unit_clause (id1,_,_,_) (id2,_,_,_) = id1 = id2
  let compare_unit_clause (id1,_,_,_) (id2,_,_,_) = Pervasives.compare id1 id2

end